1. Are you planning to upload your awesome spell or system to Hive? Please review the rules here.
    Dismiss Notice
  2. Updated Resource Submission Rules: All model & skin resource submissions must now include an in-game screenshot. This is to help speed up the moderation process and to show how the model and/or texture looks like from the in-game camera.
    Dismiss Notice
  3. The 15th Mini-Mapping Contest came to an end. The Secrets of Warcraft 3 are soon to be revealed! Come and vote in the public poll for your favorite maps.
    Dismiss Notice
  4. The 12th incarnation of the Music Contest is LIVE! The theme is Synthwave. Knight Rider needs a song to listen to on his journey. You should definitely have some fun with this theme!
    Dismiss Notice
  5. Join other hivers in a friendly concept-art contest. The contestants have to create a genie coming out of its container. We wish you the best of luck!
    Dismiss Notice
  6. Check out the Staff job openings thread.
    Dismiss Notice
Dismiss Notice
60,000 passwords have been reset on July 8, 2019. If you cannot login, read this.

Trigger Viewer

Savior's Aura v1.1.w3x
Variables
Savior's Aura
How to Import
SaviorAuraTriggerConfiguration
SaviorAuraEffect
SaviorAuraLearn
SaviorAuraUnlearn
DamageLibrary
DamageEvent
OnDamage
VariableCreator
Enter map-specific custom script code below. This text will be included in the map script after variables are declared and before any trigger code.

		
Name Type Is Array Initial Value
allocatedAttacks integer No
allocCounter integer No
amount real No
ATTACK_TYPE_UNIVERSAL attacktype No
BRACERS_SPELL_DAMAGE_REDUCTION real No
CODE integer No
DAMAGE_TYPE_DETECTOR integer No
damageEvent trigger No
damageEventTrigger real No
damageHandler trigger No
damageType integer No
ETHEREAL_DAMAGE_FACTOR real No
h hashtable No
PHYSICAL integer No
pureAmount real No
runAllocatedAttacks trigger No
SA_A_ActiveAbility abilcode No
SA_A_PassiveAbility abilcode No
SA_A_Unlearn abilcode Yes
SA_B_UseStat boolean No
SA_BF_Buff buffcode No
SA_I_Level integer No
SA_I_TempInt integer No
SA_I_Total integer No
SA_P_AtkPos location No
SA_PL_Player player No
SA_R_AoE real Yes
SA_R_Heal real Yes
SA_R_HealAmt real No
SA_S_Attach string No
SA_S_SFX string No
SA_U_AtkUnit unit No
SA_U_Picked unit No
SA_U_TempUnit unit No
SA_UG_UnitGroup group No
SET_MAX_LIFE integer No
source unit No
SPELL integer No
SPELL_DAMAGE_REDUCTION_ITEM integer No
SPELL_RESISTANCE_AUTO_DETECT boolean No
target unit No
totalAllocs integer No
TRIGGER_CLEANUP_PERIOD real No
UNIT_MIN_LIFE real No
1. Copy the ability and the buff from the object editor
2. Add the passive ability to the container
3. Make sure that the passive ability emits the right buff
4. Add the passive ability to the container ability
5. Add the active ability to the hero that you want to have the aura.
3. Go to the main window of the World editor and click file>preferences> then check automatically create unknown variable while pasting trigger data
4. Edit the configuration trigger
5. Have fun with the spell
SaviorAuraTriggerConfiguration
  Events
    Time - Elapsed game time is 0.00 seconds
  Conditions
  Actions
    -------- set the ability that will be the basis for the aura --------
    -------- - --------
    Set SA_A_PassiveAbility = Savior's Aura (Container)
    Set SA_A_ActiveAbility = Savior's Aura (Active)
    -------- - --------
    -------- set the buff that the ability will emit --------
    -------- - --------
    Set SA_BF_Buff = Savior's Aura
    -------- - --------
    -------- if set to true, the amount healed will be based on the percentage of strength of the hero --------
    -------- if set to false, the number will directly heal units --------
    -------- please note that 20% is 20.00 and not 0.2 --------
    -------- - --------
    Set SA_B_UseStat = True
    -------- - --------
    Set SA_R_Heal[1] = 30.00
    Set SA_R_Heal[2] = 60.00
    Set SA_R_Heal[3] = 90.00
    Set SA_R_Heal[4] = 120.00
    -------- - --------
    -------- special effects configurables --------
    -------- attachment point --------
    -------- - --------
    Set SA_S_Attach = origin
    -------- - --------
    -------- special effects attached to unit --------
    -------- - --------
    Set SA_S_SFX = Abilities\Spells\Undead\VampiricAura\VampiricAuraTarget.mdl
    -------- - --------
    -------- Area of effect of the aura --------
    -------- - --------
    Set SA_R_AoE[1] = 500.00
    Set SA_R_AoE[2] = 500.00
    Set SA_R_AoE[3] = 500.00
    Set SA_R_AoE[4] = 500.00
    -------- - --------
    -------- list abilities that unlearns all hero skills --------
    -------- SA_A_Total is the total number of abilities that can unlearn the spell --------
    -------- - --------
    Set SA_I_Total = 1
    -------- - --------
    Set SA_A_Unlearn[1] = Tome of Retraining
    -------- - --------
    -------- Disable spellbook --------
    -------- - --------
    For each (Integer SA_I_TempInt) from 1 to 12, do (Actions)
      Loop - Actions
        -------- - --------
        -------- Disable the spellbook --------
        -------- - --------
        Player - Disable SA_A_PassiveAbility for (Player(SA_I_TempInt))
    Custom script: set bj_wantDestroyGroup=true
    -------- - --------
    -------- Check if any there are units that already learnt the ability --------
    -------- - --------
    Unit Group - Pick every unit in (Units in (Playable map area)) and do (Actions)
      Loop - Actions
        -------- - --------
        -------- add the picked unit into a variable --------
        -------- - --------
        Set SA_U_Picked = (Picked unit)
        -------- - --------
        -------- Check if the unit has leveled the ability --------
        -------- - --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (Level of SA_A_ActiveAbility for SA_U_Picked) Greater than 0
          Then - Actions
            -------- - --------
            -------- add the actual aura to the picked unit --------
            -------- - --------
            Unit - Add SA_A_PassiveAbility to SA_U_Picked
          Else - Actions
SaviorAuraEffect
  Events
    Game - damageEventTrigger becomes Equal to 1.00
  Conditions
    (Level of SA_A_ActiveAbility for target) Greater than 0
    (source belongs to an enemy of (Owner of target)) Equal to True
  Actions
    -------- - --------
    -------- Set the attacked unit --------
    -------- - --------
    Set SA_U_AtkUnit = target
    -------- - --------
    -------- Determine the owner of the unit --------
    -------- - --------
    Set SA_PL_Player = (Owner of SA_U_AtkUnit)
    -------- - --------
    -------- set the level of the ability into a variable --------
    -------- - --------
    Set SA_I_Level = (Level of SA_A_ActiveAbility for SA_U_AtkUnit)
    -------- - --------
    -------- Checks on what value should be applied on the aura's healing effect --------
    -------- - --------
    If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      If - Conditions
        SA_B_UseStat Equal to True
      Then - Actions
        -------- - --------
        -------- if this is applied then the heal value is equal to a certain percentage of the attacked unit's strength --------
        -------- - --------
        Set SA_R_HealAmt = ((Real((Strength of SA_U_AtkUnit (Include bonuses)))) x (SA_R_Heal[SA_I_Level] x 0.01))
      Else - Actions
        -------- - --------
        -------- if this is applied, then the heal amount is equal to the predefined value in the trigger configuration --------
        -------- - --------
        Set SA_R_HealAmt = SA_R_Heal[SA_I_Level]
    -------- - --------
    -------- sets the position of the attacked units into a variable --------
    -------- - --------
    Set SA_P_AtkPos = (Position of SA_U_AtkUnit)
    -------- - --------
    -------- selects the valid units that can be healed --------
    -------- - --------
    Set SA_UG_UnitGroup = (Units within SA_R_AoE[SA_I_Level] of SA_P_AtkPos)
    -------- - --------
    -------- heals the picked units --------
    -------- - --------
    Unit Group - Pick every unit in SA_UG_UnitGroup and do (Actions)
      Loop - Actions
        Set SA_U_Picked = (Picked unit)
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (SA_U_Picked is dead) Equal to False
            (SA_U_Picked belongs to an ally of SA_PL_Player) Equal to True
            (SA_U_Picked is A structure) Equal to False
            (SA_U_Picked is Magic Immune) Equal to False
            (SA_U_Picked has buff SA_BF_Buff) Equal to True
            (Level of SA_A_PassiveAbility for SA_U_Picked) Less than 1
          Then - Actions
            -------- - --------
            -------- sets the picked unit into a variable --------
            -------- its ok to recycle this variable isn't it? --------
            -------- - --------
            -------- - --------
            -------- Heals the picked unit --------
            -------- - --------
            Unit - Set life of SA_U_Picked to ((Life of SA_U_Picked) + SA_R_HealAmt)
            -------- - --------
            -------- Add some visuals --------
            -------- - --------
            Special Effect - Create a special effect attached to the SA_S_Attach of SA_U_Picked using SA_S_SFX
            -------- - --------
            -------- destroy visuals to prevent leaks --------
            -------- - --------
            Special Effect - Destroy (Last created special effect)
          Else - Actions
        Set SA_U_Picked = No unit
    -------- - --------
    -------- Clean up --------
    -------- - --------
    -------- SA_UG_UnitGroup.Clear(); --------
    -------- Clear the unit group --------
    -------- - --------
    Unit Group - Remove all units from SA_UG_UnitGroup
    -------- - --------
    -------- Destroy the instance of the unit group --------
    -------- - --------
    Custom script: call DestroyGroup(udg_SA_UG_UnitGroup)
    -------- - --------
    -------- Destroy the point --------
    -------- - --------
    Custom script: call RemoveLocation(udg_SA_P_AtkPos)
SaviorAuraLearn
  Events
    Unit - A unit Learns a skill
  Conditions
    (Level of SA_A_ActiveAbility for (Triggering unit)) Greater than 0
    (Learned Hero Skill) Equal to Savior's Aura (Active)
  Actions
    -------- - --------
    -------- set the learning unit into a variable --------
    -------- - --------
    Set SA_U_TempUnit = (Triggering unit)
    -------- - --------
    -------- add the aura effect into the learning hero --------
    -------- - --------
    Unit - Add SA_A_PassiveAbility to SA_U_TempUnit
SaviorAuraUnlearn
  Events
    Unit - A unit Starts the effect of an ability
  Conditions
  Actions
    -------- - --------
    -------- This is needed if the hero unlearns the aura --------
    -------- This is coded like this just is case there are other abilities that enables hero to --------
    -------- unlearn the aura --------
    -------- - --------
    For each (Integer SA_I_TempInt) from 1 to SA_I_Total, do (Actions)
      Loop - Actions
        -------- - --------
        -------- This will loop through the abilities that allows hero to unlearn the aura --------
        -------- - --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (Ability being cast) Equal to SA_A_Unlearn[SA_I_TempInt]
          Then - Actions
            -------- - --------
            -------- This will remove the aura from the hero --------
            -------- - --------
            Unit - Remove SA_A_PassiveAbility from (Triggering unit)
          Else - Actions
////////////////////////////////////////////////////////////////////////////////////
//
//  Physical Damage Detection Engine GUI v 1.1.2.0
//  ----------------------------------------------
//  By looking_for_help aka eey
//
//  This system is able to detect, modify and deal damage. It can differentiate
//  between physical and spell damage, as well as block, reduce or increase the
//  applied damage to a desired value. You can also allocate damage events from
//  running damage events.
//
//  This is the GUI version of the system, meaning that you can use this with the
//  standard editor and basically without any knowledge of JASS.
//
////////////////////////////////////////////////////////////////////////////////////
//
//  Implementation
//  --------------
//  1.  Create all variables that this system uses (compare the variable editor).
//      You don't have to set them to specific values, they get initialized
//      automatically by the system so just create them.
//  2.  Copy this trigger to your map. You can then add damage handlers by using
//      the event "value of real variable becomes equal to 1" with the variable
//      damageEventTrigger. Compare the OnDamage trigger for an example usage.
//  3.  Copy the two custom abilities to your map and make sure they have the
//      correct ID. You can specify the ID in the function InitGlobalVariables
//      above.
//  4.  Go to the locust swarm ability and invert its damage return portion
//      from (default) 0.75 to -0.75.
//  5.  Remove the spell damage reduction ability from the spell damage reduction
//      items you use (runed bracers). You can configure the resistance of this
//      item in the InitGlobalVariables function, modifying the golbal variable
//      BRACERS_SPELL_DAMAGE_REDUCTION.
//
////////////////////////////////////////////////////////////////////////////////////
//
//  Important Notes
//  ---------------
//  1.  Life Drain does not work with this system, so you should use a triggered
//      version of this spell if you want to use it.
//  2.  Same for Finger of Death, if you want to use this spell bug free with this
//      system, you should use a triggered version of it.
//  3.  If you use damage modifiers by setting the damage amount variable, you have
//      to use GetUnitLife, GetUnitMaxLife and SetUnitLife instead of GetWidgetLife,
//      GetUnitState for UNIT_STATE_MAX_LIFE and SetWidgetLife in your whole map to
//      ensure there occure no bugs.
//  4.  The boolean USE_SPELL_RESISTANCE_AUTO_DETECT is only neccessary set to true
//      if you want to use a customized damage table with spell damage resistance
//      above 100%. If this is not the case, it should be set to false, as the
//      system is faster then and still works correct.
//  5.  As already mentioned you can't use the spell reduction ability when using this
//      system (runed bracers and elunes grace). If you want to use them, you can
//      trigger them by using the damage modifiers. Runed bracers is already considered
//      in this system, so you don't have to code it.
//
////////////////////////////////////////////////////////////////////////////////////
//  
//  System API
//  ----------
//  real damageEventTrigger
//      - Use the event "value of real variable becomes equal to 1" to detect a damage
//        event. In this event you can use the following API. Compare the OnDamage
//        trigger for an example usage.
//
//  unit target
//      - In this global unit variable, the damaged unit is saved. Don't write any-
//        thing into this variable, use it as readonly.
//
//  unit source
//      - In this global unit variable, the damage source is saved. Don't write any-
//        thing into this variable, use it as readonly.
//
//  real amount
//      - In this global real variable, the amount of damage is saved. This amount
//        can be modified by simply setting it to the desired amount that should be
//        applied to the target. Set the amount to 0.0 to block the damage completly.
//        Negative values will result in heal.
//
//  integer damageType
//      - In this global integer variable, the damage type of the current damage is
//        saved. Use it to differentiate between physical, spell and code damage. The
//        variable can takes the values PHYSICAL == 0, SPELL == 1 and CODE == 2. Don't
//        write anything into this variable, use it as readonly.        
//
//  function GetUnitLife takes unit u returns real
//      - Use this function instead of the GetWidgetLife native. It ensures that you
//        get the correct health value, even when damage modifiers are applied. If
//        you don't use damage modifiers at all, you don't need this function.
//
//  function GetUnitMaxLife takes unit u returns real
//      - Use this function instead of the GetUnitState(u, UNIT_STATE_MAX_LIFE) native.
//        It will return the correct value, even when damage modifiers are applied. If
//        you don't use damage modifiers at all, you don't need this function.
//
//  function SetUnitLife takes unit u, real newLife returns nothing
//      - Use this function instead of the SetWidgetLife(u, newLife) native if you use
//        damage modifiers in your map. Same rules as for the GetUnitMaxLife and the
//        GetUnitMaxLife functions.
//
//  function AddDamageHandler takes code damageHandler returns nothing
//      - Allows you to add a damage handler function to the system. This is not
//        required for GUI users, only for vanilla JASS users. GUI users should
//        use the real variable damageEventTrigger to add damage handlers to this
//        system as explained above.
//
//  function RemoveDamageHandler takes code damageHandler returns nothing
//      - Allows you to remove a damage handler function from the system dynamic-
//        ally. If you added the same handler function multiple times to the sys-
//        tem, this function will remove all of these equal functions. This is not
//        required for GUI users, only for vanilla JASS users.
//
//////////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////////
//  Configurable globals
//////////////////////////////////////////////////////////////////////////////////

function InitGlobalVariables takes nothing returns nothing
    // Put here the correct ability IDs
    set udg_DAMAGE_TYPE_DETECTOR = 'A003'
    set udg_SET_MAX_LIFE = 'A004'
   
    // Here you can configure some stuff, read the documentation for further info
    set udg_SPELL_DAMAGE_REDUCTION_ITEM = 'brac'
    set udg_SPELL_RESISTANCE_AUTO_DETECT = false
    set udg_ETHEREAL_DAMAGE_FACTOR = 1.66
    set udg_BRACERS_SPELL_DAMAGE_REDUCTION = 0.33
    set udg_TRIGGER_CLEANUP_PERIOD = 60.0
endfunction

//////////////////////////////////////////////////////////////////////////////////
//  End of configurable globals
//////////////////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////////////////
//  User functions
//////////////////////////////////////////////////////////////////////////////////

function AddDamageHandler takes code func returns nothing
    local integer id = GetHandleId(Condition(func))
    local integer index = 0
   
    // Loop to manage equal damage handlers
    loop
        exitwhen ( LoadTriggerConditionHandle(udg_h, id, index) == null )
        set index = index + 1
    endloop
   
    // Store the desired damage handler function
    call SaveTriggerConditionHandle(udg_h, id, index, TriggerAddCondition(udg_damageHandler, Filter(func)))
endfunction

function RemoveDamageHandler takes code func returns nothing
    local integer id = GetHandleId(Condition(func))
    local integer index = 0
   
    // Loop through all equal damage handlers
    loop
        exitwhen ( LoadTriggerConditionHandle(udg_h, id, index) == null )
        call TriggerRemoveCondition(udg_damageHandler, LoadTriggerConditionHandle(udg_h, id, index))
        set index = index + 1
    endloop
   
    // Clean things up
    call FlushChildHashtable(udg_h, id)
endfunction

function GetUnitLife takes unit u returns real
    local boolean duringModification
    local integer uId = GetHandleId(u)
    local real health
    local real storedHealth = LoadReal(udg_h, uId, 2)
    local real storedDamage = LoadReal(udg_h, uId, 1)
   
    // Check if the unit is being rescued from damage
    set duringModification = GetUnitAbilityLevel(u, udg_SET_MAX_LIFE) > 0
    if duringModification then
        call UnitRemoveAbility(u, udg_SET_MAX_LIFE)
    endif

    // Get the correct health value of the unit
    if storedHealth != 0.0 then
        set health = storedHealth - storedDamage
    else
        set health = GetWidgetLife(u) - storedDamage
    endif

    // Restore the rescue ability and return
    if duringModification then
        call UnitAddAbility(u, udg_SET_MAX_LIFE)
    endif
    return health
endfunction

function GetUnitMaxLife takes unit u returns real
    local real maxHealth
   
    // Check if the unit is being rescued from damage
    if GetUnitAbilityLevel(u, udg_SET_MAX_LIFE) > 0 then
        call UnitRemoveAbility(u, udg_SET_MAX_LIFE)
        set maxHealth = GetUnitState(u, UNIT_STATE_MAX_LIFE)
        call UnitAddAbility(u, udg_SET_MAX_LIFE)
        return maxHealth
    endif
   
    // If the unit isn't being rescued, use the standard native
    return GetUnitState(u, UNIT_STATE_MAX_LIFE)
endfunction

function SetUnitLife takes unit u, real newLife returns nothing
    local integer targetId
    local integer oldTimerId
    local real oldHealth

    // Check if the unit is being rescued from damage
    if GetUnitAbilityLevel(u, udg_SET_MAX_LIFE) > 0 then
        call UnitRemoveAbility(u, udg_SET_MAX_LIFE)
        call SetWidgetLife(u, newLife)
        call UnitAddAbility(u, udg_SET_MAX_LIFE)
       
        // Get the unit specific timer information
        set targetId = GetHandleId(u)
        set oldHealth = LoadReal(udg_h, targetId, 0)
       
        // Update the unit specific timer information
        if oldHealth != 0.0 then
            set oldTimerId = LoadInteger(udg_h, targetId, 3)
            call SaveReal(udg_h, targetId, 2, newLife)
            call SaveReal(udg_h, targetId, 0, newLife)
            call SaveReal(udg_h, oldTimerId, 4, newLife)
        endif
        return
    endif
   
    // If the unit isn't being rescued, use the standard native
    call SetWidgetLife(u, newLife)
endfunction

function UnitDamageTargetEx takes unit localSource, unit localTarget, real localAmount, boolean attack, boolean ranged, attacktype localAttackType, damagetype localDamageType, weapontype localWeaponType returns boolean
    // Avoid infinite loop due to recursion
    if udg_damageType == udg_CODE then
        return false
    endif
   
    // Avoid allocating attacks on units that are about to be killed
    if ( localTarget == udg_target and GetUnitLife(localTarget) - udg_amount < udg_UNIT_MIN_LIFE ) then
        return false
    endif
   
    // Store all damage parameters determined by the user
    set udg_allocatedAttacks = udg_allocatedAttacks + 1
    call SaveUnitHandle(udg_h, udg_allocatedAttacks, 0, localSource)
    call SaveUnitHandle(udg_h, udg_allocatedAttacks, 1, localTarget)
    call SaveReal(udg_h, udg_allocatedAttacks, 2, localAmount)
    call SaveBoolean(udg_h, udg_allocatedAttacks, 3, attack)
    call SaveBoolean(udg_h, udg_allocatedAttacks, 4, ranged)
    call SaveInteger(udg_h, udg_allocatedAttacks, 5, GetHandleId(localAttackType))
    call SaveInteger(udg_h, udg_allocatedAttacks, 6, GetHandleId(localDamageType))
    call SaveInteger(udg_h, udg_allocatedAttacks, 7, GetHandleId(localWeaponType))

    // Return true if the damage was allocated
    return true
endfunction

////////////////////////////////////////////////////////////////////////////////////
//  Sub functions
////////////////////////////////////////////////////////////////////////////////////

function DealFixDamage takes unit source, unit target, real pureAmount returns nothing
    local real MAX_DAMAGE = 1000000.0
    local real beforeHitpoints
    local real newHitpoints

    // Ensure the amount is positive
    if pureAmount < 0 then
        set pureAmount = -pureAmount
    endif

    // Save the targets hitpoints
    set beforeHitpoints = GetWidgetLife(target)
    set newHitpoints = beforeHitpoints - pureAmount

    // Apply the desired, fixed amount
    if newHitpoints >= udg_UNIT_MIN_LIFE then
        call SetUnitState(target, UNIT_STATE_LIFE, newHitpoints)
    else
        if ( IsUnitType(target, UNIT_TYPE_ETHEREAL) == false ) then
            call SetWidgetLife(target, 1.0)
            call UnitDamageTarget(source, target, MAX_DAMAGE, true, false, udg_ATTACK_TYPE_UNIVERSAL, DAMAGE_TYPE_UNIVERSAL, null)
            call SetWidgetLife(target, 0.0)
        else
            call UnitRemoveAbility(target, udg_DAMAGE_TYPE_DETECTOR)
            call SetWidgetLife(target, 1.0)
            call UnitDamageTarget(source, target, MAX_DAMAGE, true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_UNIVERSAL, null)
            call SetWidgetLife(target, 0.0)
        endif
    endif
endfunction

function GetUnitSpellResistance takes unit u returns real
    local real originalHP
    local real beforeHP
    local real afterHP
    local real resistance
    local real DUMMY_DAMAGE = 100
    local real DUMMY_FACTOR = 0.01
   
    // Deal spell damage in order to get the units resistance
    call UnitRemoveAbility(udg_target, udg_DAMAGE_TYPE_DETECTOR)
    set originalHP = GetWidgetLife(udg_target)
    call UnitAddAbility(udg_target, udg_SET_MAX_LIFE)
    call SetWidgetLife(udg_target, 20000.0)
    set beforeHP = GetWidgetLife(udg_target)
    call DisableTrigger(udg_damageEvent)
    call UnitDamageTarget(udg_source, udg_target, DUMMY_DAMAGE, true, false, null, DAMAGE_TYPE_UNIVERSAL, null)
    call EnableTrigger(udg_damageEvent)
    set afterHP = GetWidgetLife(udg_target)
    call UnitRemoveAbility(udg_target, udg_SET_MAX_LIFE)
    call SetWidgetLife(udg_target, originalHP)
    call UnitAddAbility(udg_target, udg_DAMAGE_TYPE_DETECTOR)
    call UnitMakeAbilityPermanent(udg_target, true, udg_DAMAGE_TYPE_DETECTOR)

    // Calculate this resistance
    set resistance = DUMMY_FACTOR*(beforeHP - afterHP)

    // If the resistance was greater than 100%, return it
    if resistance > 1.0 then
        return resistance
    else
        return 1.0
    endif
endfunction

function UnitHasItemOfType takes unit u, integer itemId returns integer
    local integer index = 0
    local item indexItem

    // Check if the target has a spell damage reducing item
    loop
        set indexItem = UnitItemInSlot(u, index)
        if ( indexItem != null ) and ( GetItemTypeId(indexItem) == itemId ) then
            return index + 1
        endif

        set index = index + 1
        exitwhen index >= bj_MAX_INVENTORY
    endloop
    return 0
endfunction


////////////////////////////////////////////////////////////////////////////////////
//  Damage Engine
////////////////////////////////////////////////////////////////////////////////////

function AfterDamage takes nothing returns nothing
    local timer time = GetExpiredTimer()
    local integer id = GetHandleId(time)
    local unit localSource = LoadUnitHandle(udg_h, id, 0)
    local unit localTarget = LoadUnitHandle(udg_h, id, 1)
    local real pureAmount = LoadReal(udg_h, id, 2)
    local real amount = LoadReal(udg_h, id, 3)
    local real originalHealth = LoadReal(udg_h, id, 4)

    // If the damage was modified, restore units health
    if originalHealth != 0.0 then
        call UnitRemoveAbility(localTarget, udg_SET_MAX_LIFE)
        call SetWidgetLife(localTarget, originalHealth)
    endif

    // Apply the desired amount of damage
    if amount > 0.0 then
        call DisableTrigger(udg_damageEvent)
        call DealFixDamage(localSource, localTarget, amount)
        call EnableTrigger(udg_damageEvent)
    else
        call SetWidgetLife(localTarget, originalHealth - amount)
    endif
   
    // Clean things up
    call FlushChildHashtable(udg_h, id)
    call FlushChildHashtable(udg_h, GetHandleId(localTarget))
    call DestroyTimer(time)
    set time = null
    set localSource = null
    set localTarget = null
endfunction

function DamageEngine takes nothing returns nothing
    local timer time
    local integer id
    local real health
    local real rawAmount
    local real originalHealth
    local integer targetId
    local integer oldTimerId
    local real oldHealth
    local real oldOriginalHealth
    local real oldAmount

    // Set damage variables  
    set udg_source = GetEventDamageSource()
    set udg_target = GetTriggerUnit()
    set rawAmount = GetEventDamage()
   
    // Determine the damage type
    if udg_damageType == udg_CODE and rawAmount != 0.0 then
        set udg_damageType = udg_CODE
    elseif rawAmount > 0.0 then
        set udg_damageType = udg_PHYSICAL
    elseif rawAmount < 0.0 then
        set udg_damageType = udg_SPELL
    else
        return
    endif
   
    // Correct the damage amount
    if rawAmount < 0.0 then
        set udg_amount = -rawAmount
    else
        set udg_amount = rawAmount
    endif
   
    // Register spell reduction above 100%
    if udg_SPELL_RESISTANCE_AUTO_DETECT then
        set udg_amount = GetUnitSpellResistance(udg_target)*udg_amount
    else
        if ( IsUnitType(udg_target, UNIT_TYPE_ETHEREAL) and IsUnitEnemy(udg_target, GetOwningPlayer(udg_source)) and rawAmount < 0.0 ) then
            set udg_amount = udg_ETHEREAL_DAMAGE_FACTOR*udg_amount
        endif
    endif
   
    // Register spell damage reducing items like runed bracers
    if ( IsUnitType(udg_target, UNIT_TYPE_HERO) and UnitHasItemOfType(udg_target, udg_SPELL_DAMAGE_REDUCTION_ITEM) > 0 ) and rawAmount < 0.0 then
        set udg_amount = (1 - udg_BRACERS_SPELL_DAMAGE_REDUCTION)*udg_amount
    endif
   
    // Save health and damage variables
    if udg_damageType != udg_CODE then
        call UnitRemoveAbility(udg_target, udg_SET_MAX_LIFE)
    endif
    set udg_pureAmount = udg_amount
    set originalHealth = GetWidgetLife(udg_target)
    set oldTimerId = 0
   
    // Call damage handlers
    set udg_damageEventTrigger = 1.0
    set udg_damageEventTrigger = 0.0

    // If the damage was modified, apply the rescue ability
    if udg_amount != udg_pureAmount then
        call UnitAddAbility(udg_target, udg_SET_MAX_LIFE)
        call SetWidgetLife(udg_target, GetWidgetLife(udg_target) + udg_pureAmount)
    endif
   
    // Check if a previous timer didn't yet expire
    set targetId = GetHandleId(udg_target)
    set oldHealth = LoadReal(udg_h, targetId, 0)
   
    // If this is the case, update the timer information
    if oldHealth != 0.0 then
        set oldTimerId = LoadInteger(udg_h, targetId, 3)
        set oldOriginalHealth = LoadReal(udg_h, targetId, 2)
        set oldAmount = LoadReal(udg_h, targetId, 1)
        set originalHealth = oldOriginalHealth - oldAmount
        call SaveReal(udg_h, oldTimerId, 4, oldOriginalHealth)
    endif

    // Call after damage event if damage was spell, modified, code or parallel
    if ( rawAmount < 0.0 or udg_pureAmount != udg_amount or oldTimerId != 0 or udg_allocatedAttacks > 0 ) then
        set time = CreateTimer()
        set id = GetHandleId(time)
       
        // Save handles for after damage event
        call SaveUnitHandle(udg_h, id, 0, udg_source)
        call SaveUnitHandle(udg_h, id, 1, udg_target)
        call SaveReal(udg_h, id, 2, udg_pureAmount)
        call SaveReal(udg_h, id, 3, udg_amount)
        call SaveReal(udg_h, id, 4, originalHealth)

        // Save this extra to manage parallel damage instances
        call SaveReal(udg_h, targetId, 0, GetWidgetLife(udg_target))
        call SaveReal(udg_h, targetId, 1, udg_amount)
        call SaveReal(udg_h, targetId, 2, originalHealth)
        call SaveInteger(udg_h, targetId, 3, id)

        // Avoid healing of negative spell damage
        if rawAmount < 0.0 then
            call DisableTrigger(udg_damageEvent)
            call DealFixDamage(udg_source, udg_target, -rawAmount)
            if ( originalHealth - udg_amount < udg_UNIT_MIN_LIFE ) then
                call UnitRemoveAbility(udg_target, udg_SET_MAX_LIFE)
                call DealFixDamage(udg_source, udg_target, udg_amount)
            endif
            call EnableTrigger(udg_damageEvent)
        endif
       
        // Guarantee unit exploding
        if originalHealth - udg_amount < udg_UNIT_MIN_LIFE then
            if rawAmount > 0.0 then
                call UnitRemoveAbility(udg_target, udg_SET_MAX_LIFE)
                call SetWidgetLife(udg_target, udg_UNIT_MIN_LIFE)
            endif
        endif
       
        // Start the after damage event
        call TimerStart(time, 0.0, false, function AfterDamage)
    endif

    // Handle allocated attacks from UnitDamageTargetEx
    if udg_totalAllocs == 0 then
        set udg_totalAllocs = udg_allocatedAttacks
    endif
    if udg_allocatedAttacks > 0 then
        set udg_allocatedAttacks = udg_allocatedAttacks - 1
        set udg_allocCounter = udg_allocCounter + 1
        call TriggerEvaluate(udg_runAllocatedAttacks)
    endif

    // Reset all required variables
    set udg_damageType = -1
    set udg_totalAllocs = 0
    set udg_allocCounter = -1
endfunction


////////////////////////////////////////////////////////////////////////////////////
//  Initialization
////////////////////////////////////////////////////////////////////////////////////

function RestoreTriggers takes nothing returns nothing
    local unit enumUnit = GetEnumUnit()

    // Re-register units that are alive
    if GetWidgetLife(enumUnit) >= udg_UNIT_MIN_LIFE then
        call TriggerRegisterUnitEvent(udg_damageEvent, enumUnit, EVENT_UNIT_DAMAGED)
    endif
    set enumUnit = null
endfunction

function ClearMemory_Actions takes nothing returns nothing
    local group g = CreateGroup()
    local code c = function DamageEngine
   
    // Reset the damage event
    call GroupEnumUnitsInRect(g, GetWorldBounds(), null)
    call ResetTrigger(udg_damageEvent)
    call DestroyTrigger(udg_damageEvent)
    set udg_damageEvent = null
   
    // Rebuild it then
    set udg_damageEvent = CreateTrigger()
    call TriggerAddCondition(udg_damageEvent, Filter(c))
    call ForGroup(g, function RestoreTriggers)
   
    // Clean things up
    call DestroyGroup(g)
    set g = null
    set c = null
endfunction

function MapInit takes nothing returns nothing
    local unit enumUnit = GetEnumUnit()

    // Register units on map initialization
    call UnitAddAbility(enumUnit, udg_DAMAGE_TYPE_DETECTOR)
    call UnitMakeAbilityPermanent(enumUnit, true, udg_DAMAGE_TYPE_DETECTOR)
    call TriggerRegisterUnitEvent(udg_damageEvent, enumUnit, EVENT_UNIT_DAMAGED)
    set enumUnit = null
endfunction

function UnitEntersMap takes nothing returns nothing
    local unit triggerUnit = GetTriggerUnit()

    // Register units that enter the map
    if ( GetUnitAbilityLevel(triggerUnit, udg_DAMAGE_TYPE_DETECTOR) < 1 ) then
        call UnitAddAbility(triggerUnit, udg_DAMAGE_TYPE_DETECTOR)
        call UnitMakeAbilityPermanent(triggerUnit, true, udg_DAMAGE_TYPE_DETECTOR)
        call TriggerRegisterUnitEvent(udg_damageEvent, triggerUnit, EVENT_UNIT_DAMAGED)
    endif
    set triggerUnit = null
endfunction

function RunAllocatedAttacks takes nothing returns nothing
    local integer localAllocAttacks = udg_allocatedAttacks + 1

    // Calculate the correct sequence of allocated attacks
    set localAllocAttacks = localAllocAttacks - udg_totalAllocs + 1 + 2*udg_allocCounter
   
    // Deal code damage if the unit isn't exploding
    set udg_damageType = udg_CODE
    if GetUnitLife(LoadUnitHandle(udg_h, localAllocAttacks, 1)) >= udg_UNIT_MIN_LIFE then
        call UnitDamageTarget(LoadUnitHandle(udg_h, localAllocAttacks, 0), LoadUnitHandle(udg_h, localAllocAttacks, 1), LoadReal(udg_h, localAllocAttacks, 2), LoadBoolean(udg_h, localAllocAttacks, 3), LoadBoolean(udg_h, localAllocAttacks, 4), ConvertAttackType(LoadInteger(udg_h, localAllocAttacks, 5)), ConvertDamageType(LoadInteger(udg_h, localAllocAttacks, 6)), ConvertWeaponType(LoadInteger(udg_h, localAllocAttacks, 7)))
    else
        call FlushChildHashtable(udg_h, localAllocAttacks - 1)
    endif
   
    // Clean things up
    call FlushChildHashtable(udg_h, localAllocAttacks)
endfunction

function InitTrig_DamageEvent takes nothing returns nothing
    local group g = CreateGroup()
    local region r = CreateRegion()
    local trigger UnitEnters = CreateTrigger()
    local trigger ClearMemory = CreateTrigger()
    local code cDamageEngine = function DamageEngine
    local code cUnitEnters = function UnitEntersMap
    local code cClearMemory = function ClearMemory_Actions
    local code cRunAllocatedAttacks = function RunAllocatedAttacks
   
    // Initialize global variables
    set udg_h = InitHashtable()
    set udg_damageEvent = CreateTrigger()
    set udg_damageHandler = CreateTrigger()
    set udg_damageType = -1
    set udg_allocatedAttacks = 0
    set udg_runAllocatedAttacks = CreateTrigger()
   
    // Initialize global configurable constants
    call InitGlobalVariables()
   
    // Initialize global fixed constants
    set udg_PHYSICAL = 0
    set udg_SPELL = 1
    set udg_CODE = 2
    set udg_UNIT_MIN_LIFE = 0.406
    set udg_ATTACK_TYPE_UNIVERSAL = ConvertAttackType(7)
    set udg_totalAllocs = 0
    set udg_allocCounter = -1
    set udg_damageEventTrigger = 0.0
   
    // Register units on map initialization
    call TriggerRegisterVariableEvent(udg_damageHandler, "damageEventTrigger", EQUAL, 1.0)
    call TriggerAddCondition(udg_damageEvent, Filter(cDamageEngine))  
    call GroupEnumUnitsInRect(g, GetWorldBounds(), null)
    call ForGroup(g, function MapInit)
   
    // Register units that enter the map
    call RegionAddRect(r, GetWorldBounds())
    call TriggerRegisterEnterRegion(UnitEnters, r, null)
    call TriggerAddCondition(UnitEnters, Filter(cUnitEnters))
   
    // Register trigger for allocated attacks
    call TriggerAddCondition(udg_runAllocatedAttacks, Filter(cRunAllocatedAttacks))
   
    // Clear memory leaks
    call TriggerRegisterTimerEvent(ClearMemory, udg_TRIGGER_CLEANUP_PERIOD, true)
    call TriggerAddCondition(ClearMemory, Filter(cClearMemory))

    // Clean things up
    call DestroyGroup(g)
    set UnitEnters = null
    set ClearMemory = null
    set cDamageEngine = null
    set cUnitEnters = null
    set cClearMemory = null
    set cRunAllocatedAttacks = null
    set g = null
    set r = null
endfunction
 
OnDamage
  Events
    Game - damageEventTrigger becomes Equal to 1.00
  Conditions
  Actions
    If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      If - Conditions
        damageType Equal to PHYSICAL
      Then - Actions
        -------- Actions for PHYSICAL damage --------
        -------- Block all physical damage from the Archmage --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (target has buff Berserk) Equal to True
          Then - Actions
            Set amount = (amount x 0.50)
          Else - Actions
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            source Equal to Archmage 0001 <gen>
          Then - Actions
            Set amount = 0.00
          Else - Actions
        -------- Let the Blademaster heal 50 hitpoints on every attack --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            source Equal to Blademaster 0000 <gen>
          Then - Actions
            Set amount = -50.00
          Else - Actions
        Game - Display to (All players) for 10.00 seconds the text: ((Name of source) + ( damages + ((Name of target) + ( with damage: + (|cffff0000 + (String(amount)))))))
        -------- End of Actions for PHYISCAL damage --------
      Else - Actions
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            damageType Equal to SPELL
          Then - Actions
            -------- Actions for SPELL damage --------
            -------- Double all spell damage from the Mountain King --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                source Equal to Mountain King 0002 <gen>
              Then - Actions
                Set amount = (2.00 x amount)
              Else - Actions
            Game - Display to (All players) for 10.00 seconds the text: ((Name of source) + ( damages + ((Name of target) + ( with damage: + (|cff6495ed + (String(amount)))))))
            -------- End of Actions for SPELL damage --------
          Else - Actions
            -------- Actions for CODE damage --------
            Game - Display to (All players) for 10.00 seconds the text: ((Name of source) + ( damages + ((Name of target) + ( with damage: + (|cff32cd32 + (String(amount)))))))
            -------- End of Actions for CODE damage --------
    -------- Reflect 50 damage from the Kodo back on the damage source --------
    If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      If - Conditions
        target Equal to Kodo Beast 0006 <gen>
      Then - Actions
        Custom script: call UnitDamageTargetEx(udg_target, udg_source, 50.0, true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNIVERSAL, null)
      Else - Actions
Use this script to automatically create all variables in your map.

Copy this BEFORE the damage library to your map and save the map.
Make sure you checked "Automatically create unknown variables" in the preferences of the World Editor.

After the variables are created DELETE this trigger, then implement the DamageEvent library as explained
in the documentation.

You do not need to set the variables to a specific value, they get initialized automatically by the DamageEvent library, so just create them.
VariableCreator
  Events
  Conditions
  Actions
    Set ATTACK_TYPE_UNIVERSAL = Spells
    Set BRACERS_SPELL_DAMAGE_REDUCTION = 0.00
    Set CODE = 0
    Set DAMAGE_TYPE_DETECTOR = 0
    Set ETHEREAL_DAMAGE_FACTOR = 0.00
    Set PHYSICAL = 0
    Set SET_MAX_LIFE = 0
    Set SPELL = 0
    Set SPELL_DAMAGE_REDUCTION_ITEM = 0
    Set SPELL_RESISTANCE_AUTO_DETECT = False
    Set TRIGGER_CLEANUP_PERIOD = 0.00
    Set UNIT_MIN_LIFE = 0.00
    Set allocCounter = 0
    Set allocatedAttacks = 0
    Set amount = 0.00
    Set damageEvent = (Load 0 of 0 in (Last created hashtable))
    Set damageEventTrigger = 0.00
    Set damageHandler = (Load 0 of 0 in (Last created hashtable))
    Set damageType = 0
    Set h = (Last created hashtable)
    Set pureAmount = 0.00
    Set runAllocatedAttacks = (Load 0 of 0 in (Last created hashtable))
    Set source = (Load 0 of 0 in (Last created hashtable))
    Set target = (Load 0 of 0 in (Last created hashtable))
    Set totalAllocs = 0