[JASS] Part of code isn't running

[Linaze]

function GruntFilter takes nothing returns boolean
    return GetUnitTypeId(GetFilterUnit()) == 'o60D' and not IsUnitType(GetFilterUnit(),UNIT_TYPE_DEAD) 
endfunction

function FarmsFilter takes nothing returns boolean
    return GetUnitTypeId(GetFilterUnit()) == 'o607' and not IsUnitType(GetFilterUnit(),UNIT_TYPE_DEAD) 
endfunction

function BarracksFilter takes nothing returns boolean
    return GetUnitTypeId(GetFilterUnit()) == 'o60A' and not IsUnitType(GetFilterUnit(),UNIT_TYPE_DEAD) 
endfunction

function QuestBaseFinished takes nothing returns nothing
    call QuestSetCompleted(udg_QuestBase,true)
endfunction

function QuestBaseActions takes nothing returns nothing
    local boolean BaseGrunts
    local boolean BaseFarms
    local boolean BaseBarracks
    
    call GroupEnumUnitsOfPlayer(udg_enumGrpGrunts,Player(0),Filter(function GruntFilter))
    call GroupEnumUnitsOfPlayer(udg_enumGrpFarms,Player(0),Filter(function FarmsFilter))
    call GroupEnumUnitsOfPlayer(udg_enumGrpBarracks,Player(0),Filter(function BarracksFilter))
    if (not IsQuestItemCompleted(udg_QuestBaseGrunts)) then
        if CountUnitsInGroup(udg_enumGrpGrunts) == 3 then
            set BaseGrunts = true
            call QuestItemSetCompleted(udg_QuestBaseGrunts,true)
            if (BaseFarms == true and BaseBarracks == true) then
                call BJDebugMsg("Test")
                call QuestBaseFinished()
            else
                call BJDebugMsg("Fail")
            endif                      
        endif
    endif
    if (not IsQuestItemCompleted(udg_QuestBaseFarms)) then
        if CountUnitsInGroup(udg_enumGrpFarms) == 2 then
            set BaseFarms = true
            call QuestItemSetCompleted(udg_QuestBaseFarms,true)
        endif
    endif
    if (not IsQuestItemCompleted(udg_QuestBaseBarracks)) then
        if CountUnitsInGroup(udg_enumGrpBarracks) == 1 then
            set BaseBarracks = true
            call QuestItemSetCompleted(udg_QuestBaseBarracks,true)
        endif
    endif
endfunction

function InitTrig_QuestBaseComplete takes nothing returns nothing
    set gg_trg_QuestBaseComplete = CreateTrigger()
    call TriggerRegisterPlayerUnitEvent(gg_trg_QuestBaseComplete,Player(0),EVENT_PLAYER_UNIT_CONSTRUCT_FINISH,null)
    call TriggerRegisterPlayerUnitEvent(gg_trg_QuestBaseComplete, Player(0),EVENT_PLAYER_UNIT_TRAIN_FINISH,null)
    call TriggerAddAction(gg_trg_QuestBaseComplete, function QuestBaseActions )
endfunction

The problem is that this part never runs:

if (BaseFarms == true and BaseBarracks == true) then
    call BJDebugMsg("Test")
    call QuestBaseFinished()
else
    call BJDebugMsg("Fail")
endif

I have no clue to as what the problem could be, so any help would be welcome.

 

[SlayerII]

I never seen a and at jass code- maybe i just never used it but try this:

if BaseFarms == true then
  if BaseBarracks == true then    
    call BJDebugMsg("Test")    
    call QuestBaseFinished()
  else    
    call BJDebugMsg("Fail")
  endif
else
  call BJDebugMsg("Fail")
endif

 

[Shadow Daemon]

The problem is in that there are no values assigned to local variables before "that part of code". This variant should work:

function QuestBaseActions takes nothing returns nothing
    // setting initial values
    local boolean BaseGrunts   = false
    local boolean BaseFarms    = false
    local boolean BaseBarracks = false

    call GroupEnumUnitsOfPlayer(udg_enumGrpGrunts,Player(0),Filter(function GruntFilter))
    call GroupEnumUnitsOfPlayer(udg_enumGrpFarms,Player(0),Filter(function FarmsFilter))
    call GroupEnumUnitsOfPlayer(udg_enumGrpBarracks,Player(0),Filter(function BarracksFilter))
    
    if (not IsQuestItemCompleted(udg_QuestBaseGrunts)) then
        if CountUnitsInGroup(udg_enumGrpGrunts) == 3 then
            set BaseGrunts = true
            call QuestItemSetCompleted(udg_QuestBaseGrunts,true)
        endif
    endif
    
    if (not IsQuestItemCompleted(udg_QuestBaseFarms)) then
        if CountUnitsInGroup(udg_enumGrpFarms) == 2 then
            set BaseFarms = true
            call QuestItemSetCompleted(udg_QuestBaseFarms,true)
        endif
    endif
    
    if (not IsQuestItemCompleted(udg_QuestBaseBarracks)) then
        if CountUnitsInGroup(udg_enumGrpBarracks) == 1 then
            set BaseBarracks = true
            call QuestItemSetCompleted(udg_QuestBaseBarracks,true)
        endif
    endif
    
    // checking for all quest requirements
    if (BaseFarms and BaseBarracks and BaseGrunts) then
        call BJDebugMsg("Test")
        call QuestBaseFinished()
    else
        call BJDebugMsg("Fail")
    endif
endfunction

 

[Cheezeman]

Just like Shadow_Demon said here, you have to initalize variables sometimes.
I often get wierd bugs that code doesn't run cause I forgot to initialize an integer, which makes no sence to me.
Keep that in mind to next time you find a similar bug

 

[Linaze]

Yeah, thanks. Poot already helped me, though. ^^