//==============================================================================
// Collections -- STRUCT STORAGE SYSTEM BY COHADAR -- v2.1
//==============================================================================
//
// PURPOUSE:
// * Storing structs for spells that require variable number of data
// * Great for algorithms that need random access.
// * Able to create 100% MUI spells.
//
// REFERENCE:
// * This system was inspired by java Collection interface
// [url]http://java.sun.com/docs/books/tutorial/collections/interfaces/collection.html[/url]
// [url]http://java.sun.com/javase/6/docs/api/java/util/Iterator.html[/url]
//
// DETAILS:
// * Collections are now implemented as static-only classes
// this removes limitations in number of elements from version 1.3
//
// * Main purpouse of collections is fast storing and removing of structs,
// Structs in Collection are NOT ordered in any way.
// Structs can change place inside collection at any time.
// Iterators are the only safe way to access collection elements.
//
// * Do NOT create or destoy Collection or Iterator classes,
// there is no point to that because all operations are static
//
// * Each Collection has exactly one iterator (for performanse reasons)
//
// * Collections are implemented with global array that is created
// by calling a collection macro inside a trigger scope.
// you can have 8191 structs stored in one collection.
//
// * Since collections are just a wrapper around of global array $X$_buff
// some people will feel the need to inline collection calls.
// Please do NOT do this unless it is really necessary for performanse.
// This will almost never be the case, collections are extremely fast.
//
//
// HOW TO USE:
// * For a trigger to use collections it MUST be inside a scope.
// At the beginning of scope insert this macro call
// //! runtextmacro COLLECTION("A")
//
// * This will create global array and other fields and methods
// needed for collection manipulation
//
// * To prevent lag when collections are first used put this into spells InitTrigger
// call CollectionA.init() // This is optional
//
//---------------------------------------------------------------------------
// BASIC LOOP: (data is your custom struct)
//---------------------------------------------------------------------------
//
// call IteratorA.reset() // <-- positions iterator at the beginning of collection
// loop
// exitwhen IteratorA.noNext()
// set data = IteratorA.next()
//
// if SomeExitCondition(data)
// call data.destroy()
// call IteratorA.remove()
// else
// -- Process data --
// endif
// endloop
//
//---------------------------------------------------------------------------
// LIST OF FUNCTIONS: (all methods are static)
//---------------------------------------------------------------------------
// struct CollectionX
// .init()
// .isEmpty() -> boolean
// .size() -> integer
// .contains(integer) -> boolean
// .add(integer) -> boolean
// .remove(integer) -> boolean
// .clear()
// endstruct
//
// struct IteratorX
// .reset()
// .noNext() -> boolean
// .next() -> integer
// .remove()
// endstruct
//---------------------------------------------------------------------------
//
// HOW TO IMPORT:
// * Just create a trigger named Collections
// * convert it to text and replace the whole trigger text with this one
//
//==============================================================================
globals
integer MAX_COLLECTION_SIZE = 8191
endglobals
//! textmacro COLLECTION takes X
// Do NOT use this fields directly
globals
// Collection fields
private integer array $X$_buff
private integer $X$_size = 0
// Iterator fields
private integer $X$_index = -1
private boolean $X$_removeOK = false
endglobals
//==============================================================================
private struct Collection$X$
// prevents the lag by forcing wc3 to allocate whole array at once
static method init takes nothing returns nothing
set $X$_buff[MAX_COLLECTION_SIZE-1] = 1
endmethod
// checks if collection is empty
static method isEmpty takes nothing returns boolean
return $X$_size <= 0
endmethod
// returns the current size of collection
static method size takes nothing returns integer
return $X$_size
endmethod
// checks is element e is inside collection
static method contains takes integer e returns boolean
local integer i = 0
loop
exitwhen i >= $X$_size
if e == $X$_buff[i] then
return true
endif
set i = i + 1
endloop
return false
endmethod
// adds element e into collection
static method add takes integer e returns boolean
if $X$_size < MAX_COLLECTION_SIZE then
set $X$_buff[$X$_size] = e
set $X$_size = $X$_size + 1
return true
else
call BJDebugMsg("|C00FF0000ERROR: Collection$X$ overflow in scope " + SCOPE_PREFIX)
return false
endif
endmethod
// removes first element that matches e from collection
static method remove takes integer e returns boolean
local integer i = 0
loop
exitwhen i >= $X$_size
if e == $X$_buff[i] then
set $X$_size = $X$_size - 1
set $X$_buff[i] = $X$_buff[$X$_size]
return true
endif
set i = i + 1
endloop
return false
endmethod
// removes ALL elements from collection
static method clear takes nothing returns nothing
set $X$_size = 0
endmethod
endstruct
//==============================================================================
private struct Iterator$X$
// Use before any looping to reset iterator to the beginning of collection
static method reset takes nothing returns nothing
set $X$_index = -1
set $X$_removeOK = false
endmethod
// returns true if at the end of collection
static method noNext takes nothing returns boolean
return $X$_index >= ($X$_size-1)
endmethod
// Not safe operation, use only if noNext returns false
static method next takes nothing returns integer
set $X$_index = $X$_index + 1
set $X$_removeOK = true
return $X$_buff[$X$_index]
endmethod
//This method can be called only once per call to next.
static method remove takes nothing returns nothing
if $X$_removeOK then
set $X$_size = $X$_size - 1
set $X$_buff[$X$_index] = $X$_buff[$X$_size]
set $X$_index = $X$_index - 1
set $X$_removeOK = false
else
call BJDebugMsg("|c00FF0000ERROR: Iterator$X$ attempted invalid remove in scope" + SCOPE_PREFIX)
endif
endmethod
endstruct
//! endtextmacro
I was actually able to make this system using structs the other day, but I always encounter an error now :/ No, I didnt exceed limit of 8190(1) 
