Jass Multiboard unique to each player

[bobmanone]

Hello, I am having an issue getting a multiboard working so that each player has a unique multiboard. The multiboard for player 1 loads, then when I have the one load for player 2, the multiboard for player 1 disappears. I have tested this as player 2, and that multiboard does appear after 10 seconds.

Multiboard code

• Quest Multiboard Copy
  • Events
    • Time - Elapsed game time is 0.01 seconds
  • Conditions
  • Actions
    • Set VariableSet unit[0] = "working"
    • Set VariableSet unit[1] = not working
    • Multiboard - Create a multiboard with 2 columns and 2 rows, titled Test.
    • Set VariableSet QuestMultiboard_P1 = (Last created multiboard)
    • Multiboard - Hide QuestMultiboard_P1
    • Multiboard - Set the display style for QuestMultiboard_P1 item in column 1, row 1 to Show text and Hide icons
    • Multiboard - Set the text for QuestMultiboard_P1 item in column 1, row 1 to unit[0]
    • Multiboard - Create a multiboard with 2 columns and 2 rows, titled Test.
    • Set VariableSet QuestMultiboard_P2 = (Last created multiboard)
    • Multiboard - Hide QuestMultiboard_P2
    • Multiboard - Set the display style for QuestMultiboard_P2 item in column 1, row 1 to Show text and Hide icons
    • Multiboard - Set the text for QuestMultiboard_P2 item in column 1, row 1 to unit[1]

Player 1 Multiboard code

function Trig_Show_for_player_1_Copy_Actions takes nothing returns nothing
    local boolean show = false
    if ( GetLocalPlayer() == Player(0) ) then
         set show = true
    endif
    call MultiboardDisplay(udg_QuestMultiboard_P1,show)
endfunction

//===========================================================================
function InitTrig_Show_for_player_1_Copy takes nothing returns nothing
    set gg_trg_Show_for_player_1_Copy = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_Show_for_player_1_Copy, 5 )
    call TriggerAddAction( gg_trg_Show_for_player_1_Copy, function Trig_Show_for_player_1_Copy_Actions )
endfunction

Player 2 Multiboard code

function Trig_Show_for_player_2_Copy_Actions takes nothing returns nothing
    local boolean show = false
    if ( GetLocalPlayer() == Player(1) ) then
         set show = true
    endif
    call MultiboardDisplay(udg_QuestMultiboard_P2,show)
endfunction

//===========================================================================
function InitTrig_Show_for_player_2_Copy takes nothing returns nothing
    set gg_trg_Show_for_player_2_Copy = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_Show_for_player_2_Copy, 10 )
    call TriggerAddAction( gg_trg_Show_for_player_2_Copy, function Trig_Show_for_player_2_Copy_Actions )
endfunction

 

[Wrda]

Probably the MultiboardDisplay function should be inside the local player block not outside.
Possibly the boolean is unnecessary.

 

[PurgeandFire]

+1 to what Wrda said. It should be safe to use MultiboardDisplay for a single player (locally). I'm guessing if you call that function globally, it might do some weird side-effects that cause the current multiboard to disappear.

Here's how you'd adjust your triggers:

function Trig_Show_for_player_1_Copy_Actions takes nothing returns nothing
    if ( GetLocalPlayer() == Player(0) ) then
        call MultiboardDisplay(udg_QuestMultiboard_P1, true)
    endif
endfunction

//===========================================================================
function InitTrig_Show_for_player_1_Copy takes nothing returns nothing
    set gg_trg_Show_for_player_1_Copy = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_Show_for_player_1_Copy, 5 )
    call TriggerAddAction( gg_trg_Show_for_player_1_Copy, function Trig_Show_for_player_1_Copy_Actions )
endfunction

function Trig_Show_for_player_2_Copy_Actions takes nothing returns nothing
    if ( GetLocalPlayer() == Player(1) ) then
        call MultiboardDisplay(udg_QuestMultiboard_P2, true)
    endif
endfunction

//===========================================================================
function InitTrig_Show_for_player_2_Copy takes nothing returns nothing
    set gg_trg_Show_for_player_2_Copy = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_Show_for_player_2_Copy, 10 )
    call TriggerAddAction( gg_trg_Show_for_player_2_Copy, function Trig_Show_for_player_2_Copy_Actions )
endfunction