1. Are you planning to upload your awesome spell or system to Hive? Please review the rules here.
    Dismiss Notice
  2. Seek unity between the elements in the 22nd Terraining Contest Poll.
    Dismiss Notice
  3. Seize the moment! The 18th Mini Mapping Contest has commenced.
    Dismiss Notice
  4. The heavens smile on the old faithful. The 16th Techtree Contest has begun.
    Dismiss Notice
  5. Check out the Staff job openings thread.
    Dismiss Notice
Dismiss Notice
60,000 passwords have been reset on July 8, 2019. If you cannot login, read this.

Trigger Viewer

Hammer_of_Thor.w3x
Variables
Initialization
Melee Initialization
Hammer of Thor
|ZZZZZZZZZZZZZZZZZZZZZZ|
|ZZZZZZZ| README |ZZZZZZZ|
Hammer of Thor
Hammer of Thor Move Up Down
Hammer of Thor Lightning Move
Hammer of Thor Slam
Hammer of Thor Up
Hammer of Thor Stun
|ZZZZZZZZZZZZZZZZZZZZZZ|
Level
Reset Unit
Revive
Greetings
Enter map-specific custom script code below. This text will be included in the map script after variables are declared and before any trigger code.

		
Name Type Is Array Initial Value
HoT_Const_AoE real No 600.00
HoT_Const_Dmg_Base real No 50.00
HoT_Const_Dmg_Bonus real No 25.00
HoT_Const_Dmg_Burn real No 24.00
HoT_Const_Dmg_Stun real No 75.00
HoT_Const_Dmg_Stun_Bonus real No 25.00
HoT_Const_Duration real No 8.00
HoT_Const_Range real No 600.00
HoT_Const_Stun_Duration real No 3.00
HoT_Group group No
HoT_Hash hashtable No
HoT_Lightning_Group group No
HoT_Slam_Group group No
HoT_Stun_Group group No
HoT_Targets group No
HoT_Up_Group group No
Temp_Group_1 group No
Temp_Lightning lightning No
Temp_Loc_1 location No
Temp_Loc_2 location No
Temp_Loc_3 location No
Temp_Real_1 real No
Temp_Real_2 real No
Temp_Real_3 real No
Temp_Unit_1 unit No
Temp_Unit_2 unit No
Temp_Unit_3 unit No
Temp_Unit_4 unit No
Default melee game initialization for all players
Melee Initialization
  Events
    Map initialization
  Conditions
  Actions
    Melee Game - Use melee time of day (for all players)
    -------- -------------------- --------
    Visibility - Create an initially Enabled visibility modifier for Player 1 (Red) emitting Visibility across (Playable map area)
    -------- -------------------- --------
    Hashtable - Create a hashtable
    Set VariableSet HoT_Hash = (Last created hashtable)
Hammer of Thor by Maker v1.08

You can edit the abiltity with the following variables. Use variable editor.

HoT_Const_AoE = Area inside which units get stunned and burned when the hammer slams down.

HoT_Const_Dmg_Base = The base damage of a projectile.
HoT_Const_Dmg_Bonus = Bonus damage per ability level.

The spell does
HoT_Const_Dmg_Base + HoT_Const_Dmg_Bonus * Ability_Level damage per projectile

HoT_Const_Dmg_Burn = Burn damage per second.

HoT_Const_Dmg_Stun = Base damage done when the hammer slams down.
HoT_Const_Dmg_Stun_Bonus = Bonus damage of the slam per ability level.

The spell does
HoT_Const_Dmg_Stunse + HoT_Const_Dmg_Stun_Bonus * Ability_Level damage with the slam.

HoT_Const_Duration = For how long the hammer shoots projectiles.
Hot_Const_Range = How far the projectiles will shoot.
Hot_Const_Stun_Duration = For how long the targets will get stunned and burned.
Hammer of Thor
  Events
    Unit - A unit Starts the effect of an ability
  Conditions
    (Ability being cast) Equal to Hammer of Thor
  Actions
    Set VariableSet HoT_Const_Duration = 8.00
    Set VariableSet HoT_Const_Stun_Duration = 3.00
    Set VariableSet HoT_Const_AoE = 600.00
    Set VariableSet HoT_Const_Range = 600.00
    Set VariableSet HoT_Const_Dmg_Burn = 24.00
    Set VariableSet HoT_Const_Dmg_Base = 50.00
    Set VariableSet HoT_Const_Dmg_Bonus = 25.00
    Set VariableSet HoT_Const_Dmg_Stun = 75.00
    Set VariableSet HoT_Const_Dmg_Stun_Bonus = 25.00
    -------- -------------------- --------
    Set VariableSet Temp_Unit_1 = (Triggering unit)
    -------- -------------------- --------
    Set VariableSet Temp_Loc_1 = (Position of Temp_Unit_1)
    -------- -------------------- --------
    Unit - Create 1.Hammer_of_Thor_Dummy for Neutral Passive at Temp_Loc_1 facing (Random angle) degrees
    Set VariableSet Temp_Unit_2 = (Last created unit)
    Custom script: call UnitAddAbility(udg_Temp_Unit_2, 'Aloc')
    -------- -------------------- --------
    Animation - Change Temp_Unit_2 flying height to 1500.00 at 0.00
    -------- -------------------- --------
    Special Effect - Create a special effect attached to the chest (attachpoint) of Temp_Unit_2 using Hammer_of_Thor.mdx
    Hashtable - Save Handle Of(Last created special effect) as (Key eff1.) of (Key (Last created unit).) in HoT_Hash.
    Special Effect - Create a special effect attached to the chest (attachpoint) of Temp_Unit_2 using Abilities\Spells\Other\ImmolationRed\ImmolationRedTarget.mdl
    Hashtable - Save Handle Of(Last created special effect) as (Key eff3.) of (Key (Last created unit).) in HoT_Hash.
    Special Effect - Create a special effect attached to the origin (attachpoint) of Temp_Unit_2 using Abilities\Spells\Human\Banish\BanishTarget.mdl
    Hashtable - Save Handle Of(Last created special effect) as (Key eff4.) of (Key (Last created unit).) in HoT_Hash.
    Special Effect - Create a special effect attached to the chest (attachpoint) of Temp_Unit_2 using Abilities\Spells\Items\AIob\AIobTarget.mdl
    Hashtable - Save Handle Of(Last created special effect) as (Key eff5.) of (Key (Last created unit).) in HoT_Hash.
    -------- -------------------- --------
    Hashtable - Save -0.99 as (Key time.) of (Key (Last created unit).) in HoT_Hash.
    Hashtable - Save 0.00 as (Key loop.) of (Key (Last created unit).) in HoT_Hash.
    Hashtable - Save Handle OfTemp_Unit_1 as (Key caster.) of (Key (Last created unit).) in HoT_Hash.
    Hashtable - Save Handle Of(Last created unit) as (Key hammer.) of (Key (Triggering unit).) in HoT_Hash.
    -------- -------------------- --------
    Unit Group - Add Temp_Unit_2 to HoT_Group
    -------- -------------------- --------
    Custom script: call RemoveLocation(udg_Temp_Loc_1)
    Custom script: call RemoveLocation(udg_Temp_Loc_2)
    -------- -------------------- --------
    Animation - Change Temp_Unit_2 flying height to 350.00 at 1000.00
    -------- -------------------- --------
    If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      If - Conditions
        (Hammer_of_Thor_Move_Up_Down <gen> is on) Equal to False
      Then - Actions
        Trigger - Turn on Hammer_of_Thor_Move_Up_Down <gen>
      Else - Actions
Hammer of Thor Move Up Down
  Events
    Time - Every 0.03 seconds of game time
  Conditions
  Actions
    Unit Group - Pick every unit in HoT_Group and do (Actions)
      Loop - Actions
        Set VariableSet Temp_Unit_1 = (Picked unit)
        Set VariableSet Temp_Unit_2 = (Load (Key caster.) of (Key (Picked unit).) in HoT_Hash.)
        -------- -------------------- --------
        Set VariableSet Temp_Real_1 = (Load (Key time.) of (Key (Picked unit).) from HoT_Hash.)
        -------- -------------------- --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            Temp_Real_1 Less than HoT_Const_Duration
            (Current order of Temp_Unit_2) Equal to (Order(chemicalrage))
          Then - Actions
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                Temp_Real_1 Less than 0.00
              Then - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                  If - Conditions
                    Temp_Real_1 Equal to -0.99
                  Then - Actions
                    Set VariableSet Temp_Loc_1 = (Position of Temp_Unit_1)
                    -------- -------------------- --------
                    Unit - Create 1.Hammer_of_Thor_Dummy for Neutral Passive at Temp_Loc_1 facing (Random angle) degrees
                    Set VariableSet Temp_Unit_2 = (Last created unit)
                    -------- -------------------- --------
                    Animation - Change Temp_Unit_2 flying height to 1500.00 at 0.00
                    Animation - Change Temp_Unit_2 flying height to 350.00 at 1000.00
                    -------- -------------------- --------
                    Special Effect - Create a special effect attached to the origin (attachpoint) of Temp_Unit_2 using Abilities\Spells\Human\ManaShield\ManaShieldCaster.mdl
                    Hashtable - Save Handle Of(Last created special effect) as (Key eff2.) of (Key (Picked unit).) in HoT_Hash.
                    -------- -------------------- --------
                    Hashtable - Save Handle Of(Last created unit) as (Key dummy.) of (Key (Picked unit).) in HoT_Hash.
                    -------- -------------------- --------
                    Custom script: call RemoveLocation(udg_Temp_Loc_1)
                  Else - Actions
                Hashtable - Save (Temp_Real_1 + 0.03) as (Key time.) of (Key (Picked unit).) in HoT_Hash.
              Else - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                  If - Conditions
                    Temp_Real_1 Less than HoT_Const_Duration
                  Then - Actions
                    Set VariableSet Temp_Real_2 = (Load (Key loop.) of (Key (Picked unit).) from HoT_Hash.)
                    -------- -------------------- --------
                    Animation - Change Temp_Unit_1 flying height to (350.00 + (30.00 x (Sin(Temp_Real_2)))) at 0.00
                    Animation - Change (Load (Key dummy.) of (Key (Picked unit).) in HoT_Hash.) flying height to (Current flying height of Temp_Unit_1) at 0.00
                    -------- -------------------- --------
                    Hashtable - Save (Temp_Real_1 + 0.03) as (Key time.) of (Key (Picked unit).) in HoT_Hash.
                    Hashtable - Save (Temp_Real_2 + 3.00) as (Key loop.) of (Key (Picked unit).) in HoT_Hash.
                    -------- -------------------- --------
                    If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                      If - Conditions
                        Or - Any (Conditions) are true
                          Conditions
                            And - All (Conditions) are true
                              Conditions
                                (Abs((Sin(Temp_Real_2)))) Greater than 0.68
                                (Abs((Sin(Temp_Real_2)))) Less than 0.72
                            And - All (Conditions) are true
                              Conditions
                                (Abs((Sin(Temp_Real_2)))) Less than 0.02
                      Then - Actions
                        -------- -------------------- --------
                        Set VariableSet Temp_Loc_1 = (Position of Temp_Unit_1)
                        -------- -------------------- --------
                        Set VariableSet Temp_Group_1 = (Units within HoT_Const_Range of Temp_Loc_1 matching (((((Matching unit) is alive) Equal to True) and (((Matching unit) is in HoT_Targets.) Equal to False)) and (((Owner of (Matching unit)) is an enemy of (Owner of Temp_Unit_2).) Equal to True)).)
                        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                          If - Conditions
                            (Temp_Group_1 is empty) Equal to False
                          Then - Actions
                            Set VariableSet Temp_Unit_3 = (Random unit from Temp_Group_1)
                            -------- -------------------- --------
                            Set VariableSet Temp_Loc_2 = (Position of Temp_Unit_3)
                            -------- -------------------- --------
                            Unit - Create 1.Hammer_of_Thor_Dummy for Neutral Passive at Temp_Loc_1 facing Default building facing degrees
                            Custom script: call UnitAddAbility(GetLastCreatedUnit(), 'Aloc')
                            Animation - Change (Last created unit) flying height to 350.00 at 0.00
                            -------- -------------------- --------
                            Special Effect - Create a special effect attached to the chest (attachpoint) of (Last created unit) using Abilities\Weapons\PhoenixMissile\Phoenix_Missile.mdl
                            Hashtable - Save Handle Of(Last created special effect) as (Key eff1.) of (Key (Last created unit).) in HoT_Hash.
                            -------- -------------------- --------
                            Hashtable - Save Handle OfTemp_Unit_2 as (Key caster.) of (Key (Last created unit).) in HoT_Hash.
                            Hashtable - Save Handle OfTemp_Unit_3 as (Key target.) of (Key (Last created unit).) in HoT_Hash.
                            -------- -------------------- --------
                            Unit Group - Add Temp_Unit_3 to HoT_Targets
                            Unit Group - Add (Last created unit) to HoT_Lightning_Group
                            -------- -------------------- --------
                            Custom script: call RemoveLocation(udg_Temp_Loc_2)
                            -------- -------------------- --------
                            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                              If - Conditions
                                (Hammer_of_Thor_Lightning_Move <gen> is on) Equal to False
                              Then - Actions
                                Trigger - Turn on Hammer_of_Thor_Lightning_Move <gen>
                              Else - Actions
                          Else - Actions
                        -------- -------------------- --------
                        Custom script: call DestroyGroup(udg_Temp_Group_1)
                        Custom script: call RemoveLocation(udg_Temp_Loc_1)
                      Else - Actions
                  Else - Actions
          Else - Actions
            Unit Group - Remove Temp_Unit_1 from HoT_Group.
            Unit Group - Add Temp_Unit_1 to HoT_Slam_Group
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Hammer_of_Thor_Slam <gen> is on) Equal to False
              Then - Actions
                Trigger - Turn on Hammer_of_Thor_Slam <gen>
              Else - Actions
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Number of units in HoT_Group) Equal to 0
              Then - Actions
                Trigger - Turn off (This trigger)
              Else - Actions
Hammer of Thor Lightning Move
  Events
    Time - Every 0.03 seconds of game time
  Conditions
  Actions
    Unit Group - Pick every unit in HoT_Lightning_Group and do (Actions)
      Loop - Actions
        Set VariableSet Temp_Unit_1 = (Picked unit)
        Set VariableSet Temp_Unit_2 = (Load (Key target.) of (Key (Picked unit).) in HoT_Hash.)
        -------- -------------------- --------
        Set VariableSet Temp_Loc_1 = (Position of Temp_Unit_1)
        Set VariableSet Temp_Loc_2 = (Position of Temp_Unit_2)
        -------- -------------------- --------
        Set VariableSet Temp_Real_1 = (Distance between Temp_Loc_1 and Temp_Loc_2)
        -------- -------------------- --------
        Set VariableSet Temp_Lightning = (Load (Key lightning.) of (Key (Picked unit).) in HoT_Hash.)
        Custom script: call DestroyLightning (udg_Temp_Lightning)
        -------- -------------------- --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (Temp_Unit_2 is alive) Equal to True
            Temp_Real_1 Greater than or equal to 16.00
          Then - Actions
            -------- -------------------- --------
            Set VariableSet Temp_Loc_3 = (Temp_Loc_1 offset by 25.00 towards (Angle from Temp_Loc_1 to Temp_Loc_2) degrees.)
            -------- -------------------- --------
            Unit - Move Temp_Unit_1 instantly to Temp_Loc_3
            Animation - Change Temp_Unit_1 flying height to ((Current flying height of Temp_Unit_1) - ((Current flying height of Temp_Unit_1) / (Temp_Real_1 / 25.00))) at 0.00
            Set VariableSet Temp_Real_1 = (Current flying height of Temp_Unit_1)
            -------- -------------------- --------
            Custom script: set udg_Temp_Real_2 = (GetLocationZ(udg_Temp_Loc_3) + udg_Temp_Real_1 + 60)
            Custom script: set udg_Temp_Real_3 = GetLocationZ(udg_Temp_Loc_2) + 60
            Custom script: set udg_Temp_Lightning = AddLightningEx( "AFOD" , true, GetLocationX(udg_Temp_Loc_3), GetLocationY(udg_Temp_Loc_3), udg_Temp_Real_2, GetLocationX(udg_Temp_Loc_2), GetLocationY(udg_Temp_Loc_2), udg_Temp_Real_3)
            -------- -------------------- --------
            Hashtable - Save Handle OfTemp_Lightning as (Key lightning.) of (Key (Picked unit).) in HoT_Hash.
            -------- -------------------- --------
            Custom script: call RemoveLocation(udg_Temp_Loc_3)
          Else - Actions
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Temp_Unit_2 is alive) Equal to True
              Then - Actions
                Set VariableSet Temp_Unit_3 = (Load (Key caster.) of (Key (Picked unit).) in HoT_Hash.)
                -------- -------------------- --------
                Unit - Cause Temp_Unit_3 to damage Temp_Unit_2, dealing (HoT_Const_Dmg_Base + (HoT_Const_Dmg_Bonus x (Real((Level of Hammer of Thor for Temp_Unit_3))))) damage of attack type Spells and damage type Normal
                -------- -------------------- --------
                Special Effect - Create a special effect attached to the origin (attachpoint) of Temp_Unit_2 using Abilities\Spells\NightElf\Blink\BlinkCaster.mdl
                Special Effect - Destroy (Last created special effect)
              Else - Actions
            Special Effect - Destroy (Load (Key eff1.) of (Key (Picked unit).) in HoT_Hash.)
            -------- -------------------- --------
            Hashtable - Clear all child hashtables of child (Key (Picked unit).) in HoT_Hash.
            -------- -------------------- --------
            Unit Group - Remove Temp_Unit_2 from HoT_Targets.
            Unit Group - Remove (Picked unit) from HoT_Lightning_Group.
            -------- -------------------- --------
            Unit - Add a 1.00 second Generic expiration timer to Temp_Unit_1
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Number of units in HoT_Lightning_Group) Equal to 0
              Then - Actions
                Trigger - Turn off (This trigger)
              Else - Actions
        -------- -------------------- --------
        Custom script: call RemoveLocation(udg_Temp_Loc_1)
        Custom script: call RemoveLocation(udg_Temp_Loc_2)
Hammer of Thor Slam
  Events
    Time - Every 0.03 seconds of game time
  Conditions
  Actions
    Unit Group - Pick every unit in HoT_Slam_Group and do (Actions)
      Loop - Actions
        Set VariableSet Temp_Unit_1 = (Picked unit)
        -------- -------------------- --------
        Set VariableSet Temp_Loc_1 = (Position of Temp_Unit_1)
        -------- -------------------- --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (Current flying height of Temp_Unit_1) Greater than 10.00
          Then - Actions
            Animation - Change Temp_Unit_1 flying height to ((Current flying height of Temp_Unit_1) - ((400.00 - (Current flying height of Temp_Unit_1)) / 10.00)) at 0.00
            Animation - Change (Load (Key dummy.) of (Key (Picked unit).) in HoT_Hash.) flying height to (Current flying height of Temp_Unit_1) at 0.00
          Else - Actions
            Set VariableSet Temp_Unit_2 = (Load (Key caster.) of (Key (Picked unit).) in HoT_Hash.)
            -------- -------------------- --------
            Unit - Create 1.Hammer_of_Thor_Dummy for Neutral Passive at Temp_Loc_1 facing Default building facing degrees
            Set VariableSet Temp_Unit_3 = (Last created unit)
            Unit - Add a 2.00 second Generic expiration timer to Temp_Unit_3
            Animation - Change Temp_Unit_3's size to (200.00%, 200.00%, 200.00%) of its original size
            -------- -------------------- --------
            Special Effect - Create a special effect attached to the origin (attachpoint) of Temp_Unit_3 using Abilities\Spells\Human\Thunderclap\ThunderClapCaster.mdl
            Special Effect - Destroy (Last created special effect)
            Special Effect - Create a special effect attached to the origin (attachpoint) of Temp_Unit_3 using Abilities\Spells\Orc\WarStomp\WarStompCaster.mdl
            Special Effect - Destroy (Last created special effect)
            -------- -------------------- --------
            Special Effect - Destroy (Load (Key eff2.) of (Key (Picked unit).) in HoT_Hash.)
            Special Effect - Destroy (Load (Key eff3.) of (Key (Picked unit).) in HoT_Hash.)
            -------- -------------------- --------
            Animation - Change (Load (Key dummy.) of (Key (Picked unit).) in HoT_Hash.) flying height to 5000.00 at 0.00
            Unit - Add a 3.00 second Generic expiration timer to (Load (Key dummy.) of (Key (Picked unit).) in HoT_Hash.)
            -------- -------------------- --------
            Set VariableSet Temp_Group_1 = (Units within HoT_Const_AoE of Temp_Loc_1 matching ((((Matching unit) is alive) Equal to True) and (((Owner of (Matching unit)) is an enemy of (Owner of Temp_Unit_2).) Equal to True)).)
            Unit Group - Pick every unit in Temp_Group_1 and do (Actions)
              Loop - Actions
                Set VariableSet Temp_Unit_4 = (Picked unit)
                Set VariableSet Temp_Loc_2 = (Position of Temp_Unit_4)
                -------- -------------------- --------
                Unit - Cause Temp_Unit_2 to damage Temp_Unit_4, dealing (HoT_Const_Dmg_Stun + (HoT_Const_Dmg_Stun_Bonus x (Real((Level of Hammer of Thor for Temp_Unit_2))))) damage of attack type Spells and damage type Normal
                -------- -------------------- --------
                Unit - Create 1.Hammer_of_Thor_Dummy for Neutral Passive at Temp_Loc_2 facing Default building facing degrees
                Unit - Order (Last created unit) to Human Mountain King - Storm Bolt.Temp_Unit_4
                Unit - Add a 1.00 second Generic expiration timer to (Last created unit)
                -------- -------------------- --------
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                  If - Conditions
                    (Temp_Unit_4 is in HoT_Stun_Group.) Equal to False
                  Then - Actions
                    Special Effect - Create a special effect attached to the chest (attachpoint) of Temp_Unit_4 using Abilities\Spells\Human\FlameStrike\FlameStrikeEmbers.mdl
                    Hashtable - Save Handle Of(Last created special effect) as (Key eff2.) of (Key (Picked unit).) in HoT_Hash.
                    Special Effect - Create a special effect attached to the chest (attachpoint) of Temp_Unit_4 using Abilities\Spells\Human\FlameStrike\FlameStrikeDamageTarget.mdl
                    Hashtable - Save Handle Of(Last created special effect) as (Key eff3.) of (Key (Picked unit).) in HoT_Hash.
                  Else - Actions
                -------- -------------------- --------
                Unit Group - Add Temp_Unit_4 to HoT_Stun_Group
                -------- -------------------- --------
                Hashtable - Save HoT_Const_Stun_Duration as (Key time.) of (Key (Picked unit).) in HoT_Hash.
            -------- -------------------- --------
            Environment - Create a 1.00 second Normal ripple deformation at Temp_Loc_1 with starting radius 0.00, ending radius 600.00, and depth 64, using 1 second ripples spaced 256.00 apart
            -------- -------------------- --------
            Unit Group - Remove Temp_Unit_1 from HoT_Slam_Group.
            Unit Group - Add Temp_Unit_1 to HoT_Up_Group
            -------- -------------------- --------
            Animation - Change Temp_Unit_1 flying height to 10.00 at 0.00
            -------- -------------------- --------
            Custom script: call DestroyGroup(udg_Temp_Group_1)
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Hammer_of_Thor_Stun <gen> is on) Equal to False
              Then - Actions
                Trigger - Turn on Hammer_of_Thor_Stun <gen>
              Else - Actions
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Hammer_of_Thor_Up <gen> is on) Equal to False
              Then - Actions
                Trigger - Turn on Hammer_of_Thor_Up <gen>
              Else - Actions
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Number of units in HoT_Slam_Group) Equal to 0
              Then - Actions
                Trigger - Turn off (This trigger)
              Else - Actions
        -------- -------------------- --------
        Custom script: call RemoveLocation(udg_Temp_Loc_1)
Hammer of Thor Up
  Events
    Time - Every 0.03 seconds of game time
  Conditions
  Actions
    Unit Group - Pick every unit in HoT_Up_Group and do (Actions)
      Loop - Actions
        Set VariableSet Temp_Unit_1 = (Picked unit)
        -------- -------------------- --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            (Current flying height of Temp_Unit_1) Less than 1500.00
          Then - Actions
            Animation - Change Temp_Unit_1 flying height to ((Current flying height of Temp_Unit_1) x 1.10) at 0.00
          Else - Actions
            Unit Group - Remove Temp_Unit_1 from HoT_Up_Group.
            -------- -------------------- --------
            Special Effect - Destroy (Load (Key eff1.) of (Key (Picked unit).) in HoT_Hash.)
            Special Effect - Destroy (Load (Key eff4.) of (Key (Picked unit).) in HoT_Hash.)
            Special Effect - Destroy (Load (Key eff5.) of (Key (Picked unit).) in HoT_Hash.)
            -------- -------------------- --------
            Hashtable - Clear all child hashtables of child (Key (Picked unit).) in HoT_Hash.
            Hashtable - Clear all child hashtables of child (Key (Load (Key caster.) of (Key (Picked unit).) in HoT_Hash.).) in HoT_Hash.
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Number of units in HoT_Up_Group) Equal to 0
              Then - Actions
                Trigger - Turn off (This trigger)
              Else - Actions
Hammer of Thor Stun
  Events
    Time - Every 0.25 seconds of game time
  Conditions
  Actions
    Unit Group - Pick every unit in HoT_Stun_Group and do (Actions)
      Loop - Actions
        Set VariableSet Temp_Unit_1 = (Picked unit)
        -------- -------------------- --------
        Set VariableSet Temp_Real_1 = (Load (Key time.) of (Key (Picked unit).) from HoT_Hash.)
        -------- -------------------- --------
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          If - Conditions
            Temp_Real_1 Greater than 0.00
            (Temp_Unit_1 is dead) Equal to False
          Then - Actions
            Unit - Set life of Temp_Unit_1 to ((Life of Temp_Unit_1) - (HoT_Const_Dmg_Burn / 4.00))
            Hashtable - Save (Temp_Real_1 - 0.25) as (Key time.) of (Key (Picked unit).) in HoT_Hash.
          Else - Actions
            Unit - Remove Stunned (Pause) buff from Temp_Unit_1
            -------- -------------------- --------
            Special Effect - Destroy (Load (Key eff2.) of (Key (Picked unit).) in HoT_Hash.)
            Special Effect - Destroy (Load (Key eff3.) of (Key (Picked unit).) in HoT_Hash.)
            -------- -------------------- --------
            Hashtable - Clear all child hashtables of child (Key (Picked unit).) in HoT_Hash.
            -------- -------------------- --------
            Unit Group - Remove Temp_Unit_1 from HoT_Stun_Group.
            -------- -------------------- --------
            If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              If - Conditions
                (Number of units in HoT_Stun_Group) Equal to 0
              Then - Actions
                Trigger - Turn off (This trigger)
              Else - Actions
Reset Unit
  Events
    Player - Player 1 (Red) skips a cinematic sequence
  Conditions
  Actions
    Unit Group - Pick every unit in (Units owned by Player 1 (Red).) and do (Actions)
      Loop - Actions
        Unit - Set life of (Picked unit) to 100%
        Unit - Set mana of (Picked unit) to 100%
        Unit - Reset ability cooldowns for (Picked unit).
Revive
  Events
    Unit - A unit Dies
  Conditions
    (Unit-type of (Triggering unit)) Not equal to Hammer_of_Thor_Dummy
  Actions
    If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      If - Conditions
        (Unit-type of (Triggering unit)) Equal to Paladin
      Then - Actions
        Set VariableSet Temp_Loc_1 = (Position of (Triggering unit))
        Hero - Instantly revive (Triggering unit) at Temp_Loc_1, Hide revival graphics
        Custom script: call RemoveLocation(udg_Temp_Loc_1)
      Else - Actions
        Wait 30.00 seconds
        Set VariableSet Temp_Loc_1 = (Position of (Triggering unit))
        Unit - Create 1 (Unit-type of (Triggering unit)) for Neutral Hostile at Temp_Loc_1 facing Temp_Loc_1
        Custom script: call RemoveLocation(udg_Temp_Loc_1)
Greetings
  Events
    Time - Elapsed game time is 2.00 seconds
  Conditions
  Actions
    Quest - Display to (All players) the Hint message: Hammer of Thor by Maker @ Hiveworkshop.com
    Wait 4.00 seconds
    Quest - Display to (All players) the Hint message: Hit esc to reset health, mana and cooldown.Monsters and your heroes will respawn after death.