[JASS] Can someone fix this?

[Val-Gaav]

Well, im not so good jasser, so im asking you to help me. This spells summons x units and then it should order them to attack target of ability being cast and get removed after x time, though they dont get removed, they dont even attack the target, just random units.

function Trig_Ancestral_Call_Conditions takes nothing returns boolean
   return GetSpellAbilityId() == 'A00G'
endfunction

function Trig_Ancestral_Call_Actions takes nothing returns nothing

        local unit a = GetSpellAbilityUnit()
        local group g
        local integer i=0
        local unit pickedunit

        set g = CreateGroup()

        loop
              set i = i + 1
              exitwhen i >  GetUnitAbilityLevelSwapped('A00G', a)
              call GroupAddUnit(g, CreateUnit(GetOwningPlayer(a) , 'oshm', GetUnitX(a) , GetUnitY(a) , 0))
              call IssueTargetOrder( GetLastCreatedUnit(), "attack", GetSpellTargetUnit() )
        endloop
        call PolledWait(0.50)
loop
            exitwhen FirstOfGroup(g)  == null
            set pickedunit = FirstOfGroup(g) 
            call RemoveUnit(pickedunit)
            call GroupRemoveUnit(g, pickedunit)
            set pickedunit=null
        endloop

endfunction

//===========================================================================
function InitTrig_Ancestral_Call takes nothing returns nothing
    set gg_trg_Ancestral_Call = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Ancestral_Call, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Ancestral_Call, Condition( function Trig_Ancestral_Call_Conditions ) )
    call TriggerAddAction( gg_trg_Ancestral_Call, function Trig_Ancestral_Call_Actions )
endfunction

 

[PurplePoot]

CreateUnit() doesn't set bj_lastCreatedUnit.

Try changing it to

local unit temp

[loop]
set temp = CreateUnit(bleh)

then using temp to do your stuff

Also, use UnitApplyTimedLife( someUnit, 'BTlf', 1 ) to clean them up (with SetUnitExploded( someUnit, true ) and having them have no Art-Special, or a 'death' art of your choice) instead of the wait. Finally, use GetUnitAbilityLevel instead of GetUnitAbilityLevelSwapped

 

[wyrmlord]

Though if you follow PurlePoot's instructions, what I'm going to say won't be necessary to your code, but it's good to know. In the second loop, you're removing the picked unit from the game and then trying to remove the unit from the group. You should instead do it the other way around. Also, I notice you'll have 2 FirstOfGroup calls per loop in the second one. Instead, set a unit to the FirstOfGroup and then the exitwhen statement should exit when that unit is == null.

 

[PurplePoot]

to follow up on wyrm's instructions, a loop like that (if you chose to go about this that way) would look like

loop
    set u = FirstOfGroup( g )
    exitwhen u == null
    call GroupRemoveUnit( g, u )
    call RemoveUnit( u )
endloop

Though

call SetUnitExploded( u, true )
call UnitApplyTimedLife( u, 'BTlf', 1 )

Is still a much cleaner way to do it than the wait + loop, for reasons like

-a non-variable wait time before the unit is killed
-you don't need a group
-you don't need the wait

 

[paskovich]

Does SetUnitExploded work for you guys? Cause it does not for me...

 

[Val-Gaav]

if i get it right, i should get something like this?

function Trig_Ancestral_Call_Conditions takes nothing returns boolean
   return GetSpellAbilityId() == 'A00G'
endfunction

function Trig_Ancestral_Call_Actions takes nothing returns nothing

        local unit a = GetSpellAbilityUnit()
        local unit b = GetSpellTargetUnit()
        local unit temp
        local integer i = 0

        loop
              set i = i + 1
              exitwhen i >  GetUnitAbilityLevel( a, 'A00G' )
              set temp = CreateUnit(GetOwningPlayer(a) , 'oshm', GetUnitX(a) , GetUnitY(a) , 0)
              call IssueTargetOrder( temp, "attack", b )
              call UnitApplyTimedLife( temp, 'BTlf', 1 )
              call SetUnitExploded( temp, true )
        endloop
endfunction

//===========================================================================

function InitTrig_Ancestral_Call takes nothing returns nothing
    set gg_trg_Ancestral_Call = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Ancestral_Call, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Ancestral_Call, Condition( function Trig_Ancestral_Call_Conditions ) )
    call TriggerAddAction( gg_trg_Ancestral_Call, function Trig_Ancestral_Call_Actions )
endfunction

Edit: just tested it, works fine, thenks for help

1 more question regarding this ability, how can i create units around the caster in random position within 300 area?
is that correct?

          set temp = CreateUnitAtLoc( GetOwningPlayer(a), 'oshm', OffsetLocation(GetUnitLoc(a), GetRandomReal(0, 300.00), GetRandomReal(0.00, 300.00)), 0 )

 

[wyrmlord]

Yes, but you'll be leaking a location each time you do that. You are calling GetUnitLoc(a) without removing that location. The best way to do this would be with using x/y coordinates instead of locations for the whole thing:

set caster_x = GetUnitX(a)
set caster_y = GetUnitY(a)

// Later on...

set temp = CreateUnit(GetOwningPlayer(a), 'oshm', caster_x + GetRandomReal(-300., 300.), caster_y + GetRandomReal(-300., 300.), 0.)

 

[Val-Gaav]

what type of locals are caster_x/y ? location? WE gave me 3 errors, 2 of them were "Type missmatch in assigment" and other one was " Invalid type for specified operator " when using location

 

[HappyTauren]

thing is, you shouldnt use CreateUnitAtLoc, but just CreateUnit, first one takes location (leaks) and other one takes x and y coordinates.

 

[PurplePoot]

X/Y are reals

and yes, the script looks good now.

Cept, use GetTriggerUnit() instead of GetSpellAbilityUnit()

and pask, the SetUnitExploded( u, true ) doesnt kill the unit. It makes it explode on death.

 

[paskovich]

and pask, the SetUnitExploded( u, true ) doesnt kill the unit. It makes it explode on death.

I know, i know, but when it is set to true, and the unit is killed, it does not explode, just simply dies...

 

[PurplePoot]

That's weird... I've never had problems with it