[JASS] Mana reduce upon movment

[GhostWolf]

I tried making this code that reduces the mana of any mechanical unit on the map that is moving... it isn't working lol.

I can only guess its because I don't know how to use unit groups... lol.

Here's the code

// This will reduce the mana of any mechanical unit on the map upon moving.
// The actual value is the distance that unit moves within 0.2 seconds.
// If you want to change that value, see the comment in 13 lines.

function mechanicCon takes nothing returns boolean
    return IsUnitType(GetEnumUnit(),UNIT_TYPE_MECHANICAL)    
endfunction
function mecahnictimer takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local unit whichUnit = GetHandleUnit(t, "whichUnit")
    local real x = GetHandleReal(t, "x")
    local real y = GetHandleReal(t, "y")
    local real newx = GetUnitX(whichUnit)
    local real newy = GetUnitY(whichUnit)
    local real distance = DistanceBetweenPointsXY(x, y, newx, newy)
    local real mana = GetUnitStatePercent(whichUnit, UNIT_STATE_MANA, UNIT_STATE_MAX_MANA)
    call SetUnitState(whichUnit, UNIT_STATE_MANA, mana-distance) // if you want to reduce or raise the value, just make it something like "mana-distance*20" or "mana-distance/20"
    call FlushHandleLocals(t)
    call DestroyTimer(t) 
    set t = null
    set whichUnit = null
endfunction
function mechanic takes nothing returns nothing
    local timer t = CreateTimer()
    local group g = CreateGroup()
    local unit whichUnit
    local real x
    local real y
    call GroupEnumUnitsInRect(g, bj_mapInitialPlayableArea, Condition(function mechanicCon)) 
    loop
        set whichUnit = FirstOfGroup(g)
        exitwhen whichUnit == null
        call GroupRemoveUnit(g, whichUnit)
        set x = GetUnitX(whichUnit)
        set y = GetUnitY(whichUnit)
        call SetHandleReal(t, "x", x)
        call SetHandleReal(t, "y", y)
        call SetHandleHandle(t, "whichUnit", whichUnit)
        call TimerStart(t, 0.2, true, function mecahnictimer)
    endloop
    set t = null
    call DestroyGroup(g)
    set g = null
    set whichUnit = null 
endfunction

//==== Init Trigger NewTrigger ====
function InitTrig_NewTrigger takes nothing returns nothing
    set gg_trg_NewTrigger = CreateTrigger()
    call TriggerRegisterTimerEventPeriodic( gg_trg_NewTrigger, 0.20 )
    call TriggerAddAction(gg_trg_NewTrigger, function mechanic)
endfunction

 

[wd40bomber7]

When using a condition/filter function you need to use

GetFilterUnit() //This is used inside a condition func.

instead of

GetEnumUnit() //This is used during a ForGroup

 

[GhostWolf]

Ok thanks, I really wonderd about the value that needs to be put there.

The problem still occurs though (can hardly call it a problem... it doesn't work at all ).

 

[Gallin]

so its still not working : ( i really would like this

 

[PurplePoot]

Try adding ==true to the end of the condition. Don't ask why, just do it . (If it doesn't work then you can remove it)

Also, you're using one timer for all the units, which means it will only work for the last unit! You should recreate the timer within the loop.

Also also, you'll want to set the fact that the timer created within the loop is periodic to false since you destroy it anyways.

Also also also, inline the "x" and "y" variables in "mechanic", there is no reason to have them as variables (just a longer script!)

Also also also also, TriggerRegisterTimerEventPeriodic is a BJ

Also also also also also, inline "newx", "newy", "x", and "y" in "mechanictimer".

Also also also also also also, remember to edit your post and update your code when you make changes

(The also also thing is from Monty Python and the Holy Grail, if you haven't seen it)

 

[GhostWolf]

Ok it works now, thanks Purple !

Try adding ==true to the end of the condition. Don't ask why, just do it . (If it doesn't work then you can remove it)

Seems like I didn't didn't to do that since anyway it returns true/false.

Also, you're using one timer for all the units, which means it will only work for the last unit! You should recreate the timer within the loop.

This fixed it, thanks

Also also, you'll want to set the fact that the timer created within the loop is periodic to false since you destroy it anyways.

You were too late, done that before you commented (although I never said I did lol).

Also also also, inline the "x" and "y" variables in "mechanic", there is no reason to have them as variables (just a longer script!)

Didn't get what you are saying...

Also also also also, TriggerRegisterTimerEventPeriodic is a BJ

And... ?

Also also also also also, inline "newx", "newy", "x", and "y" in "mechanictimer".

Again didn't get what you are trying to say.

(The also also thing is from Monty Python and the Holy Grail, if you haven't seen it)

Nope haven't seen that.


Now a new question, why would moving about... 20 range or so remove like 180 mana ?
I could just do something like reduceValue/number but im still wondering about it.

And another question, using a Wait wouldn't work here because not like timers it stops the code from working... right ? (Well the true question is - timers don't stop the code from working, right ? ^^)

Here is the new code

// This will reduce the mana of any mechanical unit on the map upon moving.
// The actual value is the distance that unit moves within 0.2 seconds.
// If you want to change that value, see the comment in 13 lines.

function mechanicCon takes nothing returns boolean
    return IsUnitType(GetFilterUnit(),UNIT_TYPE_MECHANICAL)    
endfunction
function mecahnictimer takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local unit whichUnit = GetHandleUnit(t, "whichUnit")
    local real x = GetHandleReal(t, "x")
    local real y = GetHandleReal(t, "y")
    local real newx = GetUnitX(whichUnit)
    local real newy = GetUnitY(whichUnit)
    local real distance = DistanceBetweenPointsXY(x, y, newx, newy)
    local real mana = GetUnitStatePercent(whichUnit, UNIT_STATE_MANA, UNIT_STATE_MAX_MANA)
    if distance > 0 then
        call SetUnitState(whichUnit, UNIT_STATE_MANA, mana-distance) // if you want to reduce or raise the value, just make it something like "mana-distance*20" or "mana-distance/20"
    endif
    call FlushHandleLocals(t)
    call DestroyTimer(t) 
    set t = null
    set whichUnit = null
endfunction
function mechanic takes nothing returns nothing
    local timer t = CreateTimer()
    local group g = CreateGroup()
    local unit whichUnit
    local real x
    local real y
    call GroupEnumUnitsInRect(g, bj_mapInitialPlayableArea, Condition(function mechanicCon)) 
    loop
        set whichUnit = FirstOfGroup(g)
        exitwhen whichUnit == null
        call GroupRemoveUnit(g, whichUnit)
        set t = null
        set t = CreateTimer()
        set x = GetUnitX(whichUnit)
        set y = GetUnitY(whichUnit)
        call SetHandleReal(t, "x", x)
        call SetHandleReal(t, "y", y)
        call SetHandleHandle(t, "whichUnit", whichUnit)
        call TimerStart(t, 0.2, false, function mecahnictimer)
    endloop
    set t = null
    call DestroyGroup(g)
    set g = null
    set whichUnit = null 
endfunction

//==== Init Trigger NewTrigger ====
function InitTrig_NewTrigger takes nothing returns nothing
    set gg_trg_NewTrigger = CreateTrigger()
    call TriggerRegisterTimerEventPeriodic( gg_trg_NewTrigger, 0.20 )
    call TriggerAddAction(gg_trg_NewTrigger, function mechanic)
endfunction

 

[GhostWolf]

Ok, it doesn't work... lol.

It takes about 400 mana for a range of 20 or so.
I tried making it mana-distace/100, it still takes around 400 for some reason...

It also took mana when the distance was 0 (the unit didn't move) for some unknown reason so I added that condition (distance > 0).

Here's the new code

// This will reduce the mana of any mechanical unit on the map upon moving.
// The actual value is the distance that unit moves within 0.2 seconds.
// If you want to change that value, see the comment in 13 lines.

function mechanicCon takes nothing returns boolean
    return IsUnitType(GetFilterUnit(),UNIT_TYPE_MECHANICAL)    
endfunction
function mecahnictimer takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local unit whichUnit = GetHandleUnit(t, "whichUnit")
    local real x = GetHandleReal(t, "x")
    local real y = GetHandleReal(t, "y")
    local real distance = DistanceBetweenPointsXY(x, y, GetUnitX(whichUnit), GetUnitY(whichUnit))
    local real mana = GetUnitStatePercent(whichUnit, UNIT_STATE_MANA, UNIT_STATE_MAX_MANA)
    if distance > 0 then
        call SetUnitState(whichUnit, UNIT_STATE_MANA, mana-distance) // if you want to reduce or raise the value, just make it something like "mana-distance*20" or "mana-distance/20"
    endif
    call FlushHandleLocals(t)
    call DestroyTimer(t) 
    set t = null
    set whichUnit = null
endfunction
function mechanic takes nothing returns nothing
    local timer t = CreateTimer()
    local group g = CreateGroup()
    local unit whichUnit
    local real x
    local real y
    call GroupEnumUnitsInRect(g, bj_mapInitialPlayableArea, Condition(function mechanicCon)) 
    loop
        set t = null
        set whichUnit = FirstOfGroup(g)
        exitwhen whichUnit == null
        call GroupRemoveUnit(g, whichUnit)
        set t = CreateTimer()
        call SetHandleReal(t, "x", GetUnitX(whichUnit))
        call SetHandleReal(t, "y", GetUnitY(whichUnit))
        call SetHandleHandle(t, "whichUnit", whichUnit)
        call TimerStart(t, 0.2, false, function mecahnictimer)
    endloop
    call DestroyGroup(g)
    set g = null
    set whichUnit = null 
endfunction

//==== Init Trigger NewTrigger ====
function InitTrig_NewTrigger takes nothing returns nothing
    set gg_trg_NewTrigger = CreateTrigger()
    call TriggerRegisterTimerEventPeriodic( gg_trg_NewTrigger, 0.20 )
    call TriggerAddAction(gg_trg_NewTrigger, function mechanic)
endfunction

 

[GhostWolf]

(sorry for spamming)

Ok I fixed it, instead of using that stupid precent I just got the mana value (thats basicly what I wanted from the start, I didn't know the command for it though lol).

Works now perfectly !

 

[PurplePoot]

Seems like I didn't didn't to do that since anyway it returns true/false.

It's a bug with IsUnitType with certain types - if it is the last boolean in a boolexpr, it may return false even if it should return true, unless it is compared to ==true.

 

[GhostWolf]

Ok so I should change it to "return IsUnitType(GetFilterUnit(),UNIT_TYPE_MECHANICAL) == true", right ?

It does make sense why it would work (false=true - false, true=true - true) but I didn't really get why it is needed but whatever.

 

[PurplePoot]

No, if it works already it's fine.

It has to do with the fact that booleans are 4-byte in warcraft, and are not always equal to 1 or 0. Apparently == and the lack thereof compare it differently (where == assumes 0 = false, and otherwise assumes 1 = true). I haven't looked too much into the explanation, but it's something along those lines.