[JASS] How to make nocd script?

[nafre]

Could someone give me a no cooldown script in jass to put in my map?

 

[mckill2009]

paste this in your map...

scope CD initializer init

private function ResetNow takes nothing returns boolean
    call UnitResetCooldown(GetFilterUnit())
    return false
endfunction

private function ResetCooldown takes nothing returns boolean
    call GroupEnumUnitsInRect(bj_lastCreatedGroup, bj_mapInitialPlayableArea, function ResetNow)
    return false    
endfunction

private function init takes nothing returns nothing
    local trigger t = CreateTrigger()  
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_ENDCAST)
    call TriggerAddCondition(t, Condition(function ResetCooldown))
    set t = null
endfunction

endscope

 

[nafre]

Just paste it in a custom script? and do i need extra variables?

 

[mckill2009]

like you said, "put in my map", so no need to do anything, just copy and paste it...

 

[Maker]

Why that kind of script, mckill2009? Why not unit starts the effect -> add to group, start countdown timer with about 0.00 expiration time. When timer expires, reset cooldown for all units in group. Remove units from group.

 

[nafre]

The reason i need it because i want to make a nocd mode in my map. Will it be easier and better if i just do it in GUI?(I didn't do in GUI because i heard Jass is better and sometimes when i finish casting the ability it does not reset the cooldown)

 

[mckill2009]

yeah a global group will work but timer needs to be destroyed also...
anyway, this will work also...

scope CD initializer init

private function ResetCooldown takes nothing returns boolean
    call UnitResetCooldown(GetTriggerUnit())
    return false    
endfunction

private function init takes nothing returns nothing
    local trigger t = CreateTrigger()  
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_ENDCAST)
    call TriggerAddCondition(t, Condition(function ResetCooldown))
    set t = null
endfunction

endscope

 

[Bannar]

@nafre You can do this in GUI, although it's always less efficient than Jass script.

• call reset
  • Events
    • Unit - A unit Starts effect of ability
  • Conditions
  • Actions
    • Unit Group - Add (Triggering unit) to CDgroup
    • Timer - Countdown timer as One shot that will expire in 0.00 seconds

• reset
  • Events
    • Time - timer expires
  • Conditions
  • Actions
    • Unit Group - Pick all units in CDgroup and do Actions
      • Loop - Actions
        • Unit - Reset cooldowns for (Picked unit)
        • Unit Group - Remove (Picked unit) from CDgroup

Now for activating the 'nocd' mode simply create trigger that reacts on 'event - player types message'. Follow this with action: Trigger - Turn on call reset <gen>. Make sure 'call reset' trigger is disabled by default.

 

[Maker]

yeah a global group will work but timer needs to be destroyed also...

Use one timer for the system, don't destroy it.

Cooldown will trigger before _ENDCAST event, so you'll see the cooldown run for some time. Better to use _SPELL_EFFECT and 0.00 timer. Spinnaker's trigger is the method I described earlier.

 

[nafre]

@mckill2009
ok thx i will have to try it later because i have to study.
@Spinnaker
Thx for your trigger but i already know how to do it in GUI.

 

[Bannar]

Respresentation of my trigger in simple jass (doesn't require use of NewGen):

Thanks to Maker, Pharaoh_ and Bribe for script improvements.

function Callrestore takes nothing returns nothing
    call UnitResetCooldown(GetEnumUnit())
    call GroupRemoveUnit(udg_CDgroup, GetEnumUnit())
endfunction

function Callback takes nothing returns nothing
    call ForGroup(udg_CDgroup, function Callrestore)
endfunction

function GetUnit takes nothing returns boolean
    if udg_ModeEnabled then
        call GroupAddUnit(udg_CDgroup, GetTriggerUnit())
        call TimerStart(udg_timer, 0.00, false, function Callback)
    endif
    return false
endfunction

function InitTrig_ResetCooldown takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_ENDCAST)
    call TriggerAddCondition(t, Condition(function GetUnit))
    set t = null
endfunction

Requires one global group variable: CDgroup and one timer variable: timer.
Now, to enable/disable 'nocd' mode, make use of boolean variable (here it's 'udg_ModeEnabled'). If set to true, trigger will reset every cooldown.

 

[Maker]

^You could combine the action function with the condition function. Conditions are said to run faster.

I don't think you need to pause the timer since it is a non repeating timer.

 

[Bannar]

Done (=

 

[Pharaoh_]

Don't use "null" as an argument in registered event (or any boolexpr). Create a function that returns true; for some odd reason, it creates a permanent leak otherwise. It is more preferable if it has anything but "null".

 

[Ceday]

Don't use "null" as an argument in registered event (or any boolexpr). Create a function that returns true; for some odd reason, it creates a permanent leak otherwise. It is more preferable if it has anything but "null".

We are living in 2011 Null boolexpr leak doesn't exist anymore.

 

[Pharaoh_]

I am aware of how Blizzard stated that in the 1.24 patch, but there are some people still claiming it was never changed. I will have a look at this a bit more, if needed.

 

[Troll-Brain]

I am aware of how Blizzard stated that in the 1.24 patch, but there are some people still claiming it was never changed. I will have a look at this a bit more, if needed.

I'm 100 % sure it was fixed in a patch, haven't tried the newest though.

But they give us a new (minor) leak http://www.thehelper.net/forums/sho...Found-Keeping-references-to-destroyed-objects

 

[Pharaoh_]

If you are 100% sure, then I trust that and my apologies to Spinnaker.
Even better, I don't have to create redundant functions.

 

[Bannar]

Don't appologize. I wasn't sure - because all knowledge about that came from 'hearing' (so I had no real argument, to even talk - fail me). Great that conclusion was made!

 

[Bribe]

It's useless to inline TriggerRegisterAnyUnitEventBJ, in fact it does more harm than good
because it adds to the map file size more than it has to.