Triggers

//##START##
//===========================================================================

//============================================================
 
// ===========================
function H2I takes handle h returns integer
    return h
    return 0
endfunction
 
// ===========================
function LocalVars takes nothing returns gamecache
    if udg_cach == null then
        call FlushGameCache(InitGameCache("cach"))
        set udg_cach=InitGameCache("cach")
    endif
    return udg_cach
endfunction
 
function SetHandleHandle takes handle subject, string name, handle value returns nothing
    if value==null then
        call FlushStoredInteger(LocalVars(),I2S(H2I(subject)),name)
    else
        call StoreInteger(LocalVars(), I2S(H2I(subject)), name, H2I(value))
    endif
endfunction
 
function SetHandleInt takes handle subject, string name, integer value returns nothing
    if value==0 then
        call FlushStoredInteger(LocalVars(),I2S(H2I(subject)),name)
    else
        call StoreInteger(LocalVars(), I2S(H2I(subject)), name, value)
    endif
endfunction
 
function SetHandleReal takes handle subject, string name, real value returns nothing
    if value==0 then
        call FlushStoredReal(LocalVars(), I2S(H2I(subject)), name)
    else
        call StoreReal(LocalVars(), I2S(H2I(subject)), name, value)
    endif
endfunction
 
function SetHandleString takes handle subject, string name, string value returns nothing
    if value==null then
        call FlushStoredString(LocalVars(), I2S(H2I(subject)), name)
    else
        call StoreString(LocalVars(), I2S(H2I(subject)), name, value)
    endif
endfunction
 
function GetHandleHandle takes handle subject, string name returns handle
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
    return null
endfunction
function GetHandleInt takes handle subject, string name returns integer
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
endfunction
function GetHandleReal takes handle subject, string name returns real
    return GetStoredReal(LocalVars(), I2S(H2I(subject)), name)
endfunction
function GetHandleString takes handle subject, string name returns string
    return GetStoredString(LocalVars(), I2S(H2I(subject)), name)
endfunction
 
function GetHandleUnit takes handle subject, string name returns unit
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
    return null
endfunction
function GetHandleTimer takes handle subject, string name returns timer
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
    return null
endfunction
function GetHandleTrigger takes handle subject, string name returns trigger
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
    return null
endfunction
function GetHandleEffect takes handle subject, string name returns effect
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
    return null
endfunction
function GetHandleGroup takes handle subject, string name returns group
    return GetStoredInteger(LocalVars(), I2S(H2I(subject)), name)
    return null
endfunction
 
function FlushHandleLocals takes handle subject returns nothing
    call FlushStoredMission(LocalVars(), I2S(H2I(subject)) )
endfunction

//*******************************************
//AUXILIARY FUNCTIONS

function PolarProjectionX takes real x, real distance, real angle returns real
    return x+distance*Cos(angle * bj_DEGTORAD)
endfunction
 
function PolarProjectionY takes real y, real distance, real angle returns real
    return y+distance*Sin(angle * bj_DEGTORAD)
endfunction
 
function GetAngleBetweenPoints takes real x1, real y1, real x2, real y2 returns real
    return bj_RADTODEG * Atan2(y2 - y1, x2 - x1)
endfunction
 
function GetDistanceBetweenPoints takes real x1, real y1,real x2, real y2 returns real
    return SquareRoot((x2-x1)*(x2-x1) + (y2-y1) * (y2-y1))
endfunction

function GetGroupUnitMinLife takes group g returns unit
local group k = CreateGroup()
local unit u 
local unit min
local real quota

if FirstOfGroup(g)!=null then
call GroupAddGroup(g,k)
set min = FirstOfGroup(k)
set quota = GetUnitState(min, UNIT_STATE_LIFE)
call GroupRemoveUnit(k,min)

loop
    set u = FirstOfGroup(k)
    exitwhen u==null
    call GroupRemoveUnit(k,u)
    if GetUnitState(u, UNIT_STATE_LIFE)<quota then
    set quota = GetUnitState(u, UNIT_STATE_LIFE)
    set min = u
    endif
    set u = FirstOfGroup(k)
endloop
return min
endif
return null
endfunction
//********************************************************************************************
//*
//*  Pool Class Functions
//*  ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*   To implement them, first make sure that you have a gamecache variable udg_poolclass , to
//*  Copy it either use next trigger called "Variable Copyness" or just go the trigger editor,
//*  press ctrol + b and create a gamecache variable called poolclass, the udg_ is added
//*  automatically.
//*
//*   After that, copy the contents of this trigger begining with the //##Start## and
//* ending with the //##End## TO YOUR MAP'S CUSTOM SCRIPT SECTION , DON'T JUST Copy the trigger
//* ( The custom script section is at the top of the trigger list with the map's name.
//*
//*   In theory, you may just copy the trigger, making sure it is above any other trigger, then
//* Instantly save, this is easier, but may not work well.
//*
//********************************************************************************************

//===================================================================================
function PoolClass takes nothing returns gamecache
    if udg_poolclass==null then
        call FlushGameCache(InitGameCache("pool.vx"))
        set udg_poolclass=InitGameCache("pool.vx")
        call ExecuteFunc("Pool_SetupCharMap")
    endif
 return udg_poolclass
endfunction

//===================================================================================
function PoolGetItem takes integer poolid, integer itemn returns integer
    return GetStoredInteger( PoolClass(), I2S(poolid), I2S(itemn))
endfunction

//===================================================================================
function CountItemsInPool takes integer poolid returns integer
    return GetStoredInteger( PoolClass(), I2S(poolid), "n")
endfunction

//===================================================================================
function GetEnumPoolItem takes nothing returns integer
    return GetStoredInteger( PoolClass(), "Class", "Enum")    
endfunction

//===================================================================================
function ForPool takes integer poolid, code callback returns nothing
 local trigger t=CreateTrigger()
 local integer a=1
 local integer n=CountItemsInPool( poolid)
 local gamecache pc=PoolClass()
    call TriggerAddAction( t, callback)
    call TriggerWaitOnSleeps( t, true)
    loop
        exitwhen a>n
        call StoreInteger( pc, "Class", "Enum", PoolGetItem( poolid, a))
        call TriggerExecute(t)
        set a=a+1
    endloop
    call FlushStoredInteger( pc, "Class", "Enum")
 call DestroyTrigger( t)
 set t=null
 set pc=null
endfunction

//===================================================================================
// Uses a the function's name instead of a code argumment, it is better than ForPool
// because ForPool Creates Triggers to run the callback
//
function ForPool2 takes integer poolid, string callbackfuncname returns nothing
 local integer a=1
 local integer n=CountItemsInPool( poolid)
 local gamecache pc=PoolClass()
    loop
        exitwhen a>n
        call StoreInteger( pc, "Class", "Enum", PoolGetItem( poolid, a))
        call ExecuteFunc(callbackfuncname)
        set a=a+1
    endloop
 set pc=null
endfunction


//===================================================================================
function GetFirstOfPool takes integer poolid returns integer
    return GetStoredInteger( PoolClass(), I2S(poolid), "1")
endfunction

//===================================================================================
function PoolPickRandomItem takes integer poolid returns integer
    return GetStoredInteger( PoolClass(), I2S(poolid), I2S( GetRandomInt(  1, GetStoredInteger( PoolClass(), I2S(poolid), "n" ) ) ))
endfunction

//===================================================================================
function GetItemPositionInPool takes integer poolid, integer it returns integer
    return GetStoredInteger( PoolClass(), I2S(poolid), "i"+I2S(it))
endfunction

//===================================================================================
function IsItemInPool takes integer poolid, integer it returns boolean
    return GetItemPositionInPool( poolid, it) != 0
endfunction

//===================================================================================
function PoolAddItem takes integer poolid, integer value returns nothing
 local integer n
 local gamecache pc=PoolClass()
    if not IsItemInPool( poolid, value) then
        set n=GetStoredInteger( pc, I2S(poolid), "n") + 1
        call StoreInteger( pc, I2S(poolid), "n", n)
        call StoreInteger( pc, I2S(poolid), I2S(n), value)
        call StoreInteger( pc, I2S(poolid) , "i"+I2S(value), n )
    endif
 set pc=null
endfunction

//===================================================================================
function PoolRemoveItem takes integer poolid, integer value returns nothing
 local integer p=GetItemPositionInPool( poolid, value)
 local integer n=GetStoredInteger( PoolClass(), I2S(poolid), "n")
 local gamecache pc=PoolClass()
    if p!=0 then
        call FlushStoredInteger( pc, I2S(poolid), I2S(p))
        call FlushStoredInteger( pc, I2S(poolid), "i"+I2S(value))
        if n > p then
            call StoreInteger( pc, I2S(poolid), I2S(p), GetStoredInteger( pc, I2S(poolid), I2S(n)))
            call StoreInteger( pc, I2S(poolid), "i"+I2S( GetStoredInteger( pc, I2S(poolid), I2S(n))), p)
            call FlushStoredInteger( pc, I2S(poolid), I2S(n))
        endif
        call StoreInteger( pc, I2S(poolid), "n", n - 1)
    endif
 set pc=null
endfunction

//===================================================================================
function PoolAddPool takes integer sourcepoolid, integer destpoolid returns nothing
 local integer a=1
 local integer n=CountItemsInPool( sourcepoolid)
    loop
        exitwhen a>n
        call PoolAddItem( destpoolid, PoolGetItem( sourcepoolid, a))
        set a=a+1
    endloop
endfunction

//===================================================================================
function PoolRemovePool takes integer sourcepoolid, integer destpoolid returns nothing
 local integer a=1
 local integer n=CountItemsInPool( sourcepoolid)
    loop
        exitwhen a>n
        call PoolRemoveItem( destpoolid, PoolGetItem( sourcepoolid, a))
        set a=a+1
    endloop
endfunction

//===================================================================================
function DestroyPool takes integer poolid returns nothing
    call FlushStoredMission( PoolClass(), I2S(poolid))
endfunction

//===================================================================================
function CreatePool takes nothing returns integer
 local integer N=GetStoredInteger( PoolClass(), "Class", "N") + 1
    call StoreInteger( PoolClass(), "Class", "N", N)
 return N
endfunction

//===================================================================================
// Adds a tokenized string to a pool,
//  Example: PoolAddS(udg_p, "1;2;3;4") will add to the udg_p pool : 1,2,3 and 4
//
function PoolAddS takes integer poolid, string s returns nothing
 local string current=""
 local integer i=0
    set s=s+";"
    loop
        exitwhen SubString(s, i, i+1) == "" or SubString(s, i, i+1) == null
        if SubString(s, i, i+1) == ";" then
            call PoolAddItem( poolid, S2I(current))
            set current=""
        else
            set current=current+SubString(s, i, i+1)
        endif
        set i=i+1
    endloop
endfunction

//===================================================================================
// Converts a tokenized string into a pool,
//  Example: S2Pool( "1;2;3;4") will return a pool that has 1,2,3 and 4 inside
//
function S2Pool takes string s returns integer
 local integer spool= CreatePool()
    call PoolAddS(spool,s)
 return spool
endfunction

//=============================================================================================================
constant function Pool_SafePercent takes nothing returns string
    if ("%"=="") then
        return "%%"
    endif
 return "%" //would like to thank blizzard for the dumb bug.
endfunction


//=============================================================================================================
function Pool_SetupCharMap takes nothing returns nothing
 local gamecache g=udg_poolclass
 local string cm=".................................!.#$"+Pool_SafePercent()+"&'()*+,-./0123456789:;<=>.@ABCDEFGHIJKLMNOPQRSTUVWXYZ[.]^_`abcdefghijklmnopqrstuvwxyz{|}~................................................................................................................................."
 local integer i=0
 local string c
    if HaveStoredInteger(g,"charmap","A2") then
        return
    endif
    loop
        set c=SubString(cm,i,i+1)
        exitwhen (c==null) or (c=="")
        if (c!=".") then
            if c==StringCase(c,true) then
                set c=c+"2"
            else
                set c=c+"1"
            endif
            call StoreInteger(g,"charmap",c,i)
        endif
        set i=i+1
    endloop
 set g=null
endfunction
function Pool_Rawcode2Int takes gamecache g, string s returns integer
 local string c
 local integer i=0
 local integer r=0
    loop
        exitwhen i>3
        set c=SubString(s,i,i+1)
        set r=r*256
        if c==StringCase(c,true) then
            set c=c+"2"
        else
            set c=c+"1"
        endif
        set r=r+GetStoredInteger(g,"charmap",c)
        set i=i+1
    endloop
 return r
endfunction

function PoolAddRawcodes_thread takes nothing returns nothing
//Threaded because I don't want it to halt execution for no reason
//
 local gamecache g=PoolClass()
 local string s=bj_lastPlayedMusic
 local integer poolid=bj_groupEnumTypeId
 local string current=""
 local integer i=0
    set s=s+";"
    loop
        exitwhen SubString(s, i, i+1) == "" or SubString(s, i, i+1) == null
        if SubString(s, i, i+1) == ";" then
            call PoolAddItem(poolid, Pool_Rawcode2Int(g,current))
            set current=""
        else
            set current=current+SubString(s, i, i+1)
        endif
        set i=i+1
    endloop
 set g=null
endfunction

//=====================================================================================================================
// Adds a string of tokenized rawcodes to a pool
//  Example: PoolAddRawcodes(udg_p,"A000;A001")  will add 'A000' and 'A001' to the pool
//
// (Saves some lines, but is not as good efficiency wise)
//
function PoolAddRawcodes takes integer poolid, string s returns nothing
 local string b=bj_lastPlayedMusic
    set bj_groupEnumTypeId=poolid
    set bj_lastPlayedMusic=s
    call ExecuteFunc("PoolAddRawcodes_thread")
    set bj_lastPlayedMusic=b
endfunction

//===================================================================================================================
// Converts a tokenized string of rawcodes into a pool,
//  Example: Rawcodes2Pool( "A000;A001;AHbz;S000") will return a pool that has 'A000,'A001','AHbx' and 'S000' inside
//
// (Saves some lines, but is not as good efficiency wise)
//
function Rawcodes2Pool takes string s returns integer
 local integer spool= CreatePool()
    call PoolAddRawcodes(spool,s)
 return spool
endfunction

//=================================================================================================
//
// For more JASS scripts, visit : http://www.wc3jass.com
//
//=================================================================================================

//=================================================================================================
function Ascii_cache takes nothing returns gamecache
    if (udg_ascii==null) then
        call FlushGameCache(InitGameCache("arcii.vx"))
        set udg_ascii=InitGameCache("arcii.vx")
    endif
 return udg_ascii
endfunction

constant function Ascii_SafePercent takes nothing returns string
    if ("%"=="") then
        return "%%"
    endif
 return "%" //would like to thank blizzard for the dumb bug.
endfunction

//=================================================================================================
// Ascii table, kinda
//
function AsciiCharToInteger_sub takes string u returns integer
 local string charMap = " !\"#$"+Ascii_SafePercent()+"&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\\]^_`abcdefghijklmnopqrstuvwxyz{|}~"
 local string c
 local integer i = 0
    if (u == "\b") then // Backspace?
        return 8
    elseif u == "\t" then // Horizontal Tab?
        return 9
    elseif u == "\n" then // Newline
        return 10
    elseif u == "\f" then // Form feed?
        return 12
    elseif u == "\r" then // Carriage return
        return 13
    endif
    loop
        set c = SubString(charMap, i, i + 1)
        exitwhen c == ""
        if c == u then
            return i + 32
        endif
        set i = i + 1
    endloop
 return 0
endfunction
function AsciiCharToInteger takes string char returns integer
 local string k
 local string u = SubString(char, 0, 1)
 local integer r
    if (u == "") or (u == null) then
        return 0
    endif
    if (StringCase(u,true)==u) then
        set k=u
    else            //Gamecache is not case sensitive, we have to deal with that
        set k=u+"1"
    endif
    if HaveStoredInteger(Ascii_cache(),"ascii",k) then
        return GetStoredInteger(Ascii_cache(),"ascii",k)
    endif
    set r=AsciiCharToInteger_sub(u)
    call StoreInteger(Ascii_cache(),"ascii",k,r)
 return r
endfunction

//=================================================================================================
// Each string belongs to a group out of range groups, the bigger the range value is, the lesser
// the chance 2 strings will have the same Identity will be
//
function GetStringIdentity takes string s, integer range returns integer
 local integer len = StringLength(s)
 local integer i = 0
 local integer Result = 0
    loop
        exitwhen (i>=len)
        set Result = Result+AsciiCharToInteger(SubString(s,i,i+1))
        if (Result>=range) then
            set Result=Result-range
        endif
        set i = i + 1
    endloop
 return Result
endfunction
//##End##
function InitTrig_Codemaker takes nothing returns nothing
endfunction
//##start##
//*************************************************************************************************
//*
//*  The code maker engine
//*
//*************************************************************************************************


//#################################################################################################
//
// Constants:
//
//=================================================================================================
constant function Codemaker_Charmap takes nothing returns string
    return "abcdefghijkmnopqrstuvwxyzABCDEFGHJKLMNOPQRSTUVWXYZ0123456789@+!*"
//
// (Affects default charmap)
//
// Length of charmap must be a power of 2 (64 in this case)
// The bigger the charmap is, the sorter the code will be.
//
// The order, and the characters you use, will change the resulting code,
// you can have an unique charmap.
//
endfunction

constant function Codemaker_FCSsize takes nothing returns integer
    return 7
//
// (Affects default charmap)
//
endfunction

//################################################################################################
// 
// Private Functions:
//
//=================================================================================================
function Codemaker takes nothing returns gamecache
    if (udg_codemaker==null) then
        call FlushGameCache(InitGameCache("codemaker"))
        set udg_codemaker=InitGameCache("codemaker")
    endif
 return udg_codemaker
endfunction

//=================================================================================================
// I think a limit of 4095 is way enough for saveable values
//
function Codemaker_val takes integer i returns integer
    return udg_codemaker_vals[i]
endfunction

function Codemaker_size takes integer i returns integer
    return udg_codemaker_size[i]
endfunction

function Codemaker_vals takes nothing returns integer
    return udg_codemaker_vals[0]
endfunction

//=================================================================================================
// 
//
function Codemaker_UseCharmap takes integer id returns boolean
 local string k=I2S(id)
    if GetStoredBoolean(Codemaker(),"charmaps",k) then
        call StoreInteger(Codemaker(),"charmaps","current",id)
        return true
    endif
 return false
endfunction

function Codemaker_CurrentCharmap takes nothing returns string
    return I2S( GetStoredInteger(Codemaker(),"charmaps","current") )
endfunction

         
function BinStr_NOT takes string bin, integer bits returns string
 local integer i=0
 local string r=""
    loop
        exitwhen (i>=bits)
        if (SubString(bin,i,i+1)=="1") then
            set r=r+"0"
        else
            set r=r+"1"
        endif
        set i=i+1
    endloop
 return r
endfunction

function BinStr_ADD takes string bina, string binb, integer n returns string
 local string r=""
 local string c1
 local string c2
 local string c3
 local boolean cr=false

    loop
        exitwhen (n<=0)
        set c1=SubString(bina,n-1,n)
        set c2=SubString(binb,n-1,n)
        if (c2!=c1) then
            if cr then
                set c3="0"
            else
                set c3="1"
            endif
        elseif (c1==c2) and (c1=="1") then
            if cr then
                set c3="1"
            else
                set c3="0"
                set cr=true
            endif
        else
            if cr then
                set c3="1"
                set cr=false
            else
                set c3="0"
            endif
        endif
        set r=c3+r
        set n=n-1
    endloop

 return r
endfunction

//=========================================================================================================================================
function BinStr_XOR takes string bin1, string bin2, integer bits returns string
 local string r=""
 local integer i=1
 local integer c1=1
 local integer c2=1
 local integer L1=StringLength(bin1)
 local integer L2=StringLength(bin2)

    loop
        exitwhen (i>bits)
        
        if (  (SubString(bin1,c1-1,c1)=="1")  !=  (SubString(bin2,c2-1,c2)=="1")  ) then
            set r=r+"1"
        else
            set r=r+"0"
        endif
        set i=i+1
        set c1=c1+1
        set c2=c2+1
        if (c1>L1) then
            set c1=1
        endif
        if (c2>L2) then
            set c2=1
        endif

    endloop
 return r
endfunction

//=========================================================================================================================================
function Codemaker_Int2BinStr takes integer i, integer bits returns string
//Example 0,4="0000"
//Example 1,4="1000"
//Example 5,5="10100"
 local integer div
 local string r=""
 local string max=""

    if (bits<32) then
        if (i<0) then
            return Codemaker_Int2BinStr(0,bits)
        endif

    elseif (i<0) then
        set r=Codemaker_Int2BinStr(-i,31)
        set r=BinStr_NOT(r,31)
        set r=BinStr_ADD(r,Codemaker_Int2BinStr(1,31),31)
        return "1"+r+max
    endif
    loop
        exitwhen (bits==0)
        set div=i/2
        if (div*2==i) then
            set r="0"+r
        else
            set r="1"+r
        endif
        set max="1"+max
        set i=div
        set bits=bits-1
    endloop
    if (i!=0) then
        return max
    endif
 return r
endfunction
function Codemaker_BinStr2Int takes string bin, integer bits returns integer
// "0000",4= 0
// "0010",4= 2
// "04H1",4= 1
// ""    ,4= 0
// "11"  ,4=12
 local integer div
 local string ch
 local integer r=0
 local integer p=1
    loop
        exitwhen (bits<=0)
        set ch=SubString(bin,bits-1,bits)
        if (ch=="1") then
            set r=r+p
        endif
        set p=p*2
        set bits=bits-1
    endloop

 return r
endfunction

function Codemaker_EncodeBinStr takes string bin returns string
 local gamecache g=Codemaker()
 local string k=Codemaker_CurrentCharmap()
 local integer sz=GetStoredInteger(g,k+"bitsperchar","now")
 local integer l
 local integer i=0
 local string ch
 local string r=""


    set k=k+"bin2char"
   // loop
       // exitwhen (ModuloInteger(StringLength(bin) , sz)==0)
      //  set bin=bin+"0"
    //endloop
    loop
        set ch=SubString(bin,i,i+sz)
        exitwhen (ch=="") or (ch==null)
        if HaveStoredString(g,k,ch) then
            set r=r+GetStoredString(g,k,ch)
        else
            set r=r+GetStoredString(g,k,"def")
        endif
        set i=i+sz
    endloop
 set g=null
 return r
endfunction

function Codemaker_DecodeBinStr takes string cod returns string
 local gamecache g=Codemaker()
 local integer i=0
 local string k=Codemaker_CurrentCharmap()+"char2bin"
 local string r=""
 local string ch
    loop
        set ch=SubString(cod,i,i+1)
        exitwhen (ch=="") or (ch==null)
        if (StringCase(ch,true)==ch) then
            set ch=ch+"1"
        endif      
        if HaveStoredString(g,k,ch) then
            set r=r+GetStoredString(g,k,ch)
        else
            set g=null
            return ""
        endif
        set i=i+1
    endloop
 set g=null
 return r
endfunction

//=========================================================================================================================================
function Codemaker_FromArrayToBin takes nothing returns string
 local integer n=Codemaker_vals()
 local integer i=1
 local string r=""
    loop
        exitwhen (i>n)
        set r=r+Codemaker_Int2BinStr(Codemaker_val(i),Codemaker_size(i))
        set i=i+1
    endloop
 return r
endfunction

function Codemaker_GetCRC takes string bin, integer n returns string
 local integer mod=R2I(Pow(2,n))
 local integer s=0
 local string c
 local integer i=0
    loop
        set c=SubString(bin,i,i+n)
        exitwhen (c=="") or (c==null)
        set s= ModuloInteger(s+Codemaker_BinStr2Int(c,n),mod)
        set i=i+n
    endloop
 return Codemaker_Int2BinStr(s,n)
endfunction

function Codemaker_AddCRC takes string bin returns string
 local integer n=GetStoredInteger( Codemaker() , Codemaker_CurrentCharmap() , "FCS")
 local string crc=Codemaker_GetCRC(bin,n)

 return( crc+ BinStr_XOR(bin,crc,StringLength(bin)) )
endfunction

function Codemaker_FixBitNumber takes string bin returns string
 local integer sz=GetStoredInteger(Codemaker(),Codemaker_CurrentCharmap()+"bitsperchar","now")
    loop
        exitwhen (ModuloInteger(StringLength(bin) , sz)==0)
        set bin=bin+"0"
    endloop
 return bin
endfunction


function Codemaker_EncodeForPlayer takes string bin, player p returns string
 local string in=Codemaker_FixBitNumber(bin)
 local integer i=0
 local integer l=StringLength(in)
 local integer tt= IMinBJ(l, 31)
 local string id=  Codemaker_Int2BinStr( GetStringIdentity(GetPlayerName(p),R2I( Pow(2,tt) )) , tt)
 local string r=""
    loop
        exitwhen i>=l
        if (i+tt>=l) then
            set tt=l-i
        endif
        set r=r+BinStr_XOR(SubString(in,i,i+tt),id,tt)
        set i=i+tt
    endloop
 return r
endfunction

//=============================================================================================================
function Codemaker_DecodeForPlayer takes string bin, player p returns string

 local integer i=0
 local integer l=StringLength(bin)
 local integer tt= IMinBJ(l, 31)
 local string id=  Codemaker_Int2BinStr( GetStringIdentity(GetPlayerName(p),R2I( Pow(2,tt) )) , tt)
 local string r=""
    loop
        exitwhen i>=l
        if (i+tt>=l) then
            set tt=l-i
        endif
        set r=r+BinStr_XOR(SubString(bin,i,i+tt),id,tt)
        set i=i+tt
    endloop
 return r
endfunction


function Codemaker_TotalBits takes nothing returns integer
 local integer i=udg_codemaker_vals[0]
 local integer r=0
    loop
        exitwhen (i<=0)
        set r=r+udg_codemaker_size[i]
        set i=i-1
    endloop
 return r
endfunction

function Codemaker_TotalCodeLength takes nothing returns integer
 local string k=Codemaker_CurrentCharmap()
 local integer r=Codemaker_TotalBits()+GetStoredInteger( Codemaker() , k , "FCS")
 local integer l=GetStoredInteger (Codemaker(),k+"bitsperchar","now")
    loop
        exitwhen (ModuloInteger(r,l)==0)
        set r=r+1
    endloop
 return (r/l)
endfunction

function Codemaker_CheckCRC takes string bin returns string
 local integer n=GetStoredInteger( Codemaker() , Codemaker_CurrentCharmap() , "FCS")
 local integer T=Codemaker_TotalBits()
 local string rbin= SubString(bin,n,n+T)
 local string crc= SubString(bin,0,n)

    set rbin=BinStr_XOR(rbin,crc,T)

    if (Codemaker_GetCRC(rbin,n)!=crc) then
        return ""
    endif
 return rbin
endfunction

function Codemaker_FromBinToArray takes string bin returns integer
 local integer n=Codemaker_vals()
 local integer i=1
 local integer j=0
 local integer sz
 local string ch
    loop
        exitwhen (i>n)
        set sz=Codemaker_size(i)
        set ch=SubString(bin,j,j+sz)
        if (StringLength(ch)< sz ) then
            return 4 //Missing bits
        endif
        set udg_codemaker_vals[i] = Codemaker_BinStr2Int(ch,sz)
        set i=i+1
        set j=j+sz
    endloop
 return 0
endfunction

function Codemaker_GetId takes trigger t returns integer
    return t
    return 0
endfunction


function Codemaker_AskString_Child takes nothing returns nothing
 local gamecache g=Codemaker()
 local string k= I2S( Codemaker_GetId( GetTriggeringTrigger() ) )
 local string cmd=GetStoredString(g,k,"cmd")
 local integer l=StringLength(cmd)
 local boolean b=false
 local string chat=GetEventPlayerChatString()
 local string r

    if (chat==GetStoredString(g,k,"cnl")) then
        call DisplayTimedTextToPlayer(GetTriggerPlayer(),0,0,2,chat)
        set b=true
        set r=""
    elseif (SubString(chat,0,l)==cmd) then
        set r=SubString(chat,l,StringLength(chat))
        set b=((r!=null) and (r!=""))
    endif
    if not(b) then
        call DisplayTimedTextToPlayer(GetTriggerPlayer(),0,0,GetStoredReal(g,k,"rem"),GetStoredString(g,k,"prm"))
    else
        call StoreString(g,k,"result",r)
    endif
 set g=null
endfunction


function Codemaker_GenerateCode_Thread takes nothing returns nothing
 local string r
    set r=Codemaker_FromArrayToBin()
    set r=Codemaker_AddCRC(r)
    if (bj_groupEnumOwningPlayer!=null) then
        set r=Codemaker_EncodeForPlayer(r,bj_groupEnumOwningPlayer)
    endif
    set bj_lastPlayedMusic=Codemaker_EncodeBinStr(r)
endfunction

function Codemaker_ReadCode_thread takes nothing returns nothing
 local player p=bj_groupEnumOwningPlayer
 local string cod=bj_lastPlayedMusic
 local integer T=Codemaker_TotalCodeLength()
 local integer L=StringLength(cod)

    set bj_groupEnumTypeId=5
    if (L<T) then
        set bj_groupEnumTypeId=1
    else
        if (L>T) then
            set cod=SubString(cod,0,T)
        endif
        set cod=Codemaker_DecodeBinStr(cod)
        if (cod=="") then
            set bj_groupEnumTypeId=2
        else
            if (p!=null) then
                set cod=Codemaker_DecodeForPlayer(cod,p)
            endif
            set cod=Codemaker_CheckCRC(cod)
            if (cod=="") then
                set bj_groupEnumTypeId=3
            else
                set bj_groupEnumTypeId=Codemaker_FromBinToArray(cod)
            endif
        endif
    endif
 set p=null
endfunction

//################################################################################################
//
// Public Functions:
//
//================================================================================================
// Generates a code for player p based on udg_codemaker_vals and udg_codemaker_size arrays
//
function Codemaker_GenerateCode takes player p returns string
 local string s=bj_lastPlayedMusic
 local string r
    set bj_groupEnumOwningPlayer=p
    call ExecuteFunc("Codemaker_GenerateCode_Thread")
    // I don't want the trigger to halt execution because of too long process
    set r=bj_lastPlayedMusic
    set bj_lastPlayedMusic=s
 return r
endfunction



//================================================================================================
// Reads a code for player p based on udg_codemaker_size array and saves result in
// udg_codemaker_vals array, returns non 0 when there is an error.
//
// Error 1 : Phisical Error - Missing Characters
// Error 2 : Phisical Error - Invalid Characters
// Error 3 : CRC Error (Could also be that the Code belongs to another player)
// Error 4 : Missing Bit (I doubt this will ever happen since 1,2,3 should give errors if there are missing bits
// Error 5 : Long process made thread quit!
//
function Codemaker_ReadCode takes player p, string cod returns integer
 local string b=bj_lastPlayedMusic
    set bj_lastPlayedMusic=cod
    set bj_groupEnumOwningPlayer=p
    call ExecuteFunc("Codemaker_ReadCode_thread")
    // I don't want the trigger to halt execution because of too long process
    set bj_lastPlayedMusic=b
 return bj_groupEnumTypeId
endfunction

//=============================================================================================================
// Sets a new charmap, charmap 0 is initialized automatically when you call Codemaker_init,
// Using multiple charmaps is possible and might be good when you have different codes for
// different stuff in your map.
//
// Always init the charmaps at map initialization.
//
function Codemaker_SetCharmap takes integer id, string ch, integer FCSsize returns nothing
 local gamecache g=Codemaker()
 local integer i=0
 local integer log=0
 local integer p=1
 local string c
 local string k=I2S(id)
 local integer EXITTHREAD
 local string bin
    if (FCSsize>30) then
        call BJDebugMsg("|cffff0000Invalid FCS size: Must be <= 30")
        call FlushGameCache(g)
        set EXITTHREAD=EXITTHREAD
    endif
    call StoreBoolean(g,"charmaps",k,true)
    loop
        set c=SubString(ch,i,i+1)
        exitwhen (c=="")
        if (StringCase(c,true)==c) then
            set c=c+"1"
        endif
        set i=i+1
        if (i>p) then
            set p=p*2
            set log=log+1
        endif
    endloop
    if (i!=p) then
        call BJDebugMsg("|cffff0000Invalid charmap: Length must be a power of 2")
        call FlushGameCache(g)
        set EXITTHREAD=EXITTHREAD
    endif
    if (ModuloInteger(p,FCSsize)==0) then
        call BJDebugMsg("|cffff0000Invalid charmap/FCS size: FCS size can't be a multiple of the number of bits per character")
        call FlushGameCache(g)
        set EXITTHREAD=EXITTHREAD
    endif



    set i=0
    call StoreInteger(g,k,"FCS",FCSsize)
    call StoreInteger(g,k+"bitsperchar","now",log)
    loop
        exitwhen (i>=p)
        set bin=Codemaker_Int2BinStr(i,log)
        set c=SubString(ch,i,i+1)
        call StoreString(g,k+"bin2char",bin,c)
        if (i==0) then
            call StoreString(g,k+"bin2char","def",c)
        endif
        if (StringCase(c,true)==c) then
            set c=c+"1"
        endif
        call StoreString(g,k+"char2bin",c,bin)
        if (i==0) then
            call StoreString(g,k+"char2bin","def",bin)
        endif
        set i=i+1
    endloop
 set g=null
endfunction

//=============================================================================================================
// Asks the player to input a string
//
function Codemaker_AskString takes player p, string prompt, string cmd, string canc, real timeout returns string
 local gamecache g=Codemaker()
 local trigger t=CreateTrigger()
 local triggeraction ac=TriggerAddAction(t,function Codemaker_AskString_Child )
 local string k= I2S( Codemaker_GetId(t) )
 local string pk=I2S(GetPlayerId(p))
 local string r
 local timer x

    loop
        exitwhen not( GetStoredBoolean(g,pk,"notfree") )
        call StoreBoolean(g,pk,"haltnow",true)
        call TriggerSleepAction(0)
    endloop
    call StoreBoolean(g,pk,"notfree",true)

    call DisplayTimedTextToPlayer(p,0,0,timeout,prompt)
    call TriggerRegisterPlayerChatEvent(t,p,cmd,false)
    call TriggerRegisterPlayerChatEvent(t,p,canc,true)
    call StoreString(g,k,"cmd",cmd)
    call StoreString(g,k,"prm",prompt)
    call StoreString(g,k,"cnl",canc)
    set x=CreateTimer()
    call TimerStart(x,timeout,false,null)
    loop
        exitwhen HaveStoredString(g,k,"result") or (TimerGetRemaining(x)<=0) or GetStoredBoolean(g,pk,"haltnow")
        call StoreReal(g,k,"rem",TimerGetRemaining(x))
        call TriggerSleepAction(0)
    endloop
    call StoreBoolean(g,pk,"haltnow",false)
    set r=GetStoredString(g,k,"result")
    call FlushStoredMission( g,k)
    call TriggerRemoveAction(t,ac)
    call DestroyTrigger(t)
    call DestroyTimer(x)
    call StoreBoolean(g,pk,"notfree",false)
 set x=null
 set ac=null
 set g=null
 set t=null
 return r
endfunction


//=============================================================================================================
// Initializes Charmap 0 (default)
//
function Codemaker_init takes nothing returns nothing
    call Codemaker_SetCharmap(0,Codemaker_Charmap(),Codemaker_FCSsize())
endfunction

//=============================================================================================================
// Recolors input string, so Capital letters, Lower case letters and symbols have different colors
//
function Codemaker_HighlightCode takes string cod, string cColor, string lColor, string sColor returns string
 local integer l=StringLength(cod)
 local integer i=0
 local string r=""
 local string c
 local string x
 local boolean b
    loop
        exitwhen (i>=l)
        set c=SubString(cod,i,i+1)
        set x=""
        loop
            exitwhen (i>=l)
            set b= (StringCase(c,true)==c) and (StringCase(c,false)!=c)
            exitwhen not( b)
            set x=x+c
            set i=i+1
            set c=SubString(cod,i,i+1)
        endloop
        if (x!="") then
            set r=r+"|c"+cColor+x+"|r"
        endif
        set x=""
        loop
            exitwhen (i>=l)
            set b= (StringCase(c,true)!=c) and (StringCase(c,false)==c)
            exitwhen not ( b)
            set x=x+c
            set i=i+1
            set c=SubString(cod,i,i+1)
        endloop
        if (x!="") then
            set r=r+"|c"+lColor+x+"|r"
        endif
        set x=""
        loop
            exitwhen (i>=l)
            set b= (StringCase(c,true)==c) and (StringCase(c,false)==c)
            exitwhen not ( b)
            set x=x+c
            set i=i+1
            set c=SubString(cod,i,i+1)
        endloop
        if (x!="") then
            set r=r+"|c"+sColor+x+"|r"
        endif
    endloop
 return r
endfunction

function Codemaker_Code2Serial takes string cod, string token , integer charspergroup, string cColor, string lColor, string sColor returns string
 local integer i=charspergroup
 local integer j=0
 local gamecache g=Codemaker()
 local string k=Codemaker_CurrentCharmap()
 local integer b=GetStoredInteger(g,k+"bitsperchar","now")
 local integer mx=R2I(Pow(2,b)-1)
 local string r=""
 local string c
    loop
        exitwhen (ModuloInteger(StringLength(cod),i)==0)
        set cod=cod+GetStoredString(g,k+"bin2char", Codemaker_Int2BinStr(GetRandomInt(0,mx),b) )
    endloop
    loop
        set c=SubString(cod,j,j+i)
        exitwhen (c=="") or (c==null)
        if (r=="") then
            set r=Codemaker_HighlightCode(c,cColor,lColor,sColor)
        else
            set r=r+"-"+Codemaker_HighlightCode(c,cColor,lColor,sColor)
        endif
        set j=j+i
    endloop

 set g=null
 return r
endfunction

function Codemaker_Serial2Code takes string serial, string token returns string
 local string r=""
 local string c=""
 local integer i=0
    loop
        set c=SubString(serial,i,i+1)
        exitwhen (c=="") or (c==null)
        if (c!=token) then
            set r=r+c
        endif
        set i=i+1
    endloop
 return r
endfunction



//=============================================================================================================
// Returns the required size to save a value if its maximum is i
//
function Codemaker_GetRequiredSize takes integer i returns integer
 local integer p=1
 local integer r=0
    loop
        exitwhen (p>i)
        set r=r+1
        set p=p*2
    endloop
 return r
endfunction

//##end##