Converting GUI to JASS

[Celio]

I just starting out learning about JASS. can someone help me convert this one so i can see a clear example.

 

[MarshMello]

it doesn't seem to have any leaks. i got a question. maybe this is not the place but. what are the advantages of JASS. even tho u have no leaks.

 

[busterkomo]

Click edit and then convert to custom text.

 

[Celio]

oh. i meant like mking it a proper jass script

 

[PurplePoot]

Plain JASS (Trigger name: CounterHelix):

You should have a global Unit Group called enumGrp declared.

function CounterHelixConditions takes nothing returns boolean
    return GetRandomInt(1,100) <= 15 and GetUnitAbilityLevel(GetTriggerUnit(), 'BFID') > 0
    //replace BFID with your spell's rawcode
endfunction

function CounterHelixFilter takes nothing returns boolean
    local unit u = GetTriggerUnit()
    local unit t = GetFilterUnit()
    if IsUnitEnemy(t,GetOwningPlayer(u)) and not IsUnitType(t,UNIT_TYPE_DEAD) then
        call UnitDamageTarget(u,t,75.+25.*GetUnitAbilityLevel(u,'SPID'),true,false,ATTACK_TYPE_HERO,DAMAGE_TYPE_NORMAL,null)
         //replace SPID with your counter helix spell rawcode
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Other\\Stampede\\StampedeMissileDeath.mdl",t,"origin"))
    endif
    set u = null
    set t = null
    return false
endfunction

function CounterHelixActions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    call GroupEnumUnitsInRange(udg_enumGrp,GetUnitX(u),GetUnitY(u),200.,Filter(function CounterHelixFilter))
    call SetUnitAnimation(u,"spin")
    call DisableTrigger(GetTriggeringTrigger())
    call TriggerSleepAction(.25)
    call EnableTrigger(GetTriggeringTrigger())
    call SetUnitAnimation(u,"stand")
    set u = null
endfunction

function InitTrig_CounterHelix takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_ATTACKED)
    call TriggerAddCondition(t,Condition(function CounterHelixConditions))
    call TriggerAddAction(t,function CounterHelixActions)
endfunction

 

[Celio]

cant that group be a local variable?

 

[PurplePoot]

Destroying groups is leaky and pointless.

 

[Dr Super Good]

Destroying groups is leaky and pointless.

In what way is it leaky? Please enlighten us.

 

[PurplePoot]

Search it on wc3c. They have a lot of problems with memory handling.

 

[MortAr]

I don't have answer for you question, but I can suggest you to increase the cooldown the of the couter helix, because .25 is a bit too small (like 4 spins in 2 seconds), try .45 or 1.00

 

[MarshMello]

@MortAr- lool potentially 4 spins in 1 second. but thast only if ur lucky xD 15% chance each attack

 

[Celio]

thank you guys for all your help. and the script that purplepoot posted works wonders
. +rep