Triggers

//TESH.scrollpos=247
//TESH.alwaysfold=0
[B][SIZE="3"]Summoned Escort v1.5[/SIZE][/B]
[box=Information]
Allows your summoned units to follow and guards the summoner, if summoner dies, the summoned unit searches for a new master or returns to it's original location.
[/box]
[jass]
library SummonedEscort /* v1.5 
***************************************************************************
*   by mckill2009
***************************************************************************
*
*   */ uses /*
*       */ GetClosestWidget /* www.hiveworkshop.com/forums/jass-resources-412/snippet-getclosestwidget-204217
*       */ Table            /* www.hiveworkshop.com/forums/jass-resources-412/snippet-new-table-188084
*
***************************************************************************
*
*   Features:
*       - Allows your summoned units to follow and guards the summoner.
*       - If the summoner dies, the summoned unit searches for a new ally or
*         returns to it's original location.
*       - Used also to focus attack an enemy hero or unit.
*
***************************************************************************
*   
*   Installation:
*       Copy and paste the required libraries and this code to your map     
*
***************************************************************************
*
*   API: 
*       static method summoned takes unit summoningUnit, unit summonedUnit returns nothing
*           - call SE.summoned(GetSummoningUnit(),GetTriggerUnit())
*           - If AUTO is true, it will do automatically for you.
*           - AUTO only works for summoned unit           
*
*       static method remove takes unit escortUnit returns nothing
*           - Removes the escort from the system
*
***************************************************************************/

globals
/**************************************************************************
*   Auto registers ALL summoned units in map, it is recommended to set this
*   to false if you want a unit to escort an ally or attack an enemy hero/unit
***************************************************************************/
    private constant boolean AUTO = true 
    
    
/**************************************************************************
*   Searches for closest ally hero if main hero is dead, if FOLLOW_ONLY_HEROES
*   is false, the escort will follow a closest ally
***************************************************************************/
    private constant boolean ALLY_IN_RANGE = true
    
/**************************************************************************
*   The unit only follows heroes when the main unit dies
***************************************************************************/
    private constant boolean FOLLOW_ONLY_HEROES = true

/**************************************************************************
*   This is the offset distance from the unit to his master   
***************************************************************************/
    private constant real OFFSET = 200

/**************************************************************************
*   Searches for closest ally if main ally unit is dead
*   ALLY_IN_RANGE must be true
***************************************************************************/
    private constant real CLOSEST_ALLY = 600 

/**************************************************************************
*   Targets/attacks closest enemy in range of master
***************************************************************************/
    private constant real CLOSEST_ENEMY = 400 
endglobals

struct SE
    private unit master
    private unit sum   
    private real xUnit
    private real yUnit
    
    private static integer DATA
    private static constant integer ATTACK = 851983
    private static timer t = CreateTimer()
    private static integer instance = 0
    private static integer array insAR
    private static unit TempUnit = null
    private static Table tb
    
    private static method UnitAlive takes unit u returns boolean
        return not IsUnitType(u,UNIT_TYPE_DEAD) and u!=null
    endmethod
    
    private static method closestEnemy takes nothing returns boolean
        local thistype this = DATA
        set TempUnit = GetFilterUnit()   
        return UnitAlive(TempUnit) and IsUnitEnemy(TempUnit, GetOwningPlayer(.sum))
    endmethod
    
    private static method closestAlly takes nothing returns boolean
        local thistype this = DATA
        set TempUnit = GetFilterUnit()        
        if UnitAlive(TempUnit) and GetOwningPlayer(TempUnit)==GetOwningPlayer(.sum) and TempUnit!=.sum /*
        */ and not IsUnitType(TempUnit,UNIT_TYPE_STRUCTURE) and GetUnitMoveSpeed(TempUnit)>0 then
            static if FOLLOW_ONLY_HEROES then
                return IsUnitType(TempUnit, UNIT_TYPE_HERO)
            endif
            return true
        endif
        return false
    endmethod
    
    private method destroy takes nothing returns nothing
        set .master = null
        set .sum = null
        call .deallocate()        
    endmethod        
    
    private static method looper takes nothing returns nothing
        local thistype this
        local unit target
        local integer orderSum
        local integer index = 0
        local real angle
        local real xMaster
        local real yMaster
        local real xSummoned
        local real ySummoned
        loop
            set index = index+1
            set this = insAR[index]
            if UnitAlive(.sum) and tb.has(GetHandleId(.sum)) then
                set angle = GetRandomReal(0,6.28)
                set orderSum = GetUnitCurrentOrder(.sum)
                if UnitAlive(.master) then   
                    if orderSum==0 then
                        set xMaster = GetUnitX(.master)+OFFSET*Cos(angle)
                        set yMaster = GetUnitY(.master)+OFFSET*Sin(angle)
                        call IssuePointOrderById(.sum,ATTACK,xMaster,yMaster)
                        set DATA = this
                        set target = GetClosestUnitInRange(xMaster,yMaster,CLOSEST_ENEMY,Filter(function thistype.closestEnemy))
                        if target!=null then
                            if IsUnitType(target,UNIT_TYPE_SLEEPING) then
                                call IssueTargetOrderById(.sum,ATTACK,target)
                            else
                                call IssuePointOrderById(.sum,ATTACK,GetUnitX(target),GetUnitY(target))
                            endif
                            set target = null
                        endif
                    endif  
                else
                    set DATA = this
                    set xSummoned = GetUnitX(.sum)
                    set ySummoned = GetUnitY(.sum)
                    static if ALLY_IN_RANGE then
                        set .master = GetClosestUnitInRange(xSummoned,ySummoned,CLOSEST_ALLY,Filter(function thistype.closestAlly))
                    else
                        set .master = GetClosestUnit(xSummoned,ySummoned,Filter(function thistype.closestAlly))   
                    endif
                    if .master==null and orderSum==0 then
                        call IssuePointOrderById(.sum,ATTACK,.xUnit+OFFSET*Cos(angle),.yUnit+OFFSET*Sin(angle))
                    endif
                endif            
            else
                call .destroy()
                set insAR[index] = insAR[instance]
                set insAR[instance] = this
                set index = index - 1
                set instance = instance - 1
                if instance==0 then
                    call PauseTimer(t)
                endif              
            endif      
            exitwhen index==instance
        endloop
    endmethod   
    
    private static method create takes unit summoningUnit, unit summonedUnit returns thistype
        local thistype this
        if instance==8190 then
            call BJDebugMsg("Library_SummonedEscort ERROR: Too many instances!")
        else
            set this = allocate()
            set .master = summoningUnit
            set .sum = summonedUnit
            set .xUnit = GetUnitX(summonedUnit)
            set .yUnit = GetUnitY(summonedUnit)
            set tb[GetHandleId(.sum)] = 0
            if instance==0 then
                call TimerStart(t,1.0,true,function thistype.looper)
            endif
            set instance = instance + 1
            set insAR[instance] = this
            call RemoveGuardPosition(summonedUnit)
        endif
        return this
    endmethod
    
    private static method fire takes nothing returns boolean
        call thistype.create(GetSummoningUnit(),GetTriggerUnit())
        return false
    endmethod
    
    private static method onInit takes nothing returns nothing    
        static if AUTO then
            local trigger t = CreateTrigger()
            call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SUMMON)
            call TriggerAddCondition(t,function thistype.fire)
            set t = null
        endif
        set tb = Table.create()
    endmethod  
    
    //API:======================================
    static method summoned takes unit summoningUnit, unit summonedUnit returns nothing
        call thistype.create(summoningUnit,summonedUnit)
    endmethod
    
    static method remove takes unit escortUnit returns nothing
        call tb.remove(GetHandleId(escortUnit))
    endmethod    
endstruct

endlibrary
[/jass]

[B]HOW TO USE IN GUI: If AUTO is false[/B]
[trigger]
GUI Sample Without Auto
    Events
        Unit - A unit Spawns a summoned unit
    Conditions
    Actions
        Custom script:   call SE.summoned(GetSummoningUnit(),GetTriggerUnit())
        Wait 10.00 seconds
        -------- New addition, removes the unit from the system --------
        Custom script:   call SE.remove(GetTriggerUnit())
[/trigger]

[hidden=Another Usage]
- You can also use this system to follow/guard any allied units in the map but this can only be done manually.
- Allows auto follow-attack an enemy unit.

Sample:
[trigger]
GUI Sample Spell
    Events
        Unit - A unit Starts the effect of an ability
    Conditions
    Actions
        Custom script:   call SE.summoned(GetTriggerUnit(), GetSpellTargetUnit())
        Wait 10.00 seconds
        -------- New addition, removes the unit from the system --------
        Custom script:   call SE.remove(GetSpellTargetUnit())
[/trigger]
[/hidden]

[hidden=Credits]
- [url=www.hiveworkshop.com/forums/jass-resources-412/snippet-new-table-188084/]Table[/url]Table by Bribe 
- [url=www.hiveworkshop.com/forums/jass-resources-412/snippet-getclosestwidget-204217]GetClosestWidget[/url] by Spinnaker
[/hidden]

[hidden=Changelogs]
v1.5
- Added feature to remove the escort from system
- Improved documentation

v1.4
- Added 1 configuration to follow allied heroes or not

v1.3
- UnitAlive native removed
- Non configurables isolated

v1.2
- Suggested by the moderator applied

v1.1
- Added many configurations
- RegisterPlayerUnitEvent removed
[/hidden]

//TESH.scrollpos=36
//TESH.alwaysfold=0
/*****************************************************************************
*
*    Get Closest Widget
*        by Spinnaker v2.0.0.0
*
*      Special thanks to Troll-Brain
*
******************************************************************************
*
*    This snippet contains several functions which returns closest
*       widget to given coordinates and passed filter.
*
******************************************************************************
*
*    Requirements:
*       Snippet optionaly requires IsDestructableTree,
*       enabling user to choose if enumerated should be all destructables
*       or only tree-type ones, therefore gives option to get closest tree.
*
******************************************************************************
*
*    Important:
*       Performance drop depends on amount of objects currently on the map
*       Snippet functions are designed to reduce the search time as much as
*       posible, although it's recommended to use non specific functions
*       wisely, especialy if your map contains large numbers of widgets.
*
******************************************************************************
*
*    Functions:
*       function  GetClosestItem takes real x, real y, boolexpr filter returns item
*          - Gets single item, nearest passed coordinates
*       function GetClosestItemInRange takes real x, real y, real radius, boolexpr filter returns item
*          - Returns single item, closest to coordinates in given range
*
*       function GetClosestDestructable takes real x, real y, boolean treeOnly, boolexpr filter returns destructable
*          - Gets single destructable, nearest passed coordinates
*       function GetClosestDestructableInRange takes real x, real y, real radius, boolean treeOnly, boolexpr filter returns destructable
*          - Retrieves single destructable, closest to coordinates in given range
*
*       function GetClosestUnit takes real x, real y, boolexpr filter returns unit
*          - Returns closest unit matching specific filter
*       function GetClosestUnitInRange takes real x, real y, real radius, boolexpr filter returns unit
*          - Gets nearest unit in range matching specific filter
*       function GetClosestUnitInGroup takes real x, real y, group g returns unit
*          - Retrieves closest unit in given group
*
*       function GetClosestNUnitsInRange takes real x, real y, real radius, integer n, group g, boolexpr filter returns nothing
*          - Returns up to N nearest units in range of passed coordinates
*       function GetClosestNUnitsInGroup takes real x, real y, integer n, group sourceGroup, group destGroup returns nothing
*          - Retrieves up to N closest units in passed group
*
*****************************************************************************/
library GetClosestWidget uses optional IsDestructableTree

    private keyword Init
    globals
        private unit array Q
        private real array V
        private integer C=0
    endglobals
    
    struct ClosestWidget extends array
        readonly static destructable cDest=null
        readonly static item  cItem=null
        readonly static real distance=0
        readonly static real cX=0
        readonly static real cY=0
        readonly static unit cUnit=null
        static boolean cTree=false
        static rect initRect=null
        static method resetData takes real x, real y returns nothing
            set cDest=null
            set distance=100000
            set cItem=null
            set cUnit=null
            set cX=x
            set cY=y
        endmethod
        static method enumItems takes nothing returns nothing
            local item i=GetEnumItem()
            local real dx=GetWidgetX(i)-cX
            local real dy=GetWidgetY(i)-cY
            set dx = (dx*dx+dy*dy)/10000.
            if dx<distance then
                set cItem=i
                set distance=dx
            endif
            set i =null
        endmethod
        static method enumDestructables takes nothing returns nothing
            local destructable d=GetEnumDestructable()
            local real dx
            local real dy
            static if LIBRARY_IsDestructableTree then
                if cTree and not IsDestructableTree(d) then
                    return
                endif
            endif
            set dx=GetWidgetX(d)-cX
            set dy=GetWidgetY(d)-cY
            set dx=(dx*dx+dy*dy)/10000.
            if dx<distance then
                set cDest=d
                set distance=dx
            endif
            set d=null
        endmethod
        static method enumUnits takes nothing returns nothing
            local unit u=GetEnumUnit()
            local real dx=GetUnitX(u)-cX
            local real dy=GetUnitY(u)-cY
            set dx=(dx*dx+dy*dy)/10000.
            if dx<distance then
                set cUnit=u
                set distance=dx
            endif
            set u=null
        endmethod
        static method sortUnits takes integer l, integer r returns nothing
            local integer i=l
            local integer j=r
            local real v=V[(l+r)/2]
            loop
                loop
                    exitwhen V[i]>=v
                    set i=i+1
                endloop
                loop
                    exitwhen V[j]<=v
                    set j=j-1
                endloop
                if i<=j then
                    set V[0]=V[i]
                    set V[i]=V[j]
                    set V[j]=V[0]
                    set Q[0]=Q[i]
                    set Q[i]=Q[j]
                    set Q[j]=Q[0]
                    set i=i+1
                    set j=j-1
                endif
                exitwhen i>j
            endloop
            if l<j then
                call sortUnits(l,j)
            endif
            if r>i then
                call sortUnits(i,r)
            endif
        endmethod
        static method saveGroup takes nothing returns nothing
            local real dx
            local real dy
            set C=C+1
            set Q[C]=GetEnumUnit()
            set dx=GetUnitX(Q[C])-cX
            set dy=GetUnitY(Q[C])-cY
            set V[C]=(dx*dx+dy*dy)/10000.
        endmethod
        implement Init
    endstruct
    private module Init
        private static method onInit takes nothing returns nothing
            set thistype.initRect=Rect(0,0,0,0)
        endmethod
    endmodule

    function  GetClosestItem takes real x, real y, boolexpr filter returns item
        local real r=800.
        call ClosestWidget.resetData(x,y)
        loop
            if r>3200. then
                call EnumItemsInRect(bj_mapInitialPlayableArea, filter, function ClosestWidget.enumItems)
                exitwhen true
            else
                call SetRect(ClosestWidget.initRect,x-r,y-r,x+r,y+r)
                call EnumItemsInRect(ClosestWidget.initRect, filter, function  ClosestWidget.enumItems)
                exitwhen ClosestWidget.cItem!=null
            endif
            set r=2*r
        endloop
        return ClosestWidget.cItem
    endfunction

    function GetClosestItemInRange takes real x, real y, real radius, boolexpr filter returns item
        call ClosestWidget.resetData(x,y)
        if radius>=0 then
            call SetRect(ClosestWidget.initRect,x-radius,y-radius,x+radius,y+radius)
            call EnumItemsInRect(ClosestWidget.initRect, filter, function ClosestWidget.enumItems)
        endif
        return ClosestWidget.cItem
    endfunction

    function GetClosestDestructable takes real x, real y, boolean treeOnly, boolexpr filter returns destructable
        local real r=800.
        call ClosestWidget.resetData(x,y)
        set ClosestWidget.cTree=treeOnly
        loop
            if r>3200. then
                call EnumDestructablesInRect(bj_mapInitialPlayableArea, filter, function ClosestWidget.enumDestructables)
                exitwhen true
            else
                call SetRect(ClosestWidget.initRect,x-r,y-r,x+r,y+r)
                call EnumDestructablesInRect(ClosestWidget.initRect, filter, function ClosestWidget.enumDestructables)
                exitwhen ClosestWidget.cDest!=null
            endif
            set r=2*r
        endloop
        return ClosestWidget.cDest
    endfunction

    function GetClosestDestructableInRange takes real x, real y, real radius, boolean treeOnly, boolexpr filter returns destructable
        call ClosestWidget.resetData(x,y)
        if radius>=0 then
            set ClosestWidget.cTree=treeOnly
            call SetRect(ClosestWidget.initRect,x-radius,y-radius,x+radius,y+radius)
            call EnumDestructablesInRect(ClosestWidget.initRect, filter, function ClosestWidget.enumDestructables)
        endif
        return ClosestWidget.cDest
    endfunction
    
    function GetClosestUnit takes real x, real y, boolexpr filter returns unit
        local real r=800.
        call ClosestWidget.resetData(x,y)
        loop
            if r>3200. then
                call GroupEnumUnitsInRect(bj_lastCreatedGroup, bj_mapInitialPlayableArea, filter)
                exitwhen true
            else
                call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, r, filter)
                exitwhen FirstOfGroup(bj_lastCreatedGroup)!=null
            endif
            set r=2*r
        endloop
        call ForGroup(bj_lastCreatedGroup, function ClosestWidget.enumUnits)
        return ClosestWidget.cUnit
    endfunction
    
    function GetClosestUnitInRange takes real x, real y, real radius, boolexpr filter returns unit
        call ClosestWidget.resetData(x,y)
        if radius>=0 then
            call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, radius, filter)
            call ForGroup(bj_lastCreatedGroup, function ClosestWidget.enumUnits)
        endif
        return ClosestWidget.cUnit
    endfunction

    function GetClosestUnitInGroup takes real x, real y, group g returns unit
        call ClosestWidget.resetData(x,y)
        call ForGroup(g, function ClosestWidget.enumUnits)
        return ClosestWidget.cUnit
    endfunction

    function GetClosestNUnitsInRange takes real x, real y, real radius, integer n, group g, boolexpr filter returns nothing
        local integer q=n+1
        call ClosestWidget.resetData(x,y)
        if radius>=0 then
            call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, radius, filter)
            call ForGroup(bj_lastCreatedGroup, function ClosestWidget.saveGroup)
            call ClosestWidget.sortUnits(1,C)
            loop
            exitwhen n==0 or Q[-n+q]==null
                call GroupAddUnit(g, Q[-n+q])
                set n =n-1
            endloop
        endif
        set C=0
    endfunction
    
    function GetClosestNUnitsInGroup takes real x, real y, integer n, group sourceGroup, group destGroup returns nothing
        local integer q=n+1
        call ClosestWidget.resetData(x,y)
        call ForGroup(sourceGroup, function ClosestWidget.saveGroup)
        call ClosestWidget.sortUnits(1,C)
        loop
            exitwhen n==0 or Q[-n+q]==null
            call GroupAddUnit(destGroup, Q[-n+q])
            set n=n-1
        endloop
        set C=0
    endfunction
endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
library Table /* made by Bribe, special thanks to Vexorian & Nestharus, version 3.1.0.1
    
    One map, one hashtable. Welcome to NewTable 3.1
    
    This library was originally called NewTable so it didn't conflict with
    the API of Table by Vexorian. However, the damage is done and it's too
    late to change the library name now. To help with damage control, I
    have provided an extension library called TableBC, which bridges all
    the functionality of Vexorian's Table except for 2-D string arrays &
    the ".flush(integer)" method. I use ".flush()" to flush a child hash-
    table, because I wanted the API in NewTable to reflect the API of real
    hashtables (I thought this would be more intuitive).
    
    API
    
    ------------
    struct Table
    | static method create takes nothing returns Table
    |     create a new Table
    |    
    | method destroy takes nothing returns nothing
    |     destroy it
    |    
    | method flush takes nothing returns nothing
    |     flush all stored values inside of it
    |    
    | method remove takes integer key returns nothing
    |     remove the value at index "key"
    |    
    | method operator []= takes integer key, $TYPE$ value returns nothing
    |     assign "value" to index "key"
    |    
    | method operator [] takes integer key returns $TYPE$
    |     load the value at index "key"
    |    
    | method has takes integer key returns boolean
    |     whether or not the key was assigned
    |
    ----------------
    struct TableArray
    | static method operator [] takes integer array_size returns TableArray
    |     create a new array of Tables of size "array_size"
    |
    | method destroy takes nothing returns nothing
    |     destroy it
    |
    | method flush takes nothing returns nothing
    |     flush and destroy it
    |
    | method operator size takes nothing returns integer
    |     returns the size of the TableArray
    |
    | method operator [] takes integer key returns Table
    |     returns a Table accessible exclusively to index "key"
*/
    
globals
    private integer less = 0    //Index generation for TableArrays (below 0).
    private integer more = 8190 //Index generation for Tables.
    //Configure it if you use more than 8190 "key" variables in your map (this will never happen though).
    
    private hashtable ht = InitHashtable()
    private key sizeK
    private key listK
endglobals
    
private struct dex extends array
    static method operator size takes nothing returns Table
        return sizeK
    endmethod
    static method operator list takes nothing returns Table
        return listK
    endmethod
endstruct
    
private struct handles extends array
    method has takes integer key returns boolean
        return HaveSavedHandle(ht, this, key)
    endmethod
    method remove takes integer key returns nothing
        call RemoveSavedHandle(ht, this, key)
    endmethod
endstruct
    
private struct agents extends array
    method operator []= takes integer key, agent value returns nothing
        call SaveAgentHandle(ht, this, key, value)
    endmethod
endstruct
    
//! textmacro NEW_ARRAY_BASIC takes SUPER, FUNC, TYPE
private struct $TYPE$s extends array
    method operator [] takes integer key returns $TYPE$
        return Load$FUNC$(ht, this, key)
    endmethod
    method operator []= takes integer key, $TYPE$ value returns nothing
        call Save$FUNC$(ht, this, key, value)
    endmethod
    method has takes integer key returns boolean
        return HaveSaved$SUPER$(ht, this, key)
    endmethod
    method remove takes integer key returns nothing
        call RemoveSaved$SUPER$(ht, this, key)
    endmethod
endstruct
private module $TYPE$m
    method operator $TYPE$ takes nothing returns $TYPE$s
        return this
    endmethod
endmodule
//! endtextmacro
    
//! textmacro NEW_ARRAY takes FUNC, TYPE
private struct $TYPE$s extends array
    method operator [] takes integer key returns $TYPE$
        return Load$FUNC$Handle(ht, this, key)
    endmethod
    method operator []= takes integer key, $TYPE$ value returns nothing
        call Save$FUNC$Handle(ht, this, key, value)
    endmethod
endstruct
private module $TYPE$m
    method operator $TYPE$ takes nothing returns $TYPE$s
        return this
    endmethod
endmodule
//! endtextmacro
    
//Run these textmacros to include the entire hashtable API as wrappers.
//Don't be intimidated by the number of macros - Vexorian's map optimizer is
//supposed to kill functions which inline (all of these functions inline).
//! runtextmacro NEW_ARRAY_BASIC("Real", "Real", "real")
//! runtextmacro NEW_ARRAY_BASIC("Boolean", "Boolean", "boolean")
//! runtextmacro NEW_ARRAY_BASIC("String", "Str", "string")
    
//! runtextmacro NEW_ARRAY("Player", "player")
//! runtextmacro NEW_ARRAY("Widget", "widget")
//! runtextmacro NEW_ARRAY("Destructable", "destructable")
//! runtextmacro NEW_ARRAY("Item", "item")
//! runtextmacro NEW_ARRAY("Unit", "unit")
//! runtextmacro NEW_ARRAY("Ability", "ability")
//! runtextmacro NEW_ARRAY("Timer", "timer")
//! runtextmacro NEW_ARRAY("Trigger", "trigger")
//! runtextmacro NEW_ARRAY("TriggerCondition", "triggercondition")
//! runtextmacro NEW_ARRAY("TriggerAction", "triggeraction")
//! runtextmacro NEW_ARRAY("TriggerEvent", "event")
//! runtextmacro NEW_ARRAY("Force", "force")
//! runtextmacro NEW_ARRAY("Group", "group")
//! runtextmacro NEW_ARRAY("Location", "location")
//! runtextmacro NEW_ARRAY("Rect", "rect")
//! runtextmacro NEW_ARRAY("BooleanExpr", "boolexpr")
//! runtextmacro NEW_ARRAY("Sound", "sound")
//! runtextmacro NEW_ARRAY("Effect", "effect")
//! runtextmacro NEW_ARRAY("UnitPool", "unitpool")
//! runtextmacro NEW_ARRAY("ItemPool", "itempool")
//! runtextmacro NEW_ARRAY("Quest", "quest")
//! runtextmacro NEW_ARRAY("QuestItem", "questitem")
//! runtextmacro NEW_ARRAY("DefeatCondition", "defeatcondition")
//! runtextmacro NEW_ARRAY("TimerDialog", "timerdialog")
//! runtextmacro NEW_ARRAY("Leaderboard", "leaderboard")
//! runtextmacro NEW_ARRAY("Multiboard", "multiboard")
//! runtextmacro NEW_ARRAY("MultiboardItem", "multiboarditem")
//! runtextmacro NEW_ARRAY("Trackable", "trackable")
//! runtextmacro NEW_ARRAY("Dialog", "dialog")
//! runtextmacro NEW_ARRAY("Button", "button")
//! runtextmacro NEW_ARRAY("TextTag", "texttag")
//! runtextmacro NEW_ARRAY("Lightning", "lightning")
//! runtextmacro NEW_ARRAY("Image", "image")
//! runtextmacro NEW_ARRAY("Ubersplat", "ubersplat")
//! runtextmacro NEW_ARRAY("Region", "region")
//! runtextmacro NEW_ARRAY("FogState", "fogstate")
//! runtextmacro NEW_ARRAY("FogModifier", "fogmodifier")
//! runtextmacro NEW_ARRAY("Hashtable", "hashtable")
    
struct Table extends array
    
    // Implement modules for intuitive syntax (tb.handle; tb.unit; etc.)
    implement realm
    implement booleanm
    implement stringm
    implement playerm
    implement widgetm
    implement destructablem
    implement itemm
    implement unitm
    implement abilitym
    implement timerm
    implement triggerm
    implement triggerconditionm
    implement triggeractionm
    implement eventm
    implement forcem
    implement groupm
    implement locationm
    implement rectm
    implement boolexprm
    implement soundm
    implement effectm
    implement unitpoolm
    implement itempoolm
    implement questm
    implement questitemm
    implement defeatconditionm
    implement timerdialogm
    implement leaderboardm
    implement multiboardm
    implement multiboarditemm
    implement trackablem
    implement dialogm
    implement buttonm
    implement texttagm
    implement lightningm
    implement imagem
    implement ubersplatm
    implement regionm
    implement fogstatem
    implement fogmodifierm
    implement hashtablem
    
    method operator handle takes nothing returns handles
        return this
    endmethod
    
    method operator agent takes nothing returns agents
        return this
    endmethod
    
    //set this = tb[GetSpellAbilityId()]
    method operator [] takes integer key returns Table
        return LoadInteger(ht, this, key)
    endmethod
    
    //set tb[389034] = 8192
    method operator []= takes integer key, Table tb returns nothing
        call SaveInteger(ht, this, key, tb)
    endmethod
    
    //set b = tb.has(2493223)
    method has takes integer key returns boolean
        return HaveSavedInteger(ht, this, key)
    endmethod
    
    //call tb.remove(294080)
    method remove takes integer key returns nothing
        call RemoveSavedInteger(ht, this, key)
    endmethod
    
    //Remove all data from a Table instance
    method flush takes nothing returns nothing
        call FlushChildHashtable(ht, this)
    endmethod
    
    //local Table tb = Table.create()
    static method create takes nothing returns Table
        local Table this = dex.list[0]
        
        if this == 0 then
            set this = more + 1
            set more = this
        else
            set dex.list[0] = dex.list[this]
            call dex.list.remove(this) //Clear hashed memory
        endif
        
        debug set dex.list[this] = -1
        return this
    endmethod
    
    // Removes all data from a Table instance and recycles its index.
    //
    //     call tb.destroy()
    //
    method destroy takes nothing returns nothing
        debug if dex.list[this] != -1 then
            debug call BJDebugMsg("Table Error: Tried to double-free instance: " + I2S(this))
            debug return
        debug endif
        
        call this.flush()
        
        set dex.list[this] = dex.list[0]
        set dex.list[0] = this
    endmethod
    
    //! runtextmacro optional TABLE_BC_METHODS()
endstruct
    
//! runtextmacro optional TABLE_BC_STRUCTS()
    
struct TableArray extends array
    
    //Returns a new TableArray to do your bidding. Simply use:
    //
    //    local TableArray ta = TableArray[array_size]
    //
    static method operator [] takes integer array_size returns TableArray
        local Table tb = dex.size[array_size] //Get the unique recycle list for this array size
        local TableArray this = tb[0]         //The last-destroyed TableArray that had this array size
        
        debug if array_size <= 0 then
            debug call BJDebugMsg("TypeError: Invalid specified TableArray size: " + I2S(array_size))
            debug return 0
        debug endif
        
        if this == 0 then
            set this = less - array_size
            set less = this
        else
            set tb[0] = tb[this]  //Set the last destroyed to the last-last destroyed
            call tb.remove(this)  //Clear hashed memory
        endif
        
        set dex.size[this] = array_size //This remembers the array size
        return this
    endmethod
    
    //Returns the size of the TableArray
    method operator size takes nothing returns integer
        return dex.size[this]
    endmethod
    
    //This magic method enables two-dimensional[array][syntax] for Tables,
    //similar to the two-dimensional utility provided by hashtables them-
    //selves.
    //
    //ta[integer a].unit[integer b] = unit u
    //ta[integer a][integer c] = integer d
    //
    //Inline-friendly when not running in debug mode
    //
    method operator [] takes integer key returns Table
        static if DEBUG_MODE then
            local integer i = this.size
            if i == 0 then
                call BJDebugMsg("IndexError: Tried to get key from invalid TableArray instance: " + I2S(this))
                return 0
            elseif key < 0 or key >= i then
                call BJDebugMsg("IndexError: Tried to get key [" + I2S(key) + "] from outside TableArray bounds: " + I2S(i))
                return 0
            endif
        endif
        return this + key
    endmethod
    
    //Destroys a TableArray without flushing it; I assume you call .flush()
    //if you want it flushed too. This is a public method so that you don't
    //have to loop through all TableArray indices to flush them if you don't
    //need to (ie. if you were flushing all child-keys as you used them).
    //
    method destroy takes nothing returns nothing
        local Table tb = dex.size[this.size]
        
        debug if this.size == 0 then
            debug call BJDebugMsg("TypeError: Tried to destroy an invalid TableArray: " + I2S(this))
            debug return
        debug endif
        
        if tb == 0 then
            //Create a Table to index recycled instances with their array size
            set tb = Table.create()
            set dex.size[this.size] = tb
        endif
        
        call dex.size.remove(this) //Clear the array size from hash memory
        
        set tb[this] = tb[0]
        set tb[0] = this
    endmethod
    
    private static Table tempTable
    private static integer tempEnd
    
    //Avoids hitting the op limit
    private static method clean takes nothing returns nothing
        local Table tb = .tempTable
        local integer end = tb + 0x1000
        if end < .tempEnd then
            set .tempTable = end
            call ForForce(bj_FORCE_PLAYER[0], function thistype.clean)
        else
            set end = .tempEnd
        endif
        loop
            call tb.flush()
            set tb = tb + 1
            exitwhen tb == end
        endloop
    endmethod
    
    //Flushes the TableArray and also destroys it. Doesn't get any more
    //similar to the FlushParentHashtable native than this.
    //
    method flush takes nothing returns nothing
        debug if this.size == 0 then
            debug call BJDebugMsg("TypeError: Tried to flush an invalid TableArray instance: " + I2S(this))
            debug return
        debug endif
        set .tempTable = this
        set .tempEnd = this + this.size
        call ForForce(bj_FORCE_PLAYER[0], function thistype.clean)
        call this.destroy()
    endmethod
    
endstruct
    
endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
library SummonedEscort /* v1.5 
***************************************************************************
*   by mckill2009
***************************************************************************
*
*   */ uses /*
*       */ GetClosestWidget /* www.hiveworkshop.com/forums/jass-resources-412/snippet-getclosestwidget-204217
*       */ Table            /* www.hiveworkshop.com/forums/jass-resources-412/snippet-new-table-188084
*
***************************************************************************
*
*   Features:
*       - Allows your summoned units to follow and guards the summoner.
*       - If the summoner dies, the summoned unit searches for a new ally or
*         returns to it's original location.
*       - Used also to focus attack an enemy hero or unit.
*
***************************************************************************
*   
*   Installation:
*       Copy and paste the required libraries and this code to your map     
*
***************************************************************************
*
*   API: 
*       static method summoned takes unit summoningUnit, unit summonedUnit returns nothing
*           - call SE.summoned(GetSummoningUnit(),GetTriggerUnit())
*           - If AUTO is true, it will do automatically for you.
*           - AUTO only works for summoned unit           
*
*       static method remove takes unit escortUnit returns nothing
*           - Removes the escort from the system
*
***************************************************************************/

globals
/**************************************************************************
*   Auto registers ALL summoned units in map, it is recommended to set this
*   to false if you want a unit to escort an ally or attack an enemy hero/unit
***************************************************************************/
    private constant boolean AUTO = true 
    
    
/**************************************************************************
*   Searches for closest ally hero if main hero is dead, if FOLLOW_ONLY_HEROES
*   is false, the escort will follow a closest ally
***************************************************************************/
    private constant boolean ALLY_IN_RANGE = true
    
/**************************************************************************
*   The unit only follows heroes when the main unit dies
***************************************************************************/
    private constant boolean FOLLOW_ONLY_HEROES = true

/**************************************************************************
*   This is the offset distance from the unit to his master   
***************************************************************************/
    private constant real OFFSET = 200

/**************************************************************************
*   Searches for closest ally if main ally unit is dead
*   ALLY_IN_RANGE must be true
***************************************************************************/
    private constant real CLOSEST_ALLY = 600 

/**************************************************************************
*   Targets/attacks closest enemy in range of master
***************************************************************************/
    private constant real CLOSEST_ENEMY = 400 
endglobals

struct SE
    private unit master
    private unit sum   
    private real xUnit
    private real yUnit
    
    private static integer DATA
    private static constant integer ATTACK = 851983
    private static timer t = CreateTimer()
    private static integer instance = 0
    private static integer array insAR
    private static unit TempUnit = null
    private static Table tb
    
    private static method UnitAlive takes unit u returns boolean
        return not IsUnitType(u,UNIT_TYPE_DEAD) and u!=null
    endmethod
    
    private static method closestEnemy takes nothing returns boolean
        local thistype this = DATA
        set TempUnit = GetFilterUnit()   
        return UnitAlive(TempUnit) and IsUnitEnemy(TempUnit, GetOwningPlayer(.sum))
    endmethod
    
    private static method closestAlly takes nothing returns boolean
        local thistype this = DATA
        set TempUnit = GetFilterUnit()        
        if UnitAlive(TempUnit) and GetOwningPlayer(TempUnit)==GetOwningPlayer(.sum) and TempUnit!=.sum /*
        */ and not IsUnitType(TempUnit,UNIT_TYPE_STRUCTURE) and GetUnitMoveSpeed(TempUnit)>0 then
            static if FOLLOW_ONLY_HEROES then
                return IsUnitType(TempUnit, UNIT_TYPE_HERO)
            endif
            return true
        endif
        return false
    endmethod
    
    private method destroy takes nothing returns nothing
        set .master = null
        set .sum = null
        call .deallocate()        
    endmethod        
    
    private static method looper takes nothing returns nothing
        local thistype this
        local unit target
        local integer orderSum
        local integer index = 0
        local real angle
        local real xMaster
        local real yMaster
        local real xSummoned
        local real ySummoned
        loop
            set index = index+1
            set this = insAR[index]
            if UnitAlive(.sum) and tb.has(GetHandleId(.sum)) then
                set angle = GetRandomReal(0,6.28)
                set orderSum = GetUnitCurrentOrder(.sum)
                if UnitAlive(.master) then   
                    if orderSum==0 then
                        set xMaster = GetUnitX(.master)+OFFSET*Cos(angle)
                        set yMaster = GetUnitY(.master)+OFFSET*Sin(angle)
                        call IssuePointOrderById(.sum,ATTACK,xMaster,yMaster)
                        set DATA = this
                        set target = GetClosestUnitInRange(xMaster,yMaster,CLOSEST_ENEMY,Filter(function thistype.closestEnemy))
                        if target!=null then
                            if IsUnitType(target,UNIT_TYPE_SLEEPING) then
                                call IssueTargetOrderById(.sum,ATTACK,target)
                            else
                                call IssuePointOrderById(.sum,ATTACK,GetUnitX(target),GetUnitY(target))
                            endif
                            set target = null
                        endif
                    endif  
                else
                    set DATA = this
                    set xSummoned = GetUnitX(.sum)
                    set ySummoned = GetUnitY(.sum)
                    static if ALLY_IN_RANGE then
                        set .master = GetClosestUnitInRange(xSummoned,ySummoned,CLOSEST_ALLY,Filter(function thistype.closestAlly))
                    else
                        set .master = GetClosestUnit(xSummoned,ySummoned,Filter(function thistype.closestAlly))   
                    endif
                    if .master==null and orderSum==0 then
                        call IssuePointOrderById(.sum,ATTACK,.xUnit+OFFSET*Cos(angle),.yUnit+OFFSET*Sin(angle))
                    endif
                endif            
            else
                call .destroy()
                set insAR[index] = insAR[instance]
                set insAR[instance] = this
                set index = index - 1
                set instance = instance - 1
                if instance==0 then
                    call PauseTimer(t)
                endif              
            endif      
            exitwhen index==instance
        endloop
    endmethod   
    
    private static method create takes unit summoningUnit, unit summonedUnit returns thistype
        local thistype this
        if instance==8190 then
            call BJDebugMsg("Library_SummonedEscort ERROR: Too many instances!")
        else
            set this = allocate()
            set .master = summoningUnit
            set .sum = summonedUnit
            set .xUnit = GetUnitX(summonedUnit)
            set .yUnit = GetUnitY(summonedUnit)
            set tb[GetHandleId(.sum)] = 0
            if instance==0 then
                call TimerStart(t,1.0,true,function thistype.looper)
            endif
            set instance = instance + 1
            set insAR[instance] = this
            call RemoveGuardPosition(summonedUnit)
        endif
        return this
    endmethod
    
    private static method fire takes nothing returns boolean
        call thistype.create(GetSummoningUnit(),GetTriggerUnit())
        return false
    endmethod
    
    private static method onInit takes nothing returns nothing    
        static if AUTO then
            local trigger t = CreateTrigger()
            call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SUMMON)
            call TriggerAddCondition(t,function thistype.fire)
            set t = null
        endif
        set tb = Table.create()
    endmethod  
    
    //API:======================================
    static method summoned takes unit summoningUnit, unit summonedUnit returns nothing
        call thistype.create(summoningUnit,summonedUnit)
    endmethod
    
    static method remove takes unit escortUnit returns nothing
        call tb.remove(GetHandleId(escortUnit))
    endmethod    
endstruct

endlibrary