Triggers

//TESH.scrollpos=1
//TESH.alwaysfold=0
library GetPlayerNameColored

function GetPlayerNameColored takes player id returns string
    local playercolor col = GetPlayerColor(id)
    local string r = GetPlayerName(id)
    
    if col == PLAYER_COLOR_RED then
        set r="|cffff0000"+r+"|r"
    elseif col == PLAYER_COLOR_BLUE then
        set r="|cff0000ff"+r+"|r"
    elseif col == PLAYER_COLOR_CYAN then
        set r="|cff93ffc9"+r+"|r"
    elseif col == PLAYER_COLOR_PURPLE then
        set r="|cff400080"+r+"|r"
    elseif col == PLAYER_COLOR_YELLOW then
        set r="|cffffff00"+r+"|r"
    elseif col == PLAYER_COLOR_ORANGE then
        set r="|cffff8000"+r+"|r"
    elseif col == PLAYER_COLOR_GREEN then
        set r="|cff00c400"+r+"|r"
    elseif col == PLAYER_COLOR_PINK then
        set r="|cffff80c0"+r+"|r"
    elseif col == PLAYER_COLOR_LIGHT_GRAY then
        set r="|cff808080"+r+"|r"
    elseif col == PLAYER_COLOR_LIGHT_BLUE then
        set r="|cffc1c1ff"+r+"|r"
    elseif col == PLAYER_COLOR_AQUA then
        set r="|cff5e5e2f"+r+"|r"
    elseif col == PLAYER_COLOR_BROWN then
        set r="|cff004000"+r+"|r"
    else
        set r="|cff000000"+r+"|r"
    endif
    
    return r
endfunction
// Added this so when heroes are created they can have their name in their players color, the S stands for string, since it returns the
// string, not the actual playercolor constant
function GetPlayerColorS takes player id returns string
    local playercolor col = GetPlayerColor(id)
    local string r = ""
    
    if col == PLAYER_COLOR_RED then
        set r="|cffff0000"
    elseif col == PLAYER_COLOR_BLUE then
        set r="|cff0000ff"
    elseif col == PLAYER_COLOR_CYAN then
        set r="|cff93ffc9"
    elseif col == PLAYER_COLOR_PURPLE then
        set r="|cff400080"
    elseif col == PLAYER_COLOR_YELLOW then
        set r="|cffffff00"
    elseif col == PLAYER_COLOR_ORANGE then
        set r="|cffff8000"
    elseif col == PLAYER_COLOR_GREEN then
        set r="|cff00c400"
    elseif col == PLAYER_COLOR_PINK then
        set r="|cffff80c0"
    elseif col == PLAYER_COLOR_LIGHT_GRAY then
        set r="|cff808080"
    elseif col == PLAYER_COLOR_LIGHT_BLUE then
        set r="|cffc1c1ff"
    elseif col == PLAYER_COLOR_AQUA then
        set r="|cff5e5e2f"
    elseif col == PLAYER_COLOR_BROWN then
        set r="|cff004000"
    else
        set r="|cff000000"
    endif
    
    return r
endfunction

endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
library HSS initializer GetOrders needs GetPlayerNameColored

//=====HSS 1.30b=====\\

globals
    // Config. Options:
    private constant integer ChooseHeroUnitId = 'h001' // Rawcode of Choose Hero Unit
    private constant integer ChooseHeroOrder = 1747988529 // Orderid when Choose Hero is selected
    private constant integer RandomHeroUnitId = 'h002' // Rawcode of Random Hero Unit
                                                       // Use 0 if you don't want to let players choose a random hero
    private constant integer RandomHeroOrder = 1747988530 // Orderid when Random Hero is selected
    private constant real TimeLimit = 120. // Time limit for selecting heroes, after which players get a random hero
                                          // Use 0. if you desire no time limit
    private constant real MaxCompTime = 15. // Max time a computer will take to choose a random hero, this should be lower then TimeLimit
    private constant boolean CleanUp = true // Whether you want the hero gallery removed after all players have a hero
    private constant boolean DoubleHeroes = false // Whether you want to allow more then one of the same hero to be chosen
    private constant boolean CompHeroes = false // Whether you want computer players to choose heroes.
    private constant boolean RemoveChosen = true // Whether you want chosen heroes removed if DoubleHeroes is true
                                                  // If this is false, heroes will become opaque and non-selectable
    private constant string DialogTitle = "Hero Selection Time" // The title of the timerdialog that shows the remaining selection time
    
//===========Don't touch past here unless you know what you are doing===========\\
    // Needed Globals:
    public unit array Heroes
    public trigger CreatedHeroTrigger = null
    public location array HeroCreation
    public rect array HeroSelection
    public group SelectableHeroes = CreateGroup() 
    public integer Players = 0
    
    private unit Hero = null
    private trigger Sell = CreateTrigger()
    private trigger Orders = CreateTrigger()
    private trigger Setup = CreateTrigger()
    private string S = " has chosen the "
endglobals


//=====Get Selection Orders=====\\
private function GetSelectionOrders_Effects takes nothing returns nothing
    local integer id = GetIssuedOrderId()
    local unit u = GetOrderedUnit()
    
    if GetTriggerEventId()==EVENT_UNIT_ISSUED_ORDER and id!=851972 then
        call BJDebugMsg("The order for that selection is |cffff0000"+I2S(id)+"|r.")
    endif
    
    call DisableTrigger(Setup)
    call PauseUnit( u, true)
    call IssueImmediateOrder( u, "stop" )
    call PauseUnit( u, false) 
    call EnableTrigger(Setup)
endfunction
private function GetSelectionOrders takes nothing returns boolean
    local real x 
    local real y 
    local unit u 
    
    if not bj_isSinglePlayer then
        return false
    endif
    
    set x = GetPlayerStartLocationX(Player(0))
    set y = GetPlayerStartLocationY(Player(0))
    set u = CreateUnit(Player(15),'Hpal',x,y,0)
    set Setup = CreateTrigger()
    
    call SetPlayerAlliance(Player(15),Player(0),ALLIANCE_SHARED_CONTROL,true)
    call SetPlayerAlliance(Player(15),Player(0),ALLIANCE_SHARED_VISION,true)
    if GetLocalPlayer()==Player(0) then
        call SetCameraPosition(x,y)
        call ClearSelection()
        call SelectUnit(u,true)
    endif
    
    call UnitRemoveAbility(u, 'Amov')
    call UnitAddAbility(u, 'Abun')
    call UnitAddAbility(u,'Asud') 
    call AddUnitToStock(u, ChooseHeroUnitId,1,1) 
    call AddUnitToStock(u, RandomHeroUnitId,1,1)
    call SetUnitInvulnerable(u,true)
    call UnitModifySkillPoints(u, -1)
    
    call TriggerRegisterUnitEvent(Setup, u, EVENT_UNIT_ISSUED_ORDER )
    call TriggerAddAction(Setup,function GetSelectionOrders_Effects)
    
    call DestroyTrigger(GetTriggeringTrigger())
    return false
endfunction
private function GetOrders takes nothing returns nothing
    call TriggerRegisterPlayerChatEvent( Setup, Player(0), "-HSSGetOrders", true )
    call TriggerAddCondition(Setup,Condition(function GetSelectionOrders))
endfunction

//=====Main System=====\\
private function Cleaner takes nothing returns nothing
    if CleanUp then
        loop
            set Hero = FirstOfGroup(SelectableHeroes)
            exitwhen Hero==null
            call GroupRemoveUnit(SelectableHeroes,Hero)         
            call RemoveUnit(Hero) // Lets hope for no bugs.... :)
        endloop
    endif
    call DestroyGroup(SelectableHeroes)
    set SelectableHeroes = null
    call DestroyTrigger(Sell) 
    call DestroyTrigger(Orders)
    call DestroyTrigger(Setup)
    set Sell = null
    set Orders = null
    set Setup = null
endfunction

private function CreateHero takes unit u, player p returns nothing
    local integer id = GetPlayerId(p)
    local real x = GetLocationX(HeroCreation[id])
    local real y = GetLocationY(HeroCreation[id])
    
    set Hero = CreateUnit(p,GetUnitTypeId(u),x,y,GetRandomReal(0.,360.))
    if GetLocalPlayer()==p then
        call SelectUnit(Hero,true)
        call SetCameraPosition(x,y)
    endif
    if (IsPlayerInForce(GetLocalPlayer(), bj_FORCE_ALL_PLAYERS)) then
        call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, GetPlayerNameColored(p)+S+GetPlayerColorS(p)+GetUnitName(Hero)+"|r.")
    endif
    
    call SetPlayerAlliance(Player(15),p,ALLIANCE_SHARED_CONTROL,false)
    call SetPlayerAlliance(Player(15),p,ALLIANCE_SHARED_VISION,false)

    set Heroes[id] = Hero
    if CreatedHeroTrigger != null then
        set bj_lastCreatedUnit = Hero
        if TriggerEvaluate(CreatedHeroTrigger) then
            call TriggerExecute(CreatedHeroTrigger)
        endif
    endif
    
    if not DoubleHeroes then
        if RemoveChosen then
            call RemoveUnit(u) // please don't bug :)
        else
            call UnitAddAbility(u,'Aloc')
            call SetUnitVertexColor( u, 255, 255, 255, 127 )
            call GroupRemoveUnit(SelectableHeroes,u)
        endif
    endif
endfunction
private function GiveRandomHero takes player p, boolean forced returns nothing
    if CountUnitsInGroup(SelectableHeroes)<=0 then
        call BJDebugMsg("HSS Error: "+GetPlayerNameColored(p)+" |cffff0000will not recieve a hero because there are none left to give.")
        return
    endif
    
    if forced then
        set S = " has been forced into the "
    else
        set S = " has randomed the "
    endif
    
    set Hero = GroupPickRandomUnit(SelectableHeroes)
    call CreateHero(Hero,p)
    
    set S = " has chosen the "
endfunction
private function GiveComputerHero takes player p returns nothing
    if MaxCompTime>TimeLimit then
        call PolledWait(GetRandomReal(2.,TimeLimit-1.))
        call BJDebugMsg("HSS Error: |cffff0000Your TimeLimit is lower then your MaxCompTime.")
    else
        call PolledWait(GetRandomReal(2.,MaxCompTime))
    endif
    call GiveRandomHero(p,false)
endfunction
private function GiveAllRandomHeroes takes nothing returns nothing
    local integer i = 0
    
    loop
        exitwhen i>Players
        if GetPlayerSlotState(Player(i))==PLAYER_SLOT_STATE_PLAYING and (CompHeroes or GetPlayerController(Player(i))!=MAP_CONTROL_COMPUTER) then
            call GiveRandomHero(Player(i),false)
        endif
        
        call TriggerSleepAction(0.)
        set i = i + 1
    endloop
    
    call Cleaner()
endfunction

private function Sold takes nothing returns nothing
    set bj_ghoul[55] = GetSoldUnit()    
    if GetUnitTypeId(bj_ghoul[55])==ChooseHeroUnitId then
        call CreateHero(GetSellingUnit(),GetOwningPlayer(bj_ghoul[55]))
    else
        call GiveRandomHero(GetOwningPlayer(bj_ghoul[55]),false)
    endif
    call RemoveUnit(bj_ghoul[55])
endfunction
private function StopOrders takes nothing returns nothing
    local integer id = GetIssuedOrderId()
    
    set Hero = GetTriggerUnit()
    if id == 851972 or id == ChooseHeroOrder or id == RandomHeroOrder then
        return
    endif
    
    call DisableTrigger(Orders)
    call PauseUnit( Hero, true)
    call IssueImmediateOrder( Hero, "stop" )
    call PauseUnit( Hero, false) 
    call EnableTrigger(Orders)
endfunction

private function FilterHeroes takes nothing returns boolean
    return IsUnitType(GetFilterUnit() , UNIT_TYPE_HERO)
endfunction
private function SetupHeroes takes nothing returns nothing
    set Hero = GetEnumUnit()
    call UnitRemoveAbility(Hero, 'Amov')
    call UnitAddAbility(Hero, 'Abun')
    call UnitAddAbility(Hero,'Asud') 
    call AddUnitToStock(Hero, ChooseHeroUnitId,1,1) 
    if RandomHeroUnitId > 0 then
        call AddUnitToStock(Hero, RandomHeroUnitId,1,1)
    endif
    call SetUnitInvulnerable(Hero,true)  
    
    call TriggerRegisterUnitEvent(Sell,Hero,EVENT_UNIT_SELL)
    call TriggerRegisterUnitEvent( Orders, Hero, EVENT_UNIT_ISSUED_TARGET_ORDER )
    call TriggerRegisterUnitEvent( Orders, Hero, EVENT_UNIT_ISSUED_POINT_ORDER )
    call TriggerRegisterUnitEvent( Orders, Hero, EVENT_UNIT_ISSUED_ORDER ) 
endfunction
public function Start takes nothing returns nothing
    local integer i = 0
    local integer j = 0
    local real x 
    local real y 
    local timer t = null
    local timerdialog td
    
    set Players = GetPlayers() - 1
    call GroupEnumUnitsOfPlayer(SelectableHeroes,Player(15) , Condition(function FilterHeroes))
    
    if IsMapFlagSet(MAP_RANDOM_HERO) then
        call GiveAllRandomHeroes()
        return
    endif
    call TriggerAddAction(Sell,function Sold)
    call TriggerAddAction(Orders,function StopOrders)
    call ForGroup(SelectableHeroes,function SetupHeroes)
    loop
        exitwhen i > Players
        set x = GetRectCenterX(HeroSelection[i])
        set y = GetRectCenterY(HeroSelection[i])
        call SetPlayerAlliance(Player(15),Player(i),ALLIANCE_SHARED_CONTROL,true)
        call SetPlayerAlliance(Player(15),Player(i),ALLIANCE_SHARED_VISION,true)
        if GetLocalPlayer()==Player(i) then
            call SetCameraPosition(x,y)
        endif
        
        if CompHeroes and GetPlayerSlotState(Player(i))==PLAYER_SLOT_STATE_PLAYING and GetPlayerController(Player(i))==MAP_CONTROL_COMPUTER then
            call GiveComputerHero.execute(Player(i))
        endif
        set i = i + 1
    endloop
    
    if TimeLimit>0. then
        set t = CreateTimer()
        call TimerStart(t,TimeLimit,false,null)
        set td = CreateTimerDialog(t)
        call TimerDialogSetTitle(td,DialogTitle)
        call TriggerSleepAction(0.)
        call TimerDialogDisplay(td,true)
    endif
    
    loop
        set i = 0
        set j = 0
        
        loop
            exitwhen i > Players
            if Heroes[i]==null and GetPlayerSlotState(Player(i))==PLAYER_SLOT_STATE_PLAYING and (CompHeroes or GetPlayerController(Player(i))!=MAP_CONTROL_COMPUTER) then
                if t!=null and TimerGetRemaining(t)<=.1 then
                    call GiveRandomHero(Player(i),true)
                endif
                set j = j + 1
            elseif GetLocalPlayer()==Player(i) then
                call TimerDialogDisplay(td,false)
            endif
            set i = i + 1
        endloop
        
        exitwhen j<=0
        if CountUnitsInGroup(SelectableHeroes)<=0 then
            call BJDebugMsg("HSS Error: |cffff0000There are no more heroes left to select.")
            exitwhen true
        endif
        call TriggerSleepAction(0.)
    endloop
    
    if t!=null then
        call DestroyTimer(t)
        call DestroyTimerDialog(td)  
        set t = null  
        set td = null         
    endif
    call Cleaner()
endfunction

endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
scope HSSSetup

//=====HSS 1.30b=====\\

globals
    // This trigger can be referred to as HSSSetup_Trigger publically
    // I have this as running after 0.0s, but you can execute it when you want, or change the time length to your liking (among other things)
    public trigger Trigger = CreateTrigger()
endglobals

private function Actions takes nothing returns nothing 
    // Get total players in your map, but in JASS players start at 0, so subtract 1
    local integer i = GetPlayers() - 1
    
    // Loop through players in map, setting up their hero selection rects and hero creation locs
    loop
        exitwhen i < 0
        // This is the rect where this player can choose heroes from
        set HSS_HeroSelection[i] = gg_rct_Hero_Tavern
        // This is the loc where this players heroes will be created once chosen
        set HSS_HeroCreation[i] = GetStartLocationLoc(GetPlayerStartLocation(Player(i)))
        set i = i - 1
    endloop
    // Store the trigger to be ran when a hero is created
    set HSS_CreatedHeroTrigger = gg_trg_PostHeroCreation
    // Start the selection system
    call HSS_Start()
    
    // Clean leak
    call DestroyTrigger(Trigger)
    set Trigger = null
endfunction

//===========================================================================
public function InitTrig takes nothing returns nothing
    call TriggerAddAction( Trigger, function Actions )
    // Length in time after game starts that we want to start the HSS
    call TriggerRegisterTimerEvent(Trigger,0.0,false)
endfunction

endscope