[JASS] fixing it so it only works for saving player

[Tal'Rarity]

Does anyone know how to do a identify player check so it doesn't create a load code .txt file for everyone?

function CreateTextFile takes nothing returns nothing
     local integer p = GetPlayerId(GetTriggerPlayer())+1
     local string heroName = GetUnitName(udg_Hero)
     local integer heroLevel = GetHeroLevel(udg_Hero)
     
     call PreloadGenClear()
     call PreloadGenStart()
     
     // The line below creates the log
     // Right now, this is:
     //      Hero: (hero name)
     //      Level: (hero level)
     //      Code: -load XXXX
     call Preload("\r\n\t\t\t\tHero: " + heroName + "\r\n\t\t\t\t" + "Level: " + I2S(heroLevel) + "\t\t\r\n\t\t\t\t" + "Code: -load " + udg_NPS_Password + "\r\n\n\t\t    ")
     
     // The line below creates the file at the specified location
     // Right now, this is:
     //      "Warcraft III\FolderName\(hero name) - (hero level)"
     call PreloadGenEnd("FolderName\\" + heroName + " - " + I2S(heroLevel) + ".txt")
endfunction

• Custom script: call CreateTextFile()

 

[Magtheridon96]

Try this.

function CreateTextFileForPlayer takes player pl returns nothing
     local integer p = GetPlayerId(pl) + 1
     local string heroName = GetUnitName(udg_Hero)
     local integer heroLevel = GetHeroLevel(udg_Hero)

     // Right now, this is:
     //      Hero: (hero name)
     //      Level: (hero level)
     //      Code: -load XXXX
     local string fileData = "\r\n\t\t\t\tHero: " + heroName + "\r\n\t\t\t\t" + "Level: " + I2S(heroLevel) + "\t\t\r\n\t\t\t\t" + "Code: -load " + udg_NPS_Password + "\r\n\n\t\t    "

     // Right now, this is:
     //      "Warcraft III\FolderName\(hero name) - (hero level)"
     local string fileName = "FolderName\\" + heroName + " - " + I2S(heroLevel) + ".txt"
     
     if GetLocalPlayer() == pl then
          call PreloadGenClear()
          call PreloadGenStart()

          call Preload(fileData)
          call PreloadGenEnd(fileName)
     endif
endfunction

This will keep the string table in sync for all players.

You would call it like this:

• Custom script: call CreateTextFileForPlayer(GetTriggerPlayer())

 

[Almia]

Then how would you load/read this?

 

[Arhowk]

Then how would you load/read this?

you wouldn't?

 

[Tal'Rarity]

Sorry forgot to let everyone know this question was solved. Thanks again mag.