function SaveLoad_InitialSetup takes nothing returns nothing
local integer i = 0
local integer j = 0
loop
set udg_SaveLoad_Compress[i + 48] = j
set udg_SaveLoad_Uncompress[i] = i + 48
set j = j + 1
set i = i + 1
exitwhen i >= 10
endloop
set i = 0
loop
set udg_SaveLoad_Compress[i + 97] = j
set udg_SaveLoad_Compress[i + 65] = j + 26
set udg_SaveLoad_Uncompress[i + 10] = i + 97
set udg_SaveLoad_Uncompress[i + 26 + 10] = i + 65
set j = j + 1
set i = i + 1
exitwhen i >= 26
endloop
endfunction
function SaveLoad_Id2CId takes integer n returns integer
local integer i = n / (256 * 256 * 256)
local integer r
set n = n - i * (256 * 256 * 256)
set r = udg_SaveLoad_Compress[i]
set i = n / (256 * 256)
set n = n - i * (256 * 256)
set r = r * 64 + udg_SaveLoad_Compress[i]
set i = n / 256
set r = r * 64 + udg_SaveLoad_Compress[i]
return r * 64 + udg_SaveLoad_Compress[n - i * 256]
endfunction
function SaveLoad_CId2Id takes integer n returns integer
local integer i = n / (64 * 64 * 64)
local integer r
set n = n - i * (64 * 64 * 64)
set r = udg_SaveLoad_Uncompress[i]
set i = n / (64 * 64)
set n = n - i * (64 * 64)
set r = r * 256 + udg_SaveLoad_Uncompress[i]
set i = n / 64
set r = r * 256 + udg_SaveLoad_Uncompress[i]
return r * 256 + udg_SaveLoad_Uncompress[n - i * 64]
endfunction
function SaveLoad_Unit2Integer takes unit u returns integer
local integer i = 0
local integer n = GetUnitTypeId(u)
if udg_SaveLoad_Initialized == false then
set udg_SaveLoad_Initialized = true
call SaveLoad_InitialSetup()
endif
loop
set i = i + 1
exitwhen i > udg_SaveLoad_Heroes_LastIndex
if udg_SaveLoad_Heroes[i] == n then
return i
endif
endloop
return SaveLoad_Id2CId(n)
endfunction
function SaveLoad_Integer2Unit takes integer i returns integer
if udg_SaveLoad_Initialized == false then
set udg_SaveLoad_Initialized = true
call SaveLoad_InitialSetup()
endif
if i <= udg_SaveLoad_Heroes_LastIndex then
return udg_SaveLoad_Heroes[i]
endif
return SaveLoad_CId2Id(i)
endfunction
function SaveLoad_Item2Integer takes item t returns integer
local integer i = 0
local integer n = GetItemTypeId(t)
if udg_SaveLoad_Initialized == false then
set udg_SaveLoad_Initialized = true
call SaveLoad_InitialSetup()
endif
loop
set i = i + 1
exitwhen i > udg_SaveLoad_Items_LastIndex
if udg_SaveLoad_Items[i] == n then
return i
endif
endloop
return SaveLoad_Id2CId(n)
endfunction
function SaveLoad_Integer2Item takes integer i returns integer
if udg_SaveLoad_Initialized == false then
set udg_SaveLoad_Initialized = true
call SaveLoad_InitialSetup()
endif
if i <= udg_SaveLoad_Items_LastIndex then
return udg_SaveLoad_Items[i]
endif
return SaveLoad_CId2Id(i)
endfunction
function SaveLoad_Ability2Integer takes integer a returns integer
local integer i = 0
if udg_SaveLoad_Initialized == false then
set udg_SaveLoad_Initialized = true
call SaveLoad_InitialSetup()
endif
loop
set i = i + 1
exitwhen i > udg_SaveLoad_Abilities_LastIndex
if udg_SaveLoad_Abilities[i] == a then
return i
endif
endloop
return SaveLoad_Id2CId(a)
endfunction
function SaveLoad_Integer2Ability takes integer i returns integer
if udg_SaveLoad_Initialized == false then
set udg_SaveLoad_Initialized = true
call SaveLoad_InitialSetup()
endif
if i <= udg_SaveLoad_Abilities_LastIndex then
return udg_SaveLoad_Abilities[i]
endif
return SaveLoad_CId2Id(i)
endfunction
function SaveLoad_Color takes string s returns string
local integer i = StringLength(s)
local string c
local string r = ""
loop
set i = i - 1
set c = SubString(s,i,i + 1)
if c == "0" or c == "1" or c == "2" or c == "3" or c == "4" or c == "5" or c == "6" or c == "7" or c == "8" or c == "9" then
set r = "|cffff9999" + c + "|r" + r
elseif c == "-" then
set r = "|cffdddddd-|r" + r
elseif c == "a" or c == "b" or c == "c" or c == "d" or c == "e" or c == "f" or c == "g" or c == "h" or c == "i" or c == "j" or c == "k" or c == "l" or c == "m" or c == "n" or c == "o" or c == "p" or c == "q" or c == "r" or c == "s" or c == "t" or c == "u" or c == "v" or c == "w" or c == "x" or c == "y" or c == "z" then
set r = "|cff99ff99" + c + "|r" + r
elseif c == "A" or c == "B" or c == "C" or c == "D" or c == "E" or c == "F" or c == "G" or c == "H" or c == "I" or c == "J" or c == "K" or c == "L" or c == "M" or c == "N" or c == "O" or c == "P" or c == "Q" or c == "R" or c == "S" or c == "T" or c == "U" or c == "V" or c == "W" or c == "X" or c == "Y" or c == "Z" then
set r = "|cff9999ff" + c + "|r" + r
else
set r = c + r
endif
exitwhen i <= 0
endloop
return r
endfunction
function SaveLoad_EncodeChar takes string n returns integer
local integer i = 0
local string s1 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
local string s2 = "abcdefghijklmnopqrstuvwxyz"
local string s3 = "0123456789"
loop
if SubString(s1,i,i + 1) == n then
return i
endif
if SubString(s2,i,i + 1) == n then
return i
endif
set i = i + 1
exitwhen i >= 26
endloop
set i = 0
loop
if SubString(s3,i,i + 1) == n then
return i
endif
set i = i + 1
exitwhen i >= 10
endloop
return 0
endfunction
function SaveLoad_EncodeVerify takes string buffer returns integer
local integer i = 0
local integer j = 0
local string name = GetPlayerName(GetTriggerPlayer())
if udg_SaveLoad_UsePlayername == true then
loop
set j = j + SaveLoad_EncodeChar(SubString(name,i,i + 1))
set i = i + 1
exitwhen i >= StringLength(name)
endloop
endif
set i = 0
loop
set j = j + SaveLoad_EncodeChar(SubString(buffer,i,i + 1))
set i = i + 1
exitwhen i >= StringLength(buffer)
endloop
return j
endfunction
function SaveLoad_EncodeValues takes nothing returns string
local integer i
local integer j
local integer k
local integer l
local integer m
local integer CodeLength = StringLength(udg_SaveLoad_Alphabet)
local integer array a
local string buffer = ""
local string c = ""
local integer skip = 0
local integer CONST = 1000000
local string abc = "0123456789"
set i = 0
loop
set i = i + 1
exitwhen i > udg_SaveCount
set buffer = buffer + I2S(udg_Save[i]) + "-"
endloop
set buffer = buffer + I2S(SaveLoad_EncodeVerify(buffer))
if udg_Save[1] == 0 then
set buffer = "-" + buffer
endif
set i = 0
loop
set a[i] = 0
set i = i + 1
exitwhen i >= 100
endloop
set m = 0
set i = 0
loop
set j = 0
loop
set a[j] = a[j] * 11
set j = j + 1
exitwhen j > m
endloop
set l = 0
set c = SubString(buffer,i,i + 1)
loop
exitwhen SubString(abc,l,l + 1) == c
set l = l + 1
exitwhen l > 9
endloop
set a[0] = a[0] + l
set j = 0
loop
set k = a[j] / CONST
set a[j] = a[j] - k * CONST
set a[j + 1] = a[j + 1] + k
set j = j + 1
exitwhen j > m
endloop
if k > 0 then
set m = m + 1
endif
set i = i + 1
exitwhen i >= StringLength(buffer)
endloop
set buffer = ""
loop
exitwhen m < 0
set j = m
loop
exitwhen j <= 0
set k = a[j] / CodeLength
set a[j - 1] = a[j - 1] + (a[j] - k * CodeLength) * CONST
set a[j] = k
set j = j - 1
endloop
set k = a[j] / CodeLength
set i = a[j] - k * CodeLength
set buffer = buffer + SubString(udg_SaveLoad_Alphabet,i,i + 1)
set a[j] = k
if a[m] == 0 then
set m = m - 1
endif
endloop
set i = StringLength(buffer)
set skip = 0
set c = ""
loop
set i = i - 1
set c = c + SubString(buffer,i,i + 1)
set skip = skip + 1
if skip == 4 and i > 0 then
set c = c + "-"
set skip = 0
endif
exitwhen i <= 0
endloop
return c
endfunction
function SaveLoad_DecodeValues takes string s returns boolean
local integer i
local integer j
local integer k
local integer l
local integer SaveCode = 0
local integer m
local integer array a
local string buffer = ""
local integer CodeLength = StringLength(udg_SaveLoad_Alphabet)
local integer skip = -1
local integer CONST = 1000000
local string abc = "0123456789-"
local string c
set i = 0
loop
set a[i] = 0
set i = i + 1
exitwhen i >= 100
endloop
set m = 0
set i = 0
loop
set j = 0
loop
set a[j] = a[j] * CodeLength
set j = j + 1
exitwhen j > m
endloop
set skip = skip + 1
if skip == 4 then
set skip = 0
set i = i + 1
endif
set l = CodeLength
set c = SubString(s,i,i + 1)
loop
set l = l - 1
exitwhen l < 1
exitwhen SubString(udg_SaveLoad_Alphabet,l,l + 1) == c
endloop
set a[0] = a[0] + l
set j = 0
loop
set k = a[j] / CONST
set a[j] = a[j] - k * CONST
set a[j + 1] = a[j + 1] + k
set j = j + 1
exitwhen j > m
endloop
if k > 0 then
set m = m + 1
endif
set i = i + 1
exitwhen i >= StringLength(s)
endloop
loop
exitwhen m < 0
set j = m
loop
exitwhen j <= 0
set k = a[j] / 11
set a[j - 1] = a[j - 1] + (a[j] - k * 11) * CONST
set a[j] = k
set j = j - 1
endloop
set k = a[j] / 11
set i = a[j] - k * 11
set buffer = SubString(abc,i,i + 1) + buffer
set a[j] = k
if a[m] == 0 then
set m = m - 1
endif
endloop
set i = 0
set j = 0
loop
loop
exitwhen i >= StringLength(buffer)
exitwhen i > 0 and SubString(buffer,i,i + 1) == "-" and SubString(buffer,i - 1,i) != "-"
set i = i + 1
endloop
if i < StringLength(buffer) then
set k = i
endif
set SaveCode = SaveCode + 1
set udg_Save[SaveCode] = S2I(SubString(buffer,j,i))
set j = i + 1
set i = i + 1
exitwhen i >= StringLength(buffer)
endloop
set j = SaveLoad_EncodeVerify(SubString(buffer,0,k))
set udg_SaveCount = SaveCode - 1
if j == udg_Save[SaveCode] then
return true
endif
return false
endfunction
function SaveLoad_Encode takes nothing returns string
if udg_SaveLoad_CaseSensitive == false then
set udg_SaveLoad_Alphabet = StringCase(udg_SaveLoad_Alphabet,true)
endif
return SaveLoad_Color(SaveLoad_EncodeValues())
endfunction
function SaveLoad_Decode takes string s returns boolean
if udg_SaveLoad_CaseSensitive == false then
set udg_SaveLoad_Alphabet = StringCase(udg_SaveLoad_Alphabet,true)
set s = StringCase(s,true)
endif
if SaveLoad_DecodeValues(s) then
return true
endif
return false
endfunction
Name | Type | is_array | initial_value |
BonusesFound | integer | No | |
BonusesTotal | integer | No | |
Cairne | unit | No | |
CancelDemonFall | boolean | No | |
CancelIntro | boolean | No | |
CancelOutro | boolean | No | |
CancelThrallMeetsGrom | boolean | No | |
Code | string | No | |
CodeError | boolean | No | |
CPRankLimit | integer | Yes | |
CPRankMax | integer | No | |
DemonCinIsOver | boolean | No | false |
DemonsPlayer | player | No | Player06 |
EndGromOkay | boolean | No | false |
EnterTheCanyon | boolean | No | false |
EveryXSecondsSummonTargets | group | No | |
EXTRAS | integer | No | |
EXTRAStotal | integer | No | |
FinalComment | string | No | |
FinalCPRank | string | No | |
FinalRank | string | No | |
FinalScore | integer | No | |
GAMEOVER | boolean | No | false |
GameSelection | boolean | No | |
Grom | unit | No | |
GromCinHasPlayed | boolean | No | false |
Hero1 | unit | No | |
Hero2 | unit | No | |
HideGroup | group | No | |
InfernalFall | location | No | |
InfernalFallPoint | location | Yes | |
InfernalFallTimer | timer | No | |
InfernalFallWait | real | Yes | |
InsaneMode | boolean | No | |
Jaina | unit | No | |
JainaAliveGroup | group | No | |
JainaAssaultTimer | timer | No | |
JainaAttackWarsongInteger | integer | No | 3 |
JainaCrapReset | timer | No | |
JainaHELP | integer | No | |
LocalPlayer | player | No | |
Nazgrel | unit | No | |
NazgrelEnfeebleGroup | group | No | |
NazgrelLightningUnit | unit | No | |
NazgrelMeteor | unit | No | |
NazgrelPickUpTimer | timer | No | |
NazgrelPickUpTimer2 | timer | No | |
OhCrapOmeter | real | No | 0.00 |
Player1 | player | No | Player00 |
Player1CameraPosition | location | No | |
Player2 | player | No | Player05 |
Player2CameraPosition | location | No | |
PlayerSwapperInt | integer | No | 1 |
PositionOfGrom | location | No | |
PurgePartyArray | unit | Yes | |
RankInteger | integer | No | |
ReqBringGromCOP | questitem | No | |
ReqCaptureGrom | questitem | No | |
ResearchMax | integer | No | |
ResearchString | string | Yes | |
ResearchType | techcode | Yes | |
Save | integer | Yes | |
SaveCount | integer | No | |
SaveGromQuest | quest | No | |
SaveLoad_Abilities | abilcode | Yes | |
SaveLoad_Abilities_LastIndex | integer | No | |
SaveLoad_Alphabet | string | No | |
SaveLoad_CaseSensitive | boolean | No | |
SaveLoad_Compress | integer | Yes | |
SaveLoad_Heroes | unitcode | Yes | |
SaveLoad_Heroes_LastIndex | integer | No | |
SaveLoad_Initialized | boolean | No | |
SaveLoad_Items | itemcode | Yes | |
SaveLoad_Items_LastIndex | integer | No | |
SaveLoad_Uncompress | integer | Yes | |
SaveLoad_UsePlayername | boolean | No | |
ScoreBonuses | integer | No | |
ScoreExtra | integer | No | |
ScoreLimit | integer | Yes | |
ScoreMax | integer | No | |
ScoreTime | integer | No | |
SelectedUnits | group | Yes | |
SoulItemVar | item | No | |
SummonArray | rect | Yes | |
SummonHere | integer | No | |
SummonHereAlternateBoolean | boolean | No | false |
SumRank | integer | No | |
TechHash | hashtable | No | |
TempBoolean | boolean | No | |
TempInteger | integer | No | |
TempItem | item | No | |
TempItemType | itemcode | No | |
TempNazgrell | unit | No | |
temppoint | location | No | |
TempPoint | location | No | |
TempString | string | No | |
TempThrall | unit | No | |
tempugroup | group | No | |
TempUGroup | group | No | |
TempUnit | unit | No | |
TempUnitType | unitcode | No | |
Thrall | unit | No | |
TimeHours | integer | No | |
TimeMax | real | No | |
TimeMin | real | No | |
TimeMinutes | integer | No | |
TimeRange | real | No | |
TimeSeconds | integer | No | |
TimeString | string | No | |
TimeTotal | integer | No | |
tipEu | boolean | No | |
tipGr | boolean | No | |
UnitGroup | group | No | |
Validate | boolean | No | |
VaultRandomizer | integer | No | 0 |
VICTORY | boolean | No | |
VoteNew1 | boolean | No | |
VoteNew2 | boolean | No | |
VoteSkip1 | boolean | No | false |
VoteSkip2 | boolean | No | false |
VoteSkipFinal | boolean | No | false |
WarSong | player | No | Player03 |
WarsongAttackTimer | timer | No | |
WaterfallSight | boolean | No | false |
WaterfallVis | fogmodifier | No | |
WSBaseCleared1 | boolean | No | |
WSBaseCleared2 | boolean | No | |
x | real | No | |
y | real | No |
//TESH.scrollpos=0
//TESH.alwaysfold=0
function ResearchStart takes nothing returns boolean
local player p1 = GetTriggerPlayer()
local player p2
local integer i
local integer t = GetResearched()
if p1 == udg_Player1 then
set p2 = udg_Player2
else
set p2 = udg_Player1
endif
call SetPlayerTechMaxAllowed(p2, t, GetPlayerTechCount(p1, t, true))
set p1 = null
set p2 = null
return false
endfunction
function ResearchComplete takes nothing returns boolean
local player p1 = GetTriggerPlayer()
local player p2
local integer t = GetResearched()
local integer i
local integer tn
local integer t1
local integer t2
if p1 == udg_Player1 then
set p2 = udg_Player2
else
set p2 = udg_Player1
endif
set i = 1
loop
exitwhen i > udg_ResearchMax
if udg_ResearchType[i] == t then
set t1 = GetPlayerTechMaxAllowed(p1, t)
set t2 = GetPlayerTechMaxAllowed(p2, t)
// In one of the players transfered the building that doing the research
// Without this, it wouldn't let the other player research the next level(s)
if t1 >= t2 then
set tn = GetPlayerTechCount(p1, t, true)
call SetPlayerTechMaxAllowed(p1, t, t1)
call SetPlayerTechResearched(p1, t, tn)
call SetPlayerTechMaxAllowed(p2, t, t1)
call SetPlayerTechResearched(p2, t, tn)
else
set tn = GetPlayerTechCount(p2, t, true)
call SetPlayerTechMaxAllowed(p1, t, t2)
call SetPlayerTechResearched(p1, t, tn)
call SetPlayerTechMaxAllowed(p2, t, t2)
call SetPlayerTechResearched(p2, t, tn)
endif
call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, "|cff9966ccRESEARCH|r - " + GetPlayerName(p1) + " has researched " + udg_ResearchString[(i - 1)*3 + tn] + " for both players.")
call StartSound(gg_snd_Hint)
exitwhen true
endif
set i = i + 1
endloop
set p1 = null
set p2 = null
return false
endfunction
function ResearchCancel takes nothing returns boolean
local player p1 = GetTriggerPlayer()
local player p2
local integer t = GetResearched()
local integer i
local integer t1
local integer t2
if p1 == udg_Player1 then
set p2 = udg_Player2
else
set p2 = udg_Player1
endif
set i = 1
loop
exitwhen i > udg_ResearchMax
if udg_ResearchType[i] == t then
set t1 = GetPlayerTechMaxAllowed(p1, t)
set t2 = GetPlayerTechMaxAllowed(p2, t)
// In one of the players transfered the building that doing the research
// Without this, it wouldn't let the other player research the next level(s)
if t1 >= t2 then
call SetPlayerTechMaxAllowed(p1, t, t1)
call SetPlayerTechMaxAllowed(p2, t, t1)
else
call SetPlayerTechMaxAllowed(p1, t, t2)
call SetPlayerTechMaxAllowed(p2, t, t2)
endif
exitwhen true
endif
set i = i + 1
endloop
set p1 = null
set p2 = null
return false
endfunction
function InitTrig_ResearchStart takes nothing returns nothing
local trigger t1 = CreateTrigger()
local trigger t2 = CreateTrigger()
local trigger t3 = CreateTrigger()
call TriggerRegisterPlayerUnitEvent(t1, udg_Player1, EVENT_PLAYER_UNIT_RESEARCH_START, null)
call TriggerRegisterPlayerUnitEvent(t1, udg_Player2, EVENT_PLAYER_UNIT_RESEARCH_START, null)
call TriggerAddCondition(t1, Condition(function ResearchStart))
call TriggerRegisterPlayerUnitEvent(t2, udg_Player1, EVENT_PLAYER_UNIT_RESEARCH_FINISH, null)
call TriggerRegisterPlayerUnitEvent(t2, udg_Player2, EVENT_PLAYER_UNIT_RESEARCH_FINISH, null)
call TriggerAddCondition(t2, Condition(function ResearchComplete))
call TriggerRegisterPlayerUnitEvent(t3, udg_Player1, EVENT_PLAYER_UNIT_RESEARCH_CANCEL, null)
call TriggerRegisterPlayerUnitEvent(t3, udg_Player2, EVENT_PLAYER_UNIT_RESEARCH_CANCEL, null)
call TriggerAddCondition(t3, Condition(function ResearchCancel))
set t1 = null
set t2 = null
set t3 = null
endfunction
//TESH.scrollpos=10
//TESH.alwaysfold=0
function ConstructionComplete takes nothing returns boolean
local player p1 = GetTriggerPlayer()
local player p2
local unit u1 = GetTriggerUnit()
local unit u2
local integer id = GetUnitTypeId(u1)
local integer i
local integer hid = GetHandleId(u1)
local real x = GetUnitX(u1)
local real y = GetUnitY(u1)
local string s = "constructed"
if id == 'ogre' or id == 'ostr' or id == 'ofrt' or id == 'oalt' or id == 'ofor' then
if p1 == udg_Player1 then
set p2 = udg_Player2
else
set p2 = udg_Player1
endif
if id == 'ostr' or id == 'ofrt' then
set s = "upgraded to"
elseif id == 'oalt' then
set s = s + " an "
else
set s = s + " a "
endif
set u2 = LoadUnitHandle(udg_TechHash, 0, hid)
if not (u2 == null) then
call RemoveUnit(u2)
endif
call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, "|cff6666ccTECHTREE|r - " + GetPlayerName(p1) + " has " + s + GetUnitName(u1) + " for both players.")
set i = id - 'o'*256*256*256 + 'z'*256*256*256
set u2 = CreateUnit(p2, i, x, y, 0)
call SaveUnitHandle(udg_TechHash, 0, hid, u2)
call SetUnitX(u2, x)
call SetUnitY(u2, y)
endif
set p1 = null
set p2 = null
set u1 = null
set u2 = null
return false
endfunction
function BuildingDies takes nothing returns boolean
local unit u1 = GetTriggerUnit()
local unit u2
local integer id = GetUnitTypeId(u1)
if id == 'ogre' or id == 'ostr' or id == 'ofrt' or id == 'oalt' or id == 'ofor' then
set u2 = LoadUnitHandle(udg_TechHash, 0, GetHandleId(u1))
if not (u2 == null) then
call RemoveUnit(u2)
endif
endif
set u1 = null
set u2 = null
return false
endfunction
function Order takes nothing returns boolean
local unit u = GetTriggerUnit()
local unit u1
if GetIssuedOrderId() == OrderId("smart") and GetUnitTypeId(u) == 'opeo' and GetOwningPlayer(GetOrderTargetUnit()) != GetTriggerPlayer() then
set u1 = LoadUnitHandle(udg_TechHash, 0, GetHandleId(GetOrderTargetUnit()))
if u1 != null then
call IssueTargetOrder(u, "smart", u1)
endif
endif
set u = null
return false
endfunction
function InitTrig_TechShare takes nothing returns nothing
local trigger t1 = CreateTrigger()
local trigger t2 = CreateTrigger()
local trigger t3 = CreateTrigger()
local player p1 = udg_Player1
local player p2 = udg_Player2
local unit u
local real x
local real y
set udg_TechHash = InitHashtable()
//On Completion
call TriggerRegisterPlayerUnitEvent(t1, p1, EVENT_PLAYER_UNIT_CONSTRUCT_FINISH, null)
call TriggerRegisterPlayerUnitEvent(t1, p2, EVENT_PLAYER_UNIT_CONSTRUCT_FINISH, null)
call TriggerRegisterPlayerUnitEvent(t1, p1, EVENT_PLAYER_UNIT_UPGRADE_FINISH, null)
call TriggerRegisterPlayerUnitEvent(t1, p2, EVENT_PLAYER_UNIT_UPGRADE_FINISH, null)
call TriggerAddCondition(t1, Condition(function ConstructionComplete))
//On Death
call TriggerRegisterPlayerUnitEvent(t2, p1, EVENT_PLAYER_UNIT_DEATH, null)
call TriggerRegisterPlayerUnitEvent(t2, p2, EVENT_PLAYER_UNIT_DEATH, null)
call TriggerAddCondition(t2, Condition(function BuildingDies))
//On Order
call TriggerRegisterPlayerUnitEvent(t3, p1, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, null)
call TriggerRegisterPlayerUnitEvent(t3, p2, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, null)
call TriggerAddCondition(t3, Condition(function Order))
//Red Stronghold
set x = GetUnitX(gg_unit_ostr_0024)
set y = GetUnitY(gg_unit_ostr_0024)
set u = CreateUnit(p2, 'zstr', x, y, 0)
call SetUnitX(u, x)
call SetUnitY(u, y)
call SaveUnitHandle(udg_TechHash, 0, GetHandleId(gg_unit_ostr_0024), u)
//Orange Great Hall
set x = GetUnitX(gg_unit_ogre_0290)
set y = GetUnitY(gg_unit_ogre_0290)
set u = CreateUnit(p1, 'zgre', x, y, 0)
call SetUnitX(u, x)
call SetUnitY(u, y)
call SaveUnitHandle(udg_TechHash, 0, GetHandleId(gg_unit_ogre_0290), u)
//Red Altar
set x = GetUnitX(gg_unit_oalt_0053)
set y = GetUnitY(gg_unit_oalt_0053)
set u = CreateUnit(p2, 'zalt', x, y, 0)
call SetUnitX(u, x)
call SetUnitY(u, y)
call SaveUnitHandle(udg_TechHash, 0, GetHandleId(gg_unit_oalt_0053), u)
//Orange Mill
set x = GetUnitX(gg_unit_ofor_0022)
set y = GetUnitY(gg_unit_ofor_0022)
set u = CreateUnit(p1, 'zfor', x, y, 0)
call SetUnitX(u, x)
call SetUnitY(u, y)
call SaveUnitHandle(udg_TechHash, 0, GetHandleId(gg_unit_ofor_0022), u)
set p1 = null
set p2 = null
set u = null
set t1 = null
set t2 = null
set t3 = null
endfunction
//TESH.scrollpos=0
//TESH.alwaysfold=0
function GiveResource takes nothing returns nothing
local playerstate ps
local integer i
local integer a
local player p1 = GetTriggerPlayer()
local player p2
local string tmp
local string resource
local string message = GetEventPlayerChatString()
local string gold = SubString(message, 0, 6)
local string lumber = SubString(message, 0, 8)
if gold == "-gold " or lumber == "-lumber " then
if p1 == udg_Player1 then
set p2 = udg_Player2
else
set p2 = udg_Player1
endif
if gold == "-gold " then
set resource = "gold"
set ps = PLAYER_STATE_RESOURCE_GOLD
set a = S2I(SubString(message, 6, StringLength(message)))
else
set resource = "lumber"
set ps = PLAYER_STATE_RESOURCE_LUMBER
set a = S2I(SubString(message, 8, StringLength(message)))
endif
set i = GetPlayerState(p1, ps)
if a > i then
set a = i
endif
if a > 0 then
set tmp = I2S(a)
call SetPlayerState(p1, ps, i - a)
call SetPlayerState(p2, ps, GetPlayerState(p2, ps) + a)
call DisplayTextToPlayer(p2, 0, 0, "|cffcc6600ALLIES|r - " + tmp + " " + resource + " received from " + GetPlayerName(p1) + ".")
call DisplayTextToPlayer(p1, 0, 0, "|cffcc6600ALLIES|r - " + tmp + " " + resource + " sent to " + GetPlayerName(p2) + ".")
call StartSound(gg_snd_ItemReceived)
else
call DisplayTextToPlayer(p1, 0, 0, "|cffcc6600ALLIES|r - Not enough " + resource + ".")
endif
endif
set ps = null
set p1 = null
set p2 = null
endfunction
function InitTrig_GiveResource takes nothing returns nothing
set gg_trg_GiveResource = CreateTrigger()
call DisableTrigger(gg_trg_GiveResource)
call TriggerRegisterPlayerChatEvent(gg_trg_GiveResource, udg_Player1, "-gold ", false)
call TriggerRegisterPlayerChatEvent(gg_trg_GiveResource, udg_Player2, "-gold ", false)
call TriggerRegisterPlayerChatEvent(gg_trg_GiveResource, udg_Player1, "-lumber ", false)
call TriggerRegisterPlayerChatEvent(gg_trg_GiveResource, udg_Player2, "-lumber ", false)
call TriggerAddAction(gg_trg_GiveResource, function GiveResource)
endfunction
//TESH.scrollpos=102
//TESH.alwaysfold=0
function ExchangeUnits takes nothing returns nothing
local player p1 = GetTriggerPlayer()
local player p2
local group units = CreateGroup()
local boolean b1
local boolean b2
local boolean b3
local boolean b4
local integer food = 0
local integer uyes = 0
local integer uall = 0
local integer fUsed
local integer fMax
local integer i
local unit u
local unit u1
local unit u2
local string result
local string result2
if p1 == udg_Player1 then
set p2 = udg_Player2
else
set p2 = udg_Player1
endif
// Gonna get reused
set fUsed = GetPlayerState(p2, PLAYER_STATE_RESOURCE_FOOD_USED)
set fMax = GetPlayerState(p2, PLAYER_STATE_RESOURCE_FOOD_CAP)
call GroupEnumUnitsSelected(units, p1, null)
set u = FirstOfGroup(units)
loop
set u = FirstOfGroup(units)
exitwhen u == null
set i = GetUnitFoodUsed(u)
// Kinda confusing but better than a mile long line, trust me
set b1 = GetUnitFoodMade(u) == 0 and IsUnitType(u, UNIT_TYPE_STRUCTURE)
set b2 = i + fUsed <= fMax and not IsUnitType(u, UNIT_TYPE_STRUCTURE)
set b3 = not (IsUnitType(u, UNIT_TYPE_HERO) or IsUnitType(u, UNIT_TYPE_SUMMONED) or IsUnitType(u, UNIT_TYPE_PEON))
set b4 = GetOwningPlayer(u) == p1 and GetUnitTypeId(u) != 'eate'
if (b1 or b2) and b3 and b4 then
set uyes = uyes + 1
set food = food + i
call SetUnitOwner(u, p2, true)
set u1 = LoadUnitHandle(udg_TechHash, 0, GetHandleId(u))
if u1 != null then
call SetUnitOwner(u1, p1, true)
endif
set u2 = LoadUnitHandle(udg_TechHash, 1, GetHandleId(u))
if u2 != null then
call SetUnitOwner(u2, p1, true)
endif
call PingMinimap(GetUnitX(u), GetUnitY(u), 3)
endif
set uall = uall + 1
call GroupRemoveUnit(units, u)
endloop
if uyes == uall and uall != 0 then
call StartSound(gg_snd_Rescue)
set result = "|cffcc6600ALLIES|r - All " + I2S(uall) + " units were exchanged successfully"
set result2 = "|cffcc6600ALLIES|r - " + I2S(uyes) + " units were exchanged to you"
if food > 0 then
set result = result + " - a total of " + I2S(food) + " food."
set result2 = result2 + " - a total of " + I2S(food) + " food."
else
set result = result + "."
set result2 = result2 + "."
endif
elseif uyes != 0 then
call StartSound(gg_snd_Rescue)
set result = "|cffcc6600ALLIES|r - " + I2S(uyes) + "/" + I2S(uall) + " units were successfully exchanged"
set result2 = "|cffcc6600ALLIES|r - " + I2S(uyes) + " units were exchanged to you"
if (food > 0) then
set result = result + " - a total of " + I2S(food) + " food"
set result2 = result2 + " - a total of " + I2S(food) + " food"
else
set result = result + "."
set result2 = result2 + "."
endif
elseif uall != 0 then
if udg_LocalPlayer == p1 then
call StartSound(gg_snd_Error)
endif
set result = "|cffcc6600ALLIES|r - No units could be exchanged."
set result2 = "Empty"
else
if udg_LocalPlayer == p1 then
call StartSound(gg_snd_Error)
endif
set result = "|cffcc6600ALLIES|r - No units selected."
set result2 = "Empty"
endif
call DisplayTextToPlayer(p1, 0, 0, " ")
call DisplayTextToPlayer(p2, 0, 0, " ")
call DisplayTextToPlayer(p1, 0, 0, result)
if result2 != "Empty" then
call DisplayTextToPlayer(p2, 0, 0, result2)
endif
if not udg_tipEu then
set udg_tipEu = true
call TriggerSleepAction(bj_QUEUE_DELAY_HINT)
call StartSound(gg_snd_Hint)
call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, " ")
call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, "|cff32CD32HINT|r - You cannot exchange Peons, Heroes, Great Hall/Stronghold/Fortress, Altars and Burrows.")
call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, "Units must also obey the food limit.")
endif
call DestroyGroup(units)
set units = null
set u = null
set u1 = null
set u2 = null
set p1 = null
set p2 = null
endfunction
function InitTrig_ExchangeUnits takes nothing returns nothing
set gg_trg_ExchangeUnits = CreateTrigger()
call DisableTrigger(gg_trg_ExchangeUnits)
call TriggerRegisterPlayerChatEvent(gg_trg_ExchangeUnits, udg_Player1, "-exchange", true)
call TriggerRegisterPlayerChatEvent(gg_trg_ExchangeUnits, udg_Player2, "-exchange", true)
call TriggerAddAction(gg_trg_ExchangeUnits, function ExchangeUnits)
endfunction
//TESH.scrollpos=7
//TESH.alwaysfold=0
function CinematicSkip takes nothing returns boolean
// It is just better to read this way
local player p = GetTriggerPlayer()
local boolean b1
local boolean b2
local boolean bool = udg_CancelIntro
set bool = bool or udg_CancelDemonFall
set bool = bool or udg_CancelThrallMeetsGrom
set bool = bool or udg_CancelOutro
if bool then
if not (udg_VoteSkip1 or udg_VoteSkip2) then
if p == udg_Player1 then
set udg_VoteSkip1 = true
else
set udg_VoteSkip2 = true
endif
call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, GetPlayerName(p) + " wishes to skip this cinematic.")
else
set b1 = p == udg_Player1 and not udg_VoteSkip1
set b2 = p == udg_Player2 and not udg_VoteSkip2
if b1 or b2 then
set udg_VoteSkip1 = false
set udg_VoteSkip2 = false
set udg_VoteSkipFinal = true
call ClearTextMessages()
if udg_CancelIntro and TriggerEvaluate(gg_trg_Intro_Cancelled) then
call TriggerExecute(gg_trg_Intro_Cancelled)
elseif udg_CancelDemonFall and TriggerEvaluate(gg_trg_Demonic_Cinematic_Cancelled) then
call TriggerExecute(gg_trg_Demonic_Cinematic_Cancelled)
elseif udg_CancelThrallMeetsGrom and TriggerEvaluate(gg_trg_Confront_Grom_Cin_Cancelled) then
call TriggerExecute(gg_trg_Confront_Grom_Cin_Cancelled)
elseif udg_CancelOutro and TriggerEvaluate(gg_trg_Thrall_Gets_to_COP_with_Grom_Cin_Skip) then
call TriggerExecute(gg_trg_Thrall_Gets_to_COP_with_Grom_Cin_Skip)
endif
endif
endif
endif
return false
endfunction
function InitTrig_CinematicSkip takes nothing returns nothing
set gg_trg_CinematicSkip = CreateTrigger()
call TriggerRegisterPlayerEvent(gg_trg_CinematicSkip, udg_Player1, EVENT_PLAYER_END_CINEMATIC)
call TriggerRegisterPlayerEvent(gg_trg_CinematicSkip, udg_Player2, EVENT_PLAYER_END_CINEMATIC)
call TriggerAddCondition(gg_trg_CinematicSkip, Condition(function CinematicSkip))
endfunction
//TESH.scrollpos=0
//TESH.alwaysfold=0
function Cast takes nothing returns boolean
local unit u
local unit c = GetTriggerUnit()
if GetSpellAbilityId() == 'A005' then
set u = CreateUnit(GetTriggerPlayer(), 'h007', GetUnitX(c), GetUnitY(c), 0)
call UnitAddAbility(u, 'A00C')
call IssueTargetOrder(u, "bloodlust", c)
call UnitApplyTimedLife(u, 'BTLF', 1.00)
endif
set u = null
return false
endfunction
function InitTrig_Berserk takes nothing returns nothing
set gg_trg_Berserk = CreateTrigger()
call TriggerRegisterPlayerUnitEvent(gg_trg_Berserk, Player(3), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
call TriggerAddCondition(gg_trg_Berserk, Condition(function Cast))
endfunction
//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_GameMode_Conditions takes nothing returns boolean
local string s = GetEventPlayerChatString()
if s == "-insane" and not udg_InsaneMode then
set udg_InsaneMode = true
call TriggerExecute(gg_trg_Starttext)
elseif s == "-normal" and udg_InsaneMode then
set udg_InsaneMode = false
call TriggerExecute(gg_trg_Starttext)
endif
return false
endfunction
function InitTrig_GameMode takes nothing returns nothing
set gg_trg_GameMode = CreateTrigger()
call DisableTrigger(gg_trg_GameMode)
call TriggerRegisterPlayerChatEvent(gg_trg_GameMode, udg_Player1, "-insane", true)
call TriggerRegisterPlayerChatEvent(gg_trg_GameMode, udg_Player2, "-insane", true)
call TriggerRegisterPlayerChatEvent(gg_trg_GameMode, udg_Player1, "-normal", true)
call TriggerRegisterPlayerChatEvent(gg_trg_GameMode, udg_Player2, "-normal", true)
call TriggerAddCondition(gg_trg_GameMode, Condition( function Trig_GameMode_Conditions))
endfunction