Triggers

// Import non-standard native function to make life easier
native UnitAlive takes unit id returns boolean

// ==============================================================
// UTILITY FUNCTIONS
// Below follows utility functions, which can be called from all
// triggers. These are designed to make the life easier for the
// map makers.
// ==============================================================

//==================================================================================================================
// SOUND
//==================================================================================================================

//
// Called when the PlayTimedSound sound timer elapses. 
// Plays the sound at input position and then queues up another timer to destroy the sound after it has finished playing.
//
function PlayTimedSound_TimerElapsed takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer timer_handle = GetHandleId(t)
    local string file_name = LoadStr(udg_timer_hashtable, timer_handle, 0)
    local location position = LoadLocationHandle(udg_timer_hashtable, timer_handle, 1)
    local sound sound_handle = CreateSound(file_name, false, true, true, 10, 10, "")
    local integer sound_duration_msec = GetSoundFileDuration(file_name)
    local real sound_duration_sec = (sound_duration_msec/1000.0)
    
    call SetSoundDistances(sound_handle, 600.00, 10000.00)
    call SetSoundDistanceCutoff(sound_handle, 3000.00)
    call SetSoundPosition(sound_handle, GetLocationX(position), GetLocationY(position), 0 )
    call SetSoundDuration(sound_handle, sound_duration_msec)
    call SetSoundVolume(sound_handle, 127)
    call StartSound(sound_handle)
    call KillSoundWhenDone(sound_handle)
    
    call RemoveLocation(position)
    call PauseTimer(t)
    call DestroyTimer(t)
    call FlushChildHashtable(udg_timer_hashtable, timer_handle)

    set position = null
    set t = null
    set sound_handle = null
endfunction

//
// Takes a sound file name, location and a delay value and creates a timer
// that will play the entered sound at the target location after the delay has passed.
//
function PlayTimedSound takes string file_name, location position, real delay returns nothing
    local timer sound_timer = CreateTimer()
    local integer timer_handle = GetHandleId(sound_timer)
    
    call SaveStr(udg_timer_hashtable, timer_handle, 0, file_name)
    call SaveLocationHandle(udg_timer_hashtable, timer_handle, 1, position)
    call TimerStart(sound_timer, delay, false, function PlayTimedSound_TimerElapsed)
    
    set sound_timer = null
endfunction

//==================================================================================================================
// DAMAGE
//==================================================================================================================
//
// Called when the AOETimedDamage timer elapses.
// Will take units nearby input position and cause damage to them.
//
function AOETimedDamage_TimerElapsed takes nothing returns nothing 
    local timer t = GetExpiredTimer()
    local integer timer_handle = GetTimerData(t)
    local location position = LoadLocationHandle(udg_timer_hashtable, timer_handle, 1)      // Position
    local unit attacker = LoadUnitHandle(udg_timer_hashtable, timer_handle, 0)     // Attacker
    local real radius = LoadReal(udg_timer_hashtable, timer_handle, 2)                  // Radius
    local real damage = LoadReal(udg_timer_hashtable, timer_handle, 3)          // Damage
    local group targets_group = GetUnitsInRangeOfLocAll(radius, position)
    local unit u
    local attacktype attack_type = ConvertAttackType(LoadInteger(udg_timer_hashtable, timer_handle, 4))
    local damagetype damage_type = ConvertDamageType(LoadInteger(udg_timer_hashtable, timer_handle, 5))
    local boolean friendly_fire = LoadBoolean(udg_timer_hashtable, timer_handle, 6)        // Friendly Fire
    local boolean friendly_building_fire = LoadBoolean(udg_timer_hashtable, timer_handle, 7)        // Friendly Building Fire
    local player attacker_owner = GetOwningPlayer(attacker)
    
    loop
        set u = FirstOfGroup(targets_group)
        exitwhen u == null
        if UnitAlive(u) and (friendly_fire or IsUnitEnemy(u, attacker_owner)) and (friendly_building_fire or not (IsUnitAlly(u, attacker_owner) and IsUnitType(u, UNIT_TYPE_STRUCTURE))) then
            call UnitDamageTarget(attacker, u, damage, true, false, attack_type, damage_type, null) 
        endif
        call GroupRemoveUnit(targets_group,u)
    endloop
    
    call DestroyGroup(targets_group)
    call RemoveLocation(position)
    call ReleaseTimer(t)
    call FlushChildHashtable(udg_timer_hashtable, timer_handle)
    set t = null
    set position = null
    set targets_group = null
    set attacker = null
    set attack_type = null
    set damage_type = null
    set attacker_owner = null
endfunction

//
// Will cause damage to an area after input amount of time has passed.
//
function AOETimedDamage takes unit attacker, location position, real radius, real delay, real damage, integer attack_type, integer damage_type, boolean friendly_fire, boolean friendly_building_fire returns nothing
    local timer damage_timer = NewTimer()
    local integer timer_handle = GetHandleId(damage_timer)
    call SetTimerData(damage_timer, timer_handle)
    
    call SaveUnitHandle(udg_timer_hashtable, timer_handle, 0, attacker)
    call SaveLocationHandle(udg_timer_hashtable, timer_handle, 1, position)
    call SaveReal(udg_timer_hashtable, timer_handle, 2, radius)
    call SaveReal(udg_timer_hashtable, timer_handle, 3, damage)
    call SaveInteger(udg_timer_hashtable, timer_handle, 4, attack_type)
    call SaveInteger(udg_timer_hashtable, timer_handle, 5, damage_type)
    call SaveBoolean(udg_timer_hashtable, timer_handle, 6, friendly_fire)
    call SaveBoolean(udg_timer_hashtable, timer_handle, 7, friendly_building_fire)
    call TimerStart(damage_timer, delay, false, function AOETimedDamage_TimerElapsed)
    
    set damage_timer = null
endfunction

//==================================================================================================================
// DEBUG
//==================================================================================================================

//
// Prints a debug message to all players using the input text if input boolean should_print and udg_is_testing
// are true.
//
function DebugPrint takes string text, string title, string color, boolean should_print returns nothing  
    if udg_is_testing and should_print then
        if title != null and title != "" then
            set text = "[" + title + "] " + text
        endif
        if color != null and color != "" then
            set text = "|" + color + text + "|r"
        endif
        call DisplayTextToForce(GetPlayersAll(), text)
    endif
endfunction


//==================================================================================================================
// String Utils
//==================================================================================================================
//Prefix with zeroes
function Int2Str2Digits takes integer intToString returns string
    return SubString(I2S(intToString + 100), 1, 3)
endfunction

function Int2Str9Digits takes integer intToString returns string
    return SubString(I2S(intToString + 1000000000), 1, 10)
endfunction

function base64CharFromIndex takes integer index returns string
    return SubString("ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/", index, index + 1)
endfunction

function base64IndexOfChar takes string input returns integer
    local integer i = 0
    loop
        exitwhen base64CharFromIndex(i) == input
        set i = i + 1
    endloop
    return i
endfunction

function intToBase64 takes integer input, integer capResultChars returns string
    local integer currentValue = input
    local string result = ""
    loop
        //call BJDebugMsg("current result=" + result + ", currentValue=" + I2S(currentValue))
        set result = base64CharFromIndex(ModuloInteger(currentValue, 64)) + result
        set currentValue = currentValue / 64
        exitwhen currentValue == 0
    endloop
    //call BJDebugMsg("Final result=" + result + ", currentValue=" + I2S(currentValue))
    return SubString(result + "====", 0, capResultChars)
endfunction

function fromBase64 takes string input, integer maxLength returns integer
    local integer result = 0
    local integer i = 0
    local string currentChar
    loop
        set currentChar = SubString(input, i, i + 1)
        exitwhen i > (maxLength - 1) or currentChar == "="
        set i = i + 1
        set result = result * 64 + base64IndexOfChar(currentChar)
    endloop
    return result
endfunction

//==================================================================================================================
// Multiboard Utils
//==================================================================================================================
function PlayerToMultboardRow takes player p returns integer
    local integer i = 0
    local integer result = 0
    local player tempPlayer
    loop
        set tempPlayer = Player(i)
        if GetPlayerSlotState(tempPlayer) != PLAYER_SLOT_STATE_EMPTY then
            set result = result + 1
        endif
        set i = i + 1
        exitwhen i == 4 or tempPlayer == p
    endloop
    set tempPlayer = null
    return 3 + result
endfunction