[JASS] Cannot Convert group to unit

[khamarr3524]

In my script to loop create a hero for each player, it's telling me when i try to compile script that it cannot convert the group to unit. What group is there in my script? I'm new to this.

    set udg_Hero[i]=CreateNUnitsAtLoc(1 , udg_Random[GetRandomInt(1 , 24)] , Player(i) , udg_tempLoc , bj_UNIT_FACING)

Here is the full trigger script

function Trig_Random_Actions takes nothing returns nothing
local integer i = 0
set udg_tempLoc = (GetRectCenter(gg_rct_Hero_Spawn))
loop
    exitwhen i > 11
    set udg_Hero[i] = CreateUnitAtLoc( Player(i), udg_Random[GetRandomInt(1, 24)], udg_tempLoc, bj_UNIT_FACING)
    set i = i + 1
endloop
call RemoveLocation(udg_tempLoc)
endfunction

//===========================================================================
function InitTrig_Random takes nothing returns nothing
    local trigger RandomHero = CreateTrigger()
    call TriggerRegisterDialogButtonEvent(RandomHero, udg_StartDialogButton[1])
    call TriggerAddAction( RandomHero, function Trig_Random_Actions )
endfunction

 

[Garfield1337]

CreateNUnitsAtLoc returns a group since the function has possibility of creating multiple units. (Still, you can use bj_lastCreatedUnit variable from this function because the function is a BJ and it sets the last created, among N units, to bj_lastCreatedUnit variable.)

Just use CreateUnit takes player owner, integer rawcode, real x, real y, real facing returns unit function.

 

[khamarr3524]

Posted a different version of script. This only creates a unit. Used wrong function.

EDIT: I'm not sure how to use that function/ Where to put it.. Could you explain.

 

[Garfield1337]

Here's an optimized version of your code, you should examine it. It's more efficient to use coordinates instead of locations, they also don't leak.
Also BJ functions (the red highlighted ones should be avoided because they call on other functions within themselves so it's always better to use functions from within it (you can find such things in tools like JassCraft))

function Trig_Random_Actions takes nothing returns nothing
    local integer i = 0
    loop
        exitwhen i > 11
        set udg_Hero[i] = CreateUnit(Player(i),udg_Random[GetRandomInt(1, 24)],GetRectCenterX(gg_rct_Hero_Spawn),GetRectCenterY(gg_rct_Hero_Spawn),270.0)
        set i = i + 1
    endloop
endfunction

//===========================================================================
function InitTrig_Random takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterDialogButtonEvent(t, udg_StartDialogButton[1])
    call TriggerAddAction(t, function Trig_Random_Actions )
    set t = null
endfunction

 

[khamarr3524]

the set Hero line caused Syntax Error

 

[Garfield1337]

Fixed it, i forgot a bracket.

 

[khamarr3524]

For some reason when i make the Dialog buttons or something involving dialog buttons, it's not saving the dialog buttons to the array.

Create Dialog

function Trig_Startup_Actions takes nothing returns nothing
call DialogClear(udg_StartDialog)
set udg_StartDialog = DialogCreate()
call DialogSetMessage(udg_StartDialog, "Pick Mode")
set udg_StartDialogButton[1] = DialogAddButton(udg_StartDialog,"All Random", 1)
set udg_StartDialogButton[2] = DialogAddButton(udg_StartDialog,"All Pick", 2)
call DialogDisplay(Player(0), udg_StartDialog, true)
endfunction

//===========================================================================
function InitTrig_Startup takes nothing returns nothing
    local trigger Startup = CreateTrigger()
    call TriggerRegisterTimerEventSingle( Startup , 1.00)
    call TriggerAddAction( Startup, function Trig_Startup_Actions )
endfunction

I think it's right, but I'm sure im wrong.

EDIT: I have JassCraft, but when scripting I use JPNG. Should i switch to JC?

 

[Garfield1337]

It does save them, the thing is, their value is assigned after the event that fires upon button click is created.
Use this code instead: (You also don't need Random trigger if you use this)

Hidden

function Trig_Random_Actions takes nothing returns boolean
    local integer i = 0
    if GetClickedButton() == udg_StartDialogButton[1] then
        loop
            exitwhen i > 11
            set udg_Hero[i] = CreateUnit(Player(i),udg_Random[GetRandomInt(1, 24)],GetRectCenterX(gg_rct_Hero_Spawn),GetRectCenterY(gg_rct_Hero_Spawn),270.0)
            set i = i + 1
        endloop
    elseif GetClickedButton() == udg_StartDialogButton[2] then
        //actions for button 2
    endif
    return false
endfunction

function Trig_Startup_Actions takes nothing returns nothing
    local trigger t = CreateTrigger()
    call DialogClear(udg_StartDialog)
    set udg_StartDialog = DialogCreate()
    call DialogSetMessage(udg_StartDialog, "Pick Mode")
    set udg_StartDialogButton[1] = DialogAddButton(udg_StartDialog,"All Random", 1)
    set udg_StartDialogButton[2] = DialogAddButton(udg_StartDialog,"All Pick", 2)
    call TriggerRegisterDialogButtonEvent(t, udg_StartDialogButton[1])
    call TriggerRegisterDialogButtonEvent(t, udg_StartDialogButton[2])
    call TriggerAddCondition(t,Condition(function Trig_Random_Actions))
    call DialogDisplay(Player(0), udg_StartDialog, true)
    set t = null
endfunction

//===========================================================================
function InitTrig_Startup takes nothing returns nothing
    call TimerStart(CreateTimer(),1.00,false,function Trig_Startup_Actions)
endfunction

I suggest you examine the code a bit.

I have JassCraft, but when scripting I use JPNG. Should i switch to JC?

It doesn't matter, you can use JNGP too. Though i find JassCraft's native list easier to work with.
I have them both opened when scripting, i just use JC for native list.

 

[khamarr3524]

It's still not creating a hero. I don't know why. All my globals are declared, I changed things in the script, checked it, nothing. I'm started to be frustrated with Jass.

 

[Garfield1337]

I really don't see a reason why it wouldn't work :\

 

[khamarr3524]

Me either. I had Nestharus look at it, and he found that my GUI Variables were being reset, but other than that, the Dialog system isn't registering the Dialog Buttons on the condition or something along those lines to tell when the button was pushed.

 

[Garfield1337]

There's 1 thing that may be causing it. When i posted the trigger, i've made a slight mistake that i fixed a minute later, try copying the code again.

 

[khamarr3524]

There's still no heroes spawning.

 

[Garfield1337]

Add some debug messages using BJDebugMsg("type something random here") function.
Add one at start of Random actions function and one within the if.