[Solved] Custom Function Leak?

[GIMLI_2]

Hi
I just started messing around with the world editor again and have a simple question.
I created a custom function "CreateFloatingText" which basically just creates a floating text and sets values. Now, as i want to return the texttag, i cannot null it at the end of the function. Instead, i null it in the example trigger. Is that correct?

Hidden

library FloatingText initializer Init


   
    function CreateFloatingText takes string text, player p, real x, real y, real speed, real angle, real duration, real fade, boolean permanent returns texttag
        local texttag t = CreateTextTag()
        call SetTextTagText(t, text, 0.0345)
        call SetTextTagPos(t, x, y, 100)
        if (GetLocalPlayer() != p) then
            call SetTextTagVisibility(t, false)
        endif
        call SetTextTagVelocity(t, (speed*0.071/128)*Cos(angle*bj_DEGTORAD), (speed*0.071/128)*Sin(angle*bj_DEGTORAD))
        call SetTextTagPermanent(t, permanent)
        call SetTextTagLifespan(t, duration)
        call SetTextTagFadepoint(t, fade)
        return t
    endfunction
   


endlibrary

local texttag t = CreateFloatingText("123abc", GetTriggerPlayer(), GetCameraTargetPositionX(), GetCameraTargetPositionY(), 80.00, GetRandomReal(1.00, 360.0), 3.00, 2.00, false)
set t = null

 

[-Manuel-]

Use

bj_lastCreatedTextTag

Is a global variable that you can use freely.

 

[IcemanBo]

texttags recycle their id's by themselves, therefor it's not even required to null them.

 

[KILLCIDE]

^ What IcemanBo said.

However, assuming that texttags didn't recycle ids by themselves, then that still would not be right. It's a pretty common mistake Blizzard made with some of the GUI functions. The only way to avoid that type of local refernce leak is to use a global variable instead, as mentioned by -Manuel-

 

[Dr Super Good]

One can also use function parameters to return handles without leaking. Unlike local declared local handle variables, parameter declared local handle variables do correctly decrement reference counter on function return.

    function CreateFloatingTextCore takes string text, player p, real x, real y, real speed, real angle, real duration, real fade, boolean permanent, texttag nulltext returns texttag
        set nulltext = CreateTextTag()
        call SetTextTagText(nulltext, text, 0.0345)
        call SetTextTagPos(nulltext, x, y, 100)
        if (GetLocalPlayer() != p) then
            call SetTextTagVisibility(nulltext, false)
        endif
        call SetTextTagVelocity(nulltext, (speed*0.071/128)*Cos(angle*bj_DEGTORAD), (speed*0.071/128)*Sin(angle*bj_DEGTORAD))
        call SetTextTagPermanent(nulltext, permanent)
        call SetTextTagLifespan(nulltext, duration)
        call SetTextTagFadepoint(nulltext, fade)
        return nulltext
    endfunction

call CreateFloatingTextCore(..., null)

    // Maybe a wrapper to mask the parameter?
    function CreateFloatingText takes string text, player p, real x, real y, real speed, real angle, real duration, real fade, boolean permanent returns texttag
        return CreateFloatingTextCore(text, p, x, y, speed, angle, duration, fade, permanent, null)
    endfunction

call CreateFloatingText(...)

I wonder when Blizzard will fix the bug...

 

[IcemanBo]

Haha, nice idea!

 

[DracoL1ch]

indeed good idea by doctor, but nevertheless, simply use global var to pass out things out of function

 

[GIMLI_2]

Ok thanks! That way i can also call the function without saving the output into a variable (besides bj_lastCreatedTextTag)

Hidden

library FloatingText initializer Init


 
    function CreateFloatingText takes string text, player p, real x, real y, real speed, real angle, real duration, real fade, boolean permanent returns texttag
        set bj_lastCreatedTextTag = CreateTextTag()
        call SetTextTagText(bj_lastCreatedTextTag, text, 0.0345)
        call SetTextTagPos(bj_lastCreatedTextTag, x, y, 100)
        if (GetLocalPlayer() != p) then
            call SetTextTagVisibility(bj_lastCreatedTextTag, false)
        endif
        call SetTextTagVelocity(bj_lastCreatedTextTag, (speed*0.071/128)*Cos(angle*bj_DEGTORAD), (speed*0.071/128)*Sin(angle*bj_DEGTORAD))
        call SetTextTagPermanent(bj_lastCreatedTextTag, permanent)
        call SetTextTagLifespan(bj_lastCreatedTextTag, duration)
        call SetTextTagFadepoint(bj_lastCreatedTextTag, fade)
        return t
    endfunction
 


endlibrary

call CreateFloatingText("123abc", GetTriggerPlayer(), GetCameraTargetPositionX(), GetCameraTargetPositionY(), 80.00, GetRandomReal(1.00, 360.0), 3.00, 2.00, false)

that should work?

 

[Dr Super Good]

that should work?

No as you are trying to return t... I am guessing you mean to return bj_lastCreatedTextTag.

 

[GIMLI_2]

No as you are trying to return t... I am guessing you mean to return bj_lastCreatedTextTag.

Whoops