[Spell] How to move a unit (dummy), like projection in a missile

[Regno]

Whats the function to use to move my dummy unit from caster to target? The ability work essentially like Shockwave

The moving itself will be in a loop, every 0.03s

 

[Lordul Dracula]

Hmmm, issue order - the last created unit to move to target of the ability

 

[Regno]

Hmmm, issue order - the last created unit to move to target of the ability

Will this make the unit "walk" to the target? Essentially I want to "teleport" the unit every 0.03s to the target, so it will look like a missile

 

[Lordul Dracula]

Try this and tell me if is workin, if will not work then i will try to make this for you in 3h

 

[Bloodheaven_]

Here is a short Trigger that works how you described it, atleast I think so

Spoiler: Variables & Unit

Point = Temp_Point
Point = Temp_Point2
Unit = Temp_Unit
Unit Group = Temp_Group
Unit Group = Shockwave_Group

--Create Unit named Shockwave (Dummy)--
--Create Ability named Shockwave--

Spoiler: Shockwave Cast

• Shockwave Cast
  • Events
    • Unit - A unit Starts the effect of an ability
  • Conditions
    • (Ability being cast) Equal to Shockwave Dummy
  • Actions
    • Set VariableSet Temp_Point = (Target point of ability being cast)
    • Set VariableSet Temp_Point2 = (Position of (Triggering unit))
    • Unit - Create 1 Shockwave (Dummy) for Neutral Passive at Temp_Point2 facing (Angle from Temp_Point2 to Temp_Point) degrees
    • Unit - Move (Last created unit) instantly to Temp_Point2, facing Temp_Point
    • Custom script: call UnitAddAbilityBJ( 'Aloc', GetLastCreatedUnit() )
    • Unit - Change ownership of (Last created unit) to (Owner of (Triggering unit)) and Retain color
    • Unit - Add a 2.00 second Generic expiration timer to (Last created unit)
    • Unit Group - Add (Last created unit) to Shockwave_Group
    • Trigger - Turn on Shockwave Group <gen>
    • Custom script: call RemoveLocation(udg_Temp_Point)
    • Custom script: call RemoveLocation(udg_Temp_Point2)

Spoiler: Shockwave Group

• Shockwave Group
  • Events
    • Time - Every 0.03 seconds of game time
  • Conditions
  • Actions
    • Unit Group - Pick every unit in Shockwave_Group and do (Actions)
      • Loop - Actions
        • Set VariableSet Temp_Point = (Position of (Picked unit))
        • Set VariableSet Temp_Point2 = (Temp_Point offset by 10.00 towards (Facing of (Picked unit)) degrees.)
        • Unit - Move (Picked unit) instantly to Temp_Point2, facing (Facing of (Picked unit)) degrees
        • -------- You can add the Damage Part here --------
        • Set VariableSet Temp_Group = (Units within 128.00 of Temp_Point matching ((((Matching unit) is alive) Equal to Wahr) and (((Matching unit) belongs to an enemy of (Owner of (Picked unit)).) Equal to Wahr)).)
        • Set VariableSet Temp_Unit = (Picked unit)
        • Unit Group - Pick every unit in Temp_Group and do (Actions)
          • Loop - Actions
            • Unit - Cause Temp_Unit to damage (Picked unit), dealing 5.00 damage of attack type Spells and damage type Normal
            • -------- Maybe add an Checkup if Target was already damaged. --------
        • Custom script: call DestroyGroup(udg_Temp_Group)
        • Custom script: call RemoveLocation(udg_Temp_Point)
        • Custom script: call RemoveLocation(udg_Temp_Point2)

Spoiler: Shockwave Expiration

• Shockwave Expiration
  • Events
    • Unit - A unit Dies
  • Conditions
    • (Unit-type of (Triggering unit)) Equal to Shockwave (Dummy)
  • Actions
    • Unit Group - Remove (Triggering unit) from Shockwave_Group.
    • Unit - Remove (Triggering unit) from the game
    • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      • If - Conditions
        • (Number of units in Shockwave_Group) Less than or equal to 0
      • Then - Actions
        • Trigger - Turn off Shockwave Group <gen>
      • Else - Actions

If that's too complicated download the Map I attached to get a proper look, if you still do not understand how this works at all, refer to look up some Tutorials!
Have a good day.

 

[Pyrogasm]

Don't reinvent the wheel if you don't have to:

Shockwave System 1.2 Reforged

Credit to xyzier_24 for the original shockwave system which can be found here: Shockwave Carrion Swarm System (See the original for a full description). Updated by me to use reforged features instead of excessive dummy units. See the example spells for documentation. Also includes a dummy...

www.hiveworkshop.com

Shockwave/Carrion Swarm System v1.1

Found this laying dormant in my WIP Triggers. I decided to share this because I haven't found any Shockwave Systems yet, but if there is already, I guess it is far better than this one, so please give a link to it and just reject this one. An easy-to-use Ability-related system which allows the...

www.hiveworkshop.com