[JASS] IsUnitType Issue

[Mr_Bean]

Hello,

I am making spells and I have come across an issue. When you Explode a unit in GUI and then run the check IsUnitType(whichUnit, UNIT_TYPE_DEAD), it returns false (as if the unit is alive!). How can i fix this? It will cause lots of spells to bug

Thanks!

 

[overcold_ice]

well . . . maybe this is the solution . . .

IsUnitType(whichUnit, UNIT_TYPE_DEAD) and whichUnit != null

other than this, i don't know . . . .
it seems that exploding units is removed . . .

 

[Mr_Bean]

It is strange. The GUI function looks like this:

function ExplodeUnitBJ takes unit whichUnit returns nothing
    call SetUnitExploded(whichUnit, true)
    call KillUnit(whichUnit)
endfunction

I will try your suggestion and let you know.

 

[overcold_ice]

then, it can be the native that bug . . . .

on KillUnit(whicUnit)
before it gets killed normally, it checks whether the unit explode on dead or not . .
if it's true, then remove the unit and play the unit's 'Art - Special' special effect . . .
otherwise, kill it normally . . .

i'm just guessing :3

 

[Magtheridon96]

WTF.
Good Job Blizzard.

I'm going to test this more and come up with a solution.

edit

There's no problem.

struct Test extends array

    private static unit tester = null

    private static method print takes string s returns nothing
        call DisplayTimedTextToPlayer(GetLocalPlayer(), 0, 0, 60, s)
    endmethod
    
    private static method explode takes nothing returns nothing
        call SetUnitExploded(tester, true)
        call KillUnit(tester)
        if IsUnitType(tester, UNIT_TYPE_DEAD) then
            call print("Unit is Dead")
        else
            call print("Unit is Alive")
        endif
        call print(R2S(GetWidgetLife(tester)))
    endmethod


    private static method onInit takes nothing returns nothing
        set tester = CreateUnit(Player(0), 'hpea', 512, 512, 270)
        call TimerStart(CreateTimer(), 4, false, function thistype.explode)
    endmethod
    
endstruct

This displays:

Unit is Dead
0.000

Maybe you're checking for the wrong unit.

 

[Mr_Bean]

Hmmm, strange. I definitely do check the correct unit. I will recheck my code to make sure...

Also, please explain what extends array means (in simple terms). Thanks!

 

[Berb]

extends array makes the struct completely dependent on the user for setup and everything. The situations where it is useful is for having structs for things that there are only a constant amount of, such as players.

These guys use it nowadays to declare their own constructor algorithms which is really just a waste of time because they really don't save themselves anything. I don't suggest using it where it isn't necessary (like has been done above).

 

[Bribe]

Mr_Bean987,

Berb had this problem in the Projectile library, where he was only using IsUnitType, UNIT_TYPE_DEAD.

Here's the thing:

If you do this: IsUnitType(null, UNIT_TYPE_DEAD), it will return FALSE.

It would have been smarter for Blizzard to create UNIT_TYPE_ALIVE instead of UNIT_TYPE_DEAD, but hey, hindsight is 20/20 and we were not on the dev team.

Therefore, you also need the check "GetUnitTypeId(unit) != 0". This will check if the unit has been removed.

The correct method for checking if a unit is alive is this: not IsUnitType(unit, UNIT_TYPE_DEAD) and GetUnitTypeId(unit) != 0

unit == null will not work because remember, handles are smart pointers so they remember the handle ID, which is why you need to null unused variables. unit == null will only work if the unit variable was never pointing to a unit or was previously nulled.

 

[Magtheridon96]

Why wouldn't I use extends array here? I'm not even using allocate or deallocate >_>

 

[Berb]

Well to be honest why are you using a struct period? You've got a global and a bunch of functions.

scope SameThing initializer onInit

    globals
        private unit tester = null
    endglobals
        
        
    private function print takes string s returns nothing
        call DisplayTimedTextToPlayer(GetLocalPlayer(), 0, 0, 60, s)
    endmethod
    
    private function explode takes nothing returns nothing
        call SetUnitExploded(tester, true)
        call KillUnit(tester)
        if IsUnitType(tester, UNIT_TYPE_DEAD) then
            call print("Unit is Dead")
        else
            call print("Unit is Alive")
        endif
        call print(R2S(GetWidgetLife(tester)))
    endmethod


    private function onInit takes nothing returns nothing
        set tester = CreateUnit(Player(0), 'hpea', 512, 512, 270)
        call TimerStart(CreateTimer(), 4, false, function thistype.explode)
    endmethod

endscope

There's no reason to use more complicated syntax structure than required. Look, you already confused one person. For what?

 

[Mr_Bean]

Look, you already confused one person. For what?

I'm not confused, I've just been wondering what extends array means. I've seen it a few times but have never known what it means. I understand the rest of the code that Mag posted.

 

[Troll-Brain]

Random notes :

For debug messages, BJDebugMsg is enough (unless you want the text display for more than 60 s, which can happens sometimes with long and/or complicated debug messages).
However, the chatbox is your friend.

Aslo i would use DisplayTextFromPlayer instead of DisplayTextToPlayer, with a valid player, because GetLocalPlayer bugs with replays (always return the first human player, even if that's not that easy i'm too lazy for more explanations about it), and DisplayTextFromPlayer displays for all players, until the player argument is a valid one.

 

[Berb]

I'm not confused, I've just been wondering what extends array means. I've seen it a few times but have never known what it means. I understand the rest of the code that Mag posted.

I'm willing to bet that you would be smart enough to figure out what it means if it was being used properly. It quite literally means that the struct extends the functionality of an array.

Rather than having:

struct Example
    static integer array someDataElement
endstruct
...
    set Example.someDataElement[0] = 5

You would have:

struct Example extends array
    int someDataElement
endstruct
...
    set Example[0].someDataElement = 5

Functions the exact same. Instead of having the array index on the "someDataElement" though you put it on the struct type, identifying that type as an array.

 

[Dr Super Good]

I could have sworn that DEAD unit type refers to the unit being undead... Guess I must have been mistaken.

This is why people test the unit's life and also import the AI native test for death.

 

[Berb]

constant unittype UNIT_TYPE_UNDEAD=ConvertUnitType(14)
constant unittype UNIT_TYPE_DEAD=ConvertUnitType(1)

 

[Troll-Brain]

The problem with checking life is that you can have a dead unit with more than 0.405, and not only by trigger actions, with some native abilities also.
Honestly i think we should have a native IsUnitAlive with a boolean argument which cares or not about units being resurrected.
I'm not saying it exists, and we can already have something like that using the undefend "hack".

Someone knows how the AI unit alive handles units which are being resurrected ?

 

[Bribe]

There is an IsUnitAlive utility that I added in Unit Event (GUI, in the spells section).

It functions the exact same as the UnitAlive native.

UnitAlive returns false if the unit is in the middle of resurrection.

 

[Magtheridon96]

I only used the struct because it's faster for me to type it out.
I also use it because I like how it gives me the freedom to declare globals without using globals blocks (Reminding me of C++, and when I code C++, I'm happy :>)

I'd use scopes or libraries, but that wouldn't change a thing

 

[Troll-Brain]

If verbosity was the issue, for test code "extends array" is not needed, BJDebugMsg was also fine.
I mean, i don't care about it, but you're lying to yourself ^^

 

[moyackx]

just wondering... haven't you tested this: IsUnitType(whichUnit, UNIT_TYPE_DEAD) == true

Remember that this function generates weird values.

 

[Berb]

Are you saying it gives values other than true or false?

 

[moyackx]

Are you saying it gives values other than true or false?

Yes... something like this: http://www.wc3jass.com/viewtopic.php?t=2370

It seems it hasn't been fixed since that time. So in order to be completely sure about IsUnitType behavior, you should do this double test.

 

[mckill2009]

I've just been wondering what extends array means

its all in the JassHelper...a simple explanation is that you can use other struct's members...

struct A
   string shit
endstruct

struct B extends A
   static method create takes nothing returns thistype
      local thistype this = thistype.allocate()
      set .shit = "i shit on my pants" //can use
      return this
   endmethod
endstruct

other than that, I dunu why people made custom allocators as it consumes space, although its more efficient than the normal allocator...

I've used UNIT_TYPE_DEAD many times and it does not bugg, well, never tested it like mag does...

 

[Berb]

I don't think that is an issue here because he isn't using it in a boolean expression, he's using it in an if-statement. The issue explained by Vexorian was only the result of how boolean expressions evaluated the integer 64 typecasted to a boolean value.

 

[Bribe]

http://www.hiveworkshop.com/forums/...s-277/new-script-optimizer-204497/index3.html

Scroll down to post 44.

The IsUnitType bug only occurs with UNIT_TYPE_TOWNHALL, and the other types have (in patch 1.26) successfully been tested to not cause any errors.

You guys are more than welcome to re-confirm these findings.