[JASS] Help with this code - Game crashes!!

[Marcelo Hossomi]

I am just starting - this is my first code after reading Daelin's perfect tutorial. This trigger is supposed to cause a certain damage to the attacked unit, when a unit of type H000 attacks and the target takes the damage. Unfortunately the game is closed right after being attacked.

function ManaLeakCond1 takes nothing returns boolean
    return GetUnitTypeId(GetAttacker()) == 'H000'
endfunction

function ManaLeakCond2 takes nothing returns boolean
   return udg_AE_ManaLeakActive
endfunction

function ManaLeakAndCond takes nothing returns boolean
    return GetBooleanAnd(ManaLeakCond1(), ManaLeakCond2())
endfunction

function ManaLeakDamage takes nothing returns nothing
    local integer Level
    local integer Int
    set udg_AE_ManaLeakDamage = 1.00
    set Int = 0
    set Level = GetUnitAbilityLevelSwapped('A003', udg_AECaster)
    loop
        exitwhen Int >= Level
        set udg_AE_ManaLeakDamage = udg_AE_ManaLeakDamage * 2
        set Int = Int + 1
    endloop
    call UnitDamageTargetBJ( udg_AECaster, udg_AE_ManaLeakTarget, udg_AE_ManaLeakDamage, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL )
    call SetUnitManaBJ (udg_AE_ManaLeakTarget, GetUnitStateSwap( UNIT_STATE_MANA, udg_AE_ManaLeakTarget) - udg_AE_ManaLeakDamage )
    call SetUnitManaBJ (udg_AECaster, GetUnitStateSwap( UNIT_STATE_MANA, udg_AECaster) - 1 )
    call DestroyTrigger(udg_AE_ManaLeakTrigger)
    set udg_AE_ManaLeakTrigger = null
    set udg_AE_ManaLeakTarget = null
    set udg_AECaster = null
endfunction

function ManaLeakAct takes nothing returns nothing
    set udg_AE_ManaLeakTarget = GetAttackedUnitBJ()
    set udg_AECaster = GetAttacker()
    set udg_AE_ManaLeakTrigger = CreateTrigger()
    call TriggerRegisterUnitEvent (udg_AE_ManaLeakTrigger, udg_AE_ManaLeakTarget, EVENT_UNIT_DAMAGED)
    call TriggerAddAction (udg_AE_ManaLeakTrigger, function ManaLeakDamage )
endfunction

//===========================================================================
function InitTrig_AE_Mana_Leak takes nothing returns nothing
    set gg_trg_AE_Mana_Leak = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_AE_Mana_Leak, EVENT_PLAYER_UNIT_ATTACKED)
    call TriggerAddCondition (gg_trg_AE_Mana_Leak, Condition(function ManaLeakAndCond))
    call TriggerAddAction( gg_trg_AE_Mana_Leak, function ManaLeakAct )
endfunction

The spell name is Mana Leak. It's based on Defend, so I can activate and deactivate it. There's a trigger that changes AE_ManaLeakActive (I'm sure that the problem is not with that one). Hope I'm not wasting your time, maybe it's an idiot spelling mistake...

Already THANKS
Hossomi

[edit: Jass codes in this site looks beautiful ]

 

[LordZsar1]

Try this. I got no specific idea, where your fault could be, but maybe it is already fixed now...

function ManaLeakDamage takes nothing returns nothing
  local integer int
  set udg_AE_ManaLeakDamage = 1.00
  set int = GetUnitAbilityLevel(udg_AECaster,'A003')
  set udg_AE_ManaLeakDamage = udg_AE_ManaLeakDamage * Pow(2,int)
  call UnitDamageTarget(udg_AECaster,udg_AE_ManaLeakTarget,udg_AE_ManaLeakDamage,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,WEAPON_TYPE_WHOKNOWS)
  call SetUnitState(udg_AE_ManaLeakTarget,UNIT_STATE_MANA,RMaxBJ(0,GetUnitState(udg_AE_ManaLeakTarget,UNIT_STATE_MANA) - udg_AE_ManaLeakDamage))
  call SetUnitState(udg_AECaster,UNIT_STATE_MANA,RMaxBJ(0,GetUnitState(udg_AECaster,UNIT_STATE_MANA) - 1))
  set udg_AE_ManaLeakTarget = null
  set udg_AECaster = null
  call DestroyTrigger(udg_AE_ManaLeakTrigger)
endfunction
 
function ManaLeakAct takes nothing returns nothing
  if GetUnitTypeId(GetAttacker()) == 'H000' and udg_AE_ManaLeakActive then
    set udg_AE_ManaLeakTarget = GetTriggerUnit()
    set udg_AECaster = GetAttacker()
    set udg_AE_ManaLeakTrigger = CreateTrigger()
    call TriggerRegisterUnitEvent(udg_AE_ManaLeakTrigger,udg_AE_ManaLeakTarget,EVENT_UNIT_DAMAGED)
    call TriggerAddAction(udg_AE_ManaLeakTrigger,function ManaLeakDamage)
  endif
endfunction

function InitTrig_AE_Mana_Leak takes nothing returns nothing
  set gg_trg_AE_Mana_Leak = CreateTrigger()
  call TriggerRegisterAnyUnitEventBJ(gg_trg_AE_Mana_Leak,EVENT_PLAYER_UNIT_ATTACKED)
  call TriggerAddAction(gg_trg_AE_Mana_Leak,function ManaLeakAct)
endfunction

If it still does not work, write this into some places of the code:

call BJDebugMsg("Part: <something, that identifies the part of code, we are inside now> ")

Then try and tell me, which of these messages appeared last before your game crashes.

 

[PurplePoot]

local integer int
      [...]
      set int = GetUnitAbilityLevel(udg_AECaster,'A003')

thank god that you fixed 99% of the BJ calls, etc, etc in that code... i was dreading doing it

anyways, that can easily be

local integer int = GetUnitAbilityLevel(udg_AECaster,'A003')

why didnt you do that in the first place?

also, GetBooleanAnd = WTF

instead of using those 3 functions, with the

function a takes nothing returns boolean
return ThisIsACondition
endfunction

function b takes nothing returns boolean
return ThisIsAnotherCondition
endfunction

function And takes nothing returns boolean
return GetBooleanAnd( a,b )
endfunction

just write

function And takes nothing returns boolean
return ThisIsACondition and ThisIsAnotherCondition
endfunction

 

[Marcelo Hossomi]

hehahaha sorry PurplePoot, and thanks both for help
because, as I said, this is my first code, so I based on Converted GUI-JASS heheh

Sorry LordZsar1 for your work, rewriting almost all the code!

Well.. I've tried this many times to find where the problem is, and it is exactly in the UnitDamageTarget call.

Some questions LordZsar, why do you use RMaxBJ to change mana? And what are those 'true' and 'false' in DamageTarget?

 

[PurplePoot]

UnitDamageTarget is weird, and sometimes gets a litlle buggy

Anyways, idk what hes doing with the RMaxBJ, but for the UnitDamageTarget, try replacing WEAPON_TYPE_WHOKNOWS with null, and making sure the variables are all correctly assigned.

(and that Thank God You Cleaned Up The Script was direced to you, Zsar )

 

[Marcelo Hossomi]

It doesn't work yet, but I've discovered more about this problem: it crashes just because the event of the local trigger is EVENT_UNIT_DAMAGED. I had another spell almost the same, and then I put everything in just one, with EVENT_PLAYER_UNIT_ATTACKED event, and it worked. The same happened with Mana Leak.

So I'll make Mana Leak with 'A unit is attacked' event, to finish with this

 

[paskovich]

The crash is caused by a deadly circle. The trigger fires when the unit is damaged, but the trigger damages that unit, tre trigger fires again, damages the unit, and so on.... This way, the trigger would run infinite times.
Solution:
Destroy the trigger first, and THEN damage the unit. If you destroy the trigger right after you declare the locals, the trigger will still run, it will not break the action.

And forget EVENT_UNIT_ATTACKED. That is what causes strange things and not UnitDamageTarget...

 

[PurplePoot]

I really dont know how i missed that :shock:

anyways, lol, you could also make sure GetEventDamageSource() != AE_whatever

 

[Marcelo Hossomi]

uhuuullll that's it!!!! *jumping happy*
Thank you three for help! I learned many things with this topic



(AE is because the hero name is Aeria, and there will be only one)

 

[PurplePoot]

Well, in that case, you should probably use a dummy o do the dmg, or donut's way, so that Ae can normally do dmg.

 

[LordZsar1]

Rewriting code (or writing code from description) is my way to have fun. ^^

That is the only cause, that makes me visiting this forum: One may ask for code, I may write.
I lack the stamina to create a whole map and metascript by myself. ^^
(started 12 maps, 3 AIs, 2 metascripts... finished none)

Hell, I should have seen this! ~~
As I wrote somewhere else: Sometimes I feel very stupid. ^^

 

[PurplePoot]

*i meant pasks way, just reading multiple posts at once and thinking donut for some reason :roll:

 

[paskovich]

Rewrite the script, use locals instead of globals. They aren't needed here.

 

[Marcelo Hossomi]

Uh.. no? I think they are since I use the same variable in many functions...

 

[PurplePoot]

Handle Vars.

 

[Marcelo Hossomi]

han...
don't know hot to use well yet

 

[PurplePoot]

Practice Makes Perfect

 

[Marcelo Hossomi]

Now I am trying to understand that huge code... I can't use handlers!! I don't know how xD

Can you give me an example of how to store a local unit? The function SetHandleBoolean takes a handle, a string and a value. What shoul I put as the handle?

 

[PurplePoot]

what youre storing it ON

(most likely your timer)

to store a unit, or any other HANDLE (anything thats not an int, real, boolean, code, or string), use SetHandleHandle, but you have to individually get them (eg. GetHandleUnit, GetHandleGroup)

 

[Marcelo Hossomi]

Should this work?
It's supposed to create a kind of Wisp (a counter) at the position of the KillingUnit and store the group of Wisps as a handle attached to Kinara (the hero's name), but not if the number of Counters in the group is greater or equal to the level of the ability x2.

It seems to only create the unit...
(cut a lot of the code, but I think it's not important)

function CounterUp takes nothing returns nothing
    local unit Kinara = GetKillingUnit()
    local unit Kill = GetDyingUnit()
    local group G = GetHandleGroup(Kinara, "Counters")
    local integer Level = GetUnitAbilityLevelSwapped( 'A019', Kinara )
    local integer Counters = CountUnitsInGroup(G)

    if (Counters < Level * 2) and (IsUnitEnemy(Kill, GetOwningPlayer(Kinara)) == true) and (IsUnitType(Kill, UNIT_TYPE_STRUCTURE) == false) and (IsUnitType(Kill, UNIT_TYPE_ANCIENT) == false) and GetUnitTypeId(Kinara) == 'N002' then
        set Counters = Counters + 1
        set Ang = I2R(360 / Counters)
        call CreateUnit(GetOwningPlayer(Kinara), 'u00C', GetLocationX(GetUnitLoc(Kinara)), GetLocationY(GetUnitLoc(Kinara)), Ang)
        call GroupAddUnitSimple(GetLastCreatedUnit(), G)
        call SetHandleHandle( Kinara, "Counters", G )
    endif
    set G = null
    set Kinara = null
    set Kill = null
endfunction

Am I deluded or Handle Vars are like Attached Variables?

 

[PurplePoot]

Excuse me while I maim you *jk*

Anyways, you have to have stored the group at some point, so the first time it will return null, which is not good

About attachable vars, they were BASED off the handle vars.

and, here we go, a few code review thingees

GetDyingUnit = bleh. Use GetTriggerUnit

and that abominably long condition can be shortened to this

 if Counters < Level * 2 and IsUnitEnemy(Kill, GetOwningPlayer(Kinara)) and GetUnitTypeId(Kinara) == 'N002' and not (IsUnitType(Kill, UNIT_TYPE_STRUCTURE) or IsUnitType(Kill, UNIT_TYPE_ANCIENT))

 

[Marcelo Hossomi]

Even when you laugh at me I find something inside me that makes me laugh too (I know I'm stupid)

I think I've bothered you too much already.

 

[PurplePoot]

Jeez, continue, i LIKE answering questions like this

Its good to see someone else learning something new.

 

[Marcelo Hossomi]

Ok, if you are saying that...

You said that I must initialize it. Do I do it with this?

call SetHandleHandle(Kinara, "Counters", null)

And, just to make things clear, is the value of the handle stored with Kinara and "Counters" as references?

Really thanks for your time ^^
I need to learn this...
Hossomi

 

[PurplePoot]

nononoon

i meant

at the START OF THE GAME

do this

set udg_cache = InitGameCache( "jasslocalvars.w3v" )

 

[Marcelo Hossomi]

Uh.. Sorry.. I did that xP

But.. about that code I posted above, should it work?

 

[PurplePoot]

lol...

no.

A) atleast as far as i can see, you never created the group.

B) CreateUnit does not return GetLastCreatedUnit(). You'll have to set [variable] = CreateUnit( blah )

C) fix that GroupAddUnitSimple call . It should just be GroupAddUnit

D) Lookit what I said in the post after that code

E) Replace GetUnitAbilityLevelSwapped with GetUnitAbilityLevel

F) the variable Ang that you're using was never defined.

 

[Marcelo Hossomi]

:shock: Yang bless me...

A. Create the group, you mean, CreateGroup()? (ohh ignorance)
B. Fixed
C. Fixed
D. Read and fixed
E. Fixed
F. In fact, it was, but I cut it by accident xD

Now I wrote an If that Set G = CreateGroup() if G == null, as there was in KaTTaNa's example...

It still doesn't work, but I'll try more tomorrow morning 'cause now I need to sleep... That's what night serves for...

Again and again, thanks PurplePoot
Hossomi

 

[PurplePoot]

If you post the fixed code, then I'll have another look.

 

[Marcelo Hossomi]

Oh sorry, there's some time I don't enter here due to a lack of time ^^'

function CounterUp takes nothing returns nothing  local unit Kinara = GetKillingUnit()
local unit Kill = GetTriggerUnit()
local unit u
local group G = GetHandleGroup(Kinara, "Counters")
local integer Level = GetUnitAbilityLevel( Kinara, 'A019' )
local integer Counters = CountUnitsInGroup(G)
local real Ang = 0
if (Counters < Level * 2) and (IsUnitEnemy(Kill, GetOwningPlayer(Kinara)) == true) and GetUnitTypeId(Kinara) == 'N002' and not (IsUnitType(Kill, UNIT_TYPE_STRUCTURE) == false) or (IsUnitType(Kill, UNIT_TYPE_ANCIENT) == false) then 
if G == null then
set G = CreateGroup()
endif
set Counters = Counters + 1
set Ang = I2R(360 / Counters)
set u = CreateUnit(GetOwningPlayer(Kinara), 'u00C', GetLocationX(GetUnitLoc(Kinara)), GetLocationY(GetUnitLoc(Kinara)), Ang)
call GroupAddUnit(G, u)
call SetHandleHandle( Kinara, "Counters", G )
endif
set G = null
set Kinara = null
set Kill = null
endfunction

I think I fixed everything here.
May I change CreateUnit to CreateNUnitsAtLoc? I saw somewhere that this was buggy..

 

[paskovich]

GetUnitTypeId(Kinara) == 'N002' and not (IsUnitType(Kill, UNIT_TYPE_STRUCTURE) == false) or (IsUnitType(Kill, UNIT_TYPE_ANCIENT) == false)

should be

GetUnitTypeId(Kinara) == 'N002' and not (IsUnitType(Kill, UNIT_TYPE_STRUCTURE) or IsUnitType(Kill, UNIT_TYPE_ANCIENT))

Shouldn't these go into the conditions of the trigger???

And:

GetLocationX(GetUnitLoc(Kinara)), GetLocationY(GetUnitLoc(Kinara))

shold be

GetUnitX(Kinara), GetUnitY(Kinara)

[/code]

 

[PurplePoot]

I beat you to the condition, but I cant believe I missed that leak.

Ugh... I'm slipping as time goes by

Also, the code will break if G = null when you CountUnitsInGroup( G ).

PS. that function is ugly.