[JASS] Simple Code Problem

[Linaze]

Hello, I'm trying to create a trigger that registers when a unit enters a region, then a text should be displayed, the problem is, it isn't.

globals
    rect TriggerRect = gg_rct_Test
    region TriggerRegion = CreateRegion()
    boolean FirstSlope = false
endglobals

function Actions takes nothing returns nothing
    call BJDebugMsg("Test")
endfunction

function Init takes nothing returns nothing
    local trigger Trig = CreateTrigger()
    call RegionAddRect(TriggerRegion,TriggerRect)
    call TriggerRegisterEnterRegion(Trig,TriggerRegion,null)
    call TriggerAddAction(Trig, function Actions)
endfunction

Any help why nothing happens when a unit enters the region would be appreciated, thanks.

 

[Shadow Daemon]

gg_rct_Test is equal to null, when you are trying to set value of TriggerRect variable.

globals
    rect TriggerRect = null
    region TriggerRegion = CreateRegion()
    boolean FirstSlope = false
endglobals

function Actions takes nothing returns nothing
    call BJDebugMsg("Test")
endfunction

function Init takes nothing returns nothing
    local trigger Trig = CreateTrigger()
    // try this:
    set TriggerRect = gg_rct_Test
    // or specify required rect manually:
    // set TriggerRect = Rect(-200., -200., 200., 200.)
    call RegionAddRect(TriggerRegion,TriggerRect)
    call TriggerRegisterEnterRegion(Trig,TriggerRegion,null)
    call TriggerAddAction(Trig, function Actions)
endfunction

 

[Linaze]

Same result, nothing.

 

[Shadow Daemon]

It seems, that creating region directly (when defining global variable) screws up warcraft (I had fatal errors while working on this code). This variant is tested and should work:

globals
    // rect TriggerRect = null
    region TriggerRegion = null
    boolean FirstSlope = false
endglobals

function Actions takes nothing returns nothing
    call BJDebugMsg("Test")
endfunction

function Init takes nothing returns nothing
    local trigger Trig = CreateTrigger()
    set TriggerRegion = CreateRegion()
    // set TriggerRect = gg_rct_Test
    call RegionAddRect(TriggerRegion, gg_rct_Test)
    call TriggerRegisterEnterRegion(Trig, TriggerRegion, null)
    call TriggerAddAction(Trig, function Actions)
endfunction

Why you have maked region variable global? Is it supposed to be used in other triggers?

 

[Linaze]

Still no result.

 

[Shadow Daemon]

Test map.

 

[Linaze]

It works well, but isn't the only difference that the code in your test map is in Scope block?

 

[Shadow Daemon]

Yep. Of course, to execute function init, it should be assigned as initializer (which runs at map loading). scope xxx initializer init does this.

 

[Linaze]

New help needed!

-->

Basically, now what I really wanted to do with this code, create a unit in front of the entering unit.

scope Slope initializer Init
    globals
        region TriggerRegion = null
        boolean FirstSlope = false
        //-----
        real dist = 1.
        real angle = GetUnitFacing(GetEnteringUnit())
        location source = GetUnitLoc(GetEnteringUnit())
        location target = PolarProjectionBJ(source,dist,angle)
    endglobals

    function Actions takes nothing returns nothing
        call CreateUnitAtLoc(Player(0),'h000',target,0.)
    endfunction

    function Init takes nothing returns nothing
        local trigger Trig = CreateTrigger()
        set TriggerRegion = CreateRegion()
        call RegionAddRect(TriggerRegion, gg_rct_Test)
        call TriggerRegisterEnterRegion(Trig,TriggerRegion,null)
        call TriggerAddAction(Trig, function Actions)
    endfunction
endscope

According to what I thought, this would create a 'h000' directly in front of the entering unit, but the result is that the unit is created in front of the entering unit but in the very far end of the map. Any help is appreciated, thanks.

 

[Shadow Daemon]

The way you are setting parameters is definitely wrong. Values of global variables are "calculated" once, at the map start, while values of local variables are "calculated" on every function run. Of course, any event-specific functions like GetTriggerUnit() or GetSpellTargetLoc() would work only inside functions assigned to triggers.

Hence the code should look like:

scope Slope initializer Init
    globals
        region TriggerRegion = null
        boolean FirstSlope = false
    endglobals

    function Actions takes nothing returns nothing
        local real dist = 1.
        local real angle = GetUnitFacing(GetEnteringUnit())
        local location source = GetUnitLoc(GetEnteringUnit())
        local location target = PolarProjectionBJ(source,dist,angle)
        call CreateUnitAtLoc(Player(0), 'h000', target, 0.)
        
        // cleaning up potential leaks
        call RemoveLocation(source)
        call RemoveLocation(target)
        set source = null
        set target = null
    endfunction

    function Init takes nothing returns nothing
        local trigger Trig = CreateTrigger()
        set TriggerRegion = CreateRegion()
        call RegionAddRect(TriggerRegion, gg_rct_Test)
        call TriggerRegisterEnterRegion(Trig,TriggerRegion,null)
        call TriggerAddAction(Trig, function Actions)
    endfunction
endscope

or optimized variant:

scope Slope initializer Init
    globals
        region TriggerRegion = null
        boolean FirstSlope = false
    endglobals

    function Actions takes nothing returns nothing
        local unit e = GetEnteringUnit()
        local real f = GetUnitFacing(e) * bj_DEGTORAD
        call CreateUnit(Player(0), 'h000', GetUnitX(e) + 2.*Cos(f), GetUnitY(e) + 2.*Sin(f), 0.)
        set e = null
    endfunction

    function Init takes nothing returns nothing
        local trigger Trig = CreateTrigger()
        set TriggerRegion = CreateRegion()
        call RegionAddRect(TriggerRegion, gg_rct_Test)
        call TriggerRegisterEnterRegion(Trig,TriggerRegion,null)
        call TriggerAddAction(Trig, function Actions)
    endfunction
endscope

Well, it seems that you are not familiar with jass. I'd recommend to read some jass tutorials for better understanding.