Triggers

globals
    constant integer MAX_INTEGER = 2147483647
    constant real BIG_REAL = 1000000000.0
    constant string EMPTY_STRING = ""
    constant string DEFAULT_STRING = "Default string"
    integer array BUFFS_THAT_SLOW
    integer BUFFS_THAT_SLOW_SIZE

    constant integer RACE_NUM_RANDOM = 0
    constant integer RACE_NUM_ORDER = 1
    constant integer RACE_NUM_NATURE = 2
    constant integer RACE_NUM_DEATH = 3
    constant integer RACE_NUM_MAGIC = 4
    constant integer RACE_NUM_CHAOS = 5
    

endglobals

globals
    //************** UNITS **************
        constant integer SB_ALTAR_OF_DARKNESS = 'h01X'
        constant integer SB_ALTAR_OF_LIGHT = 'h019'
        constant integer SB_ALTAR_OF_NATURE = 'h01J'
        constant integer SB_ARCHANGEL_OF_LIFE = 'h00N'
        constant integer SB_ARCHON_AIR = 'h02B'
        constant integer SB_ARCHON_GROUND = 'h02A'
        constant integer SB_AVATAR_OF_COMMAND = 'h00F'
        constant integer SB_BARRACKS = 'h002'
        constant integer SB_BATTLE_STANDARD_UNIT = 'h01G'
        constant integer SB_BLACK_HOLE = 'A03T'
        constant integer SB_BLACK_PYRAMID = 'u018'
        constant integer SB_BLACKSMITH = 'h006'
        constant integer SB_BLIGHT_FACTORY = 'u00J'
        constant integer SB_BLIGHT_VESSEL = 'u008'
        constant integer SB_BLIGHT_VESSEL_UPGRADE_DUMMY = 'u00E'
        constant integer SB_BLIGHT_WIDOW = 'n00T'
        constant integer SB_BLIGHT_WIDOW_WEBBED = 'n01A'
        constant integer SB_BLOOD_MISTRESS = 'h01Q'
        constant integer SB_BURNING_BLOOD_EXPLOSION = 'h01M'
        constant integer SB_CELESTIAL_BEACON = 'h00E'
        constant integer SB_CELESTIAL_GATEWAY = 'h01K'
        constant integer SB_CHICKEN = 'n017'
        constant integer SB_CHANGELING_CONTROL_DUMMY = 'n01C'
        constant integer SB_CHURCH = 'h01E'
        constant integer SB_CITADEL = 'o000'
        constant integer SB_CLEAVE = 'A037'
        constant integer SB_CLERIC = 'n002'
        constant integer SB_CONSTRUCTION_DUMMY_BLIGHT_FACTORY = 'h00H'
        constant integer SB_CONSTRUCTION_DUMMY_DARK_NEXUS = 'u006'
        constant integer SB_CONSTRUCTION_DUMMY_SPELLBRINGER_DEATH = 'h007'
        constant integer SB_CROW = 'u001'
        constant integer SB_CROW_AIR = 'u005'
        constant integer SB_CRUSADER = 'h02G'
        constant integer SB_CRYPT = 'u00D'
        constant integer SB_CRYPT_OR_MANOR = 'h010'
        constant integer SB_DARK_NEXUS = 'u00C'
        constant integer SB_DEATH_KNIGHT = 'n01D'
        constant integer SB_DENDROID_CHIEFTAIN = 'e00I'
        constant integer SB_DENDROID_ELDER = 'e00G'
        constant integer SB_DENDROID_TREEHERD = 'e00E'
        constant integer SB_DENDROID_TREEHERD_WARRIOR_MODE = 'e000'
        constant integer SB_DENDROID_WARRIOR = 'e007'
        constant integer SB_DREAD_SPIRE = 'u00Z'
        constant integer SB_ECLIPSE_DEPENDENCY = 'h022'
        constant integer SB_ELVEN_ARTISAN = 'h00I'
        constant integer SB_ELVEN_ENCHANTRESS = 'h00M'
        constant integer SB_ENFORCER = 'h01O'
        constant integer SB_FALCONER = 'n001'
        constant integer SB_FALCON = 'u000'
        constant integer SB_FALCON_ATTACKER = 'u008'
        constant integer SB_FIRE_ELEMENTAL = 'hfel'
        constant integer SB_FLESH_GOLEM = 'u016'
        constant integer SB_FLESHLESS_ZOMBIE = 'n00M'
        constant integer SB_FORTIFY = 'A07L'
        constant integer SB_FORTRESS = 'h018'
        constant integer SB_FROST_TITAN = 'mtit'
        constant integer SB_GARGOYLE = 'u00A'
        constant integer SB_GIANT_TOAD = 'n003'
        constant integer SB_GLACIAL_STASIS_HIDDEN_ATTACKER = 'h01U'
        constant integer SB_GOLD_MINE = 'ngol'
        constant integer SB_GRAVEYARD = 'u010'
        constant integer SB_GREAT_STAG = 'n013'
        constant integer SB_GREMLIN = 'h00O'
        constant integer SB_HALL_OF_ELITES = 'n00A'
        constant integer SB_HALL_OF_SCHOLARS = 'n00C'
        constant integer SB_HALL_OF_WARRIORS = 'e002'
        constant integer SB_HAVEN = 'e003'
        constant integer SB_HEADMASTER = 'n010'
        constant integer SB_HIDDEN_CASTER = 'h00B'
        constant integer SB_HIDDEN_CASTER_RELEASE_FALCON = 'h012'
        constant integer SB_HOLD = 'e001'
        constant integer SB_HOODLING = 'n01G'
        constant integer SB_ICE_ELEMENTAL = 'h026'
        constant integer SB_LOST_SOUL = 'u00X'
        constant integer SB_LOST_SOUL_HAUNTING = 'u00N'
        constant integer SB_LUMBER_MILL = 'h005'
        constant integer SB_MAGIC_HALL = 'o001'
        constant integer SB_MAGIC_HALL_2 = 'o002'
        constant integer SB_MANOR = 'h00V'
        constant integer SB_MIND_VISION_DUMMY = 'hcmv'
        constant integer SB_NECROPOLIS = 'u002'
        constant integer SB_NECROMANCER = 'u003'
        constant integer SB_NECROMANCER_LICH = 'u00F'
        constant integer SB_OBLIVION_VAULT_UNIT = 'n01E'
        constant integer SB_PEASANT = 'h000'
        constant integer SB_PHANTOM_CARRIAGE = 'n00P'
        constant integer SB_PHANTOM_CARRIAGE_LANDED = 'n015'
        constant integer SB_PLACE_BLIGHT_EMBLEM = 'A07P'
        constant integer SB_PUTRID_BLOAT_UNIT = 'n01K'
        constant integer SB_ROWDY_CREW = 'n01I'
        constant integer SB_SANCTUM = 'o001'
        constant integer SB_SAPLING = 'e009'
        constant integer SB_SAPLING_WARRIOR_MODE = 'e006'
        constant integer SB_SCOUT_TOWER = 'h00W'
        constant integer SB_SCRY = 'A02N'
        constant integer SB_SEED_OF_CORRUPTION = 'A057'
        constant integer SB_SHAPELING = 'h00O'
        constant integer SB_SHAPER = 'tink'
        constant integer SB_SHEPHERD_OF_ROT = 'o005'
        constant integer SB_SKY_TOTEM = 'e004'
        constant integer SB_SLAVE = 'h01A'
        constant integer SB_SPEARMAN = 'n000'
        constant integer SB_SPEARMAN_SIEGE_SPEARS = 'n004'
        constant integer SB_SPEARTANK = 'h029'
        constant integer SB_SPEARTANK_FORTIFIED = 'h01P'
        constant integer SB_SPECIAL_EFFECT_UNIT_BLACK_HOLE = 'h027'
        constant integer SB_SPECIAL_EFFECT_UNIT_CLOUD_OF_MIST = 'h01D'
        constant integer SB_SPECIAL_EFFECT_UNIT_DEVOURING_SWARM = 'h01W'
        constant integer SB_SPECIAL_EFFECT_UNIT_ENTWINE = 'h00R'
        constant integer SB_SPECIAL_EFFECT_UNIT_GAVEL_OF_JUDGMENT = 'h00P'
        constant integer SB_SPECIAL_EFFECT_UNIT_SPIN_WEB = 'h02F'
        constant integer SB_SPECIAL_EFFECT_UNIT_UNDYING = 'h021'
        constant integer SB_SPECIAL_EFFECT_UNIT_VAMPIRE_LORD = 'n00P'
        constant integer SB_SPECIAL_EFFECT_UNIT_WALL_OF_FIRE = 'h013'
        constant integer SB_SPECIAL_EFFECT_UNIT_WHIRLWIND = 'h01C'
        constant integer SB_SPECIAL_EFFECT_UNIT_WILD_GROWTH = 'h02H'
        constant integer SB_SPECIAL_EFFECT_UNIT_WIND_BARRIER = 'h020'
        constant integer SB_SPECIAL_EFFECT_UNIT_ZOMBIE = 'n00S'
        constant integer SB_SPECIAL_EFFECT_UNIT_ZOMBIE_PLAGUE = 'h009'
        constant integer SB_SPELLBRINGER_ORDER = 'H001'
        constant integer SB_SPELLBRINGER_NATURE = 'H016'
        constant integer SB_SPELLBRINGER_DEATH = 'H00A'
        constant integer SB_SPELLBRINGER_DUMMY_DEPENDENCY = 'h01L'
        constant integer SB_SPITTER_PLANT = 'n00L'
        constant integer SB_SPIRIT_DWARF = 'h01I'
        constant integer SB_SPIRIT_OWL_UNIT = 'n00B'
        constant integer SB_SWARM_BAT = 'u009'
        constant integer SB_T_REX = 'n00V'
        constant integer SB_THICKET_UNIT = 'h02A'
        constant integer SB_TIGER = 'e00B'
        constant integer SB_TREEHERD = 'e00E'
        constant integer SB_UNIT_HAUNT = 'n007'
        constant integer SB_UNHOLY_BANNER_UNIT = 'o006'
        constant integer SB_VAMPIRE_LORD = 'n006'
        constant integer SB_VAMPIRE_BLOODFIEND = 'n00O'
        constant integer SB_VAMPIRE_LORD_COFFIN_FORM = 'n008'
        constant integer SB_VAULT_OF_PHYLACTERIES = 'u00P'
        constant integer SB_VILE_LABORATORY = 'u007'
        constant integer SB_WATER_ELEMENTAL = 'h01S'
        constant integer SB_WAR_FACTORY = 'h01F'
        constant integer SB_WAR_FACTORY_OR_CHURCH_OR_CELESTIAL_BEACON = 'h02C'
        constant integer SB_WAR_MILL = 'h02F'
        constant integer SB_WILD_GROWTH_UNIT = 'h02K'
        constant integer SB_ZOMBIE = 'n00J'
        constant integer SB_ZOMBIE_BUILD_DUMMY = 'n007'
    
    //************ ABILITIES ************
        constant integer SB_ABSORB_ESSENCE = 'A00B'
        constant integer SB_ABSORB_LUMBER = 'A00T'
        constant integer SB_ABSORB_LUMBER_NECROPOLIS = 'A082'
        constant integer SB_ACID_BREATH = 'A009'
        constant integer SB_ACID_BREATH_HIDDEN_CASTER_GROUND = 'A03I'
        constant integer SB_ACID_BREATH_HIDDEN_CASTER_AIR = 'A03K'
        constant integer SB_ACID_BREATH_CS = 'A084'
        constant integer SB_ACID_BREATH_SWOOP = 'A08K'
        constant integer SB_ANIMATE_DEAD = 'A001'
        constant integer SB_ANIMATE_DEAD_VISUAL_EFFECT = 'A039'
        constant integer SB_ARBOREAL_AVENGER = 'A005'
        constant integer SB_ARCANE_PULSE = 'A08C'
        constant integer SB_ARCANE_PULSE_BUFF = 'A009'
        constant integer SB_ARCANE_PULSE_EXPLOSION_GROUND = 'A03K'
        constant integer SB_ARCANE_PULSE_EXPLOSION_AIR = 'A084'
        constant integer SB_ARCANE_RIDDLE = 'A01W'
        constant integer SB_ARMY_TOGGLE_ADD = 'A07B'
        constant integer SB_ARMY_TOGGLE_REMOVE = 'A079'
        constant integer SB_ASCEND = 'A072'
        constant integer SB_ASCEND_DUMMY = 'A08I'
        constant integer SB_ATTACK_ARMY = 'A05S'
        constant integer SB_BANISH = 'A012'
        constant integer SB_BANISH_HIDDEN = 'A03L'
        constant integer SB_BARRAGE = 'A07W'
        constant integer SB_BATTLE_STANDARD = 'A06Y'
        constant integer SB_BATTLE_STANDARD_AURA = 'A00I'
        constant integer SB_BEAST_WITHIN = 'A02F'
        constant integer SB_BILE_BLOSSOMS = 'A03E'
        constant integer SB_BILE_BLOSSOMS_DAMAGE = 'A03B'
        constant integer SB_BILE_BLOSSOMS_SLOW = 'A03D'
        constant integer SB_BOMBARD = 'A04V'
        constant integer SB_BOUNTY = 'A078'
        constant integer SB_BLIND_HIDDEN_CASTER = 'A07F'
        constant integer SB_BLINDING_FLASH = 'A006'
        constant integer SB_BLINDING_FLASH_HIDDEN_CASTER = 'A06E'
        constant integer SB_BLIGHT_ARMOR = 'A02I'
        constant integer SB_BLIGHT_GROWTH_512 = 'A07D'
        constant integer SB_BLIGHT_GROWTH_768 = 'Abgs'
        constant integer SB_BLIGHT_GROWTH_960 = 'Abgl'
        constant integer SB_BLIGHT_SHOT = 'A07T'
        constant integer SB_BLIZZARD = 'A015'
        constant integer SB_BLIZZARD_SLOW_ABILITY = 'A013'
        constant integer SB_BLOOD_GORGE = 'S00D'
        constant integer SB_BRINK_OF_DEATH = 'A05X'
        constant integer SB_BURST_ATTACK = 'A00D'
        constant integer SB_CALL_GREAT_STAG = 'A05F'
        constant integer SB_CAMOFLAGE = 'A04S'
        constant integer SB_CAMOFLAGE_DUMMY = 'A077'
        constant integer SB_CARGO_HOLD_DEATH = 'Achd'
        constant integer SB_CARGO_HOLD_PHANTOM_CARRIAGE = 'S009'
        constant integer SB_CELESTIAL_FIRE = 'A093'
        constant integer SB_CELESTIAL_FIRE_HIDDEN_CASTER = 'A094'
        constant integer SB_CHAIN_LIGHTNING = 'A056'
        constant integer SB_CHAIN_LIGHTNING_HIDDEN_CASTER = 'A055'
        constant integer SB_CLOUD_COVER = 'A030'
        constant integer SB_CLOUD_OF_MIST = 'A06I'
        constant integer SB_CLOUD_OF_MIST_EVASION = 'A04U'
        constant integer SB_CLOUD_OF_MIST_MAGIC_IMMUNITY = 'A06F'
        constant integer SB_COFFIN_SLUMBER = 'A02M'
        constant integer SB_CONE_OF_FLAME = 'A045'
        constant integer SB_COUNTERSPELL = 'A01Y'
        constant integer SB_COUNTERSPELL_HIDDEN_CASTER = 'A02G'
        constant integer SB_DAMAGE_RESISTANCE = 'A06B'
        constant integer SB_DARKNESS = 'A06V'
        constant integer SB_DARKNESS_HIDDEN_CASTER = 'A06W'
        constant integer SB_DEATH_BEAM = 'A08T'
        constant integer SB_DEATH_WAVE = 'A03V'
        constant integer SB_DECONSTRUCT = 'A050'
        constant integer SB_DESCEND = 'A07J'
        constant integer SB_DEVOURING_SWARM = 'A033'
        constant integer SB_DISABLE_DAMAGE_DEALT = 'A07C'
        constant integer SB_DIVINE_INTERVENTION = 'A00G'
        constant integer SB_EAGLE_EYE = 'A02M'
        constant integer SB_ECLIPSE = 'A07A'
        constant integer SB_EJECT = 'A075'
        constant integer SB_ELDRITCH_GAZE = 'A08H'
        constant integer SB_ELDRITCH_GAZE_HIDDEN = 'A08F'
        constant integer SB_ENTWINE = 'A020'
        constant integer SB_ESSENCE_DRAIN = 'A02Z'
        constant integer SB_ESSENCE_DRAIN_HIDDEN_CASTER = 'A031'
        constant integer SB_EYE_BEAM = 'A014'
        constant integer SB_FAERIE_DUST = 'A005'
        constant integer SB_FEEDING_FRENZY = 'A03D'
        constant integer SB_FIND_FREE_NECROMANCERS = 'A07U'
        constant integer SB_FIND_RITUAL_NECROMANCERS = 'A00F'
        constant integer SB_FIRE_BOLT = 'A05I'
        constant integer SB_FLICKER = 'A03W'
        constant integer SB_FORCE_ARMY_UNIT = 'A00J'
        constant integer SB_FREEZETHAW = 'A052'
        constant integer SB_FROST_ARMOR = 'A05B'
        constant integer SB_FROST_ARMOR_SLOW_AURA = 'A05C'
        constant integer SB_GASEOUS_BLOAT = 'A00A'
        constant integer SB_GAVEL_OF_JUDGMENT = 'A064'
        constant integer SB_GAVEL_OF_JUDGMENT_HIDDEN_CASTER = 'A05L'
        constant integer SB_GHOST = 'Agho'
        constant integer SB_GHOST_VISIBLE = 'Aeth'
        constant integer SB_GOLD_MINE_ABILITY = 'Agld'
        constant integer SB_HARVEST_CHAOS_WEAK = 'A01O'
        constant integer SB_HARVEST_CHAOS_NORMAL = 'A022'
        constant integer SB_HARVEST_GOLD_AND_LUMBER = 'Ahar'
        constant integer SB_HARVEST_GOLD_AND_LUMBER_MAGIC = 'A03U'
        constant integer SB_HARVEST_GOLD_ONLY = 'A018'
        constant integer SB_HARVEST_ORDER_SUPER_PEASANT = 'A06C'
        constant integer SB_HAUNT = 'A05M'
        constant integer SB_HIDE_HP_BAR = 'A048'
        constant integer SB_HIDE_HP_BAR_MORPH = 'A06Q'
        constant integer SB_HOLD_THE_LINE = 'A08P'
        constant integer SB_HOLD_THE_LINE_HIDDEN_CASTER = 'A08Q'
        constant integer SB_HYDE_POTION_AOE = 'A07Q'
        constant integer SB_HYDE_POTION_HIDDEN_CASTER = 'A091'
        constant integer SB_ILLUSION = 'A01A'
        constant integer SB_ILLUSION_HIDDEN = 'A01N'
        constant integer SB_ILLUSION_HIDDEN_CASTER = 'A01R'
        constant integer SB_IMMOLATE = 'A011'
        constant integer SB_INTERDICTION_AURA = 'A06J'
        constant integer SB_INTERDICTION_AURA_HIDDEN = 'A06K'
        constant integer SB_ITS_ALIVE = 'A040'
        constant integer SB_KISS_OF_IMMORTALITY = 'A05U'
        constant integer SB_KISS_OF_IMMORTALITY_HIDDEN_CASTER = 'A092'
        constant integer SB_KUNDALINI = 'A04W'
        constant integer SB_LASH_OF_THE_WHIP = 'A01X'
        constant integer SB_LASH_OF_THE_WHIP_HIDDEN_CASTER = 'A01Z'
        constant integer SB_LAND = 'A065'
        constant integer SB_LAND_DUMMY = 'A02V'
        constant integer SB_LEAP = 'A01M'
        constant integer SB_LEECH_SEED = 'A03Z'
        constant integer SB_LEECH_SEED_HIDDEN_CASTER = 'A02N'
        constant integer SB_LICH_UPGRADE = 'S004'
        constant integer SB_LIFE_DRAIN = 'A01A'
        constant integer SB_LIFT_DEBUFF = 'A00D'
        constant integer SB_LIGHTNING_STRIKE = 'A01S'
        constant integer SB_LOAD_PHANTOM_CARRIAGE_DUMMY = 'A06Z'
        constant integer SB_LOCUST = 'Aloc'
        constant integer SB_MAGIC_MISSILE = 'A059'
        constant integer SB_MANA_BATTERY = 'A08J'
        constant integer SB_MANA_GENERATOR_HIDDEN = 'A03O'
        constant integer SB_MANA_SHIELD = 'A051'
        constant integer SB_METEOR = 'A019'
        constant integer SB_MIND_VISION = 'Ammv'
        constant integer SB_MIND_VISION_DUMMY_CAST = 'dcmv'
        constant integer SB_MOVE_ARMY = 'A05T'
        constant integer SB_MURDER_OF_CROWS = 'A04P'
        constant integer SB_MURDER_OF_CROWS_HIDDEN_CASTER_AIR = 'A01J'
        constant integer SB_MURDER_OF_CROWS_HIDDEN_CASTER_GROUND = 'A04O'
        constant integer SB_NECRO_RESTORE = 'A01L'
        constant integer SB_NECROGENESIS = 'A05Z'
        constant integer SB_NECROMANCER_UPROOT = 'A00Y'
        constant integer SB_NIGHT_STALKER = 'S00F'
        constant integer SB_NO_COLLISION = 'A01H'
        constant integer SB_NO_HERO_GLOW = 'nohg'
        constant integer SB_NON_ARMY_UNIT = 'A06R'
        constant integer SB_NULL_BOMB = 'A03N'
        constant integer SB_OBLITERATE = 'A034'
        constant integer SB_OBLIVION_VAULT = 'A07H'
        constant integer SB_OFFERING = 'A02B'
        constant integer SB_OFFERING_DUMMY = 'A02D'
        constant integer SB_OUST = 'A03H'
        constant integer SB_OVERCLOCK = 'A00P'
        constant integer SB_OVERCLOCK_ARMOR_BONUS = 'A03S'
        constant integer SB_PERMANENT_INVISIBILITY_TREETOP_SENTRY = 'A07O'
        constant integer SB_PERMANENT_INVISIBILITY_ECLIPSE = 'A08D'
        constant integer SB_PERMANENT_INVISIBILITY_ECLIPSE_NO_FADE = 'A036'
        constant integer SB_PERMANENT_INVISIBILITY_FLICKER = 'A00H'
        constant integer SB_PLAGUE_DIVE = 'A05H'
        constant integer SB_PLAGUE_DIVE_EFFECT = 'A05J'
        constant integer SB_PLAGUE_DIVE_HIDDEN_CASTER = 'A05K'
        constant integer SB_POSSESSION = 'A063'
        constant integer SB_PUTREFY = 'A00A'
        constant integer SB_PUTREFY_HIDDEN_CASTER = 'A01D'
        constant integer SB_PYRE = 'A07R'
        constant integer SB_RAPTOR_EYE = 'A04X'
        constant integer SB_RECALL = 'A01C'
        constant integer SB_RELEASE_FALCON = 'A05W'
        constant integer SB_RELEASE_FALCON_UNTARGETED = 'A044'
        constant integer SB_RELEASE_FALCON_HIDDEN_CASTER = 'A000'
        constant integer SB_RELEASE_FALCON_AUTOCAST_ON = 'A06M'
        constant integer SB_RELEASE_FALCON_AUTOCAST_OFF = 'A06O'
        constant integer SB_RENEW = 'Aren'
        constant integer SB_RENEW_SAPLING = 'A00N'
        constant integer SB_REPAIR = 'Arep'
        constant integer SB_REPAIR_DWARVES = 'A06D'
        constant integer SB_REPAIR_HUMAN = 'Ahrp'
        constant integer SB_RESTORE = 'Arst'
        constant integer SB_RESTORE_LOST_SOUL = 'A00S'
        constant integer SB_RESTORE_NECRO = 'A01L'
        constant integer SB_RESURRECTION = 'A00K'
        constant integer SB_RETURN_GOLD = 'Argd'
        constant integer SB_RETURN_GOLD_AND_LUMBER = 'Argl'
        constant integer SB_RETURN_RESOURCES_BLIGHT_FACTORY = 'A004'
        constant integer SB_RETURN_TO_HAUNT = 'A03P'
        constant integer SB_ROOTGRASP = 'A00E'
        constant integer SB_ROOTGRASP_AIR = 'A002'
        constant integer SB_ROOTGRASP_GROUND = 'A06A'
        constant integer SB_SCRY_HIDDEN_CASTER = 'A03Q'
        constant integer SB_SLURP = 'A02E'
        constant integer SB_SOOTHE = 'A025'
        constant integer SB_SOOTHE_HIDDEN = 'A07E'
        constant integer SB_SOUL_CAPTURE = 'A07Y'
        constant integer SB_SOUL_HARVEST = 'A01U'
        constant integer SB_SOUL_HARVEST_DAMAGE_BONUS = 'A01K'
        constant integer SB_SPAWN_SAPLING_UNITS = 'A02X'
        constant integer SB_SPAWN_SAPLING_STRUCTURES = 'A05Q'
        constant integer SB_SPECTRAL_SHOT = 'A03D'
        constant integer SB_SPELL_IMMUNITY_HIDDEN = 'A021'
        constant integer SB_SPIN_WEB = 'A06P'
        constant integer SB_SPIN_WEB_MORPH = 'A06P'
        constant integer SB_SPIRIT = 'A08E'
        constant integer SB_SPIRIT_OWL = 'A04E'
        constant integer SB_STAND_GROUND = 'A01P'
        constant integer SB_START_SUMMONING_RITUAL = 'A01E'
        constant integer SB_START_SUMMONING_RITUAL_LICH = 'A04G'
        constant integer SB_STOP_SUMMONING_RITUAL = 'A01F'
        constant integer SB_STOP_SUMMONING_RITUAL_LICH = 'A04H'
        constant integer SB_STORMRAGE = 'A050'
        constant integer SB_STORMRAGE_DUMMY = 'A08L'
        constant integer SB_SUICIDE = 'A08X'
        constant integer SB_SUICIDE_ATTACK = 'A090'
        constant integer SB_SUMMON_AVATAR_OF_COMMAND = 'A06L'
        constant integer SB_SUMMON_SPIRIT_DWARVES = 'A054'
        constant integer SB_SUMMONING_RITUAL_EFFECT = 'A07G'
        constant integer SB_SURGE = 'A011'
        constant integer SB_SWOOP = 'A04D'
        constant integer SB_TAIL_WHIP = 'A046'
        constant integer SB_TAIL_WHIP_SLOW = 'A04A'
        constant integer SB_TAKE_FORM = 'A00B'
        constant integer SB_TAUNT = 'A049'
        constant integer SB_THICKET = 'A06I'
        constant integer SB_THICKET_PHYS_REDUCTION = 'A068'
        constant integer SB_THICKET_SPELL_REDUCTION = 'A069'
	constant integer SB_THORNS_ARMOR = 'A05P'
        constant integer SB_THORNS_ARMOR_HIDDEN_ABILITY = 'A058'
        constant integer SB_THOUSAND_NEEDLES = 'A04J'
        constant integer SB_TIME_WARP = 'A03F'
        constant integer SB_TITANIC_INVOCATION = 'A05A'
        constant integer SB_TOGGLE_GROUND_ATTACK = 'A00Z'
        constant integer SB_TOWER_SHIELDS = 'A04L'
        constant integer SB_TRACTOR_BEAM = 'A02J'
        constant integer SB_TRAMPLE = 'A029'
        constant integer SB_TREETOP_SENTRY = 'A04B'
        constant integer SB_TRUE_SIGHT_HIDDEN = 'A024'
        constant integer SB_ORC_BUILD = 'AObu'
        constant integer SB_QUICKSAND = 'A04L'
        constant integer SB_QUICKSAND_HIDDEN = 'A04Y'
        constant integer SB_UD_BUILD = 'AUbu'
        constant integer SB_UNDYING = 'A08O'
        constant integer SB_UNHOLY_BANNER = 'A06T'
        constant integer SB_UNHOLY_CROWN = 'A08S'
        constant integer SB_UNIT_SELL_UNITS = 'A01G'
        constant integer SB_UNSUMMON_GENERIC = 'A01Q'
        constant integer SB_VIPER_STRIKE = 'A08B'
        constant integer SB_WALL_OF_FIRE = 'A02U'
        constant integer SB_WALL_OF_THORNS = 'A01Q'
        constant integer SB_WAVEFORM = 'A010'
        constant integer SB_WHIRLWIND = 'A03A'
        constant integer SB_WILD_GROWTH = 'A095'
        constant integer SB_WILD_GROWTH_SB = 'A00U'
        constant integer SB_WIND_BARRIER = 'A01Y'
        constant integer SB_WIND_BARRIER_HIDDEN = 'A03Q'
        constant integer SB_WINDED = 'A071'
        constant integer SB_WINDRUN = 'A03H'
        constant integer SB_WORKER_MODE_DENDROID_TREEHERD = 'A02O'
        constant integer SB_WORKER_MODE_SAPLING = 'A02P'
        constant integer SB_ZOMBIE_PLAGUE = 'A04K'
        constant integer SB_ZOMBIE_PLAGUE_HIDDEN_CASTER = 'A041'
    
    //************ BUFFS ************
        constant integer SB_BUFF_ARBOREAL_AVENGER = 'B02T'
        constant integer SB_BUFF_ARCANE_PULSE = 'B02J'
        constant integer SB_BUFF_BANISH = 'B02P'
        constant integer SB_BUFF_BANISH_HIDDEN = 'B000'
        constant integer SB_BUFF_BLIGHT_ARMOR = 'B022'
        constant integer SB_BUFF_BRINK_OF_DEATH= 'B011'
        constant integer SB_BUFF_COUNTERSPELL = 'B00M'
        constant integer SB_BUFF_DISEASE = 'Bapl'
        constant integer SB_BUFF_DOMINATE = 'B007'
        constant integer SB_BUFF_EAGLE_EYE = 'B02W'
        constant integer SB_BUFF_ELDRITCH_GAZE = 'B01H'
        constant integer SB_BUFF_ENTWINE = 'B00R'
        constant integer SB_BUFF_ESSENCE_DRAIN_CASTER = 'B029'
        constant integer SB_BUFF_ESSENCE_DRAIN_TARGET = 'B01P'
        constant integer SB_BUFF_FAERIE_DUST = 'B009'
        constant integer SB_BUFF_FEAR = 'B02A'
        constant integer SB_BUFF_GAVEL_OF_JUDGMENT = 'B014'
        constant integer SB_BUFF_GLACIAL_STASIS = 'B00F'
        constant integer SB_BUFF_GRASP_OF_DEATH = 'B02K'
        constant integer SB_BUFF_GROUNDED = 'B02A'
        constant integer SB_BUFF_HAUNT = 'B01B'
        constant integer SB_BUFF_IMMOLATE = 'B00Y'
        constant integer SB_BUFF_INTERDICTION_AURA = 'B015'
        constant integer SB_BUFF_KISS_OF_IMMORTALITY = 'B02T'
        constant integer SB_BUFF_KISS_OF_IMMORTALITY_HEAL = 'B02U'
        constant integer SB_BUFF_LEECH_SEED = 'B00U'
        constant integer SB_BUFF_LIFE_DRAIN = 'B013'
        constant integer SB_BUFF_LIFT = 'B02O'
        constant integer SB_BUFF_MANA_BATTERY = 'B01M'
        constant integer SB_BUFF_MIND_VISION = 'Bmmv'
        constant integer SB_BUFF_NULL_BOMB = 'B00I'
        constant integer SB_BUFF_OBLIVION_VAULT = 'B02P'
        constant integer SB_BUFF_OUST = 'B00W'
        constant integer SB_BUFF_OVERCLOCK = 'B00A'
        constant integer SB_BUFF_PLAGUE = 'B00Z'
        constant integer SB_BUFF_PLANESHIFT = 'B00K'
        constant integer SB_BUFF_POSSESSION = 'B013'
        constant integer SB_BUFF_PUTREFY = 'B019'
        constant integer SB_BUFF_QUICKSAND = 'B00X'
        constant integer SB_BUFF_REND_FLESH = 'B012'
        constant integer SB_BUFF_ROOTGRASP = 'B00V'
        constant integer SB_BUFF_SEED_OF_CORRUPTION = 'B017'
        constant integer SB_BUFF_SERRATED_SPEARS = 'B01U'
        constant integer SB_BUFF_SLOWED = 'Bfro'
        constant integer SB_BUFF_SLURP = 'B02M'
        constant integer SB_BUFF_SPECTRAL_SHOT = 'B02X'
        constant integer SB_BUFF_SPELLBURN = 'B023'
        constant integer SB_BUFF_SPORE_CLOUD = 'B01R'
        constant integer SB_BUFF_SURGE = 'B00E'
        constant integer SB_BUFF_SOOTHE = 'B00P'
        constant integer SB_BUFF_TAIL_WHIP = 'B003'
        constant integer SB_BUFF_TASKMASTER = 'B005'
        constant integer SB_BUFF_THORNS_ARMOR = 'B021'
        constant integer SB_BUFF_THOUSAND_NEEDLES = 'B006'
        constant integer SB_BUFF_TIMED_LIFE_ANIMATE_DEAD = 'BUan'
        constant integer SB_BUFF_TIMED_LIFE_GENERIC = 'BTLF'
        constant integer SB_BUFF_TIMED_LIFE_WATER_ELEMENTAL = 'BHwe'
        constant integer SB_BUFF_TRACTOR_BEAM = 'B00Q'
        constant integer SB_BUFF_TRACTOR_BEAM_CASTER = 'B00S'
        constant integer SB_BUFF_WEBBED = 'B01Z'
        constant integer SB_BUFF_WHIRLWIND = 'B02C'
        constant integer SB_BUFF_WILD_GROWTH = 'B01Z'
        constant integer SB_BUFF_WIND_BARRIER = 'B009'
        constant integer SB_BUFF_WINDED = 'B01C'
        constant integer SB_BUFF_WINDRUN = 'B00Z'
        constant integer SB_BUFF_ZOMBIE_PLAGUE = 'B02E'
    
    //************ TECH ************
        constant integer SB_TECH_ABSORB_ESSENCE = 'R02Q'
        constant integer SB_TECH_ACID_BREATH = 'R01K'
        constant integer SB_TECH_ARBOREAL_AVENGER = 'R00O'
        constant integer SB_TECH_ARCANE_RIDDLE = 'R00S'
        constant integer SB_TECH_BLIGHT_SHOT = 'R010'
        constant integer SB_TECH_CLEAVE = 'R00K'
        constant integer SB_TECH_CLOUD_COVER = 'R00G'
        constant integer SB_TECH_DARK_NEXUS = 'R00Q'
        constant integer SB_TECH_ELDER_TREEHERDS = 'R02H'
        constant integer SB_TECH_ELDER_TREEHERDS_HIDDEN = 'R01T'
        constant integer SB_TECH_ELDRITCH_GAZE = 'R01U'
        constant integer SB_TECH_ESSENCE_DRAIN = 'R015'
        constant integer SB_TECH_FALCON_TRAINING = 'R00F'
        constant integer SB_TECH_FALCON_TRAINING_HIDDEN = 'R006'
        constant integer SB_TECH_GREATER_HYDROMANCY = 'R01I'
        constant integer SB_TECH_HOLD_THE_LINE = 'R014'
        constant integer SB_TECH_IMPROVED_SOUL_HARVEST = 'R02D'
        constant integer SB_TECH_MANA_SHIELD = 'R01H'
        constant integer SB_TECH_PUTREFY = 'R02X'
        constant integer SB_TECH_SIEGE_SPEARS = 'R02A'
        constant integer SB_TECH_SLURP = 'R004'
        constant integer SB_TECH_SPELLBURN = 'R00S'
        constant integer SB_TECH_SOUL_CONNOISSEUR = 'R00D'
        constant integer SB_TECH_SURGE = 'R01B'
        constant integer SB_TECH_THOUSAND_NEEDLES = 'R01R'
        constant integer SB_TECH_TOWER_SHIELDS = 'R023'
        constant integer SB_TECH_UNDYING = 'R00H'
        constant integer SB_TECH_UNHOLY_STRENGTH = 'R00L'
    
    //************ DESTRUCTIBLES ************
        constant integer SB_ASHENVALE_TREE_WALL = 'ATtr'
        constant integer SB_ASHENVALE_CANOPY_TREE = 'ATtc'
        constant integer SB_BARRENS_TREE_WALL = 'BTtw'
        constant integer SB_BARRENS_CANOPY_TREE = 'BTtc'
        constant integer SB_BLACK_CITADEL_TREE_WALL = 'KTtw'
        constant integer SB_CITYSCAPE_FALL_TREE_WALL = 'YTft'
        constant integer SB_CITYSCAPE_SNOWY_TREE_WALL = 'YTst'
        constant integer SB_CITYSCAPE_SUMMER_TREE_WALL = 'YTct'
        constant integer SB_CITYSCAPE_WINTER_TREE_WALL = 'YTwt'
        constant integer SB_CITYSCAPE_RUINED_TREE_WALL = 'JTct'
        constant integer SB_DALARAN_RUINS_TREE_WALL = 'JTtw'
        constant integer SB_DUNGEON_TREE_WALL = 'DTsh'
        constant integer SB_FELWOOD_TREE_WALL = 'CTtr'
        constant integer SB_FELWOOD_CANOPY_TREE = 'CTtc'
        constant integer SB_ICECROWN_TREE_WALL = 'ITtw'
        constant integer SB_ICECROWN_CANOPY_TREE = 'ITtc'
        constant integer SB_NORTHREND_CANOPY_TREE = 'NTtc'
        constant integer SB_NORTHREND_ICY_TREE_WALL = 'NTiw'
        constant integer SB_FALL_TREE_WALL = 'FTtw'
        constant integer SB_SUMMER_TREE_WALL = 'LTlt'
        constant integer SB_SNOWY_TREE_WALL = 'WTst'
        constant integer SB_WINTER_TREE_WALL = 'WTtw'
        constant integer SB_NORTHREND_TREE_WALL = 'NTtw'
        constant integer SB_OUTLAND_TREE_WALL = 'OTtw'
        constant integer SB_RUINS_TREE_WALL = 'ZTtw'
        constant integer SB_RUINS_CANOPY_TREE = 'ZTtc'
        constant integer SB_UNDERGROUND_TREE_WALL = 'GTsh'
        constant integer SB_VILLAGE_TREE_WALL = 'VTlt'
    
    //************ ITEMS ************
        constant integer SB_ITEM_PATHING_CHECKER = 'I000'
    
    //************ LIGHTNING ************
        constant string SB_LIGHTNING_LIFE_DRAIN = "DRAL"
        constant string SB_LIGHTNING_MANA_FLARE = "MFPB"
        constant string SB_LIGHTNING_MYSTIC_CHAIN = "MYCH"
    
    //************ WEATHER ************
        constant integer SB_WEATHER_NORTHREND_BLIZZARD = 'SNbs'
    
    //************ ORDERS ************
        constant integer SB_ORDER_ACTIVATE_MANA_BATTERY = 852177
        constant integer SB_ORDER_DEACTIVATE_MANA_BATTERY = 852178
        constant integer SB_ORDER_AMBUSH = 852131
        constant integer SB_ORDER_ARMY_TOGGLE_ADD = 852055
        constant integer SB_ORDER_ARMY_TOGGLE_REMOVE = 852055
        constant integer SB_ORDER_ARMY_TOGGLE_UNADD = 852056
        constant integer SB_ORDER_ARMY_TOGGLE_UNREMOVE = 852056
        constant integer SB_ORDER_ATTACK = 851983
        constant integer SB_ORDER_CANCEL = 851976
        constant integer SB_ORDER_DEFEND_ON = 852055
        constant integer SB_ORDER_DEFEND_OFF = 852056
        constant integer SB_ORDER_HARVEST = 852018
        constant integer SB_ORDER_HOLD_POSITION = 851993
        constant integer SB_ORDER_MIND_VISION_AOE = 852588
        constant integer SB_ORDER_RALLY_SMART = 851970
        constant integer SB_ORDER_REPAIR = 852024
        constant integer SB_ORDER_RESUME_HARVESTING = 852017
        constant integer SB_ORDER_SMART = 851971
        constant integer SB_ORDER_STOP = 851972
        constant integer SB_ORDER_STUNNED = 851973
        constant integer SB_ORDER_WISH = 852066
    endglobals

library Vectors

    struct vec3
        real x = 0.0
        real y = 0.0
        real z = 0.0

        static method create takes real x, real y, real z returns vec3
            local vec3 v = vec3.allocate()
            set v.x = x
            set v.y = y
            set v.z = z
            return v
        endmethod

        // Copy another vector's values to this one
        method copy takes vec3 other returns vec3
            set x = other.x
            set y = other.y
            set z = other.z
            return this
        endmethod

        // Creates a new vector by duplicating this vector's value
        method dupe takes nothing returns vec3
            return vec3.create(x, y, z)
        endmethod

        method setAll takes real x, real y, real z returns vec3
            set this.x = x
            set this.y = y
            set this.z = z
            return this
        endmethod

        method setX takes real value returns vec3
            set x = value
            return this
        endmethod

        method setY takes real value returns vec3
            set y = value
            return this
        endmethod

        method setZ takes real value returns vec3
            set z = value
            return this
        endmethod

        method addX takes real value returns vec3
            set this.x = this.x + value
            return this
        endmethod

        method addY takes real value returns vec3
            set this.y = this.y + value
            return this
        endmethod

        method addZ takes real value returns vec3
            set this.z = this.z + value
            return this
        endmethod

        method sqrMag takes nothing returns real
            return (x * x) + (y * y) + (z * z)
        endmethod

        method mag takes nothing returns real
            return SquareRoot(sqrMag())
        endmethod

        method normalize takes nothing returns vec3
            local real len = mag()
            set x = x / len
            set y = y / len
            set z = z / len
            return this
        endmethod

        method add takes vec3 other returns vec3
            set x = x + other.x
            set y = y + other.y
            set z = z + other.z
            return this
        endmethod

        method sub takes vec3 other returns vec3
            set x = x - other.x
            set y = y - other.y
            set z = z - other.z
            return this
        endmethod

        method multiply takes real value returns vec3
            set x = x * value
            set y = y * value
            set z = z * value
            return this
        endmethod

        method equals takes vec3 other returns boolean
            return x == other.x and y == other.y and z == other.z
        endmethod

        method toString takes nothing returns string
            return "(" + R2S(x) + ", " + R2S(y) + ", " + R2S(z) + ")"
        endmethod

    endstruct

    function VecDivideA takes vec3 dividend, real divisor returns vec3
        set dividend.x = dividend.x / divisor
        set dividend.y = dividend.y / divisor
        set dividend.z = dividend.z / divisor
        return dividend
    endfunction

    function VecDivideB takes real dividend, vec3 divisor returns vec3
        set divisor.x = dividend / divisor.x
        set divisor.y = dividend / divisor.y
        set divisor.z = dividend / divisor.z
        return divisor
    endfunction

    // Returns a new Vec3
    function VecMultiply takes vec3 v, real multiplier returns vec3
        return vec3.create(v.x * multiplier, v.y * multiplier, v.z * multiplier)
    endfunction

    function VecAdd takes vec3 v1, vec3 v2 returns vec3
        return vec3.create(v1.x + v2.x, v1.y + v2.y, v1.z + v2.z)
    endfunction

    function VecSub takes vec3 v1, vec3 v2 returns vec3
        return vec3.create(v1.x - v2.x, v1.y - v2.y, v1.z - v2.z)
    endfunction

    function VecNormalize takes vec3 v returns vec3
        local real len = v.mag()
        return vec3.create(v.x / len, v.y / len, v.z / len)
    endfunction

    function VecMoveTowards takes vec3 source, vec3 target, real maxDelta returns vec3
        local vec3 diff = vec3.create(target.x - source.x, target.y - source.y, target.z - source.z)
        local real dist = RMinBJ(diff.mag(), maxDelta)
        local vec3 translation = VecMultiply(diff.normalize(), dist)

        call diff.destroy()
        return translation.add(source)
    endfunction

    function VecSqrDistance takes vec3 v1, vec3 v2 returns real
        local vec3 diff = VecSub(v2, v1)
        local real result = diff.sqrMag()
        call diff.destroy()
        return result
    endfunction

    function VecDistance takes vec3 v1, vec3 v2 returns real
        local vec3 diff = VecSub(v2, v1)
        local real result = diff.mag()
        call diff.destroy()
        return result
    endfunction

    function VecYawRad takes vec3 v returns real
        return Atan2(v.y, v.x)
    endfunction

    function VecPitchRad takes vec3 v returns real
        return -Asin(v.z)
    endfunction

    function VecAngle takes vec3 v returns real
        return Rad2Deg(VecYawRad(v))
    endfunction

    function VecPitchDeg takes vec3 v returns real
        return Rad2Deg(VecPitchRad(v))
    endfunction

    function VecRotateZ takes vec3 point, real angle returns vec3
        local real radian = Deg2Rad(angle)
        local real ca = Cos(radian)
        local real sa = Sin(radian)
        local real x = (point.x * ca) - (point.y * sa)
        local real y = (point.x * sa) + (point.y * ca)
        return vec3.create(x, y, point.z)
    endfunction

    function YawBetweenVecsRad takes vec3 v1, vec3 v2 returns real
        local vec3 diff = VecSub(v2, v1)
        local vec3 normal = VecNormalize(diff)
        local real result = VecYawRad(normal)
        call diff.destroy()
        call normal.destroy()
        return result
    endfunction

    function PitchBetweenVecsRad takes vec3 v1, vec3 v2 returns real
        local vec3 diff = VecSub(v2, v1)
        local vec3 normal = VecNormalize(diff)
        local real result = VecPitchRad(normal)
        call diff.destroy()
        call normal.destroy()
        return result
    endfunction

    function VecDirection takes real yawInRadians, real pitchInRadians returns vec3
        return vec3.create(Cos(yawInRadians) * Cos(pitchInRadians), Sin(yawInRadians) * Cos(pitchInRadians), Sin(pitchInRadians))
    endfunction

    function GetUnitVec takes unit whichUnit returns vec3
        return vec3.create(GetUnitX(whichUnit), GetUnitY(whichUnit), BlzGetUnitZ(whichUnit) + GetUnitFlyHeight(whichUnit))
    endfunction

    function GetLocVec takes location loc returns vec3
        return vec3.create(GetLocationX(loc), GetLocationY(loc), GetLocationZ(loc))
    endfunction

    function GetEffectVec takes effect sfx returns vec3
        return vec3.create(BlzGetLocalSpecialEffectX(sfx),BlzGetLocalSpecialEffectY(sfx), BlzGetLocalSpecialEffectZ(sfx))
    endfunction

endlibrary

//-------------------------------------------------
library Color
    struct Color
        integer r = 0
        integer g = 0
        integer b = 0
        integer a = 0
    endstruct

    function CreateColor takes integer r, integer g, integer b, integer a returns Color
        local Color c = Color.create()
        set c.r = r
        set c.g = g
        set c.b = b
        set c.a = a
        return c
    endfunction

    function RCreateColor takes real r, real g, real b, real a returns Color
        return CreateColor(R2I(r * 255), R2I(g * 255), R2I(b * 255), R2I(a * 255))
    endfunction

    function ColorGetR takes Color c returns real
        return c.r / 255.0
    endfunction

    function ColorGetG takes Color c returns real
        return c.g / 255.0
    endfunction

    function ColorGetB takes Color c returns real
        return c.b / 255.0
    endfunction

    function ColorGetA takes Color c returns real
        return c.a / 255.0
    endfunction

    function GetUnitVertexColor takes unit whichUnit returns Color
        local integer r = BlzGetUnitIntegerField(whichUnit, UNIT_IF_TINTING_COLOR_RED)
        local integer g = BlzGetUnitIntegerField(whichUnit, UNIT_IF_TINTING_COLOR_GREEN)
        local integer b = BlzGetUnitIntegerField(whichUnit, UNIT_IF_TINTING_COLOR_BLUE)
        local integer a = BlzGetUnitIntegerField(whichUnit, UNIT_IF_TINTING_COLOR_ALPHA)
        return CreateColor(r, g, b, a)
    endfunction

    function ColorToString takes Color c returns string
        return "RGBA(" + I2S(c.r) + ", " + I2S(c.g) + ", " + I2S(c.b) + ", " + I2S(c.a) + ")"
    endfunction

endlibrary

//-------------------------------------------------
library PlayerColors initializer Init requires Color
    globals
        Color array PLAYER_COLORS
    endglobals

    function PlayerColorToColor takes playercolor pc returns Color
        return PLAYER_COLORS[GetHandleId(pc)]
    endfunction

    function PlayerColor takes player p returns Color
        local playercolor pc = GetPlayerColor(p)
        return PlayerColorToColor(pc)
    endfunction

    function Init takes nothing returns nothing
        set PLAYER_COLORS[0] = CreateColor(255, 3, 3, 255)      // Red
        set PLAYER_COLORS[1] = CreateColor(0, 66, 255, 255)     // Blue
        set PLAYER_COLORS[2] = CreateColor(27, 231, 186, 255)   // Teal
        set PLAYER_COLORS[3] = CreateColor(85, 0, 129, 255)     // Purple
        set PLAYER_COLORS[4] = CreateColor(254, 252, 0, 255)    // Yellow
        set PLAYER_COLORS[5] = CreateColor(254, 137, 13, 255)   // Orange
        set PLAYER_COLORS[6] = CreateColor(33, 191, 0, 255)     // Green
        set PLAYER_COLORS[7] = CreateColor(228, 92, 175, 255)     // Pink
        set PLAYER_COLORS[8] = CreateColor(148, 150, 150, 255)     // Gray
        set PLAYER_COLORS[9] = CreateColor(126, 191, 241, 255)     // Light Blue
        set PLAYER_COLORS[10] = CreateColor(16, 98, 71, 255)     // Dark Green
        set PLAYER_COLORS[11] = CreateColor(79, 43, 5, 255)     // Brown
        set PLAYER_COLORS[12] = CreateColor(156, 0, 0, 255)     // Maroon
        set PLAYER_COLORS[13] = CreateColor(0, 0, 195, 255)     // Navy
        set PLAYER_COLORS[14] = CreateColor(0, 235, 255, 255)     // Turquoise
        set PLAYER_COLORS[15] = CreateColor(189, 0, 255, 255)     // Violet
        set PLAYER_COLORS[16] = CreateColor(236, 206, 135, 255)     // Wheat
        set PLAYER_COLORS[17] = CreateColor(247, 165, 139, 255)     // Peach
        set PLAYER_COLORS[18] = CreateColor(191, 255, 129, 255)     // Mint
        set PLAYER_COLORS[19] = CreateColor(219, 184, 235, 255)     // Lavendar
        set PLAYER_COLORS[20] = CreateColor(79, 80, 85, 255)     // Coal
        set PLAYER_COLORS[21] = CreateColor(236, 240, 255, 255)     // Snow
        set PLAYER_COLORS[22] = CreateColor(0, 120, 30, 255)     // Emerald
        set PLAYER_COLORS[23] = CreateColor(165, 111, 52, 255)     // Peanut
        set PLAYER_COLORS[24] = CreateColor(46, 45, 46, 255)     // Black
    endfunction
endlibrary

function interface ConditionFunc takes nothing returns boolean
function interface ActionFunc takes nothing returns nothing

function interface UnitFunc takes unit whichUnit returns nothing
function interface EffectFunc takes effect whichEffect returns nothing
function interface IntFunc takes integer i returns nothing

function interface UnitCondition takes unit whichUnit returns boolean
function interface IntCondition takes integer input returns boolean

function interface UnitComparer takes unit u1, unit u2 returns integer

struct RecallInstance
    unit caster = null
    real time = 0.0
    group units = null
    effect casterEffect = null
    ubersplat casterSplat = null
endstruct

library LinkedList

    function interface ILinkedListPredicate takes ILinkedListNode node returns boolean

    interface ILinkedListNode
        ILinkedListNode next = 0
        ILinkedListNode prev = 0
    endinterface

    interface ILinkedList
        ILinkedListNode head = 0
        ILinkedListNode tail = 0
        integer count = 0
    endinterface

    function LinkedListGetFirst takes ILinkedList list returns ILinkedListNode
        return list.head
    endfunction

    function LinkedListGetLast takes ILinkedList list returns ILinkedListNode
        return list.tail
    endfunction

    function LinkedListGetAtIndex takes ILinkedList list, integer index returns ILinkedListNode
        local integer i = 1
        local ILinkedListNode node = LinkedListGetFirst(list)
        loop
            exitwhen i >= index or i >= list.count
                set node = node.next
            set i = i + 1
        endloop
        return node
    endfunction

    function LinkedListAddFirst takes ILinkedList list, ILinkedListNode node returns nothing
        if (node != 0) then
            if (list.head != 0) then
                set list.head.prev = node
                set node.next = list.head
            endif

            set list.head = node
            set list.count = list.count + 1
        endif
    endfunction

    function LinkedListAddLast takes ILinkedList list, ILinkedListNode node returns nothing
        if (node != 0) then
            if (list.head == 0) then
                set list.head = node
                set list.tail = node
            elseif (list.tail != 0) then
                set node.prev = list.tail
                set list.tail.next = node
            endif

            set list.tail = node
            set list.count = list.count + 1
        endif
    endfunction

    function LinkedListRemoveFirst takes ILinkedList list returns ILinkedListNode
        local ILinkedListNode removed = list.head
        if (removed != 0) then
            if (list.tail == removed) then
                set list.tail = 0
            endif
            set list.head = removed.next
            if (list.head != 0) then
                set list.head.prev = 0
            endif
            set removed.next = 0
            set list.count = list.count - 1
        endif
        return removed
    endfunction

    function LinkedListRemoveLast takes ILinkedList list returns ILinkedListNode
        local ILinkedListNode removed = list.tail
        if (removed != 0) then
            if (list.head == removed) then
                set list.head = 0
            endif
            set list.tail = removed.prev
            if (list.tail != 0) then
                set list.tail.next = 0
            endif
            set removed.prev = 0
            set list.count = list.count - 1
        endif
        return removed
    endfunction

    function LinkedListRemove takes ILinkedList list, ILinkedListNode remove returns boolean
        if (remove != 0) then
            if (remove == list.head) then
                return LinkedListRemoveFirst(list) != 0
            elseif (remove == list.tail) then
                return LinkedListRemoveLast(list) != 0
            else
                set remove.prev.next = remove.next
                set remove.next.prev = remove.prev
                set remove.next = 0
                set remove.prev = 0
                set list.count = list.count - 1
                return true
            endif
        endif
        return false
    endfunction

    function LinkedListDestroyFirst takes ILinkedList list returns nothing
        local ILinkedListNode node = LinkedListRemoveFirst(list)
        if (node != 0) then
            call node.destroy()
        endif
    endfunction

    function LinkedListDestroyLast takes ILinkedList list returns nothing
        local ILinkedListNode node = LinkedListRemoveLast(list)
        if (node != 0) then
            call node.destroy()
        endif
    endfunction

    function LinkedListDestroyNode takes ILinkedList list, ILinkedListNode remove returns boolean
        local boolean result = LinkedListRemove(list, remove)
        if (result) then
            call remove.destroy()
        endif
        return result
    endfunction

    function LinkedListFind takes ILinkedList list, ILinkedListPredicate predicate returns ILinkedListNode
        local ILinkedListNode node = LinkedListGetFirst(list)
        loop
            exitwhen node == 0
            if (predicate.evaluate(node)) then
                return node
            endif
            set node = node.next
        endloop
        return 0
    endfunction

    function DestroyLinkedList takes ILinkedList list returns nothing
        local ILinkedListNode node = 0
        loop
            exitwhen list.count <= 0
            set node = LinkedListRemoveFirst(node)
            call node.destroy()
        endloop
        call list.destroy()
    endfunction

    function LinkedListToString takes ILinkedList list returns string
        local string s = ""
        local ILinkedListNode node = list.head
        loop
            exitwhen node == 0
            set s = s + I2S(node) + ","
            set node = node.next
        endloop
        return s
    endfunction


    //------------------------------------------------------------
    //                      LinkedList_Int
    //------------------------------------------------------------
    struct LinkedListNode_Int extends ILinkedListNode
        integer value
    endstruct

    struct LinkedList_Int extends ILinkedList
    endstruct

    function CreateLinkedList_Int takes nothing returns LinkedList_Int
        return LinkedList_Int.create()
    endfunction

    function LinkedListAddFirstInt takes LinkedList_Int list, integer i returns LinkedListNode_Int
        local LinkedListNode_Int node = LinkedListNode_Int.create()
        set node.value = i
        call LinkedListAddFirst(list, node)
        return node
    endfunction

    function LinkedListAddLastInt takes LinkedList_Int list, integer i returns LinkedListNode_Int
        local LinkedListNode_Int node = LinkedListNode_Int.create()
        set node.value = i
        call LinkedListAddLast(list, node)
        return node
    endfunction

    function LinkedListFindInt takes LinkedList_Int list, integer value returns LinkedListNode_Int
        local LinkedListNode_Int node = LinkedListGetFirst(list)
        loop
            exitwhen node == 0
            if (node.value == value) then
                return node
            endif
            set node = node.next
        endloop
        return 0
    endfunction

endlibrary

globals
    constant integer ORDER_TYPE_IMMEDIATE = 0
    constant integer ORDER_TYPE_TARGET = 1
    constant integer ORDER_TYPE_POINT = 2
endglobals

struct SavedOrder
    unit whichUnit = null
    integer orderId = 0
    integer orderType = ORDER_TYPE_IMMEDIATE
    real targetX = 0.0
    real targetY = 0.0
    widget targetWidget = null
endstruct

function CreateSavedPointOrder takes integer orderId, real x, real y returns SavedOrder
    local SavedOrder order = SavedOrder.create()
    set order.orderId = orderId
    set order.targetX = x
    set order.targetY = y
    set order.orderType = ORDER_TYPE_POINT
    return order
endfunction

function CreateSavedTargetOrder takes integer orderId, widget target returns SavedOrder
    local SavedOrder order = SavedOrder.create()
    set order.orderId = orderId
    set order.targetWidget = target
    set order.orderType = ORDER_TYPE_TARGET
    return order
endfunction

function CreateSavedImmedateOrder takes integer orderId returns SavedOrder
    local SavedOrder order = SavedOrder.create()
    set order.orderId = orderId
    return order
endfunction

function CreateSavedOrder takes integer orderId, widget targetWidget, real targetX, real targetY returns SavedOrder
    if (targetWidget != null) then
        return CreateSavedTargetOrder(orderId, targetWidget)
    elseif (targetX != 0.0 and targetY != 0.0) then
        return CreateSavedPointOrder(orderId, targetX, targetY)
    else
        return CreateSavedImmedateOrder(orderId)
    endif
endfunction

function GetSavedOrderTargetX takes SavedOrder so returns real
    if (so.orderType == ORDER_TYPE_POINT) then
        return so.targetX
    elseif (so.orderType == ORDER_TYPE_TARGET) then
        return GetWidgetX(so.targetWidget)
    else
        return 0.0
    endif
endfunction

function GetSavedOrderTargetY takes SavedOrder so returns real
    if (so.orderType == ORDER_TYPE_POINT) then
        return so.targetY
    elseif (so.orderType == ORDER_TYPE_TARGET) then
        return GetWidgetY(so.targetWidget)
    else
        return 0.0
    endif
endfunction

function IssueSavedOrder takes unit whichUnit, SavedOrder order returns boolean
    if (order.orderType == ORDER_TYPE_IMMEDIATE) then
        return IssueImmediateOrderById(whichUnit, order.orderId)
    elseif (order.orderType == ORDER_TYPE_TARGET) then
        return IssueTargetOrderById(whichUnit, order.orderId, order.targetWidget)
    elseif (order.orderType == ORDER_TYPE_POINT) then
        return IssuePointOrderById(whichUnit, order.orderId, order.targetX, order.targetY)
    endif
    return false
endfunction

function IssueSavedOrderDelayed takes unit whichUnit, SavedOrder order, real delay returns nothing
    call PolledWait(delay)
    call IssueSavedOrder(whichUnit, order)
endfunction

function IsOrderEqual takes SavedOrder order, integer orderId, widget targetWidget, real targetX, real targetY returns boolean
    if (order.orderId != orderId) then
        return false
    elseif (order.orderType == ORDER_TYPE_TARGET and targetWidget != order.targetWidget) then
        return false
    elseif (order.orderType == ORDER_TYPE_POINT and (targetX != order.targetX or targetY != order.targetY)) then
        return false
    endif
    return true
endfunction

function Write takes string message returns nothing
    call DisplayTextToForce(GetPlayersAll(), message)
endfunction

function WriteReal takes string label, real r returns nothing
    call Write(label + R2S(r))
endfunction

function WriteInt takes string label, integer i returns nothing
    call Write(label + I2S(i))
endfunction

function WriteLoc takes string label, location l returns nothing
    call Write(label + "(" + R2S(GetLocationX(l)) + ", " + R2S(GetLocationY(l)) + ")")
endfunction

function DisplayError takes player whichPlayer, string message returns nothing
    local sound snd = CreateSound("Sound\\Interface\\Error.flac", false, false, true, 12700, 12700, "DefaultEAXON")
    call DisplayTextToPlayer(whichPlayer, 0, 0, "|cffffcc00" + message + "|r")
    if (GetLocalPlayer() == whichPlayer) then
        call StartSound(snd)
    endif
    call KillSoundWhenDone(snd)
endfunction

function ClearUnitTrainingQueue takes unit whichUnit returns nothing
    call IssueImmediateOrderById(whichUnit, 851976)
    call IssueImmediateOrderById(whichUnit, 851976)
    call IssueImmediateOrderById(whichUnit, 851976)
    call IssueImmediateOrderById(whichUnit, 851976)
    call IssueImmediateOrderById(whichUnit, 851976)
    call IssueImmediateOrderById(whichUnit, 851976)
    call IssueImmediateOrderById(whichUnit, 851976)
endfunction

function GetFormattedTimeString takes real time returns string
    local integer seconds = R2I(ModuloReal(time, 60.0))
    local integer minutes = R2I(ModuloReal(time / 60.0, 60.0))
    local integer hours = R2I(time / 3600.00)
    local string timeFormat = ""

    if (hours > 0) then
        set timeFormat = timeFormat + I2S(hours) + ":"
        if (minutes < 10) then
            set timeFormat = timeFormat + "0"
        endif
    endif

    set timeFormat = timeFormat + I2S(minutes) + ":"
    if (seconds < 10) then
        set timeFormat = timeFormat + "0"
    endif

    set timeFormat = timeFormat + I2S(seconds)

    return timeFormat
endfunction

function SetUnitPathingSB takes unit whichUnit, boolean flag returns nothing
    if (flag and GetUnitAbilityLevel(whichUnit, SB_NO_COLLISION) > 0) then
        return
    endif
    call SetUnitPathing(whichUnit, flag)
endfunction

function CreateNUnitsAtLocSB takes integer count, integer unitId, player whichPlayer, location loc, real face returns group
    local group created = CreateGroup()
    loop
        set count = count - 1
        exitwhen count < 0
        call GroupAddUnit(created, CreateUnitAtLoc(whichPlayer, unitId, loc, face))
    endloop
    return created
endfunction

function CreateNUnitsAtLocFacingLocSB takes integer count, integer unitId, player whichPlayer, location loc, location lookAt returns group
    return CreateNUnitsAtLocSB(count, unitId, whichPlayer, loc, AngleBetweenPoints(loc, lookAt))
endfunction

function GetMissileHeight takes real arc, real d, real x returns real
    if (d == 0.0) then
        return 0.0
    endif
    return (4 * arc) * (d - x) * (x / d)
endfunction

function IsOrder takes integer orderId, string order returns boolean
    return orderId == String2OrderIdBJ(order)
endfunction

function HashTableAddInteger takes hashtable ht, integer parentKey, integer childKey, integer add, boolean removeOnZero returns integer
    local integer value = LoadInteger(ht, parentKey, childKey)
    set value = value + add
    if (value <= 0 and removeOnZero) then
        call RemoveSavedInteger(ht, parentKey, childKey)
    else
        call SaveInteger(ht, parentKey, childKey, value)
    endif
    return value
endfunction

function HashTableAddReal takes hashtable ht, integer parentKey, integer childKey, real add, boolean removeOnZero returns real
    local real value = LoadReal(ht, parentKey, childKey)
    set value = value + add
    if (value <= 0.0 and removeOnZero) then
        call RemoveSavedReal(ht, parentKey, childKey)
    else
        call SaveReal(ht, parentKey, childKey, value)
    endif
    return value
endfunction

library MathUtil

    function RMax takes real a, real b returns real 
        if (b > a) then
            return b
        else
            return a
        endif
    endfunction
    
    function RMin takes real a, real b returns real 
        if (b < a) then
            return b
        else
            return a
        endif
    endfunction
    
    function IMax takes integer a, integer b returns integer
        if (b > a) then
            return b
        else
            return a
        endif
    endfunction
    
    function IMin takes integer a, integer b returns integer
        if (b < a) then
            return b
        else
            return a
        endif
    endfunction
    
    function DistanceBetweenPointsXY takes real x1, real y1, real x2, real y2 returns real
        local real dx = x2 - x1
        local real dy = y2 - y1
        return SquareRoot(dx * dx + dy * dy)
    endfunction
    
    function DistanceBetweenUnits takes unit unit1, unit unit2 returns real
        local real dx = GetUnitX(unit2) - GetUnitX(unit1)
        local real dy = GetUnitY(unit2) - GetUnitY(unit1)
        return SquareRoot(dx * dx + dy * dy)
    endfunction
    
    function DistanceBetweenUnitAndPoint takes unit whichUnit, real x, real y returns real
        return DistanceBetweenPointsXY(GetUnitX(whichUnit), GetUnitY(whichUnit), x, y)
    endfunction
    
    function SqrDistanceBetweenPointsXY takes real x1, real y1, real x2, real y2 returns real
        local real dx = x2 - x1
        local real dy = y2 - y1
        return dx * dx + dy * dy
    endfunction
    
    function SqrDistanceBetweenPoints takes location loc1, location loc2 returns real
        return SqrDistanceBetweenPointsXY(GetLocationX(loc1), GetLocationY(loc1), GetLocationX(loc2), GetLocationY(loc2))
    endfunction
    
    function SqrDistanceBetweenUnits takes unit unit1, unit unit2 returns real
        return SqrDistanceBetweenPointsXY(GetUnitX(unit1), GetUnitY(unit1), GetUnitX(unit2), GetUnitY(unit2))
    endfunction
    
    function SqrDistanceFromUnitToPoint takes unit whichUnit, real x, real y returns real
        return SqrDistanceBetweenPointsXY(GetUnitX(whichUnit), GetUnitY(whichUnit), x, y)
    endfunction
    
    function DistanceFromUnitToPoint takes unit whichUnit, real x, real y returns real
        local real sqrDist = SqrDistanceFromUnitToPoint(whichUnit, x, y)
        return SquareRoot(sqrDist)
    endfunction
    
    function DistanceFromUnitToDestructable takes unit whichUnit, destructable whichDestructable returns real
        return DistanceBetweenPointsXY(GetUnitX(whichUnit), GetUnitY(whichUnit), GetDestructableX(whichDestructable), GetDestructableY(whichDestructable))
    endfunction
    
    function AngleBetweenUnits takes unit unit1, unit unit2 returns real
        return bj_RADTODEG * Atan2(GetUnitY(unit2) - GetUnitY(unit1), GetUnitX(unit2) - GetUnitX(unit1))
    endfunction
    
    function AngleBetweenPointsXY takes real x1, real y1, real x2, real y2 returns real
        return bj_RADTODEG * Atan2(y2 - y1, x2 - x1)
    endfunction
    
    function PolarProjectionX takes real sourceX, real dist, real angle returns real
        return sourceX + dist * Cos(angle * bj_DEGTORAD)
    endfunction
    
    function PolarProjectionY takes real sourceY, real dist, real angle returns real
        return sourceY + dist * Sin(angle * bj_DEGTORAD)
    endfunction
    
    function RandomRadius takes real center, real radius returns real
        local real offset = GetRandomReal(-radius, radius)
        return center + offset
    endfunction
    
    function RandomPointInCircle takes real centerX, real centerY, real radius returns location
        return Location(RandomRadius(centerX, radius), RandomRadius(centerY, radius))
    endfunction
    
    function RandomPointInCircleLoc takes location center, real radius returns location
        return Location(RandomRadius(GetLocationX(center), radius), RandomRadius(GetLocationY(center), radius))
    endfunction
    
    function RDefaultIfZero takes real maybeZero, real value, real default returns real
        if (maybeZero == 0.0) then
            return default
        endif
        return value
    endfunction
    
    function Ceil takes real val returns real
        local integer int = R2I(val)
        if (val == int) then
            return val
        elseif (val > 0.0) then
            return I2R(int + 1)
        endif
        return I2R(int)
    endfunction
    
    function CeilToInt takes real val returns integer
        local integer int = R2I(val)
        if (val != int and val > 0.0) then
            return int + 1
        endif
        return int
    endfunction
    
    function DBZ takes real dividend, real divisor, real defaultValue returns real
        if (divisor == 0.0) then
            return defaultValue
        endif
        return dividend / divisor
    endfunction
    
    function RClamp takes real value, real min, real max returns real
        return RMaxBJ(RMinBJ(value, max), min)
    endfunction
    
endlibrary

function IsPlayingPlayer takes player whichPlayer, boolean usersOnly returns boolean
    return GetPlayerSlotState(whichPlayer) == PLAYER_SLOT_STATE_PLAYING and (not usersOnly or GetPlayerController(whichPlayer) == MAP_CONTROL_USER)
endfunction

function AddPlayerState takes player p, playerstate whichState, integer value returns nothing
    call SetPlayerState(p, whichState, GetPlayerState(p, whichState) + value)
endfunction

function GetPlayingPlayers takes boolean usersOnly, boolean includeLeft, boolean includeNeutrals returns force
    local force players = CreateForce()
    local player pickedPlayer = null
    local integer pIndex = 0
    local integer pCount = GetBJMaxPlayers()
    
    if (includeNeutrals) then
        set pCount = pCount + 4
    endif

    loop
        exitwhen pIndex >= pCount
        set pickedPlayer = Player(pIndex)
        if (usersOnly and GetPlayerController(pickedPlayer) != MAP_CONTROL_USER) then
	    // Do nothing
        elseif (IsPlayerSlotState(pickedPlayer, PLAYER_SLOT_STATE_PLAYING)) then
            call ForceAddPlayer(players, pickedPlayer)
        elseif (includeNeutrals and (GetPlayerController(pickedPlayer) == MAP_CONTROL_NEUTRAL or GetPlayerController(pickedPlayer) == MAP_CONTROL_CREEP)) then
            call ForceAddPlayer(players, pickedPlayer)
        elseif (includeLeft and IsPlayerSlotState(pickedPlayer, PLAYER_SLOT_STATE_LEFT)) then
            call ForceAddPlayer(players, pickedPlayer)
        endif
        set pIndex = pIndex + 1
    endloop

    return players
endfunction

function GetObservers takes nothing returns force
    local force f = CreateForce()
    local integer i = 0
    loop
        exitwhen i >= bj_MAX_PLAYERS
        if (IsPlayerObserver(Player(i))) then
            call ForceAddPlayer(f, Player(i))
        endif
        set i = i + 1
    endloop
    return f
endfunction

function GetPlayerNameColored takes player p returns string
    local integer playerNumber = GetConvertedPlayerId(p)
    return udg_String_PlayerColors[playerNumber] + GetPlayerName(p) + "|r"
endfunction

function PlayerHasTech takes player p, integer techId returns boolean
    return GetPlayerTechCount(p, techId, true) > 0
endfunction

function SpellbringerFilter takes nothing returns boolean
    local unit filter = GetFilterUnit()
    if (not IsUnitType(filter, UNIT_TYPE_HERO)) then
        return false
    elseif (not IsUnitType(filter, UNIT_TYPE_STRUCTURE)) then
        return false
    endif
    return true
endfunction

function GetPlayerSpellbringers takes player p returns group
    return GetUnitsOfPlayerMatching(p, Condition(function SpellbringerFilter))
endfunction

function CountSpellbringersForPlayer takes player p returns integer
    local integer raceNumber = 1
    local integer count = 0
    loop
        exitwhen raceNumber > udg_Int_RaceCount
        set count = count + CountLivingPlayerUnitsOfTypeId(udg_UnitType_Spellbringer[raceNumber], p)
        set raceNumber = raceNumber + 1
    endloop
    return count
endfunction

function GetSpellbringerLevelByTech takes player p, integer raceNumber returns integer
    if (PlayerHasTech(p, udg_TechType_Level3SBSpell[raceNumber])) then
        return 3
    elseif (PlayerHasTech(p, udg_TechType_Level2SBSpell[raceNumber])) then
        return 2
    else
        return 1
    endif
endfunction

function GetAllPlayersExcept takes player whichPlayer returns force
    local force players = CreateForce()
    local player p = null
    local integer playerIndex = 0

    loop
        exitwhen playerIndex >= bj_MAX_PLAYERS
        set p = Player(playerIndex)
        if (p != whichPlayer) then
            call ForceAddPlayer(players, p)
        endif
        set playerIndex = playerIndex + 1
    endloop
    return players
endfunction

function GetPlayersSelectingUnit takes unit whichUnit returns force
    local force result = CreateForce()
    local integer i = 0
    loop
        exitwhen i >= bj_MAX_PLAYERS
        if (IsUnitSelected(whichUnit, Player(i))) then
            call ForceAddPlayer(result, Player(i))
        endif
        set i = i + 1
    endloop
    return result
endfunction

function TransferUnitSelection takes unit sourceUnit, unit targetUnit returns nothing
    local integer i = 0
    local player p = null
    loop
        exitwhen i >= bj_MAX_PLAYERS
        set p = Player(i)
        if (IsUnitSelected(sourceUnit, p)) then
            call SelectUnitRemoveForPlayer(sourceUnit, p)
            call SelectUnitAddForPlayer(targetUnit, p)
        endif
        set i = i + 1
    endloop
endfunction

globals
    constant key KEY_TARGETED_AS
endglobals

function GetUnitAbilityIntegerLevelField takes unit whichUnit, integer abilityId, abilityintegerlevelfield whichField returns integer
    return BlzGetAbilityIntegerLevelField(BlzGetUnitAbility(whichUnit, abilityId), whichField, GetUnitAbilityLevel(whichUnit, abilityId) - 1)
endfunction

function GetUnitAbilityRealLevelField takes unit whichUnit, integer abilityId, abilityreallevelfield whichField returns real
    return BlzGetAbilityRealLevelField(BlzGetUnitAbility(whichUnit, abilityId), whichField, GetUnitAbilityLevel(whichUnit, abilityId) - 1)
endfunction

function GetUnitAbilityStringLevelField takes unit whichUnit, integer abilityId, abilitystringlevelfield whichField returns string
    return BlzGetAbilityStringLevelField(BlzGetUnitAbility(whichUnit, abilityId), whichField, GetUnitAbilityLevel(whichUnit, abilityId) - 1)
endfunction

function GetUnitAbilityIntegerField takes unit whichUnit, integer abilityId, abilityintegerfield whichfield returns integer
    return BlzGetAbilityIntegerField(BlzGetUnitAbility(whichUnit, abilityId), whichfield)
endfunction

function GetUnitAbilityRealField takes unit whichUnit, integer abilityId, abilityrealfield whichfield returns real
    return BlzGetAbilityRealField(BlzGetUnitAbility(whichUnit, abilityId), whichfield)
endfunction

function GetUnitAbilityStringField takes unit whichUnit, integer abilityId, abilitystringfield whichField returns string
    return BlzGetAbilityStringField(BlzGetUnitAbility(whichUnit, abilityId), whichField)
endfunction

function SetUnitAbilityBooleanField takes unit whichUnit, integer abilityId, abilitybooleanfield whichfield, boolean value returns boolean
    return BlzSetAbilityBooleanField(BlzGetUnitAbility(whichUnit, abilityId), whichfield, value)
endfunction

function SetUnitAbilityIntegerField takes unit whichUnit, integer abilityId, abilityintegerfield whichField, integer value returns nothing
    call BlzSetAbilityIntegerField(BlzGetUnitAbility(whichUnit, abilityId), whichField, value)
endfunction

function SetUnitAbilityRealLevelField takes unit whichUnit, integer abilityId, abilityreallevelfield whichField, real value returns nothing
    call BlzSetAbilityRealLevelField(BlzGetUnitAbility(whichUnit, abilityId), whichField, GetUnitAbilityLevel(whichUnit, abilityId) - 1, value)
endfunction

function SetUnitAbilityIntegerLevelField takes unit whichUnit, integer abilityId, abilityintegerlevelfield whichField, integer value returns nothing
    call BlzSetAbilityIntegerLevelField(BlzGetUnitAbility(whichUnit, abilityId), whichField, GetUnitAbilityLevel(whichUnit, abilityId) - 1, value)
endfunction

function IsUnitWard takes unit whichUnit returns boolean
    local integer classification = BlzGetUnitIntegerField(whichUnit, UNIT_IF_UNIT_CLASSIFICATION)
    return (BlzBitAnd(classification, GetHandleId(UNIT_CATEGORY_WARD)) != 0)
endfunction

function IsUnitNonNeutralAlly takes unit whichUnit, player whichPlayer returns boolean
    local player unitOwner = GetOwningPlayer(whichUnit)
    return IsPlayerAlly(unitOwner, whichPlayer) and unitOwner != Player(PLAYER_NEUTRAL_PASSIVE)
endfunction

function IsUnitGoldHarvester takes unit whichUnit returns boolean
    if (GetUnitAbilityLevel(whichUnit, SB_HARVEST_GOLD_AND_LUMBER) > 0) then
        return true
    elseif (GetUnitAbilityLevel(whichUnit, SB_HARVEST_GOLD_ONLY) > 0) then
        return true
    elseif (GetUnitAbilityLevel(whichUnit, SB_HARVEST_ORDER_SUPER_PEASANT) > 0) then
        return true
    elseif (GetUnitAbilityLevel(whichUnit, SB_HARVEST_GOLD_AND_LUMBER_MAGIC) > 0) then
        return true
    else
        return false
    endif
endfunction

function UnitHasAbility takes unit whichUnit, integer abilityId returns boolean
    return GetUnitAbilityLevel(whichUnit, abilityId) > 0
endfunction

function IsZombieLike takes unit whichUnit returns boolean
    local integer unitType = GetUnitTypeId(whichUnit)
    return unitType == SB_ZOMBIE or unitType == SB_FLESHLESS_ZOMBIE or unitType == SB_FLESH_GOLEM
endfunction

function IsUnitAlive takes unit whichUnit returns boolean
    if (whichUnit != null) then
        return not IsUnitType(whichUnit, UNIT_TYPE_DEAD)
    endif
    return false
endfunction

function GetSpellbringerRace takes unit sb returns integer
    local integer raceNumber = 1
    loop
        exitwhen raceNumber > udg_Int_RaceCount
        if (GetUnitTypeId(sb) == udg_UnitType_Spellbringer[raceNumber]) then
            return raceNumber
        endif
        set raceNumber = raceNumber + 1
    endloop
    return -1
endfunction

function ChangeUnitState takes unit whichUnit, unitstate whichUnitState, real change returns nothing
    if (whichUnitState == UNIT_STATE_MAX_LIFE) then
        call BlzSetUnitMaxHP(whichUnit, BlzGetUnitMaxHP(whichUnit) + R2I(change))
    elseif (whichUnitState == UNIT_STATE_MAX_MANA) then
        call BlzSetUnitMaxMana(whichUnit, BlzGetUnitMaxMana(whichUnit) + R2I(change))
    else
        call SetUnitState(whichUnit, whichUnitState, GetUnitState(whichUnit, whichUnitState) + change)
    endif
endfunction

function GetUnitsMiningMine takes unit mine returns integer
    return LoadInteger(udg_HashTable_UnitInfo, GetHandleId(mine), StringHash("NUM MINERS"))
endfunction

function GetUnitMinWeaponDamage takes unit whichUnit, integer weaponIndex returns integer
    local integer base = BlzGetUnitWeaponIntegerField(whichUnit, UNIT_WEAPON_IF_ATTACK_DAMAGE_BASE, weaponIndex)
    local integer numDice = BlzGetUnitWeaponIntegerField(whichUnit, UNIT_WEAPON_IF_ATTACK_DAMAGE_NUMBER_OF_DICE, weaponIndex)
    return base + numDice
endfunction

function GetUnitMaxWeaponDamage takes unit whichUnit, integer weaponIndex returns integer
    local integer base = BlzGetUnitWeaponIntegerField(whichUnit, UNIT_WEAPON_IF_ATTACK_DAMAGE_BASE, weaponIndex)
    local integer numDice = BlzGetUnitWeaponIntegerField(whichUnit, UNIT_WEAPON_IF_ATTACK_DAMAGE_NUMBER_OF_DICE, weaponIndex)
    local integer diceSides = BlzGetUnitWeaponIntegerField(whichUnit, UNIT_WEAPON_IF_ATTACK_DAMAGE_SIDES_PER_DIE, weaponIndex)
    return base + (numDice * diceSides)
endfunction

function GetUnitDamageRoll takes unit whichUnit, integer weaponIndex returns integer
    local integer min = GetUnitMinWeaponDamage(whichUnit, weaponIndex)
    local integer max = GetUnitMaxWeaponDamage(whichUnit, weaponIndex)
    return GetRandomInt(min, max)
endfunction

function GetUnitAttackRange takes unit whichUnit, integer weaponIndex returns real
    return BlzGetUnitWeaponRealField(whichUnit, UNIT_WEAPON_RF_ATTACK_RANGE, weaponIndex)
endfunction

function SetUnitAttackRange takes unit whichUnit, integer weaponIndex, real range returns nothing
    local real currentRange1 = GetUnitAttackRange(whichUnit, weaponIndex)
    local real currentRange2 = GetUnitAttackRange(whichUnit, weaponIndex + 1)
    call BlzSetUnitWeaponRealField(whichUnit, UNIT_WEAPON_RF_ATTACK_RANGE, weaponIndex + 1, range - currentRange1 + currentRange2)
endfunction

function UnitAddBaseWeaponDamage takes unit whichUnit, integer weaponIndex, integer damageAmt returns nothing
    local integer base = BlzGetUnitWeaponIntegerField(whichUnit, UNIT_WEAPON_IF_ATTACK_DAMAGE_BASE, weaponIndex)
    call BlzSetUnitBaseDamage(whichUnit, base + damageAmt, weaponIndex)
endfunction

function UnitSimulateAttack takes unit attacker, unit victim, integer weaponIndex returns nothing
    local integer damage = GetUnitDamageRoll(attacker, weaponIndex)
    local attacktype aType = ConvertAttackType(BlzGetUnitWeaponIntegerField(attacker, UNIT_WEAPON_IF_ATTACK_ATTACK_TYPE, weaponIndex))
    local weapontype wType = ConvertWeaponType(BlzGetUnitWeaponIntegerField(attacker, UNIT_WEAPON_IF_ATTACK_WEAPON_SOUND, weaponIndex))
    call UnitDamageTarget(attacker, victim, damage, true, true, aType, DAMAGE_TYPE_NORMAL, wType)
endfunction

function EnableUnitFlyHeight takes unit whichUnit returns nothing
    call UnitAddAbility(whichUnit, 'Arav')
    call UnitRemoveAbility(whichUnit, 'Arav')
endfunction

function UnitRemoveSlows takes unit whichUnit returns nothing
    local integer i = 0
    loop
        exitwhen i >= BUFFS_THAT_SLOW_SIZE
        loop
            exitwhen not UnitHasBuffBJ(whichUnit, BUFFS_THAT_SLOW[i]) or not UnitRemoveBuffBJ(BUFFS_THAT_SLOW[i], whichUnit)
        endloop
        set i = i + 1
    endloop
endfunction

function UnitApplyFakeBuff takes unit whichUnit, integer abilityId, integer buffId, real duration returns nothing
    call UnitAddAbility(whichUnit, abilityId)
    call UnitRemoveAbilityDelayed.execute(whichUnit, abilityId, buffId, duration)
endfunction

function UnitRemoveAbilityDelayed takes unit whichUnit, integer abilityId, integer buffId, real duration returns nothing
    call TriggerSleepAction(duration)
    call UnitRemoveAbility(whichUnit, abilityId)
    call UnitRemoveBuffBJ(buffId, whichUnit)
endfunction

function UnitSetMoveType takes unit whichUnit, movetype whichMoveType returns nothing
    call BlzSetUnitIntegerField(whichUnit, UNIT_IF_MOVE_TYPE, GetHandleId(whichMoveType))
endfunction

function SetUnitTargetedAsFlying takes unit whichUnit returns nothing
    local integer originalTargetedAs = 0
    local integer newTargetedAs = 0

    if (HaveSavedInteger(udg_HashTable_UnitInfo, GetHandleId(whichUnit), KEY_TARGETED_AS)) then
        set originalTargetedAs = LoadInteger(udg_HashTable_UnitInfo, GetHandleId(whichUnit), KEY_TARGETED_AS)
    else
        set originalTargetedAs = BlzGetUnitIntegerField(whichUnit, UNIT_IF_TARGETED_AS)
        call SaveInteger(udg_HashTable_UnitInfo, GetHandleId(whichUnit), KEY_TARGETED_AS, originalTargetedAs)
    endif

    set newTargetedAs = BlzBitXor(BlzBitOr(originalTargetedAs, GetHandleId(TARGET_FLAG_AIR)), GetHandleId(TARGET_FLAG_GROUND))
    call BlzSetUnitIntegerField(whichUnit, UNIT_IF_TARGETED_AS, newTargetedAs)
endfunction

function RestoreUnitTargetedAs takes unit whichUnit returns nothing
    local integer originalTargetedAs = 0
    if (HaveSavedInteger(udg_HashTable_UnitInfo, GetHandleId(whichUnit), KEY_TARGETED_AS)) then
        set originalTargetedAs = LoadInteger(udg_HashTable_UnitInfo, GetHandleId(whichUnit), KEY_TARGETED_AS)
        call BlzSetUnitIntegerField(whichUnit, UNIT_IF_TARGETED_AS, originalTargetedAs)
    endif
endfunction

function UnitAddCategory takes unit whichUnit, unitcategory category returns nothing
    local integer categories = BlzGetUnitIntegerField(whichUnit, UNIT_IF_UNIT_CLASSIFICATION)
    set categories = BlzBitOr(categories, GetHandleId(category))
    call BlzSetUnitIntegerField(whichUnit, UNIT_IF_UNIT_CLASSIFICATION, categories)
endfunction

function IsUnitInAOE takes unit whichUnit,real x,real y,real radius returns boolean
    return DistanceBetweenPointsXY(GetUnitX(whichUnit) , GetUnitY(whichUnit) , x , y) <= radius + BlzGetUnitCollisionSize(whichUnit)
endfunction

function SetUnitAnimationByIndexDelayed_Impl takes unit whichUnit, integer whichAnimation, real delay, real timeScale returns nothing
    call TriggerSleepAction(delay)
    call SetUnitAnimationByIndex(whichUnit, whichAnimation)
    call SetUnitTimeScale(whichUnit, timeScale)
endfunction

function SetUnitAnimationByIndexDelayedWithTimeScale takes unit whichUnit, integer whichAnimation, real delay, real timeScale returns nothing
    call SetUnitAnimationByIndexDelayed_Impl.execute(whichUnit, whichAnimation, delay, timeScale)
endfunction

function SetUnitAnimationByIndexDelayed takes unit whichUnit, integer whichAnimation, real delay returns nothing
    call SetUnitAnimationByIndexDelayed_Impl.execute(whichUnit, whichAnimation, delay, 1.0)
endfunction

function UnitDisableAbilitySB takes unit whichUnit, integer abilityId, boolean disable returns nothing
    call BlzUnitDisableAbility(whichUnit, abilityId, disable, false)
    if (not disable) then
        call BlzUnitHideAbility(whichUnit, abilityId, true) // This is so we dont touch the internal "hide" stack counter
    endif
endfunction

    function SetUnitPositionExact takes unit u, real x, real y returns nothing
        local integer gridSize = 0
        if (IsUnitType(u, UNIT_TYPE_STRUCTURE)) then
            call SetUnitPosition(u, x, y)
        else
            set gridSize = R2I(BlzGetUnitCollisionSize(u)) / 16
            if (gridSize == 1 or gridSize >= 3) then
            call SetUnitPosition(u, x + 16, y + 16)
            else
            call SetUnitPosition(u, x, y)
            endif
        endif
    endfunction

    function GetUnitXExact takes unit u returns real
        local integer gridSize = 0
        if (IsUnitType(u, UNIT_TYPE_STRUCTURE)) then
            return GetUnitX(u)
        endif
        set gridSize = R2I(BlzGetUnitCollisionSize(u)) / 16
        if (gridSize == 1 or gridSize >= 3) then
            return GetUnitX(u) - 16
        endif
        return GetUnitX(u)
    endfunction

    function GetUnitYExact takes unit u returns real
        local integer gridSize = 0
        if (IsUnitType(u, UNIT_TYPE_STRUCTURE)) then
            return GetUnitY(u)
        endif
        set gridSize = R2I(BlzGetUnitCollisionSize(u)) / 16
        if (gridSize == 1 or gridSize >= 3) then
            return GetUnitY(u) - 16
        endif
        return GetUnitY(u)
    endfunction

function IssueImmediateOrderAfter takes unit whichUnit, string order, real seconds returns nothing
    call IssueImmediateOrderAfter_Impl.execute(whichUnit, order, seconds)
endfunction

function IssueImmediateOrderAfter_Impl takes unit whichUnit, string order, real seconds returns nothing
    call TriggerSleepAction(seconds)
    call IssueImmediateOrder(whichUnit, order)
endfunction

function IssuePointOrderByIdAfter takes unit whichUnit, integer orderId, real x, real y, real seconds returns nothing
    call IssuePointOrderByIdAfter_Impl.execute(whichUnit, orderId, x, y, seconds)
endfunction

function IssuePointOrderByIdAfter_Impl takes unit whichUnit, integer orderId, real x, real y, real seconds returns nothing
    call TriggerSleepAction(seconds)
    call IssuePointOrderById(whichUnit, orderId, x, y)
endfunction

function IssueTargetOrderByIdAfter takes unit whichUnit, integer orderId, widget target, real seconds returns nothing
    call IssueTargetOrderByIdAfter_Impl.execute(whichUnit, orderId, target, seconds)
endfunction

function IssueTargetOrderByIdAfter_Impl takes unit whichUnit, integer orderId, widget target, real seconds returns nothing
    call TriggerSleepAction(seconds)
    call IssueTargetOrderById(whichUnit, orderId, target)
endfunction

function IsHarvestOrder takes integer orderId, unit ordered, unit orderTargetUnit returns boolean
    if (not UnitHasAbility(orderTargetUnit, SB_GOLD_MINE_ABILITY)) then
        return false
    elseif (not IsUnitGoldHarvester(ordered)) then
        return false
    elseif (orderId != SB_ORDER_HARVEST and orderId != SB_ORDER_SMART) then
        return false
    endif
    return true
endfunction

function IsReturnGoldOrder takes integer orderId, unit ordered, unit orderTargetUnit returns boolean
    if (not IsUnitGoldHarvester(ordered)) then
        return false
    elseif (orderId == SB_ORDER_RESUME_HARVESTING) then
        return true
    elseif (orderId != SB_ORDER_SMART) then
        return false
    elseif (not UnitHasAbility(orderTargetUnit, SB_RETURN_GOLD) and not UnitHasAbility(orderTargetUnit, SB_RETURN_GOLD_AND_LUMBER)) then
        return false
    endif
    return true
endfunction

function IsRepairOrder takes integer orderId, unit ordered, unit orderTargetUnit returns boolean
    if (orderId == SB_ORDER_REPAIR) then
        return true
    elseif (orderId == SB_ORDER_SMART) then
        if (not IsUnitNonNeutralAlly(ordered, GetOwningPlayer(orderTargetUnit))) then
            return false
        elseif (GetUnitLifePercent(orderTargetUnit) >= 100.0) then
            return false
        elseif (IsUnitType(orderTargetUnit, UNIT_TYPE_MECHANICAL)) then
            if (UnitHasAbility(ordered, SB_RENEW)) then
                return true
            elseif (UnitHasAbility(ordered, SB_RENEW_SAPLING)) then
                return true
            elseif (UnitHasAbility(ordered, SB_REPAIR)) then
                return true
            elseif (UnitHasAbility(ordered, SB_REPAIR_HUMAN)) then
                return true
            elseif (UnitHasAbility(ordered, SB_RESTORE)) then
                return true
            elseif (UnitHasAbility(ordered, SB_RESTORE_LOST_SOUL)) then
                return true
            elseif (UnitHasAbility(ordered, SB_RESTORE_NECRO)) then
                return true
            endif
            return false
        elseif (IsUnitType(orderTargetUnit, UNIT_TYPE_STRUCTURE)) then
            if (UnitHasAbility(ordered, SB_RENEW)) then
                return true
            elseif (UnitHasAbility(ordered, SB_RENEW_SAPLING)) then
                return true
            endif
        endif
    endif
    return false
endfunction

function IsBuildOrder takes integer orderId returns boolean
    return IsUnitIdType(orderId, UNIT_TYPE_STRUCTURE)
endfunction

scope GroupUtils
    globals
        private integer COUNT = 0
        private UnitCondition UNIT_CONDITION = 0
        private integer UNIT_TYPE_ID = 0
        private integer FOR_GROUP_INT_DATA = 0
        private integer FOR_GROUP_INT_ACTION = 0
    endglobals

    function CountUnitsInGroupWithAbility takes group whichGroup, integer abilityId returns integer
        local integer size = BlzGroupGetSize(whichGroup)
        local integer index = 0
        local integer count = 0
        local unit pickedUnit = null

        loop
            exitwhen index >= size
            if (GetUnitAbilityLevel(BlzGroupUnitAt(whichGroup, index), abilityId) > 0) then
                set count = count + 1
            endif
            set index = index + 1
        endloop
        
        return count
    endfunction

    private function CountUnitsInGroupOfTypeIdLoop takes nothing returns nothing
        if (GetUnitTypeId(GetEnumUnit()) == UNIT_TYPE_ID) then
            set COUNT = COUNT + 1
        endif
    endfunction

    function CountUnitsInGroupOfTypeId takes group whichGroup, integer unitTypeId returns integer
        set COUNT = 0
        set UNIT_TYPE_ID = unitTypeId
        call ForGroup(whichGroup, function CountUnitsInGroupOfTypeIdLoop)
        return COUNT
    endfunction

    private function CountUnitsInGroupMatchingLoop takes nothing returns nothing
        if (UNIT_CONDITION.evaluate(GetEnumUnit())) then
            set COUNT = COUNT + 1
        endif
    endfunction

    function CountUnitsInGroupMatching takes group whichGroup, UnitCondition condition returns integer
        set COUNT = 0
        set UNIT_CONDITION = condition
        call ForGroup(whichGroup, function CountUnitsInGroupMatchingLoop)
        return COUNT
    endfunction

    function GetUnitsInRectWithAbility takes rect r, integer abilityId returns group
        local group g = GetUnitsInRectAll(r)
        local group result = CreateGroup()
        local unit picked = null

        loop
            set picked = FirstOfGroup(g)
            exitwhen picked == null
            if (GetUnitAbilityLevel(picked, abilityId) > 0) then
                call GroupAddUnit(result, picked)
            endif
            call GroupRemoveUnit(g, picked)
        endloop

        call DestroyGroup(g)
        return result
    endfunction

    function GetUnitsOfPlayerWithAbility takes player p, integer abilityId returns group
        local group g = GetUnitsOfPlayerAll(p)
        local group result = CreateGroup()
        local unit picked = null

        loop
            set picked = FirstOfGroup(g)
            exitwhen picked == null
            if (GetUnitAbilityLevel(picked, abilityId) > 0) then
                call GroupAddUnit(result, picked)
            endif
            call GroupRemoveUnit(g, picked)
        endloop

        call DestroyGroup(g)
        return result
    endfunction

    function GetUnitInGroupOfType takes group g, integer unitTypeId returns unit
        local integer size = BlzGroupGetSize(g)
        local integer index = 0
        local unit pickedUnit = null
        loop
            exitwhen index >= size
            set pickedUnit = BlzGroupUnitAt(g, index)
            if (GetUnitTypeId(pickedUnit) == unitTypeId) then
                return pickedUnit
            endif
        set index = index + 1
        endloop
        return null
    endfunction

    private function UnitsWithAbilityFilter_Impl takes nothing returns boolean
        return UnitHasAbility(GetFilterUnit(), udg_Int_Temp)
    endfunction

    function UnitsWithAbilityFilter takes integer abilityId returns conditionfunc
        set udg_Int_Temp = abilityId
        return Condition(function UnitsWithAbilityFilter_Impl)
    endfunction

    function GoldMineFilter takes nothing returns boolean
        return GetUnitTypeId(GetFilterUnit()) == SB_GOLD_MINE
    endfunction

    function GroupPickClosestUnitMatching takes group g, real x, real y, UnitCondition filter returns unit
        local integer size = BlzGroupGetSize(g)
        local integer index = 0
        local unit pickedUnit = null
        local unit resultUnit = null
        local real unitX = 0.0
        local real unitY = 0.0
        local real minDist = BIG_REAL
        local real dist = 0.0

        loop
            exitwhen index >= size
            set pickedUnit = BlzGroupUnitAt(g, index)
            if (filter == 0 or filter.evaluate(pickedUnit)) then
                set unitX = GetUnitX(pickedUnit)
                set unitY = GetUnitY(pickedUnit)
                set dist = SqrDistanceBetweenPointsXY(unitX, unitY, x, y)
                if (dist < minDist) then
                    set minDist = dist
                    set resultUnit = pickedUnit
                endif
            endif
            set index = index + 1
        endloop

        return resultUnit
    endfunction

    function GroupPickClosestUnit takes group g, real x, real y returns unit
        return GroupPickClosestUnitMatching(g, x, y, 0)
    endfunction

    function GroupPickFurthestUnitMatching takes group g, real x, real y, UnitCondition filter returns unit
        local integer size = BlzGroupGetSize(g)
        local integer index = 0
        local unit pickedUnit = null
        local unit resultUnit = null
        local real unitX = 0.0
        local real unitY = 0.0
        local real maxDist = 0.0
        local real dist = 0.0

        loop
            exitwhen index >= size
            set pickedUnit = BlzGroupUnitAt(g, index)
            if (filter == 0 or filter.evaluate(pickedUnit)) then
                set unitX = GetUnitX(pickedUnit)
                set unitY = GetUnitY(pickedUnit)
                set dist = SqrDistanceBetweenPointsXY(unitX, unitY, x, y)
                if (dist > maxDist) then
                    set maxDist = dist
                    set resultUnit = pickedUnit
                endif
            endif
            set index = index + 1
        endloop

        return resultUnit
    endfunction

    function GroupPickFurthestUnit takes group g, real x, real y returns unit
        return GroupPickFurthestUnitMatching(g, x, y, 0)
    endfunction

    private function KillGroupLoop takes nothing returns nothing
        call KillUnit(GetEnumUnit())
    endfunction

    function KillGroup takes group g returns nothing
        call ForGroup(g, function KillGroupLoop)
    endfunction

    private function ForGroupIntAction takes nothing returns nothing
        local IntFunc action = FOR_GROUP_INT_ACTION
	local integer input = FOR_GROUP_INT_DATA
        call action.evaluate(input)
    endfunction

    function ForGroupInt takes group g, IntFunc action, integer input returns nothing
        set FOR_GROUP_INT_ACTION = action
        set FOR_GROUP_INT_DATA = input
        call ForGroup(g, function ForGroupIntAction)
    endfunction

endscope

scope TriggerUtil
    globals
        private constant hashtable HT_TRIGGERS = InitHashtable()
        private constant key KEY_SPELL_ABILITY
    endglobals

    function interface ItemAbilityCallback takes ability a returns nothing

    private function SpellCondition takes nothing returns boolean
        local integer abilityId = LoadInteger(HT_TRIGGERS, GetHandleId(GetTriggeringTrigger()), KEY_SPELL_ABILITY)
        return GetSpellAbilityId() == abilityId
    endfunction

    function CreateSpellBeginTrigger takes integer abilityId, code action returns trigger
        local trigger t = CreateTrigger()
        call SaveInteger(HT_TRIGGERS, GetHandleId(t), KEY_SPELL_ABILITY, abilityId)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_CAST)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerAddAction(t, action)
        return t
    endfunction

    function CreateSpellChannelTrigger takes integer abilityId, code action returns trigger
        local trigger t = CreateTrigger()
        call SaveInteger(HT_TRIGGERS, GetHandleId(t), KEY_SPELL_ABILITY, abilityId)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_CHANNEL)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerAddAction(t, action)
        return t
    endfunction

    function CreateSpellEffectTrigger takes integer abilityId, code action returns trigger
        local trigger t = CreateTrigger()
        call SaveInteger(HT_TRIGGERS, GetHandleId(t), KEY_SPELL_ABILITY, abilityId)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerAddAction(t, action)
        return t
    endfunction

    function CreateSpellCancelTrigger takes integer abilityId, code action returns trigger
        local trigger t = CreateTrigger()
        call SaveInteger(HT_TRIGGERS, GetHandleId(t), KEY_SPELL_ABILITY, abilityId)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_ENDCAST)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerAddAction(t, action)
        return t
    endfunction

    function CreateSpellFinishTrigger takes integer abilityId, code action returns trigger
        local trigger t = CreateTrigger()
        call SaveInteger(HT_TRIGGERS, GetHandleId(t), KEY_SPELL_ABILITY, abilityId)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_FINISH)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerAddAction(t, action)
        return t
    endfunction

    function CreateAnyUnitTrigger takes playerunitevent ev, code condition, code action returns trigger
        local trigger t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, ev)
        call TriggerAddCondition(t, Condition(condition))
        call TriggerAddAction(t, action)
        return t
    endfunction
endscope

globals
    constant integer AUDIO_CHANNEL_GENERAL = 0
    constant integer AUDIO_CHANNEL_UNIT_SELECTION = 1
    constant integer AUDIO_CHANNEL_UNIT_ACKNOWLEDEGMENT = 2
    constant integer AUDIO_CHANNEL_UNIT_MOVEMENT = 3
    constant integer AUDIO_CHANNEL_UNIT_READY = 4
    constant integer AUDIO_CHANNEL_COMBAT = 5
    constant integer AUDIO_CHANNEL_ERROR = 6
    constant integer AUDIO_CHANNEL_MUSIC = 7
    constant integer AUDIO_CHANNEL_USER_INTERFACE = 8
    constant integer AUDIO_CHANNEL_LOOPING_MOVEMENT = 9
    constant integer AUDIO_CHANNEL_LOOPING_AMBIENT = 10
    constant integer AUDIO_CHANNEL_ANIMATIONS = 11
    constant integer AUDIO_CHANNEL_CONSTRUCTION = 12
    constant integer AUDIO_CHANNEL_BIRTH = 13
    constant integer AUDIO_CHANNEL_FIRE = 14
    constant integer AUDIO_CHANNEL_LEGACY_MIDI = 15
    constant integer AUDIO_CHANNEL_CINEMATIC_GENERAL = 16
    constant integer AUDIO_CHANNEL_CINEMATIC_AMBIENT = 17
    constant integer AUDIO_CHANNEL_CINEMATIC_MUSIC = 18
    constant integer AUDIO_CHANNEL_CINEMATIC_DIALOG = 19
    constant integer AUDIO_CHANNEL_CINEMATIC_SFX1 = 20
    constant integer AUDIO_CHANNEL_CINEMATIC_SFX2 = 21
    constant integer AUDIO_CHANNEL_CINEMATIC_SFX3 = 22
endglobals

function PlayPitchedSound takes string fileName, integer volume, real pitch returns nothing
    local sound soundHandle = CreateSound(fileName, false, false, true, 12700, 12700, "")
    call SetSoundVolume(soundHandle, volume)
    call SetSoundPitch(soundHandle, pitch)
    call StartSound(soundHandle)
    call KillSoundWhenDone(soundHandle)
endfunction

function PlayPitchedSoundAtPositionSB takes string fileName, string eaxSetting, integer channel, real x, real y, real volume, real pitch returns nothing
    local sound snd = CreateSound(fileName, false, true, true, 1, 1, eaxSetting)
    call SetSoundChannel(snd, channel)
    call SetSoundPosition(snd, x, y, 0.0)
    call SetSoundVolumeBJ(snd, volume)
    call SetSoundPitch(snd, pitch)
    call StartSound(snd)
    call KillSoundWhenDone(snd)
endfunction

function PlaySoundAtPositionSB takes string fileName, string eaxSetting, integer channel, real x, real y, real volume returns nothing
    call PlayPitchedSoundAtPositionSB(fileName, eaxSetting, channel, x, y, volume, 1.0)
endfunction

function PlayPitchedSoundAtPointSB takes string fileName, string eaxSetting, integer channel, location point, real volume, real pitch returns nothing
    call PlayPitchedSoundAtPositionSB(fileName, eaxSetting, channel, GetLocationX(point), GetLocationY(point), volume, pitch)
endfunction

function PlaySoundAtPointSB takes string fileName, string eaxSetting, integer channel, location point, real volume returns nothing
    call PlayPitchedSoundAtPointSB(fileName, eaxSetting, channel, point, volume, 1.0)
endfunction

function PlaySoundForPlayer takes string fileName, player p returns nothing
    local sound snd = CreateSound(fileName, false, false, true, 12700, 12700, "")
    if (p == GetLocalPlayer()) then
        call PlaySoundBJ(snd)
    endif
    call KillSoundWhenDone(snd)
endfunction

library EffectUtil requires TimersPlus
    globals
        private constant hashtable HT = InitHashtable()
        private constant hashtable HT_THROTTLED_EFFECTS = InitHashtable()
        private constant key KEY_THROTTLE_UNIT
        private constant key KEY_THROTTLE_TIMER
        private constant string AREA_INDICATOR_ART = "war3mapImported\\Spell Marker TC.mdx"
        private constant real AREA_INDICATOR_RADIUS_AT_NORMAL_SCALE = 100.0
    endglobals

    function AddSpecialEffectOneShotWithZ takes string modelName, real x, real y, real z returns nothing
        local effect e = AddSpecialEffect(modelName, x, y)
        call BlzSetSpecialEffectZ(e, z)
        call DestroyEffect(e)
    endfunction

    function AddSpecialEffectOneShot takes string modelName, real x, real y returns nothing
        call DestroyEffect(AddSpecialEffect(modelName, x, y))
    endfunction

    function AddSpecialEffectOneShotEx takes string modelName, real x, real y, real height, real scale, real timeScale returns nothing
        local effect e = AddSpecialEffect(modelName, x, y)
        call BlzSetSpecialEffectHeight(e, height)
        call BlzSetSpecialEffectScale(e, scale)
        call BlzSetSpecialEffectTimeScale(e, timeScale)
        call DestroyEffect(e)
    endfunction

    function AddSpecialEffectTargetOneShot takes string modelName, widget target, string attachmentPoint returns nothing
        call DestroyEffect(AddSpecialEffectTarget(modelName, target, attachmentPoint))
    endfunction

    private function EndEffectCooldown takes nothing returns nothing
        local timer t = GetExpiredTimer()
        local unit whichUnit = LoadUnitHandle(HT_THROTTLED_EFFECTS, KEY_THROTTLE_UNIT, GetHandleId(t))
        call RemoveSavedHandle(HT_THROTTLED_EFFECTS, KEY_THROTTLE_UNIT, GetHandleId(t))
        call RemoveSavedHandle(HT_THROTTLED_EFFECTS, KEY_THROTTLE_TIMER, GetHandleId(whichUnit))
        call DestroyTimer(t)
    endfunction

    function AddSpecialEffectTargetOneShotThrottled takes string modelName, unit target, string attachmentPoint, real cooldown returns nothing
        local timer t = LoadTimerHandle(HT_THROTTLED_EFFECTS, KEY_THROTTLE_TIMER, GetHandleId(target))
        if (t == null) then
            set t = CreateTimer()
            call SaveTimerHandle(HT_THROTTLED_EFFECTS, KEY_THROTTLE_TIMER, GetHandleId(target), t)
            call SaveUnitHandle(HT_THROTTLED_EFFECTS, KEY_THROTTLE_UNIT, GetHandleId(t), target)
            call TimerStart(t, cooldown, false, function EndEffectCooldown)
            call AddSpecialEffectTargetOneShot(modelName, target, attachmentPoint)
        endif
    endfunction

    private function AddSpecialEffectTargetOneShotDelayed_Impl takes string modelName, widget target, string attachmentPoint, real delay returns nothing
        call TriggerSleepAction(delay)
        call AddSpecialEffectTargetOneShot(modelName, target, attachmentPoint)
    endfunction

    function AddSpecialEffectTargetOneShotDelayed takes string modelName, widget target, string attachmentPoint, real delay returns nothing
        call AddSpecialEffectTargetOneShotDelayed_Impl.execute(modelName, target, attachmentPoint, delay)
    endfunction

    function DestroyKeyedEffect takes integer parentKey, integer childKey returns nothing
        local effect e = LoadEffectHandle(HT, parentKey, childKey)
        call DestroyEffect(e)
        call RemoveSavedHandle(HT, parentKey, childKey)
    endfunction

    function AddKeyedEffect takes string modelName, real x, real y, integer parentKey, integer childKey returns effect
        local effect e = null
        call DestroyKeyedEffect(parentKey, childKey)
        set e = AddSpecialEffect(modelName, x, y)
        call SaveEffectHandle(HT, parentKey, childKey, e)
        return e
    endfunction

    function AddKeyedEffectTarget takes string modelName, widget target, string attachmentPoint, integer parentKey, integer childKey returns effect
        local effect e = null
        call DestroyKeyedEffect(parentKey, childKey)
        set e = AddSpecialEffectTarget(modelName, target, attachmentPoint)
        call SaveEffectHandle(HT, parentKey, childKey, e)
        return e
    endfunction

    struct AreaIndicator
        unit target = null
        effect indicator = null
        IntTimer followTimer = 0
        method onDestroy takes nothing returns nothing
            call DestroyEffect(indicator)
            call followTimer.destroy()
        endmethod
    endstruct

    function CreateAreaIndicator takes player owner, real x, real y, real radius returns AreaIndicator
        local AreaIndicator ae = AreaIndicator.create()
        set ae.indicator = AddSpecialEffect(AREA_INDICATOR_ART, x, y)
        call BlzSetSpecialEffectColorByPlayer(ae.indicator, owner)
        call BlzSetSpecialEffectScale(ae.indicator, radius / AREA_INDICATOR_RADIUS_AT_NORMAL_SCALE)
        return ae
    endfunction

    private function AreaIndicatorUpdate takes IntTimer it returns nothing
        local AreaIndicator ae = it.owner
        if (UnitAlive(ae.target)) then
            call BlzSetSpecialEffectX(ae.indicator, GetUnitX(ae.target))
            call BlzSetSpecialEffectY(ae.indicator, GetUnitY(ae.target))
        else
            call ae.destroy()
        endif
    endfunction

    function CreateAreaIndicatorUnit takes unit owner, real radius returns AreaIndicator
        local AreaIndicator ae = CreateAreaIndicator(GetOwningPlayer(owner), GetUnitX(owner), GetUnitY(owner), radius)
        set ae.target = owner
        set ae.followTimer = CreateIntTimer(ae, false)
        call StartTimerPlusPeriodic(ae.followTimer, 0.0, 0.01, AreaIndicatorUpdate, 0)
        return ae
    endfunction

    function DestroyKeyedAreaIndicator takes integer parentKey, integer childKey returns nothing
        local AreaIndicator ae = LoadInteger(HT, parentKey, childKey)
        if (ae != 0) then
            call ae.destroy()
        endif
        call RemoveSavedInteger(HT, parentKey, childKey)
    endfunction

    function CreateAreaIndicatorKeyed takes player owner, real x, real y, real radius, integer parentKey, integer childKey returns AreaIndicator
        local AreaIndicator ae = CreateAreaIndicator(owner, x, y, radius)
        call DestroyKeyedAreaIndicator(parentKey, childKey)
        call SaveInteger(HT, parentKey, childKey, ae)
        return ae
    endfunction

    function CreateAreaIndicatorUnitKeyed takes unit owner, real radius, integer parentKey, integer childKey returns AreaIndicator
        local AreaIndicator ae = CreateAreaIndicatorUnit(owner, radius)
        call DestroyKeyedAreaIndicator(parentKey, childKey)
        call SaveInteger(HT, parentKey, childKey, ae)
        return ae
    endfunction

endlibrary

globals
    item PATHING_CHECKER = null
endglobals

function IsPointWalkable takes real x, real y returns boolean
    local boolean result = false
    local real xDiff = 0.0
    local real yDiff = 0.0
    if (PATHING_CHECKER == null) then
        set PATHING_CHECKER = CreateItem(SB_ITEM_PATHING_CHECKER, x, y)
    endif

    call SetItemVisible(PATHING_CHECKER, true)
    call SetItemPosition(PATHING_CHECKER, x, y)
    call SetItemVisible(PATHING_CHECKER, false)

    set xDiff = RAbsBJ(GetItemX(PATHING_CHECKER) - x)
    set yDiff = RAbsBJ(GetItemY(PATHING_CHECKER) - y)

    set result = xDiff <= 0.01 and yDiff <= 0.01

    return result
endfunction

function LineTraceWalkability takes real startX, real startY, real endX, real endY, real maxDelta returns location
    local vec3 current = vec3.create(startX, startY, 0)
    local vec3 diff = vec3.create(0, 0, 0)
    local real dist = 0.0
    local location result = null

    loop
        exitwhen current.x == endX and current.y == endY
        set diff.x = endX - current.x
        set diff.y = endY - current.y
        set dist = RMinBJ(diff.mag(), maxDelta)
        call diff.normalize().multiply(dist)
        call current.add(diff)

        if (not IsPointWalkable(current.x, current.y)) then
            return Location(current.x - diff.x, current.y - diff.y)
        endif
    endloop
    
    set result = Location(endX, endY)

    call diff.destroy()
    call current.destroy()

    return result
endfunction

function LineTraceWalkabilityReverse takes real startX, real startY, real endX, real endY, real maxDelta returns location
    local vec3 current = vec3.create(startX, startY, 0)
    local vec3 diff = vec3.create(0, 0, 0)
    local real dist = 0.0
    local location result = null

    loop
        exitwhen current.x == endX and current.y == endY
        set diff.x = endX - current.x
        set diff.y = endY - current.y
        set dist = RMinBJ(diff.mag(), maxDelta)
        call diff.normalize().multiply(dist)
        call current.add(diff)

        if (IsPointWalkable(current.x, current.y)) then
            return Location(current.x - diff.x, current.y - diff.y)
        endif
    endloop
    
    set result = Location(endX, endY)

    call diff.destroy()
    call current.destroy()

    return result
endfunction

globals
    real ENUM_DESTRUCTABLE_RADIUS = 0.0
    real ENUM_DESTRUCTABLE_X = 0.0
    real ENUM_DESTRUCTABLE_Y = 0.0
endglobals

function IsTree takes destructable whichDestructable returns boolean
    if (whichDestructable == null) then
        return false
    endif

    if ( ( GetDestructableTypeId(whichDestructable) == SB_ASHENVALE_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_ASHENVALE_CANOPY_TREE ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_BARRENS_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_BARRENS_CANOPY_TREE ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_BLACK_CITADEL_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_CITYSCAPE_FALL_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_CITYSCAPE_SNOWY_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_CITYSCAPE_SUMMER_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_CITYSCAPE_WINTER_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_CITYSCAPE_RUINED_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_DALARAN_RUINS_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_DUNGEON_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_FELWOOD_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_FELWOOD_CANOPY_TREE ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_ICECROWN_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_ICECROWN_CANOPY_TREE ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_NORTHREND_CANOPY_TREE ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_NORTHREND_ICY_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_FALL_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_SUMMER_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_SNOWY_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_WINTER_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_NORTHREND_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_OUTLAND_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_RUINS_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_RUINS_CANOPY_TREE ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_UNDERGROUND_TREE_WALL ) ) then
        return true
    endif
    if ( ( GetDestructableTypeId(whichDestructable) == SB_VILLAGE_TREE_WALL ) ) then
        return true
    endif
    return false
endfunction

function GetRandomLivingTreeInRangeFilter takes nothing returns boolean
    local destructable d = GetFilterDestructable()
    local real dist = 0.0
    if (IsDestructableDeadBJ(d)) then
        return false
    elseif (not IsTree(d)) then
        return false
    endif
    set dist = DistanceBetweenPointsXY(ENUM_DESTRUCTABLE_X, ENUM_DESTRUCTABLE_Y, GetDestructableX(d), GetDestructableY(d))
    return dist <= ENUM_DESTRUCTABLE_RADIUS
endfunction

function GetRandomLivingTreeInRange takes real x, real y, real radius returns destructable
    local rect r = Rect(x - radius, y - radius, x + radius, y + radius)
    local destructable result = null
    set ENUM_DESTRUCTABLE_RADIUS = radius
    set ENUM_DESTRUCTABLE_X = x
    set ENUM_DESTRUCTABLE_Y = y
    set result = RandomDestructableInRectBJ(r, Condition(function GetRandomLivingTreeInRangeFilter))
    call RemoveRect(r)
    return result
endfunction

function IsDigit takes string s returns boolean
    if (s == "0") then
        return true
    elseif (s == "1") then
        return true
    elseif (s == "2") then
        return true
    elseif (s == "3") then
        return true
    elseif (s == "4") then
        return true
    elseif (s == "5") then
        return true
    elseif (s == "6") then
        return true
    elseif (s == "7") then
        return true
    elseif (s == "8") then
        return true
    elseif (s == "9") then
        return true
    endif
    return false
endfunction

function IsNumber takes string s returns boolean
    local integer decimalCount = 0
    local integer charIndex = 0
    local integer len = StringLength(s)
    local string char = null
    loop
        exitwhen charIndex >= len
        set char = SubString(s, charIndex, charIndex)
        if (char == ".") then
            set decimalCount = decimalCount + 1
            if (decimalCount > 1) then
                return false
            endif
        elseif (not IsDigit(char)) then
            return false
        endif
        set charIndex = charIndex + 1
    endloop
    return true
endfunction

function PosToString takes real x, real y returns string
    return R2S(x) + "," + R2S(y)
endfunction

function LocToString takes location loc returns string
    return PosToString(GetLocationX(loc), GetLocationY(loc))
endfunction

function StringLastIndexOf takes string whichString, string find returns integer
    local integer stringLen = StringLength(whichString)
    local integer findLen = StringLength(find)
    local integer c = stringLen - findLen
    
    loop
        exitwhen c < findLen
        if (SubString(whichString, c, c + findLen) == find) then
            return c
        endif
        set c = c - 1
    endloop
    return -1
endfunction

function ParseLoc takes string s returns location
    local integer indexOfComma = StringLastIndexOf(s, ",")
    if (indexOfComma != -1) then
        return Location(S2R(SubString(s, 0, indexOfComma)), S2R(SubString(s, indexOfComma + 1, StringLength(s))))
    endif
    return null
endfunction

library AbilityInit
    globals
        private constant hashtable HT = InitHashtable()
        private constant key KEY_ABILITY_ID
        private constant key KEY_CALLBACK
        private integer ability_id = 0
    endglobals
    
    private function interface UnitInitFunc takes unit whichUnit returns nothing

    private function UnitsWithAbilityFilter takes nothing returns boolean
        return GetUnitAbilityLevel(GetFilterUnit(), ability_id) > 0
    endfunction

    private function UnitEntersCondition takes nothing returns boolean
        local integer abilityId = LoadInteger(HT, GetHandleId(GetTriggeringTrigger()), KEY_ABILITY_ID)
        if (abilityId != 0) then
            return GetUnitAbilityLevel(GetEnteringUnit(), abilityId) > 0
        endif
        return false
    endfunction

    private function UnitEntersAction takes nothing returns nothing
        local UnitInitFunc callback = LoadInteger(HT, GetHandleId(GetTriggeringTrigger()), KEY_CALLBACK)
        if (callback != 0) then
            call callback.evaluate(GetEnteringUnit())
        endif
    endfunction

    function InitAbility takes integer abilityId, UnitInitFunc initFunc returns nothing
        local group abilityUnits = CreateGroup()
        local trigger entersTrigger = CreateTrigger()
        local unit picked = null

        call TriggerRegisterEnterRectSimple(entersTrigger, GetEntireMapRect())
        call TriggerAddCondition(entersTrigger, Condition(function UnitEntersCondition))
        call TriggerAddAction(entersTrigger, function UnitEntersAction)
        call SaveInteger(HT, GetHandleId(entersTrigger), KEY_ABILITY_ID, abilityId)
        call SaveInteger(HT, GetHandleId(entersTrigger), KEY_CALLBACK, initFunc)

        set ability_id = abilityId
        call GroupEnumUnitsInRect(abilityUnits, GetPlayableMapRect(), Condition(function UnitsWithAbilityFilter))

        loop
            set picked = FirstOfGroup(abilityUnits)
            exitwhen picked == null
            call initFunc.evaluate(picked)
            call GroupRemoveUnit(abilityUnits, picked)
        endloop

        call DestroyGroup(abilityUnits)
    endfunction

endlibrary

library Curves
    function EaseIn takes real t, real power returns real
        return Pow(t, power)
    endfunction

    function EaseInOutQuad takes real t returns real
        if (t < 0.5) then
            return 2 * t * t
        else
            return 1 - Pow(-2 * t + 2, 2) / 2
        endif
    endfunction
endlibrary

globals
    unit array QUICK_SORT_CONTAINER
endglobals

function GroupSortPartition takes integer low, integer high, UnitComparer comparer returns integer
    local unit pivot = QUICK_SORT_CONTAINER[high]
    local unit temp = null
    local integer i = (low - 1)
    local integer j = low
    loop
        exitwhen j > high - 1
        if (comparer.evaluate(QUICK_SORT_CONTAINER[j], pivot) < 0) then
            set i = i + 1
            set temp = QUICK_SORT_CONTAINER[i]
            set QUICK_SORT_CONTAINER[i] = QUICK_SORT_CONTAINER[j]
            set QUICK_SORT_CONTAINER[j] = temp
        endif
        set j = j + 1
    endloop
    set temp = QUICK_SORT_CONTAINER[i + 1]
    set QUICK_SORT_CONTAINER[i + 1] = QUICK_SORT_CONTAINER[high]
    set QUICK_SORT_CONTAINER[high] = temp
    return i + 1
endfunction

function GroupSortRecursive takes integer low, integer high, UnitComparer comparer returns nothing
    local integer partitionIndex = 0
    if (low < high) then
        set partitionIndex = GroupSortPartition(low, high, comparer)
        call GroupSortRecursive(low, partitionIndex - 1, comparer)
        call GroupSortRecursive(partitionIndex + 1, high, comparer)
    endif
endfunction

function GroupSortDestructive takes group whichGroup, UnitComparer comparer, UnitFunc callback returns integer
    local unit pickedUnit = null
    local integer i = 0
    local integer size = 0
    loop
        set pickedUnit = FirstOfGroup(whichGroup)
        exitwhen pickedUnit == null
        set QUICK_SORT_CONTAINER[size] = pickedUnit
        set size = size + 1
        call GroupRemoveUnit(whichGroup, pickedUnit)
    endloop

    call GroupSortRecursive(0, size - 1, comparer)

    if (callback != 0) then
        loop
            exitwhen i >= size
                call callback.evaluate(QUICK_SORT_CONTAINER[i])
            set i = i + 1
        endloop
    endif

    return size
endfunction

library FrameLoader initializer init_function
// in 1.31 and upto 1.32.9 PTR (when I wrote this). Frames are not correctly saved and loaded, breaking the game.
// This library runs all functions added to it with a 0s delay after the game was loaded.
// function FrameLoaderAdd takes code func returns nothing
    // func runs when the game is loaded.
    globals
        private trigger eventTrigger = CreateTrigger()
        private trigger actionTrigger = CreateTrigger()
        private timer t = CreateTimer()
    endglobals
    function FrameLoaderAdd takes code func returns nothing
        call TriggerAddAction(actionTrigger, func)
    endfunction

    private function timerAction takes nothing returns nothing
        call TriggerExecute(actionTrigger)
    endfunction
    private function eventAction takes nothing returns nothing
        call TimerStart(t, 0, false, function timerAction)
    endfunction
    private function init_function takes nothing returns nothing
        call TriggerRegisterGameEvent(eventTrigger, EVENT_GAME_LOADED)
        call TriggerAddAction(eventTrigger, function eventAction)        
    endfunction
endlibrary

library HideMinDamageText initializer init_function requires FrameLoader
// HideMinDamageV3
    globals
        private framehandle DamageA
        private framehandle DamageB
        private framehandle DamageA2
        private framehandle DamageB2
        private framehandle ParentA
        private framehandle ParentB
        private string Text
        private integer Index
        private integer LoopA
        private integer LoopAEnd
    endglobals
    private function find takes nothing returns nothing
        set LoopAEnd = StringLength(Text) - 1
        set LoopA = 1
        loop
            exitwhen LoopA >= LoopAEnd
            if SubString(Text, LoopA, LoopA +3) == " - " then
                set Index = LoopA + 3
                return
            endif
            set LoopA = LoopA + 1
        endloop
        set Index = 0
    endfunction
    
    private function update takes nothing returns nothing
        if BlzFrameIsVisible(ParentA) then
            set Text = BlzFrameGetText(DamageA)
            call find()
            call BlzFrameSetText(DamageA2, SubString(Text, Index, StringLength(Text)))
        endif
        if BlzFrameIsVisible(ParentB) then
            set Text = BlzFrameGetText(DamageB)
            call find()
            call BlzFrameSetText(DamageB2, SubString(Text, Index, StringLength(Text)))
        endif
    endfunction
    private function At0s takes nothing returns nothing
        call BlzLoadTOCFile("war3mapImported\\HideMinDamage.toc")
        set ParentA = BlzGetFrameByName("SimpleInfoPanelIconDamage", 0)
        set ParentB = BlzGetFrameByName("SimpleInfoPanelIconDamage", 1)
        set DamageA = BlzGetFrameByName("InfoPanelIconValue", 0)
        set DamageB = BlzGetFrameByName("InfoPanelIconValue", 1)
        call BlzCreateSimpleFrame("CustomDamageString", ParentA, 0)
        set DamageA2 = BlzGetFrameByName("CustomDamageStringValue", 0)
        call BlzCreateSimpleFrame("CustomDamageString", ParentB, 1)
        set DamageB2 = BlzGetFrameByName("CustomDamageStringValue", 1)
        call BlzFrameSetFont(DamageA, "", 0, 0)
        call BlzFrameSetFont(DamageB, "", 0, 0)
        call TimerStart(GetExpiredTimer(), 0.05, true, function update)
    endfunction
    private function init_function takes nothing returns nothing
        call FrameLoaderAdd(function At0s)
        call TimerStart(CreateTimer(), 0, false, function At0s)
    endfunction
endlibrary

function Trig_HideHeroUI_Actions takes nothing returns nothing
    // Hide the hero attributes (strength, agility, intelligence)
    call BlzFrameSetVisible(BlzGetFrameByName("SimpleInfoPanelIconHeroText", 6), false)
    // Hide the hero attribute icon (primary attribute)
    call BlzFrameSetSize(BlzGetFrameByName("InfoPanelIconHeroIcon", 6), 0.00001, 0.00001)
    // Hide the hero exp bar tooltip
    call BlzFrameSetTooltip(BlzGetFrameByName("SimpleHeroLevelBar", 0), BlzCreateFrameByType("SIMPLEFRAME", "", BlzGetOriginFrame(ORIGIN_FRAME_GAME_UI, 0), "", 0))
endfunction

//===========================================================================
function InitTrig_HideHeroUI takes nothing returns nothing
    set gg_trg_HideHeroUI = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_HideHeroUI, 0.00 )
    call TriggerAddAction( gg_trg_HideHeroUI, function Trig_HideHeroUI_Actions )
endfunction

library CustomConsoleUI initializer init_function requires optional FrameLoader

    // CustomConsoleUI by Tasyen
    // CustomConsoleUI allows to change the UI during the game, when setuped correctly. This excludes the mouse cursor and the UI sounds.
    // In non reforged it can also not change the Idle worker Button nor the no inventory cover.
    // How to setup this: First you have to make the default Console Textures be hidden that is done in Game Interface.
    //    Set ConsoleTexture01 to ConsoleTexture06 to UI\Widgets\EscMenu\Human\blank-background.blp
    //    The Day of Time clock has hardcoded textures therefore you need to swap it out. That also should be done in Gameinterface.
    //    TimeOfDayIndicator to the model included in this system.
    //    Now export and Import war3mapImported\CustomConsoleUI.toc & war3mapImported\CustomConsoleUI.fdf
    //    Finally you have to set the used textures into local data
        globals
            private framehandle idleWorkerButton
            private framehandle idleWorkerButtonOverlay
            private framehandle idleWorkerButtonOverlayParent
            private framehandle customInventoryCover
            private framehandle customInventoryCoverParent
            public string array data
            public integer array dataCount
            private integer dataPageSize = 11
            public real array x
            public real array y
            // workerFace = true can only be used when you save the map in 1.32.6+
            private constant boolean workerFace = false
        endglobals
    
        function AddCustomConsole takes integer index, string texture returns nothing
            set dataCount[index] = dataCount[index] + 1
            set data[index*dataPageSize + dataCount[index]] = texture
        endfunction
    
        function UseCustomConsole takes player p, integer index returns nothing
            local integer pageValue
            if GetLocalPlayer() != p then
                return
            endif
            if index < 1 then
                set index = GetHandleId(GetPlayerRace(p))
            endif
            set pageValue = index*dataPageSize
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI5T", 0), data[pageValue + 5], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI6T", 0), data[pageValue + 6], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI4T", 0), data[pageValue + 4], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI3T", 0), data[pageValue + 3], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI2TL", 0), data[pageValue + 2], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI2TR", 0), data[pageValue + 2], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI1T", 0), data[pageValue + 1], 0, false)
    
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI1B", 0), data[pageValue + 1], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI2B", 0), data[pageValue + 2], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI3B", 0), data[pageValue + 3], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI4B", 0), data[pageValue + 4], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI5B", 0), data[pageValue + 5], 0, false)
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUI6B", 0), data[pageValue + 6], 0, false)
        
            call BlzFrameSetTexture(BlzGetFrameByName("CustomConsoleUIClock", 0), data[pageValue + 7] ,0, true)
            if GetLocalizedString("REFORGED") != "REFORGED" then
                call BlzFrameSetTexture(BlzGetFrameByName("InventoryCoverTexture", 0), data[pageValue + 8] ,0, true)
                static if workerFace then
                    call BlzFrameSetTexture(idleWorkerButtonOverlay, data[pageValue + 9], 0, false)
                endif
            else
                call BlzFrameSetTexture(customInventoryCover, data[pageValue + 8] ,0, true)
            endif
            call BlzFrameSetPoint(BlzGetFrameByName("CustomConsoleUIClock", 0), FRAMEPOINT_TOP, BlzGetFrameByName("ConsoleUI", 0), FRAMEPOINT_TOP, x[index], y[index])       
        endfunction
    
        function CreateCustomConsole takes nothing returns nothing
            call BlzLoadTOCFile( "war3mapimported\\CustomConsoleUI.toc" )
            
            call BlzCreateSimpleFrame( "CustomConsoleUI", BlzGetFrameByName("ConsoleUI", 0), 0)
            call BlzFrameSetLevel(BlzGetFrameByName("CustomConsoleUI", 0), 0)
            if GetLocalizedString("REFORGED") != "REFORGED" then
                // Requires a native existing only in Reforged
                static if workerFace then
                    set idleWorkerButton = BlzFrameGetChild(BlzGetFrameByName("ConsoleUI", 0), 7)
                    set idleWorkerButtonOverlayParent = BlzCreateSimpleFrame( "SimpleTextureFrame", idleWorkerButton, 0 )
                    set idleWorkerButtonOverlay = BlzGetFrameByName("SimpleTextureFrameValue", 0)
                    call BlzFrameSetAllPoints(idleWorkerButtonOverlay, idleWorkerButton)
                    call BlzFrameSetLevel(idleWorkerButtonOverlayParent, 4)
                endif
            else
                set customInventoryCoverParent = BlzCreateSimpleFrame( "SimpleTextureFrame", BlzGetFrameByName("ConsoleUI", 0), 0)
                call BlzFrameSetLevel(customInventoryCoverParent, 4)
                set customInventoryCover = BlzGetFrameByName("SimpleTextureFrameValue", 0)
                call BlzFrameSetAbsPoint(customInventoryCover, FRAMEPOINT_BOTTOMRIGHT, 0.6, 0)
                call BlzFrameSetAbsPoint(customInventoryCover, FRAMEPOINT_TOPLEFT, 0.6 - 0.128, 0.2558)
            endif
    
            // Preload
            call BlzGetOriginFrame(ORIGIN_FRAME_ITEM_BUTTON, 0)
            call BlzGetFrameByName("InventoryCoverTexture", 0)
            call BlzGetFrameByName("CustomConsoleUIClock", 0)
            call BlzGetFrameByName("CustomConsoleUI5T", 0)
            call BlzGetFrameByName("CustomConsoleUI6T", 0)
            call BlzGetFrameByName("CustomConsoleUI4T", 0)
            call BlzGetFrameByName("CustomConsoleUI3T", 0)
            call BlzGetFrameByName("CustomConsoleUI2TL", 0)
            call BlzGetFrameByName("CustomConsoleUI2TR", 0)
            call BlzGetFrameByName("CustomConsoleUI1T", 0)
            call BlzGetFrameByName("CustomConsoleUI1B", 0)
            call BlzGetFrameByName("CustomConsoleUI2B", 0)
            call BlzGetFrameByName("CustomConsoleUI3B", 0)
            call BlzGetFrameByName("CustomConsoleUI4B", 0)
            call BlzGetFrameByName("CustomConsoleUI5B", 0)
            call BlzGetFrameByName("CustomConsoleUI6B", 0)
        endfunction
        private function Init takes nothing returns nothing
            call CreateCustomConsole()
            call UseCustomConsole(GetLocalPlayer(), 0)
        endfunction
        private function at0s takes nothing returns nothing
            call Init()
            call DestroyTimer(GetExpiredTimer())
        endfunction
        private function update takes nothing returns nothing
            call BlzFrameSetVisible(customInventoryCoverParent, not BlzFrameIsVisible(BlzGetOriginFrame(ORIGIN_FRAME_ITEM_BUTTON, 0)))
        endfunction
    
        private function init_function takes nothing returns nothing
            local integer index = 0

            set index = 0
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile01")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile02")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile03")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile04")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile05")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile06")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile-timeindicatorframe")
            call AddCustomConsole(index, "ui\\console\\human\\humanuitile-inventorycover")
            //call AddCustomConsole(index, "ReplaceableTextures\\CommandButtons\\BTNPeasant")
            // offset this mostly is used to fit to the glowing orbs showing the houers
            set x[index] = 0.0009
            set y[index] = 0.0

            set index = 1
            call AddCustomConsole(index, "war3mapImported\\orderuitile01.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile02.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile03.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile04.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile05.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile06.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile-timeindicatorframe.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile-inventorycover.dds")
            //call AddCustomConsole(index, "ReplaceableTextures\\CommandButtons\\BTNPeasant")
            set x[index] = 0.0009
            set y[index] = 0.0
    
            set index = 2
            call AddCustomConsole(index, "war3mapImported\\natureuitile01.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile02.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile03.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile04.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile05.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile06.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile-timeindicatorframe.dds")
            call AddCustomConsole(index, "war3mapImported\\natureuitile-inventorycover.dds")
            //call AddCustomConsole(index, "ReplaceableTextures\\CommandButtons\\BTNPeasant")
            set x[index] = 0.0009
            set y[index] = 0.0
    
            set index = 3
            call AddCustomConsole(index, "war3mapImported\\deathuitile01.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile02.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile03.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile04.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile05.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile06.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile-timeindicatorframe.dds")
            call AddCustomConsole(index, "war3mapImported\\deathuitile-inventorycover.dds")
            //call AddCustomConsole(index, "ReplaceableTextures\\CommandButtons\\BTNPeasant")
            set x[index] = 0.0009
            set y[index] = 0.0
    
            set index = 4
            call AddCustomConsole(index, "war3mapImported\\orderuitile01.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile02.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile03.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile04.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile05.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile06.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile-timeindicatorframe.dds")
            call AddCustomConsole(index, "war3mapImported\\orderuitile-inventorycover.dds")
            //call AddCustomConsole(index, "ReplaceableTextures\\CommandButtons\\BTNPeasant")
            set x[index] = 0.0009
            set y[index] = 0.0
    
            
            if GetLocalizedString("REFORGED") == "REFORGED" then
                call TimerStart(CreateTimer(), 1/32.0, true, function update)
            endif
            call TimerStart(CreateTimer(), 0, false, function at0s)
            static if LIBRARY_FrameLoader then
                call FrameLoaderAdd(function Init)
            endif
        endfunction
    endlibrary
    

function Trig_Preload_Models_Actions takes nothing returns nothing
    local effect model = AddSpecialEffect("war3mapImported\\Eternitys_Crown_1537.mdx", 0.0, 0.0)
    call BlzSetSpecialEffectTimeScale(model, 1000)
    call DestroyEffect(model)

    set model = AddSpecialEffect("war3mapImported\\ZombiePlagueAOE", 0.0, 0.0)
    call BlzSetSpecialEffectTimeScale(model, 1000)
    call DestroyEffect(model)
endfunction

//===========================================================================
function InitTrig_Preload_Models takes nothing returns nothing
    set gg_trg_Preload_Models = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Preload_Models, function Trig_Preload_Models_Actions )
endfunction

globals
    constant integer DEATH_STARTING_WORKER_COUNT = 3
endglobals

function Trig_Starting_Units_Death_Actions takes nothing returns nothing
    local boolexpr goldMineFilter = Condition(function GoldMineFilter)
    local group goldMines = CreateGroup()
    local unit goldMine = null
    local real x = GetPlayerStartLocationX(udg_Player_Temp)
    local real y = GetPlayerStartLocationY(udg_Player_Temp)
    local real unitX = x
    local real unitY = y
    local real angle = 0.0
    local real dist = 0.0
    local unit lastUnit = null
    local integer index = 0

    call CreateUnit(udg_Player_Temp, SB_NECROPOLIS, x, y, bj_UNIT_FACING)
    call GroupEnumUnitsInRange(goldMines, x, y, 1000.0, goldMineFilter)

    set goldMine = GroupPickClosestUnit(goldMines, x, y)
    if (goldMine != null) then
        set dist = DistanceBetweenPointsXY(x, y, GetUnitX(goldMine), GetUnitY(goldMine))
        set angle = AngleBetweenPointsXY(x, y, GetUnitX(goldMine), GetUnitY(goldMine))
        set unitX = PolarProjectionX(x, dist * 0.5, angle)
        set unitY = PolarProjectionY(y, dist * 0.5, angle)
    endif

    //set lastUnit = CreateUnit(udg_Player_Temp, SB_NECROMANCER, unitX, unitY, bj_UNIT_FACING)
    //call IssueImmediateOrder(lastUnit, "unroot")

    loop
        exitwhen index >= DEATH_STARTING_WORKER_COUNT
        set angle = index * (360.0 / DEATH_STARTING_WORKER_COUNT)
        call CreateUnit(udg_Player_Temp, SB_LOST_SOUL, PolarProjectionX(unitX, 75.0, angle), PolarProjectionY(unitY, 75.0, angle), bj_UNIT_FACING)
        set index = index + 1
    endloop
endfunction

//===========================================================================
function InitTrig_Starting_Units_Death takes nothing returns nothing
    set gg_trg_Starting_Units_Death = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Starting_Units_Death, function Trig_Starting_Units_Death_Actions )
endfunction

function Trig_Starting_Units_Nature_Actions takes nothing returns nothing
    local player p = udg_Player_Temp
    local real startX = GetPlayerStartLocationX(p)
    local real startY = GetPlayerStartLocationY(p)
    local unit hq = CreateUnit(p, SB_HOLD, startX, startY, bj_UNIT_FACING)
    local boolexpr goldMineFilter = Condition(function GoldMineFilter)
    local group nearbyMines = CreateGroup()
    local unit pickedMine = null
    local real startingUnitsCenterX = 0.0
    local real startingUnitsCenterY = 0.0
    local real placementX = 0.0
    local real placementY = 0.0
    local real angle = 0.0
    local real dist = 0.0
    local real index = 0

    call GroupEnumUnitsInRange(nearbyMines, startX, startY, 1000.0, goldMineFilter)
    set pickedMine = GroupPickClosestUnit(nearbyMines, startX, startY)

    if (pickedMine != null) then
        set dist = DistanceBetweenUnits(hq, pickedMine) * 0.5
        set angle = AngleBetweenUnits(hq, pickedMine)
        set startingUnitsCenterX = PolarProjectionX(startX, dist, angle)
        set startingUnitsCenterY = PolarProjectionY(startY, dist, angle)
    else
        set startingUnitsCenterX = PolarProjectionX(startX, 250.0, bj_UNIT_FACING)
        set startingUnitsCenterY = PolarProjectionY(startY, 250.0, bj_UNIT_FACING)
    endif

    set angle = AngleBetweenUnits(pickedMine, hq)
    set placementX = PolarProjectionX(startingUnitsCenterX, 75.0, angle)
    set placementY = PolarProjectionY(startingUnitsCenterY, 75.0, angle)
    call CreateUnit(p, SB_DENDROID_TREEHERD, placementX, placementY, bj_UNIT_FACING)

    set angle = AngleBetweenUnits(hq, pickedMine) + 60.0
    set placementX = PolarProjectionX(startingUnitsCenterX, 75.0, angle)
    set placementY = PolarProjectionY(startingUnitsCenterY, 75.0, angle)
    call CreateUnit(p, SB_ELVEN_ARTISAN, startingUnitsCenterX, startingUnitsCenterY, bj_UNIT_FACING)

    set angle = AngleBetweenUnits(hq, pickedMine) - 60.0
    set placementX = PolarProjectionX(startingUnitsCenterX, 75.0, angle)
    set placementY = PolarProjectionY(startingUnitsCenterY, 75.0, angle)
    call CreateUnit(p, SB_ELVEN_ARTISAN, placementX, placementY, bj_UNIT_FACING)

    if (GetPlayerController(p) == MAP_CONTROL_COMPUTER) then
        call StartMeleeAI(p, "war3mapImported/SBNatureAI.ai")
        //call StartNatureAIForPlayer(p)
    endif

    call DestroyGroup(nearbyMines)
    call DestroyBoolExpr(goldMineFilter)
endfunction

//===========================================================================
function InitTrig_Starting_Units_Nature takes nothing returns nothing
    set gg_trg_Starting_Units_Nature = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Starting_Units_Nature, function Trig_Starting_Units_Nature_Actions )
endfunction

function SetRaceForPlayer takes integer playerNumber, integer raceNumber returns nothing
    set udg_String_PlayerRaceName[playerNumber] = udg_String_RaceNames[raceNumber]
    set udg_Int_Race[playerNumber] = raceNumber
endfunction

function SetAIPlayerRaceSelections takes nothing returns nothing
    local integer playerNumber = 1
    local player thisPlayer = null

    loop
        exitwhen playerNumber > GetBJMaxPlayers()
        set thisPlayer = ConvertedPlayer(playerNumber)
        if (GetPlayerSlotState(thisPlayer) == PLAYER_SLOT_STATE_PLAYING and GetPlayerController(thisPlayer) == MAP_CONTROL_COMPUTER) then
            // For now set all AI players to order.
            if(GetPlayerRace(thisPlayer) == RACE_NIGHTELF)then
                call SetRaceForPlayer(playerNumber, udg_Int_RaceNum_Nature)
            else
                call SetRaceForPlayer(playerNumber, udg_Int_RaceNum_Order)
            endif
        endif
        set playerNumber = playerNumber + 1
    endloop
endfunction

function SetRaceMultiboardVisibility takes player whichPlayer, boolean flag returns nothing
    local integer playerIndex = GetPlayerId(whichPlayer)
    set udg_Bool_RaceMultiboardVisState[playerIndex] = flag
    if (GetLocalPlayer() == whichPlayer) then
        call MultiboardDisplay(udg_Multiboard_RaceSelection, flag)
    endif
endfunction

function GetRaceMultiboardVisibility takes player whichPlayer returns boolean
    local integer playerIndex = GetPlayerId(whichPlayer)
    return udg_Bool_RaceMultiboardVisState[playerIndex]
endfunction

function SetRaceMultiboardVisibilityAll takes boolean flag returns nothing
    local integer p = 0
    loop
        exitwhen p >= GetBJMaxPlayers()
        set udg_Bool_RaceMultiboardVisState[p] = flag
        set p = p + 1
    endloop

    call MultiboardDisplay(udg_Multiboard_RaceSelection, flag)
endfunction

function GetSelectionStatus takes integer raceIndex returns string
    if (raceIndex > 0 and raceIndex <= udg_Int_RaceCount) then
        return "|cff00c000Ready|r"
    else
        return "|cff808080Waiting...|r"
    endif
endfunction

function SetRaceSelectionMultiboardRowForPlayer takes player p, string selection returns nothing
    local integer playerNumber = GetConvertedPlayerId(p)
    local string playerName = GetPlayerNameColored(p)

    call MultiboardSetItemValueBJ(udg_Multiboard_RaceSelection, 1, playerNumber, playerName)
    call MultiboardSetItemWidthBJ(udg_Multiboard_RaceSelection, 1, playerNumber, 12.0)
    call MultiboardSetItemValueBJ(udg_Multiboard_RaceSelection, 2, playerNumber, selection)
    call MultiboardSetItemWidthBJ(udg_Multiboard_RaceSelection, 2, playerNumber, 4.25)
endfunction

function SetRaceSelectionMultiboardRow takes nothing returns nothing
    call SetRaceSelectionMultiboardRowForPlayer(GetEnumPlayer(), GetSelectionStatus(udg_Int_Race[GetConvertedPlayerId(GetEnumPlayer())]))
endfunction

function CreateRaceSelectionMultiboard takes nothing returns nothing
    local force players = GetPlayingPlayers(false, false, false)
    local integer playerCount = CountPlayersInForceBJ(players)

    if (playerCount > 0) then
        set udg_Multiboard_RaceSelection = CreateMultiboardBJ(2, playerCount, udg_String_RSMBTitle)
        call MultiboardSetItemsStyle(udg_Multiboard_RaceSelection, true, false)
        call ForForce(players, function SetRaceSelectionMultiboardRow)
        call MultiboardMinimizeBJ(false, udg_Multiboard_RaceSelection)
	call SetRaceMultiboardVisibilityAll(true)
    endif
    call DestroyForce(players)
endfunction

function CreateRaceMenu takes nothing returns nothing
    local integer pIndex = 0
    local player thisPlayer = null
    local integer rIndex = 1

    call DialogSetMessageBJ(udg_Dialog_RaceSelection, "Choose your alignment:")
    loop
        exitwhen rIndex > udg_Int_RaceCount
        set udg_DialogButton_RaceSelection[rIndex] = DialogAddButtonBJ(udg_Dialog_RaceSelection, udg_String_RaceNames[rIndex])
        set rIndex = rIndex + 1
    endloop
    set udg_DialogButton_RaceSelection[udg_Int_RaceNum_Random] = DialogAddButtonBJ(udg_Dialog_RaceSelection, udg_String_RaceNames[udg_Int_RaceNum_Random])

    loop
        exitwhen pIndex >= GetBJMaxPlayers()
        set thisPlayer = Player(pIndex)
        if (GetPlayerSlotState(thisPlayer) == PLAYER_SLOT_STATE_PLAYING and GetPlayerController(thisPlayer) == MAP_CONTROL_USER) then
            call DialogDisplayBJ(true, udg_Dialog_RaceSelection, thisPlayer)
        endif
        set pIndex = pIndex + 1
    endloop
endfunction

globals
    constant real RACE_SELECTION_TEXT_DURATION = 15.0
endglobals

function AllPlayersReady takes nothing returns nothing
    local integer playerNumber = 1
    local player thisPlayer = null

    call DisableTrigger(gg_trg_Race_Selection_Timer_Loop)
    call MultiboardSetTitleText(udg_Multiboard_RaceSelection, udg_String_RSMBTitle)

    call TriggerSleepAction( 1.00 )

    call ClearTextMessages()
    call DisplayTimedTextToForce( GetPlayersAll(), RACE_SELECTION_TEXT_DURATION, "|cffffcc00Welcome to Spellbringers, hosted by |cff00ccffhiveworkshop.com!|r|r" )

    loop
        exitwhen playerNumber > GetBJMaxPlayers()
        set thisPlayer = ConvertedPlayer(playerNumber)
        if (GetPlayerSlotState(thisPlayer) == PLAYER_SLOT_STATE_PLAYING) then
            if (udg_Int_Race[playerNumber] <= 0) then    // Random
                set udg_Int_Race[playerNumber] = GetRandomInt(1, udg_Int_RaceCount)
            endif
            call SetRaceSelectionMultiboardRowForPlayer(thisPlayer, udg_String_PlayerRaceName[playerNumber])
            call DisplayTimedTextToForce(GetPlayersAll(), RACE_SELECTION_TEXT_DURATION, " • " + GetPlayerNameColored(thisPlayer) + " has chosen " + udg_String_PlayerRaceName[playerNumber] + ".")
            set udg_Player_Temp = thisPlayer
            call ConditionalTriggerExecute(udg_Trigger_StartingUnits[udg_Int_Race[playerNumber]])
        endif
        set playerNumber = playerNumber + 1
    endloop


    call EnableTrigger(gg_trg_Hide_Race_Selection_Multiboard)
    call BeginGameTimer()
    call StartTimerBJ(udg_Timer_DestroyRSMultiboard, false, 10.0)
    //call ConditionalTriggerExecute( gg_trg_Game_Clock_Initialization )
    call MeleeInitVictoryDefeat()
endfunction

function AreAllPlayersReady takes nothing returns boolean
    local integer playerNumber = 1

    loop
        exitwhen playerNumber > GetBJMaxPlayers()
        if (GetPlayerSlotState(ConvertedPlayer(playerNumber)) == PLAYER_SLOT_STATE_PLAYING and udg_Int_Race[playerNumber] == -1) then
            return false
        endif
        set playerNumber = playerNumber + 1
    endloop

    return true
endfunction

function Trig_Race_Selection_Actions takes nothing returns nothing
    call SetAIPlayerRaceSelections()
    call CreateRaceSelectionMultiboard()
    if (not AreAllPlayersReady()) then
        call CreateRaceMenu()
        call EnableTrigger(gg_trg_Race_Selection_Timer_Loop)
        call DisplayTextToForce( GetPlayersAll(), "|cffffcc00Waiting for all players to choose their alignments...|r" )
    else
        call AllPlayersReady()
    endif
endfunction

//===========================================================================
function InitTrig_Race_Selection takes nothing returns nothing
    set gg_trg_Race_Selection = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_Race_Selection, 2.00 )
    call TriggerAddAction( gg_trg_Race_Selection, function Trig_Race_Selection_Actions )
endfunction

globals
    constant real RACE_SELECTION_TIMER_LOOP_INTERVAL = 1.0
endglobals

function Trig_Race_Selection_Timer_Loop_Expired takes nothing returns nothing
    local integer playerNum = 1
    local player thisPlayer = null

    loop
        exitwhen playerNum > GetBJMaxPlayers()
        set thisPlayer = ConvertedPlayer(playerNum)
        if (udg_Int_Race[playerNum] == -1) then
            if (GetPlayerSlotState(thisPlayer) == PLAYER_SLOT_STATE_LEFT or GetPlayerSlotState(thisPlayer) == PLAYER_SLOT_STATE_PLAYING) then
                call SetRaceForPlayer(playerNum, udg_Int_RaceNum_Random)
                call DialogDisplayBJ(false, udg_Dialog_RaceSelection, thisPlayer)
            endif
        endif
        set playerNum = playerNum + 1
    endloop

    call DisableTrigger(GetTriggeringTrigger())
    call AllPlayersReady()
endfunction

function Trig_Race_Selection_Timer_Loop_Actions takes nothing returns nothing
    local string mbTitle = udg_String_RSMBTitle + " (|cffffffff" + GetFormattedTimeString(udg_Real_RaceSelectionTime) + "|r)"
    call MultiboardSetTitleText(udg_Multiboard_RaceSelection, mbTitle)

    if (udg_Real_RaceSelectionTime > 0.0) then
        set udg_Real_RaceSelectionTime = udg_Real_RaceSelectionTime - RACE_SELECTION_TIMER_LOOP_INTERVAL
    else
        call Trig_Race_Selection_Timer_Loop_Expired()
    endif
endfunction

//===========================================================================
function InitTrig_Race_Selection_Timer_Loop takes nothing returns nothing
    set gg_trg_Race_Selection_Timer_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Race_Selection_Timer_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Race_Selection_Timer_Loop, RACE_SELECTION_TIMER_LOOP_INTERVAL )
    call TriggerAddAction( gg_trg_Race_Selection_Timer_Loop, function Trig_Race_Selection_Timer_Loop_Actions )
endfunction

function Trig_Race_Selection_Click_Actions takes nothing returns nothing
    local integer rIndex = 0
    local integer playerNumber = GetConvertedPlayerId(GetTriggerPlayer())

    call DialogDisplayBJ(false, udg_Dialog_RaceSelection, GetTriggerPlayer())
    loop
        exitwhen rIndex > udg_Int_RaceCount
        if (GetClickedButtonBJ() == udg_DialogButton_RaceSelection[rIndex]) then
            call SetRaceForPlayer(playerNumber, rIndex)
            call SetRaceSelectionMultiboardRowForPlayer(GetTriggerPlayer(), GetSelectionStatus(udg_Int_Race[playerNumber]))
            exitwhen true
        endif
        set rIndex = rIndex + 1
    endloop

    if (AreAllPlayersReady()) then
	call AllPlayersReady()
    else
        call DisplayTextToPlayer(GetTriggerPlayer(), 0, 0, "Waiting for other players...")
    endif
endfunction

//===========================================================================
function InitTrig_Race_Selection_Click takes nothing returns nothing
    set gg_trg_Race_Selection_Click = CreateTrigger(  )
    call TriggerRegisterDialogEventBJ(gg_trg_Race_Selection_Click, udg_Dialog_RaceSelection)
    call TriggerAddAction( gg_trg_Race_Selection_Click, function Trig_Race_Selection_Click_Actions )
endfunction

function Trig_Hide_Race_Selection_Multiboard_Actions takes nothing returns nothing
    call SetRaceMultiboardVisibilityAll(false)
    call CreateGameClock()
    call DestroyTimer(udg_Timer_DestroyRSMultiboard)
    call EnableTrigger(gg_trg_Toggle_Races_Multiboard)
    call DisableTrigger(GetTriggeringTrigger())
endfunction

//===========================================================================
function InitTrig_Hide_Race_Selection_Multiboard takes nothing returns nothing
    set gg_trg_Hide_Race_Selection_Multiboard = CreateTrigger(  )
    call DisableTrigger( gg_trg_Hide_Race_Selection_Multiboard )
    call TriggerRegisterTimerExpireEventBJ( gg_trg_Hide_Race_Selection_Multiboard, udg_Timer_DestroyRSMultiboard )
    call TriggerAddAction( gg_trg_Hide_Race_Selection_Multiboard, function Trig_Hide_Race_Selection_Multiboard_Actions )
endfunction

library ArmySystemCommon

    // Determines whether a unit should be included in army commands. This should work fine by default,
    // however, you may wish to add a way to force a unit to be in the army if it normally woudn't be, or
    // vice versa.
    public function IsArmyUnit takes unit whichUnit returns boolean
        if (GetUnitDefaultMoveSpeed(whichUnit) <= 0.0) then
            return false
        elseif (GetUnitAbilityLevel(whichUnit, 'Aloc') > 0) then
            return false
        elseif (GetUnitAbilityLevel(whichUnit, SB_ARMY_TOGGLE_REMOVE) > 0) then
            return true
        elseif (IsUnitType(whichUnit, UNIT_TYPE_PEON)) then
            return false
        elseif (IsUnitType(whichUnit, UNIT_TYPE_STRUCTURE)) then
            return false
        elseif (not (IsUnitType(whichUnit, UNIT_TYPE_MELEE_ATTACKER) or IsUnitType(whichUnit, UNIT_TYPE_RANGED_ATTACKER))) then
            return false
        elseif (GetUnitPropWindow(whichUnit) <= 0.0) then
            return false
        endif
        return true
    endfunction

endlibrary

library ArmySystemConfig initializer Init requires ArmyCommands, ArmyToggle

    private function Init takes nothing returns nothing

        // Determines which ability will cause army units to attack.
        call ArmyCommands_SetAttackArmyAbility(SB_ATTACK_ARMY)
        // Determines which ability will cause army units to move.
        call ArmyCommands_SetMoveArmyAbility(SB_MOVE_ARMY)

        // IMPORTANT CONFIG:
        // -- What is a command bucket? --
        //    A command bucket is a way to group units together when issuing army commands.
        //    It works by grouping units of similar movement speeds together. The more buckets
        //    you have, the more responsive your commands will feel. However, more buckets will
        //    also increase the chance that your commands will cause units to bug out (because of an overload of commands.)
        //    Four or five should be enough, depending on how many units an army will likely contain.
        // -- NOTE --
        //    Buckets must be added in order from slowest to fastest.
        call ArmyCommands_AddCommandBucket(150.0)  // Very slow
        call ArmyCommands_AddCommandBucket(300.0)  // Slow
        call ArmyCommands_AddCommandBucket(450.0)  // Average
        call ArmyCommands_AddCommandBucket(600.0)  // Fast

        // When adding or removing a unit from an army via user input, these models can be added to the unit
        // to identify which units have been added to or removed from the army.
        call ArmySystem_SetAddedToArmyEffectModel("Abilities\\Spells\\ArmyStatus\\ArmyStatusAdded.mdl", "overhead")
        call ArmySystem_SetRemovedFromArmyEffectModel("Abilities\\Spells\\ArmyStatus\\ArmyStatusRemoved.mdl", "overhead")

        // Determines which ability can force a non-army unit into the army when activated.
        call ArmyToggle_SetAddArmyAbility(SB_ARMY_TOGGLE_ADD, OrderId("defend"))
        // Determines which ability will undo the above action.
        call ArmyToggle_SetUnAddArmyAbility(SB_ARMY_TOGGLE_ADD, OrderId("undefend"))

        // Determines which ability can force an army unit out of the army when activated.
        call ArmyToggle_SetRemoveArmyAbility(SB_ARMY_TOGGLE_REMOVE, OrderId("defend"))
        // Determines which ability will undo the above action.
        call ArmyToggle_SetUnRemoveArmyAbility(SB_ARMY_TOGGLE_REMOVE, OrderId("undefend"))
    endfunction

endlibrary

library ArmySystem initializer Init requires ArmySystemCommon
    globals
        private constant hashtable HT = InitHashtable()
        private constant key KEY_COUNTER
        private constant key KEY_EFFECT

        private string ADDED_EFFECT_MODEL = null
        private string ADDED_EFFECT_AP = null

        private string REMOVED_EFFECT_MODEL = null
        private string REMOVED_EFFECT_AP = null
    endglobals

    // ************************************
    //          PRIVATE FUNCTIONS
    // ************************************

    private function AddArmyEffect takes unit whichUnit, string effectModel, string attachmentPoint returns effect
        local effect vfx = LoadEffectHandle(HT, GetHandleId(whichUnit), KEY_EFFECT)
        if (vfx == null) then
            if (GetLocalPlayer() != GetOwningPlayer(whichUnit)) then
                set effectModel = ""
            endif
            set vfx = AddSpecialEffectTarget(effectModel, whichUnit, attachmentPoint)
            call SaveEffectHandle(HT, GetHandleId(whichUnit), KEY_EFFECT, vfx)
        endif
        return vfx
    endfunction

    private function DestroyArmyEffect takes unit whichUnit returns nothing
        local effect vfx = LoadEffectHandle(HT, GetHandleId(whichUnit), KEY_EFFECT)
        call DestroyEffect(vfx)
        call RemoveSavedHandle(HT, GetHandleId(whichUnit), KEY_EFFECT)
    endfunction

    private function GetCounter takes unit whichUnit returns integer
        return LoadInteger(HT, GetHandleId(whichUnit), KEY_COUNTER)
    endfunction

    private function ChangeCounter takes unit whichUnit, integer delta, boolean showEffect returns integer
        local integer counter = GetCounter(whichUnit) + delta
        if (counter == 0) then
            call DestroyArmyEffect(whichUnit)
            call RemoveSavedInteger(HT, GetHandleId(whichUnit), KEY_COUNTER)
        else
            call SaveInteger(HT, GetHandleId(whichUnit), KEY_COUNTER, counter)
            if (showEffect and counter > 0) then
                call AddArmyEffect(whichUnit, ADDED_EFFECT_MODEL, ADDED_EFFECT_AP)
            elseif (showEffect and counter < 0) then
                call AddArmyEffect(whichUnit, REMOVED_EFFECT_MODEL, REMOVED_EFFECT_AP)
            endif
        endif
        return counter
    endfunction

    // ************************************
    //              PUBLIC API
    // ************************************

    public function SetAddedToArmyEffectModel takes string model, string attachmentPoint returns nothing
        set ADDED_EFFECT_MODEL = model
        set ADDED_EFFECT_AP = attachmentPoint
    endfunction

    public function SetRemovedFromArmyEffectModel takes string model, string attachmentPoint returns nothing
        set REMOVED_EFFECT_MODEL = model
        set REMOVED_EFFECT_AP = attachmentPoint
    endfunction

    public function IsUnitAddedToArmy takes unit whichUnit returns boolean
        return GetCounter(whichUnit) > 0
    endfunction

    public function IsUnitRemovedFromArmy takes unit whichUnit returns boolean
        return GetCounter(whichUnit) < 0
    endfunction

    public function AddUnitToArmy takes unit whichUnit, boolean showEffect returns nothing
        call ChangeCounter(whichUnit, 1, showEffect)
    endfunction

    public function UnAddUnitToArmy takes unit whichUnit, boolean showEffect returns nothing
        local integer counter = GetCounter(whichUnit)
        if (counter > 0) then
            call ChangeCounter(whichUnit, -1, showEffect)
        endif
    endfunction

    public function RemoveUnitFromArmy takes unit whichUnit, boolean showEffect returns nothing
        call ChangeCounter(whichUnit, -1, showEffect)
    endfunction

    public function UnRemoveUnitFromArmy takes unit whichUnit, boolean showEffect returns nothing
        local integer counter = GetCounter(whichUnit)
        if (counter < 0) then
            call ChangeCounter(whichUnit, 1, showEffect)
        endif
    endfunction

    public function GetUnitArmyCounter takes unit whichUnit returns integer
        return GetCounter(whichUnit)
    endfunction

    // ************************************
    //              TRIGGERS
    // ************************************

    private function OnUnitDies takes nothing returns nothing
        local unit dying = GetDyingUnit()
        call DestroyArmyEffect(dying)
        call FlushChildHashtable(HT, GetHandleId(dying))
    endfunction

    // ************************************
    //            INITIALIZATION
    // ************************************

    private function Init takes nothing returns nothing
        local trigger t = null

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_DEATH)
        call TriggerAddAction(t, function OnUnitDies)
    endfunction

endlibrary

library ArmyCommands initializer Init requires ArmySystem, ArmySystemCommon

    globals
        private integer ABILITY_ATTACK_ARMY = 0
        private integer ABILITY_MOVE_ARMY = 0

        private constant real array CB_MS_LIMITS
        private constant group array COMMANDBUCKETS
        private integer BUCKET_COUNT = 0

        private constant integer array unitCounter
    endglobals

    // ************************************
    //              PUBLIC API
    // ************************************

    public function AddCommandBucket takes real msLimit returns nothing
        set CB_MS_LIMITS[BUCKET_COUNT] = msLimit
        set COMMANDBUCKETS[BUCKET_COUNT] = CreateGroup()
        set BUCKET_COUNT = BUCKET_COUNT + 1
    endfunction

    public function SetAttackArmyAbility takes integer abilityId returns nothing
        set ABILITY_ATTACK_ARMY = abilityId
    endfunction

    public function SetMoveArmyAbility takes integer abilityId returns nothing
        set ABILITY_MOVE_ARMY = abilityId
    endfunction

    // ************************************
    //          PRIVATE FUNCTIONS
    // ************************************

    private function ArmyCommandFilter takes nothing returns boolean
        local unit filter = GetFilterUnit()
        if (not IsUnitAliveBJ(filter)) then
            return false
        elseif (ArmySystem_IsUnitAddedToArmy(filter)) then
            return true
        elseif (not ArmySystemCommon_IsArmyUnit(filter)) then
            return false
        elseif (ArmySystem_IsUnitRemovedFromArmy(filter)) then
            return false
        endif
        return true
    endfunction

    private function IsAttackOrder takes integer abilityId returns boolean
        return abilityId == ABILITY_ATTACK_ARMY
    endfunction

    private function IsMoveOrder takes integer abilityId returns boolean
        return abilityId == ABILITY_MOVE_ARMY
    endfunction

    private function ArmyCommandExecOrder takes group commandGroup, string order, real x, real y, widget target returns nothing
        if (target != null) then
            call GroupTargetOrder(commandGroup, order, target)
        else
            call GroupPointOrder(commandGroup, order, x, y)
        endif
        call GroupClear(commandGroup)
    endfunction

    private function ArmyCommandExecute takes player p, string order, real x, real y, widget target returns nothing
        local group armyUnits = GetUnitsOfPlayerMatching(p, Condition(function ArmyCommandFilter))
        local group commandUnits = null
        local real ms = 0.0
        local integer bucketIndex = 0
        local unit pickedUnit = null

        loop
            exitwhen bucketIndex >= BUCKET_COUNT
            set unitCounter[bucketIndex] = 0
            call GroupClear(COMMANDBUCKETS[bucketIndex])
            set bucketIndex = bucketIndex + 1
        endloop

        loop
            set pickedUnit = FirstOfGroup(armyUnits)
            exitwhen pickedUnit == null
            
            call GroupRemoveUnit(armyUnits, pickedUnit)

            set ms = GetUnitMoveSpeed(pickedUnit)
            set bucketIndex = 0
            loop
                exitwhen bucketIndex >= BUCKET_COUNT
                if (ms <= CB_MS_LIMITS[bucketIndex]) then
                    set commandUnits = COMMANDBUCKETS[bucketIndex]
                    exitwhen true
                endif
                set bucketIndex = bucketIndex + 1
            endloop

            set bucketIndex = IMinBJ(bucketIndex, BUCKET_COUNT - 1)

            call GroupAddUnit(commandUnits, pickedUnit)
            set unitCounter[bucketIndex] = unitCounter[bucketIndex] + 1

            if (unitCounter[bucketIndex] >= 12) then
                call ArmyCommandExecOrder(commandUnits, order, x, y, target)
                set unitCounter[bucketIndex] = 0
            endif
        endloop

        set bucketIndex = 0
        loop
            exitwhen bucketIndex >= BUCKET_COUNT
            if (unitCounter[bucketIndex] > 0) then
                call ArmyCommandExecOrder(COMMANDBUCKETS[bucketIndex], order, x, y, target)
                set unitCounter[bucketIndex] = 0
            endif
            set bucketIndex = bucketIndex + 1
        endloop
        
        call DestroyGroup(armyUnits)
    endfunction

    // ************************************
    //              TRIGGERS
    // ************************************

    private function CommandConditions takes nothing returns boolean
        local integer abilityId = GetSpellAbilityId()
        return IsAttackOrder(abilityId) or IsMoveOrder(abilityId)
    endfunction

    private function CommandActions takes nothing returns nothing
        local player p = GetOwningPlayer(GetSpellAbilityUnit())
        local integer abilityId = GetSpellAbilityId()
        local string order = null
        local widget target = GetSpellTargetUnit()

        if (target == null) then
            set target = GetSpellTargetDestructable()
        endif

        if (IsAttackOrder(abilityId)) then
            set order = "attack"
        elseif (GetSpellTargetUnit() != null) then
            set order = "patrol"
        else
            set order = "move"
        endif

        call ArmyCommandExecute(p, order, GetSpellTargetX(), GetSpellTargetY(), target)
    endfunction

    private function SmartCommandConditions takes nothing returns boolean
        local integer orderId = GetIssuedOrderId()
        return orderId == OrderId("smart") or orderId == OrderId("rally")
    endfunction

    private function SmartCommandActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        local player p = GetOwningPlayer(ordered)
        local widget target = GetOrderTarget()
        if (GetUnitAbilityLevel(ordered, ABILITY_ATTACK_ARMY) > 0 and target != null) then
            call ArmyCommandExecute(p, "smart", 0, 0, target)
            call BlzPauseUnitEx(ordered, true)
            call IssueImmediateOrder(ordered, "stop")
            call BlzPauseUnitEx(ordered, false)
        elseif (GetUnitAbilityLevel(ordered, ABILITY_MOVE_ARMY) > 0 and target == null) then
            call ArmyCommandExecute(p, "smart", GetOrderPointX(), GetOrderPointY(), null)
            call BlzPauseUnitEx(ordered, true)
            call IssueImmediateOrder(ordered, "stop")
            call BlzPauseUnitEx(ordered, false)
        endif
    endfunction

    // ************************************
    //            INITIALIZATION
    // ************************************

    private function Init takes nothing returns nothing
        local trigger t = null

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_CAST)
        call TriggerAddCondition(t, Condition( function CommandConditions ))
        call TriggerAddAction(t, function CommandActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
        call TriggerAddCondition(t, Condition( function SmartCommandConditions ))
        call TriggerAddAction(t, function SmartCommandActions)
    endfunction
endlibrary

library ArmyToggle initializer Init requires ArmySystem, ArmySystemCommon

    globals
        private constant hashtable HT = InitHashtable()
        private constant key KEY_HOLDING_POSITION
        private constant key KEY_CHANNELING

        private integer ABILITY_ARMY_TOGGLE_ADD = 0
        private integer ABILITY_ARMY_TOGGLE_REMOVE = 0
        private integer ABILITY_ARMY_TOGGLE_UNADD = 0
        private integer ABILITY_ARMY_TOGGLE_UNREMOVE = 0

        private integer ORDER_ARMY_TOGGLE_ADD = 0
        private integer ORDER_ARMY_TOGGLE_REMOVE = 0
        private integer ORDER_ARMY_TOGGLE_UNADD = 0
        private integer ORDER_ARMY_TOGGLE_UNREMOVE = 0

        private integer ARMY_ADD_CALLBACK = 0
        private integer ARMY_UNADD_CALLBACK = 0

        private integer ARMY_REMOVE_CALLBACK = 0
        private integer ARMY_UNREMOVE_CALLBACK = 0

    endglobals

    // ************************************
    //              PUBLIC API
    // ************************************

    public function interface UnitArmyCallback takes unit whichUnit returns nothing

    public function SetAddArmyAbility takes integer abilityId, integer orderId returns nothing
        set ABILITY_ARMY_TOGGLE_ADD = abilityId
        set ORDER_ARMY_TOGGLE_ADD = orderId
    endfunction

    public function SetUnAddArmyAbility takes integer abilityId, integer orderId returns nothing
        set ABILITY_ARMY_TOGGLE_UNADD = abilityId
        set ORDER_ARMY_TOGGLE_UNADD = orderId
    endfunction

    public function SetRemoveArmyAbility takes integer abilityId, integer orderId returns nothing
        set ABILITY_ARMY_TOGGLE_REMOVE = abilityId
        set ORDER_ARMY_TOGGLE_REMOVE = orderId
    endfunction

    public function SetUnRemoveArmyAbility takes integer abilityId, integer orderId returns nothing
        set ABILITY_ARMY_TOGGLE_UNREMOVE = abilityId
        set ORDER_ARMY_TOGGLE_UNREMOVE = orderId
    endfunction

    public function RegisterAddToArmyCallback takes UnitArmyCallback callback returns nothing
        set ARMY_ADD_CALLBACK = callback
    endfunction

    public function RegisterUnAddToArmyCallback takes UnitArmyCallback callback returns nothing
        set ARMY_UNADD_CALLBACK = callback
    endfunction

    public function RegisterRemoveFromArmyCallback takes UnitArmyCallback callback returns nothing
        set ARMY_REMOVE_CALLBACK = callback
    endfunction

    public function RegisterUnRemoveFromArmyCallback takes UnitArmyCallback callback returns nothing
        set ARMY_UNREMOVE_CALLBACK = callback
    endfunction

    // ************************************
    //              TRIGGERS
    // ************************************

    private function ArmyToggleAddConditions takes nothing returns boolean
        local unit ordered = GetOrderedUnit()
        if (IsUnitDeadBJ(ordered)) then
            return false
        elseif (GetIssuedOrderId() != ORDER_ARMY_TOGGLE_ADD) then
            return false
        elseif (GetUnitAbilityLevel(ordered, ABILITY_ARMY_TOGGLE_ADD) == 0) then
            return false
        endif
        return true
    endfunction

    private function ArmyToggleAddActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        local UnitArmyCallback callback = ARMY_ADD_CALLBACK
        call ArmySystem_AddUnitToArmy(ordered, true)
        if (callback != 0) then
            call callback.evaluate(ordered)
        endif
    endfunction

    private function ArmyToggleUnAddConditions takes nothing returns boolean
        local unit ordered = GetOrderedUnit()
        if (IsUnitDeadBJ(ordered)) then
            return false
        elseif (GetIssuedOrderId() != ORDER_ARMY_TOGGLE_UNADD) then
            return false
        elseif (GetUnitAbilityLevel(ordered, ABILITY_ARMY_TOGGLE_UNADD) == 0) then
            return false
        endif
        return true
    endfunction
    
    private function ArmyToggleUnAddActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        local UnitArmyCallback callback = ARMY_UNADD_CALLBACK
        call ArmySystem_UnAddUnitToArmy(ordered, true)
        if (callback != 0) then
            call callback.evaluate(ordered)
        endif
    endfunction

    private function ArmyToggleRemoveConditions takes nothing returns boolean
        local unit ordered = GetOrderedUnit()
        if (IsUnitDeadBJ(ordered)) then
            return false
        elseif (GetIssuedOrderId() != ORDER_ARMY_TOGGLE_REMOVE) then
            return false
        elseif (GetUnitAbilityLevel(ordered, ABILITY_ARMY_TOGGLE_REMOVE) == 0) then
            return false
        endif
        return true
    endfunction
        
    private function ArmyToggleRemoveActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        local UnitArmyCallback callback = ARMY_REMOVE_CALLBACK
        call ArmySystem_RemoveUnitFromArmy(ordered, true)
        if (callback != 0) then
            call callback.evaluate(ordered)
        endif
    endfunction

    private function ArmyToggleUnRemoveConditions takes nothing returns boolean
        local unit ordered = GetOrderedUnit()
        if (IsUnitDeadBJ(ordered)) then
            return false
        elseif (GetIssuedOrderId() != ORDER_ARMY_TOGGLE_UNREMOVE) then
            return false
        elseif (GetUnitAbilityLevel(ordered, ABILITY_ARMY_TOGGLE_UNREMOVE) == 0) then
            return false
        endif
        return true
    endfunction
    
    function ArmyToggleUnRemoveActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        local UnitArmyCallback callback = ARMY_UNREMOVE_CALLBACK
        call ArmySystem_UnRemoveUnitFromArmy(ordered, true)
        if (callback != 0) then
            call callback.evaluate(ordered)
        endif
    endfunction

    private function HoldPositionConditions takes nothing returns boolean
        return GetIssuedOrderId() == 851993 and not HaveSavedBoolean(HT, KEY_HOLDING_POSITION, GetHandleId(GetOrderedUnit()))
    endfunction
    
    private function HoldPositionActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        call ArmySystem_RemoveUnitFromArmy(GetOrderedUnit(), true)
        call SaveBoolean(HT, KEY_HOLDING_POSITION, GetHandleId(ordered), true)
    endfunction

    private function ReturnToArmyConditions takes nothing returns boolean
        local unit ordered = GetOrderedUnit()
        local integer orderId = GetIssuedOrderId()
        return HaveSavedBoolean(HT, KEY_HOLDING_POSITION, GetHandleId(ordered)) and orderId != 851993 and orderId != ORDER_ARMY_TOGGLE_REMOVE and orderId != ORDER_ARMY_TOGGLE_UNREMOVE
    endfunction
    
    private function ReturnToArmyActions takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        call ArmySystem_UnRemoveUnitFromArmy(ordered, true)
        call RemoveSavedBoolean(HT, KEY_HOLDING_POSITION, GetHandleId(ordered))
    endfunction

    private function SpellChannelConditions takes nothing returns boolean
        local unit caster = GetSpellAbilityUnit()
        return ArmySystem_IsUnitAddedToArmy(caster) or ArmySystemCommon_IsArmyUnit(caster)
    endfunction

    private function SpellChannelActions takes nothing returns nothing
        local unit caster = GetSpellAbilityUnit()
        call ArmySystem_RemoveUnitFromArmy(caster, false)
        call SaveBoolean(HT, KEY_CHANNELING, GetHandleId(caster), true)
    endfunction

    private function SpellChannelStopConditions takes nothing returns boolean
        local unit caster = GetSpellAbilityUnit()
        return HaveSavedBoolean(HT, KEY_CHANNELING, GetHandleId(caster)) or ArmySystemCommon_IsArmyUnit(caster)
    endfunction

    private function SpellChannelStopActions takes nothing returns nothing
        local unit caster = GetSpellAbilityUnit()
        call ArmySystem_UnRemoveUnitFromArmy(caster, false)
        call RemoveSavedHandle(HT, KEY_CHANNELING, GetHandleId(caster))
    endfunction

    private function UnitDiesActions takes nothing returns nothing
        local unit dying = GetDyingUnit()
        call RemoveSavedHandle(HT, KEY_CHANNELING, GetHandleId(dying))
        call RemoveSavedHandle(HT, KEY_HOLDING_POSITION, GetHandleId(dying))
    endfunction

    // ************************************
    //            INITIALIZATION
    // ************************************

    private function Init takes nothing returns nothing
        local trigger t = null

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerAddCondition(t, Condition(function ArmyToggleAddConditions))
        call TriggerAddAction(t, function ArmyToggleAddActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerAddCondition(t, Condition(function ArmyToggleUnAddConditions))
        call TriggerAddAction(t, function ArmyToggleUnAddActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerAddCondition(t, Condition(function ArmyToggleRemoveConditions))
        call TriggerAddAction(t, function ArmyToggleRemoveActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerAddCondition(t, Condition(function ArmyToggleUnRemoveConditions))
        call TriggerAddAction(t, function ArmyToggleUnRemoveActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerAddCondition(t, Condition(function HoldPositionConditions))
        call TriggerAddAction(t, function HoldPositionActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
        call TriggerAddCondition(t, Condition(function ReturnToArmyConditions))
        call TriggerAddAction(t, function ReturnToArmyActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_CHANNEL)
        call TriggerAddCondition(t, Condition(function SpellChannelConditions))
        call TriggerAddAction(t, function SpellChannelActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_ENDCAST)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_FINISH)
        call TriggerAddCondition(t, Condition(function SpellChannelStopConditions))
        call TriggerAddAction(t, function SpellChannelStopActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_DEATH)
        call TriggerAddAction(t, function UnitDiesActions)
    endfunction

endlibrary

scope BuildingSelectionHotkeys initializer Init
    globals
        private integer array SELECTED_UNIT_TYPES[4][10]
        private oskeytype array HOTKEYS
        private integer METAKEY_CTRL = 2 
        private integer METAKEY_CTRLSHIFT = 3
        private integer PRESSED_KEY = 0
    endglobals

    private function interface UnitFilter takes unit whichUnit returns boolean

    private function GetAllBuildingsOfType takes nothing returns boolean
        local player whichPlayer = GetTriggerPlayer()
        local unit u = GetFilterUnit()
        local integer id = GetUnitTypeId(u)
        local integer whichRace = udg_Int_Race[GetConvertedPlayerId(whichPlayer)]
        local UnitFilter filter = SELECTED_UNIT_TYPES[whichRace][PRESSED_KEY]
        return UnitAlive(u) and filter.evaluate(u)
    endfunction

    private function OnBuildingHotkeyPressed takes nothing returns nothing
        local oskeytype pressedKeyType = BlzGetTriggerPlayerKey()
        local player whichPlayer = GetTriggerPlayer()
        local group g = CreateGroup()
        local unit picked = null
        local integer i = 0
                
        loop
            exitwhen i > 4
            if pressedKeyType == HOTKEYS[i] then
                set PRESSED_KEY = i
                exitwhen true
            endif
            set i = i + 1
        endloop

        if (BlzGetTriggerPlayerMetaKey()) == METAKEY_CTRLSHIFT then
            set PRESSED_KEY = PRESSED_KEY + 5
        endif

        call GroupEnumUnitsOfPlayer(g , whichPlayer , Condition(function GetAllBuildingsOfType))

        if (BlzGroupGetSize(g) > 0) then
            if (GetLocalPlayer() == whichPlayer) then
                call ClearSelection()
            endif
            loop
                set picked = FirstOfGroup(g)
                exitwhen picked == null
                if (GetLocalPlayer() == whichPlayer) then
                    call SelectUnit(picked, true)
                endif
                call GroupRemoveUnit(g, picked)
            endloop
        endif
        call DestroyGroup(g)
        set g = null
    endfunction

    private function IsHall takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_CITADEL or unitTypeId == SB_HOLD or unitTypeId == SB_NECROPOLIS or unitTypeId == SB_DARK_NEXUS
    endfunction

    private function IsPrimaryRax takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_BARRACKS or unitTypeId == SB_HALL_OF_WARRIORS
    endfunction

    private function IsSecondaryRax takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_WAR_FACTORY or unitTypeId == SB_HAVEN
    endfunction

    private function IsAirStructure takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_CELESTIAL_BEACON or unitTypeId == SB_CELESTIAL_GATEWAY or unitTypeId == SB_SKY_TOTEM or unitTypeId == SB_DREAD_SPIRE
    endfunction

    private function IsLumberMill takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_LUMBER_MILL or unitTypeId == SB_WAR_MILL
    endfunction

    private function IsHallOfElites takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_HALL_OF_ELITES
    endfunction

    private function IsCryptOrManor takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_CRYPT or unitTypeId == SB_MANOR
    endfunction

    private function IsPrimaryUpgradeStructure takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_BLACKSMITH or unitTypeId == SB_HALL_OF_SCHOLARS or unitTypeId == SB_GRAVEYARD
    endfunction

    private function IsChurch takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_CHURCH
    endfunction

    private function IsScoutTower takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_SCOUT_TOWER
    endfunction

    private function IsDendroidElder takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_DENDROID_ELDER
    endfunction

    private function IsDendroidChieftain takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_DENDROID_CHIEFTAIN
    endfunction

    private function IsProductionStructure takes unit whichUnit returns boolean
        return IsPrimaryRax(whichUnit) or IsSecondaryRax(whichUnit) or IsAirStructure(whichUnit)
    endfunction

    private function IsAltar takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_ALTAR_OF_LIGHT or unitTypeId == SB_ALTAR_OF_NATURE or unitTypeId == SB_ALTAR_OF_DARKNESS
    endfunction

    private function IsIdleNecromancer takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        if (BlzGetUnitBooleanField(whichUnit, UNIT_BF_IS_A_BUILDING) == true) then
            return false
        endif
        return unitTypeId == SB_NECROMANCER or unitTypeId == SB_NECROMANCER_LICH
    endfunction

    private function IsTrainingNecromancer takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        if (BlzGetUnitBooleanField(whichUnit, UNIT_BF_IS_A_BUILDING) == false) then
            return false
        endif
        return unitTypeId == SB_NECROMANCER or unitTypeId == SB_NECROMANCER_LICH
    endfunction

    private function IsDeathProductionStructure takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        if (BlzGetUnitBooleanField(whichUnit, UNIT_BF_IS_A_BUILDING) == false) then
            return false
        endif
        return unitTypeId == SB_NECROMANCER or unitTypeId == SB_NECROMANCER_LICH or unitTypeId == SB_DREAD_SPIRE
    endfunction

    private function IsVaultOfPhylacteries takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_VAULT_OF_PHYLACTERIES
    endfunction

    private function IsVileLaboratory takes unit whichUnit returns boolean
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        return unitTypeId == SB_VILE_LABORATORY
    endfunction

    private function Init takes nothing returns nothing
        local integer i = 0
        local trigger trig = CreateTrigger()
        loop
            exitwhen i > bj_MAX_PLAYERS //Use whatever the best way is to loop through all players
                if (IsPlayingPlayer(Player(i), true)) then
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_Q, METAKEY_CTRL, true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_W, METAKEY_CTRL, true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_E, METAKEY_CTRL, true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_R, METAKEY_CTRL, true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_T, METAKEY_CTRL, true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_Q, METAKEY_CTRLSHIFT , true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_W, METAKEY_CTRLSHIFT , true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_E, METAKEY_CTRLSHIFT , true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_R, METAKEY_CTRLSHIFT , true )
                    call BlzTriggerRegisterPlayerKeyEvent( trig , Player(i) , OSKEY_T, METAKEY_CTRLSHIFT , true )
                endif
            set i = i + 1
        endloop

        call TriggerAddAction( trig , function OnBuildingHotkeyPressed )

        set HOTKEYS[0] = OSKEY_Q
        set HOTKEYS[1] = OSKEY_W
        set HOTKEYS[2] = OSKEY_E
        set HOTKEYS[3] = OSKEY_R
        set HOTKEYS[4] = OSKEY_T
        set HOTKEYS[5] = OSKEY_Q
        set HOTKEYS[6] = OSKEY_W
        set HOTKEYS[7] = OSKEY_E
        set HOTKEYS[8] = OSKEY_R
        set HOTKEYS[9] = OSKEY_T

        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][0] = IsHall
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][1] = IsPrimaryRax
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][2] = IsSecondaryRax
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][3] = IsAirStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][4] = IsProductionStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][5] = IsPrimaryUpgradeStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][6] = IsLumberMill
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][7] = IsAltar
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][8] = IsChurch
        set SELECTED_UNIT_TYPES[RACE_NUM_ORDER][9] = IsScoutTower

        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][0] = IsHall
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][1] = IsPrimaryRax
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][2] = IsSecondaryRax
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][3] = IsAirStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][4] = IsProductionStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][5] = IsPrimaryUpgradeStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][6] = IsHallOfElites
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][7] = IsAltar
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][8] = IsDendroidElder
        set SELECTED_UNIT_TYPES[RACE_NUM_NATURE][9] = IsDendroidChieftain

        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][0] = IsHall
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][1] = IsIdleNecromancer
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][2] = IsTrainingNecromancer
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][3] = IsAirStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][4] = IsDeathProductionStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][5] = IsPrimaryUpgradeStructure
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][6] = IsCryptOrManor
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][7] = IsAltar
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][8] = IsVileLaboratory
        set SELECTED_UNIT_TYPES[RACE_NUM_DEATH][9] = IsVaultOfPhylacteries

    endfunction
endscope

library GoldMineTracker initializer Init requires TimersPlus, EventSystem
    globals
        private constant hashtable HT_GOLD_MINE_TRACKER = InitHashtable()
        private constant key KEY_GOLD_MINE
        private constant key KEY_GOLD_MINE_WORKER
        private constant real GOLD_MINE_OWNERSHIP_BUFFER = 2.0
        private constant integer ORDER_HARVEST = 852018
        private constant integer ORDER_SMART = 851971
        private constant integer ORDER_SMART_FROM_RALLY = 851970
        private constant integer ORDER_RESUME_HARVESTING = 852017
        private constant integer GOLD_MINE_ABILITY = 'Agld'
        private constant integer array HARVEST_GOLD_ABILITIES
        private constant integer array RETURN_GOLD_ABILITIES

        // Events
        public Event OnBeforeWorkerAddedToMine = 0
        public Event OnAfterWorkerAddedToMine = 0
        public Event OnBeforeWorkerRemovedFromMine = 0
        public Event OnAfterWorkerRemovedFromMine = 0
        public Event OnMineGoldOrder = 0
        public Event OnReturnGoldOrder = 0

        // Mining State
        public constant integer MINING_STATE_NONE = 0
        public constant integer MINING_STATE_MINE = 1
        public constant integer MINING_STATE_RETURN = 2
    endglobals

    private struct GoldMine
        unit mine = null
        group workers = null
        player owner = null
        IntTimer emptyTimer = 0

        method onDestroy takes nothing returns nothing
            call emptyTimer.destroy()
            call DestroyGroup(workers)
            call RemoveSavedInteger(HT_GOLD_MINE_TRACKER, GetHandleId(mine), KEY_GOLD_MINE)
        endmethod
    endstruct

    private struct GoldMineWorker
        unit mine = null
        unit worker = null
        integer miningState = MINING_STATE_NONE

        method onDestroy takes nothing returns nothing
            call RemoveSavedInteger(HT_GOLD_MINE_TRACKER, GetHandleId(worker), KEY_GOLD_MINE_WORKER)
        endmethod
    endstruct

    public struct MiningEvent
        unit mine = null
        unit worker = null
        integer lastMiningState = 0
    endstruct

    private function CreateGoldMine takes unit mine returns GoldMine
        local GoldMine gm = GoldMine.create()
        set gm.mine = mine
        set gm.workers = CreateGroup()
        return gm
    endfunction

    private function CreateGoldMineWorker takes unit worker returns GoldMineWorker
        local GoldMineWorker gmw = GoldMineWorker.create()
        set gmw.worker = worker
        set gmw.miningState = MINING_STATE_NONE
        return gmw
    endfunction

    private function CreateEventData takes unit mine, unit worker, integer lastMiningState returns MiningEvent
        local MiningEvent data = MiningEvent.create()
        set data.mine = mine
        set data.worker = worker
        set data.lastMiningState = lastMiningState
        return data
    endfunction

    private function FireEvent takes Event e, unit mine, unit worker, integer lastMiningState returns nothing
        local MiningEvent data = 0
        if (EventSystem_HasListeners(e)) then
            set data = CreateEventData(mine, worker, lastMiningState)
            call EventSystem_FireEvent(e, data)
            call data.destroy()
        endif
    endfunction

    private function GetGoldMineData takes unit mine returns GoldMine
        return LoadInteger(HT_GOLD_MINE_TRACKER, GetHandleId(mine), KEY_GOLD_MINE)
    endfunction

    private function GetOrCreateGoldMineData takes unit mine returns GoldMine
        local GoldMine data = GetGoldMineData(mine)
        if (data == 0) then
            set data = CreateGoldMine(mine)
            call SaveInteger(HT_GOLD_MINE_TRACKER, GetHandleId(mine), KEY_GOLD_MINE, data)
        endif
        return data
    endfunction

    private function GetGoldMineWorkerData takes unit worker returns GoldMineWorker
        return LoadInteger(HT_GOLD_MINE_TRACKER, GetHandleId(worker), KEY_GOLD_MINE_WORKER)
    endfunction

    private function GetOrCreateGoldMineWorkerData takes unit worker returns GoldMineWorker
        local GoldMineWorker data = GetGoldMineWorkerData(worker)
        if (data == 0) then
            set data = CreateGoldMineWorker(worker)
            call SaveInteger(HT_GOLD_MINE_TRACKER, GetHandleId(worker), KEY_GOLD_MINE_WORKER, data)
        endif
        return data
    endfunction

    private function OnGoldMineEmptied takes IntTimer it returns nothing
        local GoldMine gm = it.owner
        set gm.owner = null
        set gm.emptyTimer = 0
    endfunction

    private function GoldMineSetOwner takes GoldMine gm, player owner returns nothing
        if (owner != null) then
            set gm.owner = owner
            call gm.emptyTimer.destroy()
            set gm.emptyTimer = 0
        elseif (gm.owner != null) then
            set gm.emptyTimer = CreateIntTimer(gm, true)
            call StartTimerPlus(gm.emptyTimer, GOLD_MINE_OWNERSHIP_BUFFER, OnGoldMineEmptied)
        endif
    endfunction

    private function GoldMineGetOwner takes unit mine returns player
        local GoldMine data = GetGoldMineData(mine)
        return data.owner
    endfunction

    private function GoldMineRemoveWorker takes unit mine, unit worker returns boolean
        local GoldMine gm = GetGoldMineData(mine)
        local GoldMineWorker gmw = GetGoldMineWorkerData(worker)
        call FireEvent(OnBeforeWorkerRemovedFromMine, mine, worker, gmw.miningState)
        if (GroupRemoveUnit(gm.workers, worker)) then
            set gmw.mine = null
            if (FirstOfGroup(gm.workers) == null) then
                // Mine is empty
                call GoldMineSetOwner(gm, null)
            endif
            call FireEvent(OnAfterWorkerRemovedFromMine, mine, worker, gmw.miningState)
            return true
        endif
        return false
    endfunction

    private function GoldMineAddWorker takes unit mine, unit worker returns boolean
        local GoldMine gm = GetOrCreateGoldMineData(mine)
        local GoldMineWorker gmw = GetOrCreateGoldMineWorkerData(worker)
        if (gmw.mine != mine) then
            if (gmw.mine != null) then
                call GoldMineRemoveWorker(mine, worker)
            endif
            call FireEvent(OnBeforeWorkerAddedToMine, mine, worker, gmw.miningState)
            if (GroupAddUnit(gm.workers, worker)) then
                set gmw.mine = mine
                if (CountUnitsInGroup(gm.workers) == 1) then
                    call GoldMineSetOwner(gm, GetOwningPlayer(worker))
                endif
                call FireEvent(OnAfterWorkerAddedToMine, mine, worker, gmw.miningState)
                return true
            endif
        endif
        return false
    endfunction

    private function ReportMineOrder takes integer orderId, unit mine, unit worker returns nothing
        local player owner = GoldMineGetOwner(mine)
        local GoldMineWorker gmw = 0
        local integer lastMiningState = 0
        if (owner == null or owner == GetOwningPlayer(worker)) then
            call GoldMineAddWorker(mine, worker)
            set gmw = GetGoldMineWorkerData(worker)
            set lastMiningState = gmw.miningState
            // If the worker is "returning" gold, only change mining state on an actual harvest order.
            if (lastMiningState != MINING_STATE_RETURN or orderId != ORDER_SMART) then
                set gmw.miningState = MINING_STATE_MINE
            endif
            call FireEvent(OnMineGoldOrder, mine, worker, lastMiningState)
        endif
    endfunction

    private function ReportReturnOrder takes integer orderId, unit worker returns nothing
        local GoldMineWorker gmw = GetGoldMineWorkerData(worker)
        local integer lastMiningState = 0
        if (gmw != 0) then
            set lastMiningState = gmw.miningState
            if (lastMiningState != MINING_STATE_MINE or orderId != ORDER_SMART) then
                set gmw.miningState = MINING_STATE_RETURN
            endif
            call FireEvent(OnReturnGoldOrder, gmw.mine, worker, lastMiningState)
        endif
    endfunction

    private function ReportMineDestroyed takes GoldMine mine returns nothing
        local unit worker = null
        loop
            set worker = FirstOfGroup(mine.workers)
            exitwhen worker == null
            call GoldMineRemoveWorker(mine.mine, worker)
        endloop
        call mine.destroy()
    endfunction

    private function IsGoldMine takes unit whichUnit returns boolean
        return GetUnitAbilityLevel(whichUnit, GOLD_MINE_ABILITY) > 0
    endfunction

    private function IsGoldHarvester takes unit whichUnit returns boolean
        local integer i = 0
        loop
            exitwhen HARVEST_GOLD_ABILITIES[i] == 0
            if (GetUnitAbilityLevel(whichUnit, HARVEST_GOLD_ABILITIES[i]) > 0) then
                return true
            endif
            set i = i + 1
        endloop
        return false
    endfunction

    private function IsGoldReturnUnit takes unit whichUnit returns boolean
        local integer i = 0
        loop
            exitwhen RETURN_GOLD_ABILITIES[i] == 0
            if (GetUnitAbilityLevel(whichUnit, RETURN_GOLD_ABILITIES[i]) > 0) then
                return true
            endif
            set i = i + 1
        endloop
        return false
    endfunction

    private function IsHarvestOrder takes integer orderId, unit ordered, unit target returns boolean
        if (orderId == ORDER_HARVEST or orderId == ORDER_SMART or orderId == ORDER_SMART_FROM_RALLY) then
            return IsGoldMine(target) and IsGoldHarvester(ordered)
        endif
        return false
    endfunction

    private function IsReturnGoldOrder takes integer orderId, unit ordered, unit target returns boolean
        if (orderId == ORDER_RESUME_HARVESTING) then
            return true
        elseif (orderId == ORDER_SMART and IsGoldReturnUnit(target)) then
            return true
        endif
        return false
    endfunction

    // ****************************************
    // PUBLIC API
    // ****************************************
    public function GetWorkerCount takes unit mine returns integer
        local GoldMine data = GetGoldMineData(mine)
        if (data != 0) then
            return CountUnitsInGroup(data.workers)
        endif
        return 0
    endfunction

    public function GetMiningState takes unit worker returns integer
        local GoldMineWorker gmw = GetGoldMineWorkerData(worker)
        if (gmw != 0) then
            return gmw.miningState
        endif
        return MINING_STATE_NONE
    endfunction

    // ****************************************
    // TRIGGERS
    // ****************************************
    private function HarvestTriggerCondition takes nothing returns boolean
        return IsHarvestOrder(GetIssuedOrderId(), GetOrderedUnit(), GetOrderTargetUnit())
    endfunction

    private function HarvestTriggerAction takes nothing returns nothing
        local unit mine = GetOrderTargetUnit()
        local unit harvester = GetOrderedUnit()
        call ReportMineOrder(GetIssuedOrderId(), mine, harvester)
    endfunction

    private function NonHarvestTriggerCondition takes nothing returns boolean
        return not IsHarvestOrder(GetIssuedOrderId(), GetOrderedUnit(), GetOrderTargetUnit())
    endfunction

    private function NonHarvestTriggerAction takes nothing returns nothing
        local unit ordered = GetOrderedUnit()
        local GoldMineWorker gmw = GetGoldMineWorkerData(ordered)
        if (gmw != 0 and gmw.mine != null) then
            if (IsReturnGoldOrder(GetIssuedOrderId(), ordered, GetOrderTargetUnit())) then
                call ReportReturnOrder(GetIssuedOrderId(), ordered)
            else
                call GoldMineRemoveWorker(gmw.mine, ordered)
            endif
        endif
    endfunction

    private function CreateHarvestTriggers takes nothing returns nothing
        local trigger t = CreateTrigger()

        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
        call TriggerAddCondition(t, Condition(function HarvestTriggerCondition))
        call TriggerAddAction(t, function HarvestTriggerAction)

        set t = CreateTrigger()

        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
        call TriggerAddCondition(t, Condition(function NonHarvestTriggerCondition))
        call TriggerAddAction(t, function NonHarvestTriggerAction)
    endfunction

    private function DeathTriggerCondition takes nothing returns boolean
        local unit dying = GetDyingUnit()
        if (GetGoldMineWorkerData(dying) != 0) then
            return true
        elseif (GetGoldMineData(dying) != 0) then
            return true
        endif
        return false
    endfunction

    private function DeathTriggerAction takes nothing returns nothing
        local unit dying = GetDyingUnit()
        local GoldMine gm = 0
        local GoldMineWorker gmw = GetGoldMineWorkerData(dying)
        if (gmw != 0) then
            call GoldMineRemoveWorker(gmw.mine, dying)
            call gmw.destroy()
        else
            set gm = GetGoldMineData(dying)
            if (gm != 0) then
                call ReportMineDestroyed(gm)
            endif
        endif
    endfunction

    private function CreateDeathTriggers takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_DEATH)
        call TriggerAddCondition(t, Condition(function DeathTriggerCondition))
        call TriggerAddAction(t, function DeathTriggerAction)
    endfunction

    // ****************************************
    // INITIALIZATION
    // ****************************************
    private function Init takes nothing returns nothing
        set HARVEST_GOLD_ABILITIES[0] = SB_HARVEST_CHAOS_WEAK
        set HARVEST_GOLD_ABILITIES[1] = SB_HARVEST_CHAOS_NORMAL
        set HARVEST_GOLD_ABILITIES[2] = SB_HARVEST_GOLD_AND_LUMBER
        set HARVEST_GOLD_ABILITIES[3] = SB_HARVEST_GOLD_AND_LUMBER_MAGIC
        set HARVEST_GOLD_ABILITIES[4] = SB_HARVEST_GOLD_ONLY
        set HARVEST_GOLD_ABILITIES[5] = SB_HARVEST_ORDER_SUPER_PEASANT

        set RETURN_GOLD_ABILITIES[0] = SB_RETURN_GOLD
        set RETURN_GOLD_ABILITIES[1] = SB_RETURN_GOLD_AND_LUMBER

        set OnBeforeWorkerAddedToMine = EventSystem_Create()
        set OnAfterWorkerAddedToMine = EventSystem_Create()
        set OnBeforeWorkerRemovedFromMine = EventSystem_Create()
        set OnAfterWorkerRemovedFromMine = EventSystem_Create()
        set OnMineGoldOrder = EventSystem_Create()
        set OnReturnGoldOrder = EventSystem_Create()

        call CreateHarvestTriggers()
        call CreateDeathTriggers()
    endfunction

endlibrary

library EventSystem requires LinkedList

    function interface EventHandler takes integer eventData returns nothing

    struct Event
        LinkedList_Int listeners = 0

        method onDestroy takes nothing returns nothing
            call DestroyLinkedList(listeners)
        endmethod
    endstruct

    public function Create takes nothing returns Event
        local Event ev = Event.create()
        set ev.listeners = CreateLinkedList_Int()
        return ev
    endfunction

    public function RegisterEventListener takes Event ev, EventHandler listener returns nothing
        local LinkedListNode_Int node = LinkedListFindInt(ev.listeners, listener)
        if (node == 0) then
            call LinkedListAddLastInt(ev.listeners, listener)
        endif
    endfunction

    public function UnregisterEventListener takes Event ev, EventHandler listener returns nothing
        local LinkedListNode_Int node = LinkedListFindInt(ev.listeners, listener)
        if (node != 0) then
            call LinkedListDestroyNode(ev.listeners, node)
        endif
    endfunction

    public function HasListeners takes Event ev returns boolean
        return ev.listeners.count > 0
    endfunction

    public function FireEvent takes Event ev, integer input returns nothing
        local LinkedListNode_Int node = LinkedListGetFirst(ev.listeners)
        local EventHandler listener = 0
        loop
            exitwhen node == 0
            set listener = node.value
            if (listener != 0) then
                call listener.evaluate(input)
            endif
            set node = node.next
        endloop
    endfunction

endlibrary

library Animate requires TimersPlus

    function interface AnimationCallback takes IAnimation animation returns nothing

    interface IAnimation
        AnimationCallback updateCallback = 0
        AnimationCallback endCallback = 0
        IntTimer update = 0
    endinterface

    private function AnimationUpdate takes IntTimer it returns nothing
        local IAnimation animation = it.owner
        if (animation.updateCallback != 0) then
            call animation.updateCallback.evaluate(animation)
        endif
    endfunction

    private function AnimationExpires takes IntTimer it returns nothing
        local IAnimation animation = it.owner
        if (animation.endCallback != 0) then
            call animation.endCallback.evaluate(animation)
        endif
    endfunction

    function DestroyAnimation takes IAnimation animation returns nothing
        call animation.update.destroy()
        call animation.destroy()
    endfunction

    function PlayAnimationAll takes IAnimation animation, real duration, real interval, boolean oneShot, AnimationCallback update, AnimationCallback end returns nothing
        set animation.updateCallback = update
        set animation.endCallback = end
        if (animation.update == 0) then
            set animation.update = CreateIntTimer(animation, oneShot)
        endif
        call StartTimerPlusPeriodic(animation.update, duration, interval, AnimationUpdate, AnimationExpires)
    endfunction

endlibrary

function GetUnitSize takes unit whichUnit returns real
    if (not HaveSavedReal(udg_HashTable_SizeBlending, GetHandleId(whichUnit), StringHash("START SCALE"))) then
        return BlzGetUnitRealField(whichUnit, UNIT_RF_SCALING_VALUE)
    else
        return LoadReal(udg_HashTable_SizeBlending, GetHandleId(whichUnit), StringHash("END SCALE"))
    endif
endfunction

function SetUnitSizeOverTime takes unit whichUnit, real duration, real targetScale returns nothing
    local real scale = GetUnitSize(whichUnit)

    call SaveReal(udg_HashTable_SizeBlending, GetHandleId(whichUnit), StringHash("START SCALE"), scale)
    call SaveReal(udg_HashTable_SizeBlending, GetHandleId(whichUnit), StringHash("END SCALE"), targetScale)

    if (duration > 0) then
        call SaveReal(udg_HashTable_SizeBlending, GetHandleId(whichUnit), StringHash("DURATION"), duration)
        call SaveReal(udg_HashTable_SizeBlending, GetHandleId(whichUnit), StringHash("TIMER"), 0.0)
        call GroupAddUnit(udg_UnitGroup_SizeBlending, whichUnit)
        call EnableTrigger(gg_trg_Size_Blending_Loop)
    else
        call SetUnitScale(whichUnit, targetScale, targetScale, targetScale)
    endif
endfunction

function ChangeUnitSizeOverTime takes unit whichUnit, real duration, real sizeChangePct returns nothing
    local real scale = GetUnitSize(whichUnit)
    call SetUnitSizeOverTime(whichUnit, duration, scale + sizeChangePct)
endfunction

function ChangeUnitSize takes unit whichUnit, real sizeChangePct returns nothing
    call ChangeUnitSizeOverTime(whichUnit, 0.0, sizeChangePct)
endfunction

globals
    constant real SIZE_BLENDING_INTERVAL = 0.05
endglobals

function Trig_Size_Blending_Loop_Actions takes nothing returns nothing
    local integer unitCount = BlzGroupGetSize(udg_UnitGroup_SizeBlending)
    local integer index = unitCount - 1
    local unit pickedUnit = null

    local real time = 0.0
    local real duration = 0.0
    local real scale = 0.0
    local real startScale = 0.0
    local real endScale = 0.0
    local real i = 0.0
    
    if (unitCount > 0) then
        call EnableTrigger(gg_trg_Size_Blending_Death)
        
        loop
            exitwhen index < 0

            set pickedUnit = BlzGroupUnitAt(udg_UnitGroup_SizeBlending, index)
            set time = LoadReal(udg_HashTable_SizeBlending, GetHandleId(pickedUnit), StringHash("TIMER")) + SIZE_BLENDING_INTERVAL
            set duration = LoadReal(udg_HashTable_SizeBlending, GetHandleId(pickedUnit), StringHash("DURATION"))
            set startScale = LoadReal(udg_HashTable_SizeBlending, GetHandleId(pickedUnit), StringHash("START SCALE"))
            set endScale = LoadReal(udg_HashTable_SizeBlending, GetHandleId(pickedUnit), StringHash("END SCALE"))
            set i = time / duration

            if (time >= duration) then
                set scale = endScale
                call GroupRemoveUnit(udg_UnitGroup_SizeBlending, pickedUnit)
                call RemoveSavedReal(udg_HashTable_SizeBlending, GetHandleId(pickedUnit), StringHash("TIMER"))
            else
                set scale = startScale + (endScale - startScale) * i
                call SaveReal(udg_HashTable_SizeBlending, GetHandleId(pickedUnit), StringHash("TIMER"), time)
            endif
            
            call SetUnitScale(pickedUnit, scale, scale, scale)

            set index = index - 1
        endloop
    else
        call DisableTrigger(gg_trg_Size_Blending_Death)
        call DisableTrigger(GetTriggeringTrigger())
    endif
endfunction

//===========================================================================
function InitTrig_Size_Blending_Loop takes nothing returns nothing
    set gg_trg_Size_Blending_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Size_Blending_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Size_Blending_Loop, SIZE_BLENDING_INTERVAL)
    call TriggerAddAction( gg_trg_Size_Blending_Loop, function Trig_Size_Blending_Loop_Actions )
endfunction

library ColorBlending requires Color, TimersPlus

    globals
        private constant hashtable HT_COLOR_BLENDING = InitHashtable()
        private constant key KEY_COLOR_DEFAULT
        private constant key KEY_COLOR_BLEND
    endglobals

    private struct ColorBlend
        unit target = null
        Color start = 0
        Color end = 0
        real elapsed = 0.0
        real duration = 0.0
        real delay = 0.0

        method onDestroy takes nothing returns nothing
            call start.destroy()
            call end.destroy()
        endmethod
    endstruct

    function EndColorBlendForUnit takes unit whichUnit returns nothing
        local IntTimer blendTimer = LoadInteger(HT_COLOR_BLENDING, GetHandleId(whichUnit), KEY_COLOR_BLEND)
        local ColorBlend blend = blendTimer.owner
        if (blend != 0) then
            call SetUnitVertexColor(whichUnit, blend.end.r, blend.end.g, blend.end.b, blend.end.a)
        endif
        call blendTimer.destroy()
        call blend.destroy()
        call RemoveSavedInteger(HT_COLOR_BLENDING, GetHandleId(whichUnit), KEY_COLOR_BLEND)
    endfunction

    private function CreateColorBlend takes unit whichUnit, Color start, Color end, real duration, real delay returns ColorBlend
        local ColorBlend cb = ColorBlend.create()
        set cb.target = whichUnit
        set cb.start = start
        set cb.end = end
        set cb.duration = duration
        set cb.delay = delay
        return cb
    endfunction

    private function UpdateColorBlend takes IntTimer it returns nothing
        local ColorBlend blend = it.owner
        local integer r = 0
        local integer g = 0
        local integer b = 0
        local integer a = 0
        local real i = 0.0
        
        set blend.elapsed = blend.elapsed + TimerPlusGetElapsed(it)
        if (blend.elapsed > blend.delay) then
            set i = (blend.elapsed - blend.delay) / blend.duration
        endif

        set r = blend.start.r + R2I(i * (blend.end.r - blend.start.r))
        set g = blend.start.g + R2I(i * (blend.end.g - blend.start.g))
        set b = blend.start.b + R2I(i * (blend.end.b - blend.start.b))
        set a = blend.start.a + R2I(i * (blend.end.a - blend.start.a))

        call SetUnitVertexColor(blend.target, r, g, b, a)
    endfunction

    private function EndColorBlend takes IntTimer it returns nothing
        local ColorBlend blend = it.owner
        call EndColorBlendForUnit(blend.target)
    endfunction

    function FadeUnitColorOverTime takes unit whichUnit, real dur, real delay, Color startColor, Color endColor returns nothing
        local integer unitHandle = GetHandleId(whichUnit)
        local Color defaultColor = 0
        local IntTimer blendTimer = LoadInteger(HT_COLOR_BLENDING, unitHandle, KEY_COLOR_BLEND)
        local ColorBlend blend = blendTimer.owner

        if (not HaveSavedInteger(HT_COLOR_BLENDING, unitHandle, KEY_COLOR_DEFAULT)) then
            set defaultColor = GetUnitVertexColor(whichUnit)
            call SaveInteger(HT_COLOR_BLENDING, unitHandle, KEY_COLOR_DEFAULT, defaultColor)
        endif

        if (blendTimer != 0) then
            call blend.destroy()
            call blendTimer.destroy()
        endif

        if (dur > 0) then
            call SetUnitVertexColor(whichUnit, startColor.r, startColor.g, startColor.b, startColor.a)
            set blend = CreateColorBlend(whichUnit, startColor, endColor, dur, delay)
            set blendTimer = CreateIntTimer(blend, false)
            call StartTimerPlusPeriodic(blendTimer, dur + delay, 0.01, UpdateColorBlend, EndColorBlend)
            call SaveInteger(HT_COLOR_BLENDING, unitHandle, KEY_COLOR_BLEND, blendTimer)
        else
            call SetUnitVertexColor(whichUnit, endColor.r, endColor.g, endColor.b, endColor.a)
        endif
    endfunction

    function ChangeUnitColorOverTime takes unit whichUnit, real dur, real delay, integer endR, integer endG, integer endB, integer endA returns nothing
        local Color endColor = CreateColor(endR, endG, endB, endA)
        call FadeUnitColorOverTime(whichUnit, dur, delay, GetUnitVertexColor(whichUnit), endColor)
    endfunction

    function RestoreUnitColorOverTime takes unit whichUnit, real dur, real delay returns nothing
        local Color defaultColor = 0
        if (HaveSavedInteger(HT_COLOR_BLENDING, GetHandleId(whichUnit), KEY_COLOR_DEFAULT)) then
            set defaultColor = LoadInteger(HT_COLOR_BLENDING, GetHandleId(whichUnit), KEY_COLOR_DEFAULT)
            call FadeUnitColorOverTime(whichUnit, dur, delay, GetUnitVertexColor(whichUnit), defaultColor)
        endif
    endfunction

    function RestoreUnitColor takes unit whichUnit returns nothing
        call RestoreUnitColorOverTime(whichUnit, 0.0, 0.0)
    endfunction

    function FadeUnitAlphaOverTime takes unit whichUnit, real dur, real delay, integer startA, integer endA returns nothing
        local Color startColor = GetUnitVertexColor(whichUnit)
        local Color endColor = GetUnitVertexColor(whichUnit)
        set startColor.a = startA
        set endColor.a = endA
        call FadeUnitColorOverTime(whichUnit, dur, delay, startColor, endColor)
    endfunction

    function ChangeUnitAlphaOverTime takes unit whichUnit, real dur, real delay, integer endA returns nothing
        local integer startA = BlzGetUnitIntegerField(whichUnit, UNIT_IF_TINTING_COLOR_ALPHA)
        call FadeUnitAlphaOverTime(whichUnit, dur, delay, startA, endA)
    endfunction

    function ChangeUnitColor takes unit whichUnit, integer r, integer g, integer b, integer a returns nothing
        call ChangeUnitColorOverTime(whichUnit, 0, 0, r, g, b, a)
    endfunction

    function ChangeUnitAlpha takes unit whichUnit, integer a returns nothing
        call ChangeUnitAlphaOverTime(whichUnit, 0, 0, a)
    endfunction

endlibrary

library LightningEffects requires Vectors

    globals
        private constant hashtable HT_LIGHTNING_EFFECTS = InitHashtable()
    endglobals

    struct UnitLeash
        lightning bolt = null
        unit unit1 = null
        unit unit2 = null
        vec3 unit1Offset = 0
        vec3 unit2Offset = 0
        real timeRemaining = 0.0
        timer updateTimer = null

        method onDestroy takes nothing returns nothing
            call unit1Offset.destroy()
            call unit2Offset.destroy()
            call DestroyLightning(bolt)
            call DestroyTimer(updateTimer)
        endmethod
    endstruct

    private function UpdateUnitLeash takes nothing returns nothing
        local timer t = GetExpiredTimer()
        local UnitLeash leash = LoadInteger(HT_LIGHTNING_EFFECTS, GetHandleId(t), 0)
        local vec3 offset1Rotated = VecRotateZ(leash.unit1Offset, GetUnitFacing(leash.unit1))
        local vec3 offset2Rotated = VecRotateZ(leash.unit2Offset, GetUnitFacing(leash.unit2))
        local vec3 pos1 = GetUnitVec(leash.unit1).add(offset1Rotated)
        local vec3 pos2 = GetUnitVec(leash.unit2).add(offset2Rotated)
        
        set leash.timeRemaining = leash.timeRemaining - TimerGetElapsed(t)
        call MoveLightningEx(leash.bolt, true, pos1.x, pos1.y, pos1.z, pos2.x, pos2.y, pos2.z)

        if (leash.timeRemaining <= 0.0) then
            call leash.destroy()
        endif

        call offset1Rotated.destroy()
        call offset2Rotated.destroy()
        call pos1.destroy()
        call pos2.destroy()
    endfunction

    public function CreateLightningBetweenUnits takes unit unit1, unit unit2, vec3 unit1Offset, vec3 unit2Offset, string lightningType returns lightning
        local vec3 offset1Rotated = VecRotateZ(unit1Offset, GetUnitFacing(unit1))
        local vec3 offset2Rotated = VecRotateZ(unit2Offset, GetUnitFacing(unit2))
        local vec3 pos1 = GetUnitVec(unit1).add(offset1Rotated)
        local vec3 pos2 = GetUnitVec(unit2).add(offset2Rotated)
        local lightning l = AddLightningEx(lightningType, true, pos1.x, pos1.y, pos1.z, pos2.x, pos2.y, pos2.z)
        call offset1Rotated.destroy()
        call offset2Rotated.destroy()
        call pos1.destroy()
        call pos2.destroy()
        return l
    endfunction

    public function CreateUnitLeash takes unit unit1, unit unit2, vec3 offset1, vec3 offset2, string lightningType, real updateInterval, real duration returns UnitLeash
        local UnitLeash leash = UnitLeash.create()
        set leash.bolt = CreateLightningBetweenUnits(unit1, unit2, offset1, offset2, lightningType)
        set leash.unit1 = unit1
        set leash.unit2 = unit2
        set leash.unit1Offset = offset1
        set leash.unit2Offset = offset2
        set leash.timeRemaining = duration
        set leash.updateTimer = CreateTimer()
        call SaveInteger(HT_LIGHTNING_EFFECTS, GetHandleId(leash.updateTimer), 0, leash)
        call TimerStart(leash.updateTimer, updateInterval, true, function UpdateUnitLeash)
        return leash
    endfunction

endlibrary

globals
    LightningRing array LIGHTNING_RINGS
    integer LIGHTNING_RINGS_COUNT = 0
    constant real LIGHTNING_RINGS_UPDATE_INTERVAL = 0.03
    constant integer LIGHTNING_STATE_BIRTH = 0
    constant integer LIGHTNING_STATE_STAND = 1
    constant integer LIGHTNING_STATE_DEATH = 2
    constant integer LIGHTNING_STATE_DESTROYED = 3
endglobals

struct LightningRing
    location origin
    integer resolution
    string lightningType
    real radius
    real birthTime
    real deathTime
    real timeLeft
    integer lrIndex
    integer state

    static method create takes location whichLocation, integer resolution, string lightningType, real radius, real birthTime returns LightningRing
        local LightningRing lr = LightningRing.allocate()
        local integer i = 0

        set lr.origin = whichLocation
        set lr.resolution = resolution
        set lr.lightningType = lightningType
        set lr.radius = radius
        set lr.birthTime = birthTime
        set lr.timeLeft = birthTime
        set lr.state = LIGHTNING_STATE_BIRTH

        set lr.lrIndex = LIGHTNING_RINGS_COUNT
        set LIGHTNING_RINGS[LIGHTNING_RINGS_COUNT] = lr
	    set LIGHTNING_RINGS_COUNT = LIGHTNING_RINGS_COUNT + 1

        loop
            exitwhen i >= resolution
            call lr.CreateLightning(i)
            set i = i + 1
        endloop

        if (birthTime <= 0.0) then
            call lr.Update()
        else
            call EnableTrigger(gg_trg_Lightning_Ring_Loop)
        endif

        return lr
    endmethod

    public method GetState takes nothing returns integer
        return state
    endmethod

    public method GetLightning takes integer index returns lightning
        return LoadLightningHandle(udg_HashTable_SpecialEffects, this, index)
    endmethod

    public method Destroy takes nothing returns nothing
        set timeLeft = deathTime
        if (deathTime <= 0.0) then
            set state = LIGHTNING_STATE_DESTROYED
        else
            set state = LIGHTNING_STATE_DEATH
        endif
    endmethod

    public method Update takes nothing returns nothing
        if (state == LIGHTNING_STATE_BIRTH) then
            call UpdateBirth()
        elseif (state == LIGHTNING_STATE_DEATH) then
            call UpdateDeath()
        endif
    endmethod

    private method CreateLightning takes integer index returns nothing
        local real x = GetLocationX(origin)
        local real y = GetLocationY(origin)
        local lightning l = AddLightning(lightningType, true, x, y, x, y)
        call SaveLightningHandle(udg_HashTable_SpecialEffects, this, index, l)
    endmethod

    private method DestroyLightning takes integer index returns nothing
        local lightning l = LoadLightningHandle(udg_HashTable_SpecialEffects, this, index)
        call DestroyLightningBJ(l)
        call RemoveSavedHandle(udg_HashTable_SpecialEffects, this, index)
    endmethod

    private method UpdateBirth takes nothing returns nothing
        local real angleStep = 360.0 / resolution
        local real r = radius
        local lightning l = null
        local integer i = 0
        local real x1 = 0.0
        local real y1 = 0.0
        local real x2 = 0.0
        local real y2 = 0.0
    	
        if (birthTime > 0) then
            set r = RMinBJ(radius, radius * (birthTime - timeLeft) / birthTime)
        endif
    
        loop
            exitwhen i >= resolution
            set x1 = PolarProjectionX(GetLocationX(origin), r, angleStep * i)
            set y1 = PolarProjectionY(GetLocationY(origin), r, angleStep * i)
            set x2 = PolarProjectionX(GetLocationX(origin), r, angleStep * (i + 1))
            set y2 = PolarProjectionY(GetLocationY(origin), r, angleStep * (i + 1))
            set l = GetLightning(i)
            call MoveLightning(l, true, x1, y1, x2, y2)
            set i = i + 1
        endloop
    
        set timeLeft = timeLeft - LIGHTNING_RINGS_UPDATE_INTERVAL
    
        if (timeLeft <= 0) then
            set state = LIGHTNING_STATE_STAND
        endif
    endmethod

    private method UpdateDeath takes nothing returns nothing
        local integer i = 0
        local lightning l = null

        loop
            exitwhen i >= resolution
            set l = GetLightning(i)
            call SetLightningColor(l, 1.0, 1.0, 1.0, RMaxBJ(0.0, timeLeft / deathTime))
            set i = i + 1
        endloop

        set timeLeft = timeLeft - LIGHTNING_RINGS_UPDATE_INTERVAL
        if (timeLeft <= 0) then
            set state = LIGHTNING_STATE_DESTROYED
        endif
    endmethod

    method onDestroy takes nothing returns nothing
        local integer i = 0
        call RemoveLocation(origin)
        loop
            exitwhen i >= resolution
            call DestroyLightning(i)
            set i = i + 1
        endloop

        set i = lrIndex
        loop
            exitwhen i >= LIGHTNING_RINGS_COUNT - 2
                set LIGHTNING_RINGS[i] = LIGHTNING_RINGS[i + 1]
                set LIGHTNING_RINGS[i].lrIndex = i
            set i = i + 1
        endloop

        set LIGHTNING_RINGS[LIGHTNING_RINGS_COUNT - 1] = 0
        set LIGHTNING_RINGS_COUNT = LIGHTNING_RINGS_COUNT - 1
    endmethod
endstruct

function Trig_Lightning_Ring_Loop_Actions takes nothing returns nothing
    local integer lrIndex = LIGHTNING_RINGS_COUNT - 1
    local integer state = 0

    loop
        exitwhen lrIndex < 0
            set state = LIGHTNING_RINGS[lrIndex].GetState()
            if (state != LIGHTNING_STATE_DESTROYED) then
                call LIGHTNING_RINGS[lrIndex].Update()
            else
                call LIGHTNING_RINGS[lrIndex].destroy()
            endif
        set lrIndex = lrIndex - 1
    endloop

    if (LIGHTNING_RINGS_COUNT <= 0) then
        call DisableTrigger(GetTriggeringTrigger())
    endif
    
endfunction

//===========================================================================
function InitTrig_Lightning_Ring_Loop takes nothing returns nothing
    set gg_trg_Lightning_Ring_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Lightning_Ring_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Lightning_Ring_Loop, LIGHTNING_RINGS_UPDATE_INTERVAL)
    call TriggerAddAction( gg_trg_Lightning_Ring_Loop, function Trig_Lightning_Ring_Loop_Actions )
endfunction

library OrderTracking initializer Init requires LinkedList
    globals
        private constant hashtable HT_ORDER_TRACKING = InitHashtable()
        private constant key KEY_TRACKED_ORDER

        private LinkedList_Int EVENT_HANDLERS_BEFORE_TRACK = 0
        private LinkedList_Int EVENT_HANDLERS_AFTER_TRACK = 0

        public integer EVENT_BEFORE_TRACK = 1
        public integer EVENT_TRACK = 2
    endglobals

    public struct Order
        integer orderId = 0
        unit orderTargetUnit = null
        destructable targetDestructable = null
        real targetX = 0.0
        real targetY = 0.0
    endstruct

    public struct TrackedOrder
        Order lastOrder = 0
        LinkedList_Int orderFilter = 0
    endstruct

    private function GetEventHandlers takes integer whichEvent returns LinkedList_Int
        if (whichEvent == EVENT_BEFORE_TRACK) then
            return EVENT_HANDLERS_BEFORE_TRACK
        elseif (whichEvent == EVENT_TRACK) then
            return EVENT_HANDLERS_AFTER_TRACK
        endif
        return 0
    endfunction

    public function interface EventHandler takes unit whichUnit, Order beforeTrack, Order afterTrack returns nothing

    public function RegisterListener takes integer eventType, EventHandler handler returns nothing
        local LinkedList_Int handlers = GetEventHandlers(eventType)
        if (handlers != 0 and LinkedListFindInt(handlers, handler) == 0) then
            call LinkedListAddLastInt(handlers, handler)
        endif
    endfunction

    public function UnregisterListener takes integer eventType, EventHandler handler returns nothing
        local LinkedList_Int handlers = GetEventHandlers(eventType)
        local LinkedListNode_Int existing = 0
        if (handlers != 0) then
            set existing = LinkedListFindInt(handlers, handler)
            if (existing != 0) then
                call LinkedListDestroyNode(handlers, existing)
            endif
        endif
    endfunction

    private function FireEvent takes integer eventType, unit whichUnit, Order lastOrder, Order newOrder returns nothing
        local LinkedList_Int handlers = GetEventHandlers(eventType)
        local LinkedListNode_Int node = LinkedListGetFirst(handlers)
        local EventHandler handler = 0
        loop
            exitwhen node == 0
            set handler = node.value
            call handler.evaluate(whichUnit, lastOrder, newOrder)
            set node = node.next
        endloop
    endfunction

    public function IsUnitTracked takes unit whichUnit returns boolean
        return HaveSavedInteger(HT_ORDER_TRACKING, GetHandleId(whichUnit), KEY_TRACKED_ORDER)
    endfunction

    public function TrackUnit takes unit whichUnit returns nothing
        local TrackedOrder to = 0
        if (not IsUnitTracked(whichUnit)) then
            set to = TrackedOrder.create()
            set to.orderFilter = CreateLinkedList_Int()
            call SaveInteger(HT_ORDER_TRACKING, GetHandleId(whichUnit), KEY_TRACKED_ORDER, to)
        endif
    endfunction

    public function GetTrackedOrder takes unit whichUnit returns TrackedOrder
        return LoadInteger(HT_ORDER_TRACKING, GetHandleId(whichUnit), KEY_TRACKED_ORDER)
    endfunction

    public function GetLastOrder takes unit whichUnit returns Order
        local TrackedOrder to = GetTrackedOrder(whichUnit)
        if (to != 0) then
            return to.lastOrder
        endif
        return 0
    endfunction

    public function FilterOutOrder takes unit whichUnit, integer orderId returns nothing
        local TrackedOrder to = GetTrackedOrder(whichUnit)
        call LinkedListAddLastInt(to.orderFilter, orderId)
    endfunction

    public function SaveOrder takes unit whichUnit, integer orderId, unit targetUnit, destructable targetDestructable, real targetX, real targetY returns nothing
        local TrackedOrder to = GetTrackedOrder(whichUnit)
        local Order lastOrder = 0
        local Order new = 0
        if (LinkedListFindInt(to.orderFilter, orderId) == 0) then
            set lastOrder = to.lastOrder
            set new = Order.create()
            set new.orderId = orderId
            set new.orderTargetUnit = targetUnit
            set new.targetDestructable = targetDestructable
            set new.targetX = targetX
            set new.targetY = targetY
            call FireEvent(EVENT_TRACK, whichUnit, lastOrder, new)
            set to.lastOrder = new
            call lastOrder.destroy()
        endif
    endfunction

    public function ExecuteOrder takes unit ordered, Order order returns boolean
        if (order.orderId != 0) then
            if (order.orderTargetUnit != null) then
                return IssueTargetOrderById(ordered, order.orderId, order.orderTargetUnit)
            elseif (order.targetDestructable != null) then
                return IssueTargetOrderById(ordered, order.orderId, order.targetDestructable)
            elseif (order.targetX != 0.0 and order.targetY != 0.0) then
                return IssuePointOrderById(ordered, order.orderId, order.targetX, order.targetY)
            endif
            return IssueImmediateOrderById(ordered, order.orderId)
        endif
        return false
    endfunction

    private function Init takes nothing returns nothing
        set EVENT_HANDLERS_BEFORE_TRACK = CreateLinkedList_Int()
        set EVENT_HANDLERS_AFTER_TRACK = CreateLinkedList_Int()
    endfunction

endlibrary

function Trig_Order_Tracking_Conditions takes nothing returns boolean
    return OrderTracking_IsUnitTracked(GetOrderedUnit())
endfunction

function Trig_Order_Tracking_Actions takes nothing returns nothing
    call OrderTracking_SaveOrder(GetOrderedUnit(), GetIssuedOrderId(), GetOrderTargetUnit(), GetOrderTargetDestructable(), GetOrderPointX(), GetOrderPointY())
endfunction

//===========================================================================
function InitTrig_Order_Tracking takes nothing returns nothing
    set gg_trg_Order_Tracking = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Order_Tracking, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Order_Tracking, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Order_Tracking, EVENT_PLAYER_UNIT_ISSUED_ORDER )
    call TriggerAddCondition( gg_trg_Order_Tracking, Condition( function Trig_Order_Tracking_Conditions ) )
    call TriggerAddAction( gg_trg_Order_Tracking, function Trig_Order_Tracking_Actions )
endfunction

library FloatingText

    function FloatTextAboveUnit takes unit whichUnit, string text, real size, real zOffset, real r, real g, real b, real a returns texttag
        local texttag tt = CreateTextTag()
        call SetTextTagText(tt, text, TextTagSize2Height(size))
        call SetTextTagPosUnit(tt, whichUnit, zOffset)
        call SetTextTagColor(tt, R2I(255 * r), R2I(255 * g), R2I(255 * b), R2I(255 * a))
        call SetTextTagVisibility(tt, true)
        return tt
    endfunction
    
    function FloatTextAboveUnitForPlayer takes unit whichUnit, player whichPlayer, string text, real size, real zOffset, real r, real g, real b, real a returns texttag
        local force playerForce = GetForceOfPlayer(whichPlayer)
        local texttag tt = FloatTextAboveUnit(whichUnit, text, size, zOffset, r, g, b, a)
        call SetTextTagVisibility(tt, whichPlayer == GetLocalPlayer())
        return tt
    endfunction

    function SetFloatingTextMovement takes texttag tt, real lifespan, real fadePoint, real velX, real velY returns nothing
        call SetTextTagLifespan(tt, lifespan)
        call SetTextTagFadepoint(tt, fadePoint)
        call SetTextTagVelocity(tt, TextTagSpeed2Velocity(velX), TextTagSpeed2Velocity(velY))
        call SetTextTagPermanent(tt, false)
    endfunction

endlibrary

library TrainingQueue initializer Init requires LinkedList

    globals
        public constant integer TQ_EVENT_TYPE_TRAIN = 0
        public constant integer TQ_EVENT_TYPE_FINISH = 1
        public constant integer TQ_EVENT_TYPE_CANCEL = 2

        private constant hashtable HT_TrainingQueue = InitHashtable()
        private constant timer EVENT_QUEUE_TIMER = CreateTimer()
        private constant key KEY_TRAINING_QUEUE
        private LinkedList_Int TQ_EVENT_QUEUE = 0
        private LinkedList_Int TQ_EVENT_HANDLERS_TRAIN = 0
        private LinkedList_Int TQ_EVENT_HANDLERS_FINISH = 0
        private LinkedList_Int TQ_EVENT_HANDLERS_CANCEL = 0
    endglobals

    public struct TrainingQueueEvent extends ILinkedListNode
        player owningPlayer = null
        integer unitTypeId = 0
        group trainers = null
        integer eventType = 0
        
        method onDestroy takes nothing returns nothing
            call DestroyGroup(trainers)
        endmethod
    endstruct

    public function interface TrainingQueueEventHandler takes TrainingQueueEvent tqe returns nothing

    private function Init takes nothing returns nothing
        set TQ_EVENT_QUEUE = CreateLinkedList_Int()
        set TQ_EVENT_HANDLERS_TRAIN = CreateLinkedList_Int()
        set TQ_EVENT_HANDLERS_FINISH = CreateLinkedList_Int()
        set TQ_EVENT_HANDLERS_CANCEL = CreateLinkedList_Int()
    endfunction

    public function GetTrainingQueue takes unit whichUnit returns LinkedList_Int
        return LoadInteger(HT_TrainingQueue, GetHandleId(whichUnit), KEY_TRAINING_QUEUE)
    endfunction

    private function GetOrCreateTrainingQueue takes unit whichUnit returns LinkedList_Int
        local LinkedList_Int queue = GetTrainingQueue(whichUnit)
        if (queue == 0) then
            set queue = CreateLinkedList_Int()
            call SaveInteger(HT_TrainingQueue, GetHandleId(whichUnit), KEY_TRAINING_QUEUE, queue)
        endif
        return queue
    endfunction

    private function GetEventListeners takes integer tqEventType returns LinkedList_Int
        if (tqEventType == TQ_EVENT_TYPE_TRAIN) then
            return TQ_EVENT_HANDLERS_TRAIN
        elseif (tqEventType == TQ_EVENT_TYPE_FINISH) then
            return TQ_EVENT_HANDLERS_FINISH
        elseif (tqEventType == TQ_EVENT_TYPE_CANCEL) then
            return TQ_EVENT_HANDLERS_CANCEL
        endif
        return 0
    endfunction

    public function RegisterEvent takes integer tqEventType, TrainingQueueEventHandler handler returns nothing
        local LinkedList_Int listeners = GetEventListeners(tqEventType)
        if (listeners != 0) then
            call LinkedListAddLastInt(listeners, handler)
        endif
    endfunction

    public function UnregisterEvent takes integer tqEventType, TrainingQueueEventHandler handler returns nothing
        local LinkedList_Int listeners = GetEventListeners(tqEventType)
        local LinkedListNode_Int node = LinkedListGetFirst(listeners)
        loop
            exitwhen node == 0
            if (node.value == handler) then
                exitwhen true
            endif
            set node = node.next
        endloop
        if (node != 0) then
            call LinkedListDestroyNode(listeners, node)
        endif
    endfunction

    private function FlushEventQueue takes nothing returns nothing
        local LinkedList_Int listeners = 0
        local LinkedListNode_Int listenerNode = 0
        local TrainingQueueEventHandler listener = 0
        local TrainingQueueEvent tqe = 0
        loop
            set tqe = LinkedListGetLast(TQ_EVENT_QUEUE)
            exitwhen tqe == 0
            set listeners = GetEventListeners(tqe.eventType)
            if (listeners != 0 and listeners.count > 0) then
                set listenerNode = LinkedListGetFirst(listeners)
                loop
                    exitwhen listenerNode == 0
                    set listener = listenerNode.value
                    call listener.evaluate(tqe)
                    set listenerNode = listenerNode.next
                endloop
            endif
            call LinkedListDestroyLast(TQ_EVENT_QUEUE)
        endloop
    endfunction

    private function IsEventEqual takes TrainingQueueEvent tqe, unit whichUnit, integer unitTypeId, integer tqEventType returns boolean
        local player owner = GetOwningPlayer(whichUnit)
        if (tqe.owningPlayer != owner) then
            return false
        elseif (tqe.unitTypeId != unitTypeId) then
            return false
        elseif (tqe.eventType != tqEventType) then
            return false
        elseif (IsUnitInGroup(whichUnit, tqe.trainers)) then
            return false
        endif
        return true
    endfunction

    private function QueueTQEvent takes unit whichUnit, integer tqEventType returns nothing
        local player owner = null
        local TrainingQueueEvent tqe = 0
        local integer unitTypeId = GetUnitTypeId(whichUnit)
        local LinkedList_Int listeners = GetEventListeners(tqEventType)
        
        if (listeners.count > 0) then
            set owner = GetOwningPlayer(whichUnit)
            set tqe = LinkedListGetLast(TQ_EVENT_QUEUE)
            
            // Find a pending event of this type
            loop
                exitwhen tqe == 0
                if (IsEventEqual(tqe, whichUnit, unitTypeId, tqEventType)) then
                    exitwhen true
                endif
                set tqe = tqe.prev
            endloop

            // No pending event found, create one
            if (tqe == 0) then
                set tqe = TrainingQueueEvent.create()
                set tqe.owningPlayer = owner
                set tqe.unitTypeId = unitTypeId
                set tqe.trainers = CreateGroup()
                set tqe.eventType = tqEventType
                call LinkedListAddLast(TQ_EVENT_QUEUE, tqe)
            endif

            // Add this unit to the pending event
            call GroupAddUnit(tqe.trainers, whichUnit)

            // Flush the event queue next update
            call TimerStart(EVENT_QUEUE_TIMER, 0.0, false, function FlushEventQueue)
        endif
    endfunction

    public function HasSavedTrainingQueue takes unit whichUnit returns boolean
        return HaveSavedInteger(HT_TrainingQueue, GetHandleId(whichUnit), KEY_TRAINING_QUEUE)
    endfunction

    public function GetQueueSize takes unit whichUnit returns integer
        local LinkedList_Int queue = GetTrainingQueue(whichUnit)
        if (queue != 0) then
            return queue.count
        endif
        return 0
    endfunction

    public function AddToTrainingQueue takes unit whichUnit, integer unitTypeId returns integer
        local LinkedList_Int queue = GetOrCreateTrainingQueue(whichUnit)
        call LinkedListAddLastInt(queue, unitTypeId)
        call QueueTQEvent(whichUnit, TQ_EVENT_TYPE_TRAIN)
        return queue.count
    endfunction

    public function CancelFromTrainingQueue takes unit whichUnit returns integer
        local LinkedList_Int queue = GetTrainingQueue(whichUnit)
        if (queue != 0) then
            call LinkedListDestroyLast(queue)
            call QueueTQEvent(whichUnit, TQ_EVENT_TYPE_CANCEL)
            return queue.count
        endif
        return 0
    endfunction

    public function RemoveFromTrainingQueueHead takes unit whichUnit returns integer
        local LinkedList_Int queue = GetTrainingQueue(whichUnit)
        if (queue != 0) then
            call LinkedListDestroyFirst(queue)
            call QueueTQEvent(whichUnit, TQ_EVENT_TYPE_FINISH)
            return queue.count
        endif
        return 0
    endfunction

endlibrary

function Trig_Training_Queue_Add_Conditions takes nothing returns boolean
    local integer orderId = GetIssuedOrderId()
    local integer goldCost = 0
    local integer lumberCost = 0
    local integer foodCost = 0
    local player owner = null

    if (not IsUnitType(GetOrderedUnit(), UNIT_TYPE_STRUCTURE)) then
        return false
    elseif (GetObjectName(orderId) == null or GetObjectName(orderId) == EMPTY_STRING or GetObjectName(orderId) == DEFAULT_STRING) then
        return false
    elseif (IsUnitIdType(orderId, UNIT_TYPE_STRUCTURE)) then
        return false
    else
        set owner = GetOwningPlayer(GetOrderedUnit())
        if (GetPlayerState(owner, PLAYER_STATE_RESOURCE_GOLD) < GetUnitGoldCost(orderId)) then
            return false
        elseif (GetPlayerState(owner, PLAYER_STATE_RESOURCE_LUMBER) < GetUnitWoodCost(orderId)) then
            return false
        elseif (GetPlayerState(owner, PLAYER_STATE_RESOURCE_FOOD_CAP) - GetPlayerState(owner, PLAYER_STATE_RESOURCE_FOOD_USED) < GetFoodUsed(orderId)) then
            if (TrainingQueue_GetQueueSize(GetOrderedUnit()) == 0) then
                return false
            endif
        endif
    endif
    return true
endfunction

function Trig_Training_Queue_Add_Actions takes nothing returns nothing
    call TrainingQueue_AddToTrainingQueue(GetOrderedUnit(), GetIssuedOrderId())
endfunction

//===========================================================================
function InitTrig_Training_Queue_Add takes nothing returns nothing
    set gg_trg_Training_Queue_Add = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Training_Queue_Add, EVENT_PLAYER_UNIT_ISSUED_ORDER )
    call TriggerAddCondition( gg_trg_Training_Queue_Add, Condition( function Trig_Training_Queue_Add_Conditions ) )
    call TriggerAddAction( gg_trg_Training_Queue_Add, function Trig_Training_Queue_Add_Actions )
endfunction

function Trig_Training_Queue_Cancel_Conditions takes nothing returns boolean
    return GetIssuedOrderId() == 851976 // Cancel
endfunction

function Trig_Training_Queue_Cancel_Actions takes nothing returns nothing
    if (TrainingQueue_GetQueueSize(GetOrderedUnit()) > 0) then
        call TrainingQueue_CancelFromTrainingQueue(GetOrderedUnit())
    endif
endfunction

//===========================================================================
function InitTrig_Training_Queue_Cancel takes nothing returns nothing
    set gg_trg_Training_Queue_Cancel = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Training_Queue_Cancel, EVENT_PLAYER_UNIT_ISSUED_ORDER )
    call TriggerAddCondition( gg_trg_Training_Queue_Cancel, Condition( function Trig_Training_Queue_Cancel_Conditions ) )
    call TriggerAddAction( gg_trg_Training_Queue_Cancel, function Trig_Training_Queue_Cancel_Actions )
endfunction

function Trig_Training_Queue_Finish_Conditions takes nothing returns boolean
    return TrainingQueue_HasSavedTrainingQueue(GetTriggerUnit())
endfunction

function Trig_Training_Queue_Finish_Actions takes nothing returns nothing
    call TrainingQueue_RemoveFromTrainingQueueHead(GetTriggerUnit())
endfunction

//===========================================================================
function InitTrig_Training_Queue_Finish takes nothing returns nothing
    set gg_trg_Training_Queue_Finish = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Training_Queue_Finish, EVENT_PLAYER_UNIT_TRAIN_FINISH )
    call TriggerAddCondition( gg_trg_Training_Queue_Finish, Condition( function Trig_Training_Queue_Finish_Conditions ) )
    call TriggerAddAction( gg_trg_Training_Queue_Finish, function Trig_Training_Queue_Finish_Actions )
endfunction

library BetterTraining initializer Init requires TrainingQueue

    private function OnTrainingQueueTrain takes TrainingQueue_TrainingQueueEvent tqe returns nothing
        local integer minQueueSize = MAX_INTEGER
        local integer queueSize = 0
        local group trainers = null
        local unit picked = null

        if (GetPlayerController(tqe.owningPlayer) == MAP_CONTROL_USER) then
            set trainers = CreateGroup()
            call GroupAddGroup(tqe.trainers, trainers)

            loop
                set picked = FirstOfGroup(trainers)
                exitwhen picked == null
                set minQueueSize = IMinBJ(minQueueSize, TrainingQueue_GetQueueSize(picked))
                call GroupRemoveUnit(trainers, picked)
            endloop

            call GroupAddGroup(tqe.trainers, trainers)
            loop
                set picked = FirstOfGroup(trainers)
                exitwhen picked == null
                set queueSize = TrainingQueue_GetQueueSize(picked)
                if (queueSize > minQueueSize) then
                    call PauseUnit(picked, true)
                    call IssueImmediateOrder(picked, "stop")
                    call PauseUnit(picked, false)
                    //call IssueImmediateOrderById(picked, 851976) // Cancel
                else
                    // Don't cancel this one, but cancel the rest of them
                    set minQueueSize = -1
                endif
                call GroupRemoveUnit(trainers, picked)
            endloop

            call DestroyGroup(trainers)
        endif
    endfunction

    private function Init takes nothing returns nothing
        call TrainingQueue_RegisterEvent(TrainingQueue_TQ_EVENT_TYPE_TRAIN, OnTrainingQueueTrain)
    endfunction

endlibrary

function Trig_Debugging_THis_Actions takes nothing returns nothing
    local group barracks = GetUnitsOfTypeIdAll('h002')
    local unit picked = null
    local texttag ft = null
    loop
        set picked = FirstOfGroup(barracks)
        exitwhen picked == null
        call CreateTextTagUnitBJ("0", picked, 100.0, 10, 100.0, 100.0, 100.0, 0)
        call SetTextTagPermanentBJ( GetLastCreatedTextTag(), true )
        call ShowTextTagForceBJ( true, GetLastCreatedTextTag(), GetPlayersAll())
        call SaveTextTagHandle(udg_HashTable_UnitInfo, GetHandleId(picked), StringHash("TEST"), GetLastCreatedTextTag())
        call GroupRemoveUnit(barracks, picked)
    endloop
endfunction

//===========================================================================
function InitTrig_Debugging_THis takes nothing returns nothing
    set gg_trg_Debugging_THis = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Debugging_THis, function Trig_Debugging_THis_Actions )
endfunction

function Trig_More_debugging_Actions takes nothing returns nothing
    local group barracks = GetUnitsOfTypeIdAll('h002')
    local unit picked = null
    local texttag ft = null
    local LinkedList_Int queue = 0
    loop
        set picked = FirstOfGroup(barracks)
        exitwhen picked == null
        set queue = TrainingQueue_GetTrainingQueue(picked)
        set ft = LoadTextTagHandle(udg_HashTable_UnitInfo, GetHandleId(picked), StringHash("TEST"))
        call SetTextTagTextBJ(ft, I2S(queue.count) + ": " + LinkedListToString(queue), 10)
        call GroupRemoveUnit(barracks, picked)
    endloop
    call DestroyGroup(barracks)
endfunction

//===========================================================================
function InitTrig_More_debugging takes nothing returns nothing
    set gg_trg_More_debugging = CreateTrigger(  )
    call TriggerRegisterTimerEventPeriodic( gg_trg_More_debugging, 0.01 )
    call TriggerAddAction( gg_trg_More_debugging, function Trig_More_debugging_Actions )
endfunction

globals
    constant key KEY_REFUND_MANA
endglobals

function RefundAbilityCast_Condition takes nothing returns boolean
    local integer abilityId = LoadInteger(udg_HashTable_ManaRefund, GetHandleId(GetTriggeringTrigger()), KEY_REFUND_MANA)
    return GetSpellAbilityId() == abilityId
endfunction

function RefundAbilityCast_Action takes nothing returns nothing
    local unit caster = GetSpellAbilityUnit()
    local real manaCost = GetUnitAbilityIntegerLevelField(caster, GetSpellAbilityId(), ABILITY_ILF_MANA_COST)
    call SetUnitState(caster, UNIT_STATE_MANA, GetUnitState(caster, UNIT_STATE_MANA) + manaCost)
    call BlzEndUnitAbilityCooldown(caster, GetSpellAbilityId())
    call RemoveSavedInteger(udg_HashTable_ManaRefund, GetHandleId(GetTriggeringTrigger()), KEY_REFUND_MANA)
    call DestroyTrigger(GetTriggeringTrigger())
endfunction

function RefundAbilityCast takes unit caster, integer abilityId returns nothing
    local trigger refundTrigger = CreateTrigger()
    call SaveInteger(udg_HashTable_ManaRefund, GetHandleId(refundTrigger), KEY_REFUND_MANA, abilityId)
    call TriggerRegisterUnitEvent(refundTrigger, caster, EVENT_UNIT_SPELL_ENDCAST)
    call TriggerRegisterUnitEvent(refundTrigger, caster, EVENT_UNIT_SPELL_FINISH)
    call TriggerAddCondition(refundTrigger, Condition(function RefundAbilityCast_Condition))
    call TriggerAddAction(refundTrigger, function RefundAbilityCast_Action)
    call IssueImmediateOrder(caster, "stop")
endfunction

function CreateDummyCaster takes player whichPlayer, real x, real y, integer abilityId, real duration returns unit
    local unit dummy = CreateUnit(whichPlayer, SB_HIDDEN_CASTER, x, y, bj_UNIT_FACING)
    call RemoveGuardPosition(dummy)
    call UnitAddAbility(dummy, abilityId)
    call UnitApplyTimedLife(dummy, SB_BUFF_TIMED_LIFE_GENERIC, duration)
    return dummy
endfunction

function DummyCastInstantTimed takes player whichPlayer, real x, real y, integer abilityId, string order, real duration returns unit
    local unit dummy = CreateDummyCaster(whichPlayer, x, y, abilityId, duration)
    call IssueImmediateOrder(dummy, order)
    return dummy
endfunction

function DummyCastInstant takes player whichPlayer, real x, real y, integer abilityId, string order returns unit
    return DummyCastInstantTimed(whichPlayer, x, y, abilityId, order, 2.0)
endfunction

function DummyCastPoint takes player whichPlayer, real x, real y, real targetX, real targetY, integer abilityId, string order returns unit
    local unit dummy = CreateDummyCaster(whichPlayer, x, y, abilityId, 2.0)
    call IssuePointOrder(dummy, order, targetX, targetY)
    return dummy
endfunction

function DummyCastUnit takes player whichPlayer, unit target, real x, real y, integer abilityId, string order returns unit
    local unit dummy = CreateDummyCaster(whichPlayer, x, y, abilityId, 2.0)
    call IssueTargetOrder(dummy, order, target)
    return dummy
endfunction

library IntFilters

    globals
        integer CURRENT_INT_FILTER_INPUT = 0
        real CURRENT_FILTER_AOE = 0.0
        real CURRENT_FILTER_X = 0.0
        real CURRENT_FILTER_Y = 0.0
        IntCondition CURRENT_INT_FILTER = 0
        constant real AOE_BUFFER = 128.0
    endglobals
    
    private function IsUnitInAOE takes unit whichUnit, real x, real y, real radius returns boolean
        local real dx = x - GetUnitX(whichUnit)
        local real dy = y - GetUnitY(whichUnit)
        local real aoeSqr = Pow(radius + BlzGetUnitCollisionSize(whichUnit), 2)
        return (dx * dx + dy * dy) <= aoeSqr
    endfunction

    private function IntFilterCallback takes nothing returns boolean
        if (CURRENT_INT_FILTER != 0) then
            return CURRENT_INT_FILTER.evaluate(CURRENT_INT_FILTER_INPUT)
        endif
        return true
    endfunction
    
    private function IntFilterCallbackAOE takes nothing returns boolean
        local unit filter = GetFilterUnit()
        if (not IsUnitInAOE(filter, CURRENT_FILTER_X, CURRENT_FILTER_Y, CURRENT_FILTER_AOE)) then
            return false
        else
            return IntFilterCallback()
        endif
    endfunction
    
    function GroupEnumUnitsInRangeInt takes group whichGroup, real x, real y, real radius, IntCondition filter, integer filterInput returns nothing
        local boolexpr condition = Condition(function IntFilterCallback)
        set CURRENT_INT_FILTER = filter
        set CURRENT_INT_FILTER_INPUT = filterInput
        call GroupEnumUnitsInRange(whichGroup, x, y, radius, condition)
        call DestroyBoolExpr(condition)
    endfunction
    
    function GetUnitsInRangeInt takes real x, real y, real radius, IntCondition filter, integer filterInput returns group
        local group g = CreateGroup()
        call GroupEnumUnitsInRangeInt(g, x, y, radius, filter, filterInput)
        return g
    endfunction
    
    function GroupEnumUnitsInAOEInt takes group whichGroup, real x, real y, real aoe, IntCondition filter, integer filterInput returns nothing
        local boolexpr condition = Condition(function IntFilterCallbackAOE)
        set CURRENT_INT_FILTER = filter
        set CURRENT_INT_FILTER_INPUT = filterInput
        set CURRENT_FILTER_AOE = aoe
        set CURRENT_FILTER_X = x
        set CURRENT_FILTER_Y = y
        call GroupEnumUnitsInRange(whichGroup, x, y, aoe + AOE_BUFFER, condition)
        call DestroyBoolExpr(condition)
    endfunction
    
    function GroupEnumUnitsInAOEOfUnitInt takes group whichGroup, unit whichUnit, real aoe, IntCondition filter, integer filterInput returns nothing
        call GroupEnumUnitsInAOEInt(whichGroup, GetUnitX(whichUnit), GetUnitY(whichUnit), aoe + BlzGetUnitCollisionSize(whichUnit), filter, filterInput)
    endfunction
    
    function GetUnitsInAOEInt takes real x, real y, real aoe, IntCondition filter, integer filterInput returns group
        local group g = CreateGroup()
        call GroupEnumUnitsInAOEInt(g, x, y, aoe, filter, filterInput)
        return g
    endfunction
    
    function GetUnitsInAOEOfUnitInt takes unit whichUnit, real aoe, IntCondition filter, integer filterInput returns group
        local group g = CreateGroup()
        call GroupEnumUnitsInAOEOfUnitInt(g, whichUnit, aoe, filter, filterInput)
        return g
    endfunction

endlibrary

globals
    unit CURRENT_UNIT_FILTER_INPUT = null
    UnitCondition CURRENT_UNIT_FILTER = 0
endglobals

function UnitFilterCallback takes nothing returns boolean
    if (CURRENT_UNIT_FILTER != 0) then
        return CURRENT_UNIT_FILTER.evaluate(CURRENT_UNIT_FILTER_INPUT)
    endif
    return false
endfunction

function UnitFilterCallbackAOE takes nothing returns boolean
    local unit filter = GetFilterUnit()
    if (not IsUnitInAOE(filter, CURRENT_FILTER_X, CURRENT_FILTER_Y, CURRENT_FILTER_AOE)) then
        return false
    else
        return UnitFilterCallback()
    endif
endfunction

function GroupEnumUnitsInRangeUnit takes group whichGroup, real x, real y, real radius, UnitCondition filter, unit filterInput returns nothing
    local boolexpr condition = Condition(function UnitFilterCallback)
    set CURRENT_UNIT_FILTER = filter
    set CURRENT_UNIT_FILTER_INPUT = filterInput
    call GroupEnumUnitsInRange(whichGroup, x, y, radius, condition)
    call DestroyBoolExpr(condition)
endfunction

function GetUnitsInRangeUnit takes real x, real y, real radius, UnitCondition filter, unit filterInput returns group
    local group g = CreateGroup()
    call GroupEnumUnitsInRangeUnit(g, x, y, radius, filter, filterInput)
    return g
endfunction

function GroupEnumUnitsInAOEUnit takes group whichGroup, real x, real y, real aoe, UnitCondition filter, unit filterInput returns nothing
    set CURRENT_UNIT_FILTER = filter
    set CURRENT_UNIT_FILTER_INPUT = filterInput
    set CURRENT_FILTER_AOE = aoe
    set CURRENT_FILTER_X = x
    set CURRENT_FILTER_Y = y
    call GroupEnumUnitsInRange(whichGroup, x, y, aoe + AOE_BUFFER, Condition(function UnitFilterCallbackAOE))
endfunction

function GroupEnumUnitsInAOEOfUnitUnit takes group whichGroup, unit whichUnit, real aoe, UnitCondition filter, unit filterInput returns nothing
    call GroupEnumUnitsInAOEUnit(whichGroup, GetUnitX(whichUnit), GetUnitY(whichUnit), aoe + BlzGetUnitCollisionSize(whichUnit), filter, filterInput)
endfunction

function GetUnitsInAOEUnit takes real x, real y, real aoe, UnitCondition filter, unit filterInput returns group
    local group g = CreateGroup()
    call GroupEnumUnitsInAOEUnit(g, x, y, aoe, filter, filterInput)
    return g
endfunction

function GetUnitsInAOEOfUnitUnit takes unit whichUnit, real aoe, UnitCondition filter, unit filterInput returns group
    local group g = CreateGroup()
    call GroupEnumUnitsInAOEOfUnitUnit(g, whichUnit, aoe, filter, filterInput)
    return g
endfunction

struct DumbTimer
    real duration = 0.0
    real elapsed = 0.0
endstruct

function CreateDumbTimer takes real duration returns DumbTimer
    local DumbTimer t = DumbTimer.create()
    set t.duration = duration
    return t
endfunction

function UpdateDumbTimer takes DumbTimer t, real dt returns boolean
    local boolean result = false
    set t.elapsed = t.elapsed + dt
    if (t.elapsed >= t.duration) then
        set result = true
        set t.elapsed = t.elapsed - t.duration
    endif
    return result
endfunction

library TimersPlus

    globals
        constant hashtable HT_TIMERS_PLUS = InitHashtable()
        constant key TIMER_PLUS
    endglobals

    function interface TimerPlusCallback takes ITimerPlus t returns nothing

    function OnDestroyTimerPlus takes ITimerPlus t returns nothing
        call RemoveSavedInteger(HT_TIMERS_PLUS, TIMER_PLUS, GetHandleId(t.theTimer))
        call DestroyTimerDialog(t.dialog)
        call PauseTimer(t.theTimer)
        call DestroyTimer(t.theTimer)
    endfunction

    function TimerPlusEndCallback takes nothing returns nothing
        local ITimerPlus t = LoadInteger(HT_TIMERS_PLUS, TIMER_PLUS, GetHandleId(GetExpiredTimer()))
        local TimerPlusCallback callbackEnd = t.callbackEnd
        if (callbackEnd != 0) then
        set t.callbackEnd = 0
            call callbackEnd.evaluate(t)
        endif
        if (t.oneShot) then
            call t.destroy()
        endif
    endfunction

    function TimerPlusPeriodCallback takes nothing returns nothing
        local ITimerPlus t = LoadInteger(HT_TIMERS_PLUS, TIMER_PLUS, GetHandleId(GetExpiredTimer()))
        set t.duration = t.duration - t.period
        if (t.callbackPeriodic != 0) then
            call t.callbackPeriodic.execute(t)
        endif
        if (t.duration <= 0.0) then
            if (t.callbackEnd != 0) then
                call t.callbackEnd.evaluate(t)
            endif
            if (t.oneShot) then
                call t.destroy()
            endif
        endif
    endfunction

    interface ITimerPlus
        public timer theTimer = CreateTimer()
        public boolean oneShot = false
        public real duration = 0.0
        public real period = 0.0
        public timerdialog dialog = null
        public TimerPlusCallback callbackEnd = 0
        public TimerPlusCallback callbackPeriodic = 0
    endinterface

    function InitTimerPlus takes ITimerPlus t returns nothing
        call SaveInteger(HT_TIMERS_PLUS, TIMER_PLUS, GetHandleId(t.theTimer), t)
    endfunction

    function CreateTimerPlusDialog takes ITimerPlus t, string label returns timerdialog
        set t.dialog = CreateTimerDialogBJ(t.theTimer, label)
        return t.dialog
    endfunction

    function DestroyTimerPlusDialog takes ITimerPlus t returns nothing
        call DestroyTimerDialog(t.dialog)
    endfunction

    function StartTimerPlus takes ITimerPlus t, real dur, TimerPlusCallback callback returns nothing
        set t.callbackEnd = callback
        set t.duration = dur
        call TimerStart(t.theTimer, t.duration, false, function TimerPlusEndCallback)
    endfunction

    function StartTimerPlusPeriodic takes ITimerPlus t, real dur, real interval, TimerPlusCallback periodicCallback, TimerPlusCallback endCallback returns nothing
        set t.callbackEnd = endCallback
        set t.callbackPeriodic = periodicCallback
        set t.duration = dur
        set t.period = interval
        call TimerStart(t.theTimer, t.period, true, function TimerPlusPeriodCallback)
    endfunction

    function TimerPlusGetElapsed takes ITimerPlus t returns real
        return TimerGetElapsed(t.theTimer)
    endfunction

    function PauseTimerPlus takes ITimerPlus t returns nothing
        call PauseTimer(t.theTimer)
    endfunction

    function ResumeTimerPlus takes ITimerPlus t returns nothing
        call ResumeTimer(t.theTimer)
    endfunction


    // ---------------------------------------------------
    struct UnitTimer extends ITimerPlus
        public unit owner = null
    
        method onDestroy takes nothing returns nothing
            call OnDestroyTimerPlus(this)
        endmethod
    endstruct
    
    function CreateUnitTimer takes unit whichUnit, boolean oneShot returns UnitTimer
        local UnitTimer t = UnitTimer.create()
        set t.owner = whichUnit
        set t.oneShot = oneShot
        call InitTimerPlus(t)
        return t
    endfunction


    // ---------------------------------------------------
    struct DestructableTimer extends ITimerPlus
        public destructable owner = null
    
        method onDestroy takes nothing returns nothing
            call OnDestroyTimerPlus(this)
        endmethod
    endstruct
    
    function CreateDestructableTimer takes destructable whichDestructable, boolean oneShot returns DestructableTimer
        local DestructableTimer t = DestructableTimer.create()
        set t.owner = whichDestructable
        set t.oneShot = oneShot
        call InitTimerPlus(t)
        return t
    endfunction


    // ---------------------------------------------------
    struct EffectTimer extends ITimerPlus
        public effect owner = null
    
        method onDestroy takes nothing returns nothing
            call OnDestroyTimerPlus(this)
        endmethod
    endstruct
    
    function CreateEffectTimer takes effect whichEffect, boolean oneShot returns EffectTimer
        local EffectTimer t = EffectTimer.create()
        set t.owner = whichEffect
        set t.oneShot = oneShot
        call InitTimerPlus(t)
        return t
    endfunction
    
    function OnSpecialEffectExpires takes EffectTimer t returns nothing
        call DestroyEffect(t.owner)
    endfunction
    
    function AddSpecialEffectTimed takes string model, real x, real y, real duration returns effect
        local effect e = AddSpecialEffect(model, x, y)
        local EffectTimer et = CreateEffectTimer(e, true)
        call StartTimerPlus(et, duration, OnSpecialEffectExpires)
        return e
    endfunction


    // ---------------------------------------------------
    struct IntTimer extends ITimerPlus
        public integer owner = 0
    
        method onDestroy takes nothing returns nothing
            call OnDestroyTimerPlus(this)
        endmethod
    endstruct
    
    function CreateIntTimer takes integer i, boolean oneShot returns UnitTimer
        local IntTimer t = IntTimer.create()
        set t.owner = i
        set t.oneShot = oneShot
        call InitTimerPlus(t)
        return t
    endfunction
    
    function StartIntTimer takes IntTimer it, real dur, TimerPlusCallback callback returns nothing
        call StartTimerPlus(it, dur, callback)
    endfunction
    
    function StartIntTimerPeriodic takes IntTimer it, real dur, real interval, TimerPlusCallback periodicCallback, TimerPlusCallback endCallback returns nothing
        call StartTimerPlusPeriodic(it, dur, interval, periodicCallback, endCallback)
    endfunction
    
endlibrary

globals
    constant key KEY_SPELL_WAVE
    constant real SPELL_WAVE_UPDATE_INTERVAL = 0.03
endglobals

function interface SpellWaveCallback takes SpellWave sw returns nothing
function interface SpellWaveFilterCallback takes SpellWave sw returns boolean
function interface SpellWaveOnHitCallback takes SpellWave sw, unit hit returns nothing

function SpellWavePeriod takes IntTimer it returns nothing
    local SpellWave sw = it.owner
    call sw.Update()
endfunction

struct SpellWave
    unit owner = null
    vec3 origin = 0
    vec3 position = 0
    vec3 direction = 0
    real aoeStart = 0.0
    real aoeEnd = 0.0
    real distance = 0.0
    real speed = 0.0
    DumbTimer callbackPeriod = 0
    SpellWaveFilterCallback targetFilter = 0
    SpellWaveOnHitCallback onHit = 0
    SpellWaveCallback periodCallback = 0
    
    private IntTimer updateLoop = 0
    private group unitsInAOE = CreateGroup()
    private group unitsHit = CreateGroup()

    static method create takes unit owner, real x, real y, real z returns SpellWave
        local SpellWave sw = SpellWave.allocate()
        set sw.owner = owner
        set sw.origin = vec3.create(x, y, z)
        set sw.position = vec3.create(x, y, z)
        set sw.direction = vec3.create(0, 0, 0)
        set sw.callbackPeriod = CreateDumbTimer(SPELL_WAVE_UPDATE_INTERVAL)
        set sw.updateLoop = CreateIntTimer(sw, false)
        return sw
    endmethod

    method SetDirection takes real yaw, real pitch returns nothing
        local real yawRad = Deg2Rad(yaw)
        local real pitchRad = Deg2Rad(pitch)
        set direction.x = Cos(yawRad) * Cos(pitchRad)
        set direction.y = Sin(yawRad) * Cos(pitchRad)
        set direction.z = Sin(pitchRad)
    endmethod

    method GetCurrentDoneRatio takes nothing returns real
        local real i = 1.0
        if (distance > 0.0) then
            set i = VecDistance(origin, position) / distance
        endif
        return i
    endmethod

    method CalculateAOE takes real i returns real
        return (aoeEnd - aoeStart) * i + aoeStart
    endmethod

    method GetCurrentAOE takes nothing returns real
        local real i = RMinBJ(GetCurrentDoneRatio(), 1.0)
        return CalculateAOE(i)
    endmethod

    method HitUnit takes unit whichUnit returns nothing
        call GroupAddUnit(unitsHit, whichUnit)
        if (onHit != 0) then
            call onHit.execute(this, whichUnit)
        endif
    endmethod

    method HasUnitBeenHit takes unit whichUnit returns boolean
        return IsUnitInGroup(whichUnit, unitsHit)
    endmethod

    method Begin takes nothing returns nothing
        call position.copy(origin)
        call StartTimerPlusPeriodic(updateLoop, 0.0, SPELL_WAVE_UPDATE_INTERVAL, SpellWavePeriod, 0)
    endmethod

    method Update takes nothing returns nothing
        local real i = 0.0
        local real aoe = 0.0
        local unit pickedUnit = null
        local vec3 translation = VecMultiply(direction, speed * SPELL_WAVE_UPDATE_INTERVAL)

        call position.add(translation)
        call translation.destroy()

        set i = GetCurrentDoneRatio()
        set aoe = CalculateAOE(i)
        call GroupClear(unitsInAOE)
        call GroupEnumUnitsInAOEInt(unitsInAOE, position.x, position.y, aoe, targetFilter, this)

        loop
            set pickedUnit = FirstOfGroup(unitsInAOE)
            exitwhen pickedUnit == null
            if (not HasUnitBeenHit(pickedUnit)) then
                call HitUnit(pickedUnit)
            endif
            call GroupRemoveUnit(unitsInAOE, pickedUnit)
        endloop

        if (periodCallback != 0 and UpdateDumbTimer(callbackPeriod, SPELL_WAVE_UPDATE_INTERVAL)) then
            call periodCallback.execute(this)
        endif

        if (i >= 1.0) then
            call this.destroy()
        endif
    endmethod

    method onDestroy takes nothing returns nothing
        call origin.destroy()
        call position.destroy()
        call direction.destroy()
        call updateLoop.destroy()
        call DestroyGroup(unitsInAOE)
        call DestroyGroup(unitsHit)
    endmethod
endstruct

function interface PeriodicUnitAction takes unit whichUnit returns nothing
function interface PeriodicUnitCondition takes unit whichUnit returns boolean    

struct PeriodicEffect
    real time = 0.0
    real tickDuration = 0.0
    integer buffCode = 0
    PeriodicUnitAction tickCallback = 0
    PeriodicUnitCondition validityCallback = 0
endstruct

function ClearUnitPeriodicEffect takes unit whichUnit, integer index returns nothing
    local integer unitId = GetHandleId(whichUnit)
    local integer count = LoadInteger(udg_HashTable_DOTs, GetHandleId(whichUnit), StringHash("COUNT"))
    local integer i = 0

    local PeriodicEffect pEffect = 0
    
    if (count <= 1 or index >= count) then
        call FlushChildHashtable(udg_HashTable_DOTs, GetHandleId(whichUnit))
        call GroupRemoveUnit(udg_UnitGroup_DOTs, whichUnit)
    elseif (index >= 0) then
        set i = index
        loop
            if (i >= count - 1) then
                set pEffect = LoadInteger(udg_HashTable_DOTs, unitId, i)
                call pEffect.destroy()
                call RemoveSavedInteger(udg_HashTable_DOTs, unitId, count)
                exitwhen true
            endif

            set pEffect = LoadInteger(udg_HashTable_DOTs, unitId, i + 1)
            call SaveInteger(udg_HashTable_DOTs, unitId, i, pEffect)

            set i = i + 1
        endloop
        call SaveInteger(udg_HashTable_DOTs, GetHandleId(whichUnit), StringHash("COUNT"), count - 1)
    endif
endfunction

function GetUnitPeriodicEffectByBuff takes unit whichUnit, integer buffCode returns integer
    local PeriodicEffect pEffect = 0
    local integer count = LoadInteger(udg_HashTable_DOTs, GetHandleId(whichUnit), StringHash("COUNT"))
    local integer i = 0
    if (count > 0) then
        loop
            exitwhen i >= count
            set pEffect = LoadInteger(udg_HashTable_DOTs, GetHandleId(whichUnit), i)
            if (pEffect.buffCode == buffCode) then
                return pEffect
                exitwhen true
            endif
            set i = i + 1
        endloop
    endif
    return -1
endfunction

function ClearUnitPeriodicEffectByBuff takes unit whichUnit, integer buffCode returns nothing
    local integer i = GetUnitPeriodicEffectByBuff(whichUnit, buffCode)
    if (i >= 0) then
        call ClearUnitPeriodicEffect(whichUnit, i)
    endif
endfunction

function AddUnitPeriodicEffectWithValidity takes unit whichUnit, integer buffCode, real tickDuration, PeriodicUnitAction tickCallback, PeriodicUnitCondition validityCallback returns nothing
    local integer unitId = GetHandleId(whichUnit)
    local integer count = 0
    local PeriodicEffect pEffect = 0
    local integer existingIndex = GetUnitPeriodicEffectByBuff(whichUnit, buffCode)

    if (existingIndex >= 0) then
        set pEffect = LoadInteger(udg_HashTable_DOTs, unitId, existingIndex)
        set pEffect.tickDuration = tickDuration
        set pEffect.tickCallback = tickCallback
        set pEffect.validityCallback = validityCallback
    else
        set count = LoadInteger(udg_HashTable_DOTs, unitId, StringHash("COUNT"))

        set pEffect = PeriodicEffect.create()
        set pEffect.tickDuration = tickDuration
        set pEffect.buffCode = buffCode
        set pEffect.tickCallback = tickCallback
        set pEffect.validityCallback = validityCallback

        call SaveInteger(udg_HashTable_DOTs, unitId, count, pEffect)
        call SaveInteger(udg_HashTable_DOTs, unitId, StringHash("COUNT"), count + 1)
    endif    

    call GroupAddUnit(udg_UnitGroup_DOTs, whichUnit)
    call EnableTrigger(gg_trg_Triggered_Periodic_Effects)
endfunction

function AddUnitPeriodicEffect takes unit whichUnit, integer buffCode, real tickDuration, PeriodicUnitAction tickCallback returns nothing
    call AddUnitPeriodicEffectWithValidity(whichUnit, buffCode, tickDuration, tickCallback, 0)
endfunction

globals
    constant real PERIODIC_EFFECTS_INTERVAL = 0.05
endglobals

function Trig_Triggered_Periodic_Effects_Validity takes unit whichUnit returns boolean
    if (not IsUnitAliveBJ(whichUnit)) then
        return false
    elseif (BlzIsUnitInvulnerable(whichUnit)) then
        return false
    elseif (IsUnitType(whichUnit, UNIT_TYPE_MAGIC_IMMUNE)) then
        return false
    endif
    return true
endfunction

function Trig_Triggered_Periodic_Effects_Actions takes nothing returns nothing
    local integer size = BlzGroupGetSize(udg_UnitGroup_DOTs)
    local integer unitIndex = size - 1
    local unit pickedUnit = null
    local integer count = 0
    local integer pIndex = 0

    local PeriodicEffect pEffect = 0
    local PeriodicUnitCondition validity = 0

    if (size > 0) then
        loop
            exitwhen unitIndex < 0
            set pickedUnit = BlzGroupUnitAt(udg_UnitGroup_DOTs, unitIndex)
            set count = LoadInteger(udg_HashTable_DOTs, GetHandleId(pickedUnit), StringHash("COUNT"))
            set pIndex = count - 1

            loop
                exitwhen pIndex < 0

                set pEffect = LoadInteger(udg_HashTable_DOTs, GetHandleId(pickedUnit), pIndex)
                if (pEffect.validityCallback == 0) then
                    set validity = Trig_Triggered_Periodic_Effects_Validity
                else
                    set validity = pEffect.validityCallback
                endif

                if (UnitHasBuffBJ(pickedUnit, pEffect.buffCode) and validity.evaluate(pickedUnit)) then
                    if (pEffect.time >= pEffect.tickDuration) then
                        call pEffect.tickCallback.evaluate(pickedUnit)
                        set pEffect.time = pEffect.time - pEffect.tickDuration
                    else
                        set pEffect.time = pEffect.time + PERIODIC_EFFECTS_INTERVAL
                    endif
                else
                    call ClearUnitPeriodicEffect(pickedUnit, pIndex)
                endif

                set pIndex = pIndex - 1
            endloop
            
            set unitIndex = unitIndex - 1
        endloop
    else
        call DisableTrigger(GetTriggeringTrigger())
    endif
endfunction

//===========================================================================
function InitTrig_Triggered_Periodic_Effects takes nothing returns nothing
    set gg_trg_Triggered_Periodic_Effects = CreateTrigger(  )
    call DisableTrigger( gg_trg_Triggered_Periodic_Effects )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Triggered_Periodic_Effects, PERIODIC_EFFECTS_INTERVAL)
    call TriggerAddAction( gg_trg_Triggered_Periodic_Effects, function Trig_Triggered_Periodic_Effects_Actions )
endfunction

library Lifelink initializer Init
    globals
        private constant hashtable HT_LIFELINK = InitHashtable()
        constant integer LIFELINK_NONE = 0
        constant integer LIFELINK_KILL = 1
        constant integer LIFELINK_REMOVE = 2
    endglobals

    private struct Lifelink
        group kill = null
        group remove = null

        method onDestroy takes nothing returns nothing
            call DestroyGroup(kill)
            call DestroyGroup(remove)
        endmethod
    endstruct

    private function GetLifelink takes unit whichUnit returns Lifelink
        return LoadInteger(HT_LIFELINK, GetHandleId(whichUnit), 0)
    endfunction

    private function GetOrCreateLifelink takes unit whichUnit returns Lifelink
        local Lifelink ll = GetLifelink(whichUnit)
        if (ll == 0) then
            set ll = Lifelink.create()
            call SaveInteger(HT_LIFELINK, GetHandleId(whichUnit), 0, ll)
        endif
        return ll
    endfunction

    private function AddLifelinkedUnit takes Lifelink ll, unit whichUnit, integer lifelinkType returns nothing
        if (lifelinkType == LIFELINK_KILL) then
            if (ll.kill == null) then
                set ll.kill = CreateGroup()
            endif
            call GroupAddUnit(ll.kill, whichUnit)
        elseif (lifelinkType == LIFELINK_REMOVE) then
            if (ll.remove == null) then
                set ll.remove = CreateGroup()
            endif
            call GroupAddUnit(ll.remove, whichUnit)
        endif
    endfunction

    function LifelinkUnits takes unit host, unit lifelinked, integer lifelinkType returns nothing
        local Lifelink ll = GetOrCreateLifelink(host)
        call AddLifelinkedUnit(ll, lifelinked, lifelinkType)
    endfunction

    function UnlifelinkUnits takes unit host, unit lifelinked returns nothing
        local Lifelink ll = GetLifelink(host)
        call GroupRemoveUnit(ll.kill, lifelinked)
        call GroupRemoveUnit(ll.remove, lifelinked)
    endfunction

    // ****************************************
    // TRIGGERS
    // ****************************************
    private function DeathTriggerCondition takes nothing returns boolean
        return HaveSavedInteger(HT_LIFELINK, GetHandleId(GetDyingUnit()), 0)
    endfunction

    private function DeathTriggerAction takes nothing returns nothing
        local Lifelink ll = GetLifelink(GetDyingUnit())
        local unit picked = null
        local group g = ll.kill

        if (g != null) then
            loop
                set picked = FirstOfGroup(g)
                exitwhen picked == null
                call KillUnit(picked)
                call GroupRemoveUnit(g, picked)
            endloop
        endif

        set g = ll.remove
        if (g != null) then
            loop
                set picked = FirstOfGroup(g)
                exitwhen picked == null
                call KillUnit(picked)
                call RemoveUnit(picked)
                call GroupRemoveUnit(g, picked)
            endloop
        endif

        call ll.destroy()
        call RemoveSavedInteger(HT_LIFELINK, GetHandleId(GetDyingUnit()), 0)
    endfunction


    // ****************************************
    // INITIALIZATION
    // ****************************************
    private function Init takes nothing returns nothing
        local trigger deathTrigger = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(deathTrigger, EVENT_PLAYER_UNIT_DEATH)
        call TriggerAddCondition(deathTrigger, Condition(function DeathTriggerCondition))
        call TriggerAddAction(deathTrigger, function DeathTriggerAction)
    endfunction
endlibrary

globals
    LinkedList_Int FOLLOW_DUMMIES = 0
    constant hashtable HT_FOLLOW_DUMMIES = InitHashtable()
    constant key KEY_FOLLOW_DUMMY
    constant key KEY_FOLLOW_DUMMY_TARGET
endglobals

function interface FollowDummyCallback takes unit target, unit dummy returns nothing

struct FollowDummy extends ILinkedListNode
    unit target = null
    unit dummy = null
    FollowDummyCallback callback = 0
    FollowDummyCallback onDestroyed = 0
endstruct

function AddFollowDummyWithCallback takes unit target, unit dummy, integer lifelinkType, FollowDummyCallback callback returns FollowDummy
    local FollowDummy fd = FollowDummy.create()
    set fd.target = target
    set fd.dummy = dummy
    set fd.callback = callback
    if (FOLLOW_DUMMIES == 0) then
        set FOLLOW_DUMMIES = CreateLinkedList_Int()
    endif
    call LinkedListAddLast(FOLLOW_DUMMIES, fd)
    call SaveInteger(HT_FOLLOW_DUMMIES, GetHandleId(target), KEY_FOLLOW_DUMMY_TARGET, fd)
    call SaveInteger(HT_FOLLOW_DUMMIES, GetHandleId(dummy), KEY_FOLLOW_DUMMY, fd)
    if (lifelinkType != LIFELINK_NONE) then
        call LifelinkUnits(target, dummy, lifelinkType)
    endif
    call EnableTrigger(gg_trg_Follow_Dummy_Loop)
    return fd
endfunction

function AddFollowDummy takes unit target, unit dummy, integer lifelinkType returns nothing
    call AddFollowDummyWithCallback(target, dummy, lifelinkType, 0)
endfunction

function GetFollowDummyFromTarget takes unit target returns FollowDummy
    return LoadInteger(HT_FOLLOW_DUMMIES, GetHandleId(target), KEY_FOLLOW_DUMMY_TARGET)
endfunction

function GetFollowDummyFromDummy takes unit dummy returns FollowDummy
    return LoadInteger(HT_FOLLOW_DUMMIES, GetHandleId(dummy), KEY_FOLLOW_DUMMY)
endfunction

function DestroyFollowDummy takes FollowDummy fd returns nothing
    if (fd.onDestroyed != 0) then
        call fd.onDestroyed.evaluate(fd.target, fd.dummy)
    endif
    call RemoveSavedInteger(HT_FOLLOW_DUMMIES, GetHandleId(fd.target), KEY_FOLLOW_DUMMY_TARGET)
    call RemoveSavedInteger(HT_FOLLOW_DUMMIES, GetHandleId(fd.dummy), KEY_FOLLOW_DUMMY)
    call UnlifelinkUnits(fd.target, fd.dummy)
    call LinkedListRemove(FOLLOW_DUMMIES, fd)
    call fd.destroy()
endfunction

globals
    constant real FOLLOW_DUMMY_UPDATE_INTERVAL = 0.01
endglobals

function Trig_Follow_Dummy_Loop_Actions takes nothing returns nothing
    local FollowDummy fd = LinkedListGetFirst(FOLLOW_DUMMIES)
    local FollowDummy tempNode = 0
    if (FOLLOW_DUMMIES.count > 0) then
        loop
            exitwhen fd == 0
            if (UnitAlive(fd.target) and UnitAlive(fd.dummy)) then
                call SetUnitPosition(fd.dummy, GetUnitX(fd.target), GetUnitY(fd.target))
                if (IsUnitHidden(fd.target) and not IsUnitHidden(fd.dummy)) then
                    call ShowUnitHide(fd.dummy)
                elseif (not IsUnitHidden(fd.target) and IsUnitHidden(fd.dummy)) then
                    call ShowUnitShow(fd.dummy)
                endif
                if (fd.callback != 0) then
                    call fd.callback.evaluate(fd.target, fd.dummy)
                endif
                set fd = fd.next
            else
                set tempNode = fd
                set fd = fd.next
                call DestroyFollowDummy(tempNode)
            endif
        endloop
    else
        call DisableTrigger(GetTriggeringTrigger())
    endif
endfunction

//===========================================================================
function InitTrig_Follow_Dummy_Loop takes nothing returns nothing
    set gg_trg_Follow_Dummy_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Follow_Dummy_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Follow_Dummy_Loop, FOLLOW_DUMMY_UPDATE_INTERVAL )
    call TriggerAddAction( gg_trg_Follow_Dummy_Loop, function Trig_Follow_Dummy_Loop_Actions )
endfunction

library GatedAbilityTrigger initializer Init
    globals
        private GatedAbilityTrigger array GATS
        private integer GAT_COUNT = 0
        private integer ABILITY_ID = 0
    endglobals

    function interface GatedAbilityTriggerCallback takes unit u returns nothing

    struct GatedAbilityTrigger
        trigger t = null
        integer abilityId = 0
        integer techId = 0
        group abilityUnits = null
        GatedAbilityTriggerCallback onEnable = 0
        GatedAbilityTriggerCallback onDisable = 0
    endstruct

    private function AddUnit takes GatedAbilityTrigger gat, unit whichUnit returns nothing
        if (GroupAddUnit(gat.abilityUnits, whichUnit)) then
            if (gat.techId == 0 or GetPlayerTechCount(GetOwningPlayer(whichUnit), gat.techId, true) > 0) then
                call EnableTrigger(gat.t)
                if (gat.onEnable != 0) then
                    call gat.onEnable.evaluate(whichUnit)
                endif
            endif
        endif
    endfunction

    private function RemoveUnit takes GatedAbilityTrigger gat, unit whichUnit returns nothing
        if (GroupRemoveUnit(gat.abilityUnits, whichUnit)) then
            if (gat.onDisable != 0 and (gat.techId == 0 or GetPlayerTechCount(GetOwningPlayer(whichUnit), gat.techId, true) > 0)) then
                call gat.onDisable.evaluate(whichUnit)
            endif
        endif
    endfunction

    private function ExecuteCallbackForGroup takes group g, GatedAbilityTriggerCallback callback returns nothing
        local integer i = BlzGroupGetSize(g)
        loop
            set i = i - 1
            exitwhen i < 0
            call callback.evaluate(BlzGroupUnitAt(g, i))
        endloop
    endfunction

    private function UnitsWithAbilityFilter takes nothing returns boolean
        return GetUnitAbilityLevel(GetFilterUnit(), ABILITY_ID) > 0
    endfunction

    function GateAbilityTriggerAll takes trigger t, integer abilityId, integer techId, GatedAbilityTriggerCallback onEnable, GatedAbilityTriggerCallback onDisable returns GatedAbilityTrigger
        local group units = null
        local unit picked = null
        local integer i = 0
        local player p = null
        local GatedAbilityTrigger g = GatedAbilityTrigger.create()
        set ABILITY_ID = abilityId
        set g.t = t
        set g.abilityId = abilityId
        set g.techId = techId
        set g.abilityUnits = CreateGroup()
        set g.onEnable = onEnable
        set g.onDisable = onDisable

        call GroupEnumUnitsInRect(g.abilityUnits, GetEntireMapRect(), Condition(function UnitsWithAbilityFilter))

        set GATS[GAT_COUNT] = g
        set GAT_COUNT = GAT_COUNT + 1

        if (BlzGroupGetSize(g.abilityUnits) > 0) then
            if (techId != 0) then
                set i = bj_MAX_PLAYER_SLOTS
                loop
                    set i = i - 1
                    exitwhen i < 0
                    if (GetPlayerTechCount(Player(i), techId, true) > 0) then
                        exitwhen true
                    endif
                endloop
                if (i < 0) then
                    call DisableTrigger(t)
                elseif (onEnable != 0) then
                    call ExecuteCallbackForGroup(g.abilityUnits, onEnable)
                endif
            elseif (onEnable != 0) then
                call ExecuteCallbackForGroup(g.abilityUnits, onEnable)
            endif
        else
            call DisableTrigger(t)
        endif
        return g
    endfunction

    function GateAbilityTrigger takes trigger t, integer abilityId, integer techId returns GatedAbilityTrigger
        return GateAbilityTriggerAll(t, abilityId, techId, 0, 0)
    endfunction

    private function UnitEnters takes nothing returns nothing
        local unit entering = GetEnteringUnit()
        local player p = GetOwningPlayer(entering)
        local integer i = GAT_COUNT
        local GatedAbilityTrigger gat = 0
        loop
            set i = i - 1
            exitwhen i < 0
            set gat = GATS[i]
            if (GetUnitAbilityLevel(entering, gat.abilityId) > 0) then
                call AddUnit(gat, entering)
            endif
        endloop
    endfunction

    private function UnitDies takes nothing returns nothing
        local unit dying = GetDyingUnit()
        local integer i = GAT_COUNT
        local GatedAbilityTrigger gat = 0
        if (not IsUnitType(dying, UNIT_TYPE_HERO)) then
            loop
                set i = i - 1
                exitwhen i < 0
                set gat = GATS[i]
                if (GetUnitAbilityLevel(dying, gat.abilityId) > 0) then
                    call RemoveUnit(gat, dying)
                endif
            endloop
        endif
    endfunction

    private function UnitResearchesTech takes nothing returns nothing
        local unit researching = GetResearchingUnit()
        local integer techId = GetResearched()
        local integer i = GAT_COUNT
        local GatedAbilityTrigger gat = 0
        loop
            set i = i - 1
            exitwhen i < 0
            set gat = GATS[i]
            if (gat.techId == techId and BlzGroupGetSize(gat.abilityUnits) > 0) then
                call EnableTrigger(gat.t)
                if (gat.onEnable != 0) then
                    call ExecuteCallbackForGroup(gat.abilityUnits, gat.onEnable)
                endif
            endif
        endloop
    endfunction

    private function Init takes nothing returns nothing
        local trigger t = null

        set t = CreateTrigger()
        call TriggerRegisterEnterRectSimple(t, GetEntireMapRect())
        call TriggerAddAction(t, function UnitEnters)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_DEATH)
        call TriggerAddAction(t, function UnitDies)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_RESEARCH_FINISH)
        call TriggerAddAction(t, function UnitResearchesTech)
    endfunction 
endlibrary

library TransportTracking initializer Init requires EventSystem
    globals
        private constant hashtable HT_TRANSPORTS = InitHashtable()
        private constant key KEY_UNIT_TO_TRANSPORT
        private constant key KEY_TRANSPORT_TO_UNITS

        public Event OnUnitLoadedIntoTransport = 0
        public Event OnUnitUnloadedFromTransport = 0
    endglobals

    struct TransportEvent
        unit transport = null
        unit cargo = null
    endstruct

    private function FireTransportEvent takes Event ev, unit transport, unit cargo returns nothing
        local TransportEvent input = 0
        if (EventSystem_HasListeners(ev)) then
            set input = TransportEvent.create()
            set input.transport = transport
            set input.cargo = cargo
            call EventSystem_FireEvent(ev, input)
            call input.destroy()
        endif
    endfunction

    function IsUnitLoadedIntoTransport takes unit whichUnit returns boolean
        return HaveSavedHandle(HT_TRANSPORTS, GetHandleId(whichUnit), KEY_UNIT_TO_TRANSPORT)
    endfunction

    function GetTransportingUnit takes unit whichUnit returns unit
        return LoadUnitHandle(HT_TRANSPORTS, GetHandleId(whichUnit), KEY_UNIT_TO_TRANSPORT)
    endfunction

    function GetLoadedUnits takes unit transport returns group
        return LoadGroupHandle(HT_TRANSPORTS, GetHandleId(transport), KEY_TRANSPORT_TO_UNITS)
    endfunction

    private function GetOrCreateLoadedUnits takes unit transport returns group
        local group loadedUnits = GetLoadedUnits(transport)
        if (loadedUnits == null) then
            set loadedUnits = CreateGroup()
            call SaveGroupHandle(HT_TRANSPORTS, GetHandleId(transport), KEY_TRANSPORT_TO_UNITS, loadedUnits)
        endif
        return loadedUnits
    endfunction

    private function ReportUnitLoadedIntoTransport takes unit transport, unit loaded returns nothing
        local group loadedUnits = GetOrCreateLoadedUnits(transport)
        call GroupAddUnit(loadedUnits, loaded)
        call SaveUnitHandle(HT_TRANSPORTS, GetHandleId(loaded), KEY_UNIT_TO_TRANSPORT, transport)
        call FireTransportEvent(OnUnitLoadedIntoTransport, transport, loaded)
    endfunction

    private function ReportUnitUnloadedFromTransport takes unit transport, unit unloaded returns nothing
        local group loadedUnits = GetLoadedUnits(transport)
        if (GroupRemoveUnit(loadedUnits, unloaded)) then
            call FireTransportEvent(OnUnitUnloadedFromTransport, transport, unloaded)
            if (CountUnitsInGroup(loadedUnits) == 0) then
                call DestroyGroup(loadedUnits)
                call RemoveSavedHandle(HT_TRANSPORTS, GetHandleId(transport), KEY_TRANSPORT_TO_UNITS)
            endif
            call RemoveSavedHandle(HT_TRANSPORTS, GetHandleId(unloaded), KEY_UNIT_TO_TRANSPORT)
        endif
    endfunction

    private function UnitLoadedActions takes nothing returns nothing
        call ReportUnitLoadedIntoTransport(GetTransportUnit(), GetLoadedUnit())
    endfunction

    private function UnitUnloadedConditions takes nothing returns boolean
        if (GetIssuedOrderId() != OrderId("stop")) then
            return false
        elseif (not IsUnitLoadedIntoTransport(GetOrderedUnit())) then
            return false
        endif
        return true
    endfunction

    private function UnitUnloadedActions takes nothing returns nothing
        local unit unloaded = GetOrderedUnit()
        local unit transport = GetTransportingUnit(unloaded)
        call ReportUnitUnloadedFromTransport(transport, unloaded)
    endfunction

    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_LOADED)
        call TriggerAddAction(t, function UnitLoadedActions)

        set t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ISSUED_ORDER)
        call TriggerAddCondition(t, Condition(function UnitUnloadedConditions))
        call TriggerAddAction(t, function UnitUnloadedActions)
        
        set OnUnitLoadedIntoTransport = EventSystem_Create()
        set OnUnitUnloadedFromTransport = EventSystem_Create()
    endfunction

endlibrary

globals
    constant integer SIM_MOVE_TYPE_SETXY = 0
    constant integer SIM_MOVE_TYPE_SETPOS = 1
    constant real SIM_MOVEMENT_UPDATE_INTERVAL = 0.01
endglobals

function interface SimMovementCallback takes SimMovement sim returns nothing

struct SimMovement
    integer simMoveType = SIM_MOVE_TYPE_SETXY
    unit mover = null
    real originX = 0.0
    real originY = 0.0
    real targetX = 0.0
    real targetY = 0.0
    real speed = 0.0
    real arc = 0.0
    real flyHeightStart = 0.0
    real flyHeightEnd = -1.0
    SimMovementCallback onMove = 0
    SimMovementCallback onFinish = 0
    IntTimer update = 0

    method onDestroy takes nothing returns nothing
        if (onFinish != 0) then
            call onFinish.evaluate(this)
        endif
        call update.destroy()
    endmethod
endstruct

function SimMoveApplyArc takes SimMovement sim, real curX, real curY returns nothing
    local real x = DistanceBetweenPointsXY(curX, curY, sim.targetX, sim.targetY)
    local real d = DistanceBetweenPointsXY(sim.originX, sim.originY, sim.targetX, sim.targetY)
    local real y = GetMissileHeight(sim.arc, d, x)
    local real flyHeightOffset = 0.0

    if (sim.flyHeightEnd != -1.0) then
        set flyHeightOffset = (1.0 - DBZ(x, d, 0.0)) * (sim.flyHeightEnd - sim.flyHeightStart) + sim.flyHeightStart
    endif

    call SetUnitFlyHeight(sim.mover, y + flyHeightOffset, 0.0)
endfunction

function SimMoveUnit takes SimMovement sim, real x, real y returns nothing
    if (sim.simMoveType == SIM_MOVE_TYPE_SETPOS) then
        call SetUnitPosition(sim.mover, x, y)
    else
        call SetUnitX(sim.mover, x)
        call SetUnitY(sim.mover, y)
    endif
    if (sim.arc != 0.0) then
        call SimMoveApplyArc(sim, x, y)
    endif
    if (sim.onMove != 0) then
        call sim.onMove.evaluate(sim)
    endif
endfunction

function SimMovementUpdate takes IntTimer it returns nothing
    local SimMovement sim = it.owner
    local real delta = TimerPlusGetElapsed(it)
    local real x = GetUnitX(sim.mover)
    local real y = GetUnitY(sim.mover)
    local real speed = sim.speed * delta
    local real angle = AngleBetweenPointsXY(x, y, sim.targetX, sim.targetY)
    local real dist = DistanceBetweenPointsXY(x, y, sim.targetX, sim.targetY)
    local real nextX = PolarProjectionX(x, speed, angle)
    local real nextY = PolarProjectionY(y, speed, angle)

    if (dist > speed) then // and (IsUnitType(sim.mover, UNIT_TYPE_FLYING) or IsPointWalkable(nextX, nextY))) then
        call SetUnitPathing(sim.mover, false)
        call SimMoveUnit(sim, nextX, nextY)
    else
        // Unit is close enough to the target point
        call SimMoveUnit(sim, sim.targetX, sim.targetY)
        call SetUnitPathing(sim.mover, true)
        call sim.destroy()
    endif
endfunction

function CreateSimMovement takes unit whichUnit, real startX, real startY, real endX, real endY returns SimMovement
    local SimMovement sim = SimMovement.create()
    set sim.mover = whichUnit
    set sim.originX = startX
    set sim.originY = startY
    set sim.targetX = endX
    set sim.targetY = endY
    set sim.update = CreateIntTimer(sim, false)
    return sim
endfunction

function MoveUnitToPointAtSpeedParams takes SimMovement sim returns nothing
    local location newTarget = null
    if (not IsUnitType(sim.mover, UNIT_TYPE_FLYING)) then
        if (sim.arc != 0.0 or sim.flyHeightEnd != -1.0) then
            call EnableUnitFlyHeight(sim.mover)
        endif
        set newTarget = LineTraceWalkability(sim.originX, sim.originY, sim.targetX, sim.targetY, 32.0)
	set sim.targetX = GetLocationX(newTarget)
        set sim.targetY = GetLocationY(newTarget)
        call RemoveLocation(newTarget)
    endif
    call StartIntTimerPeriodic(sim.update, 0.0, SIM_MOVEMENT_UPDATE_INTERVAL, SimMovementUpdate, 0)
endfunction

function MoveUnitToPointAtSpeedAll takes unit whichUnit, real targetX, real targetY, real speed, real arc, integer simMovementType, SimMovementCallback onMove, SimMovementCallback onFinished returns nothing
    local SimMovement sim = CreateSimMovement(whichUnit, GetUnitX(whichUnit), GetUnitY(whichUnit), targetX, targetY)
    set sim.simMoveType = simMovementType
    set sim.speed = speed
    set sim.arc = arc
    set sim.flyHeightStart = GetUnitFlyHeight(whichUnit)
    set sim.onMove = onMove
    set sim.onFinish = onFinished
    call MoveUnitToPointAtSpeedParams(sim)
endfunction

function MoveUnitToPointAtSpeedWithCallback takes unit whichUnit, real targetX, real targetY, real speed, SimMovementCallback onFinished returns nothing
    call MoveUnitToPointAtSpeedAll(whichUnit, targetX, targetY, speed, 0.0, SIM_MOVE_TYPE_SETXY, 0, onFinished)
endfunction

function MoveUnitToPointAtSpeedXY takes unit whichUnit, real targetX, real targetY, real speed returns nothing
    call MoveUnitToPointAtSpeedAll(whichUnit, targetX, targetY, speed, 0.0, SIM_MOVE_TYPE_SETXY, 0, 0)
endfunction

function MoveUnitToPointAtSpeed takes unit whichUnit, location targetLoc, real speed returns nothing
    call MoveUnitToPointAtSpeedXY(whichUnit, GetLocationX(targetLoc), GetLocationY(targetLoc), speed)
endfunction

function AddMissileTarget takes unit target, unit caster, integer buffHandle, MissileHitCallback callback returns nothing

    local integer targetHandle = GetHandleId(target)
    local integer count = LoadInteger(udg_HashTable_Missiles, targetHandle, StringHash("COUNT"))
    local integer index = count

    call SaveUnitHandle(udg_HashTable_Missiles, targetHandle, StringHash("CASTER " + I2S(index)), caster)
    call SaveInteger(udg_HashTable_Missiles, targetHandle, StringHash("BUFF " + I2S(index)), buffHandle)
    call SaveInteger(udg_HashTable_Missiles, targetHandle, StringHash("ONHIT " + I2S(index)), callback)
    call SaveInteger(udg_HashTable_Missiles, targetHandle, StringHash("COUNT"), count + 1)

    call GroupAddUnit(udg_UnitGroup_MissileTargets, target)

    call EnableTrigger(gg_trg_Triggered_Missile_Loop)

endfunction

function ClearMissileTarget takes unit whichUnit, integer index returns nothing

    local integer unitHandle = GetHandleId(whichUnit)
    local integer count = LoadInteger(udg_HashTable_Missiles, unitHandle, StringHash("COUNT"))

    local integer i = 0
    local integer tempBuff = 0
    local MissileHitCallback tempCallback = 0
    local unit tempCaster = null

    call RemoveSavedInteger(udg_HashTable_Missiles, unitHandle, StringHash("BUFF " + I2S(index)))
    call RemoveSavedInteger(udg_HashTable_Missiles, unitHandle, StringHash("ONHIT " + I2S(index)))
    call RemoveSavedHandle(udg_HashTable_Missiles, unitHandle, StringHash("CASTER " + I2S(index)))

    if (count == 1 or index >= count) then
        call FlushChildHashtable(udg_HashTable_Missiles, unitHandle)
        call GroupRemoveUnit(udg_UnitGroup_MissileTargets, whichUnit)
    elseif (index >= 0) then
	set i = index
        loop
    
            if (i >= count - 1) then
                call RemoveSavedInteger(udg_HashTable_Missiles, unitHandle, StringHash("BUFF " + I2S(i)))
                call RemoveSavedInteger(udg_HashTable_Missiles, unitHandle, StringHash("ONHIT " + I2S(i)))
                call RemoveSavedHandle(udg_HashTable_Missiles, unitHandle, StringHash("CASTER " + I2S(i)))
                exitwhen true
            endif

            set tempBuff = LoadInteger(udg_HashTable_Missiles, unitHandle, StringHash("BUFF " + I2S(i + 1)))
            set tempCallback = LoadInteger(udg_HashTable_Missiles, unitHandle, StringHash("ONHIT " + I2S(i + 1)))
            set tempCaster = LoadUnitHandle(udg_HashTable_Missiles, unitHandle, StringHash("CASTER " + I2S(i + 1)))

            call SaveInteger(udg_HashTable_Missiles, unitHandle, StringHash("BUFF " + I2S(i)), tempBuff)
            call SaveInteger(udg_HashTable_Missiles, unitHandle, StringHash("ONHIT " + I2S(i)), tempCallback)
            call SaveUnitHandle(udg_HashTable_Missiles, unitHandle, StringHash("CASTER " + I2S(i)), tempCaster)

            set i = i + 1
        endloop
        call SaveInteger(udg_HashTable_Missiles, unitHandle, StringHash("COUNT"), count - 1)
    endif

endfunction

globals
    constant real TRIGGERED_MISSILE_INTERVAL = 0.01
endglobals

function interface MissileHitCallback takes unit caster, unit target returns nothing

function IsInvalidMissileTarget takes unit whichUnit returns boolean
    if (IsUnitAliveBJ(whichUnit) == false) then
        return true
    endif
    if (IsUnitType(whichUnit, UNIT_TYPE_MAGIC_IMMUNE)) then
        return true
    endif
    if (BlzIsUnitInvulnerable(whichUnit)) then
        return true
    endif
    if (IsUnitHiddenBJ(whichUnit)) then
        return true
    endif
    return false
endfunction

function Trig_Triggered_Missile_Loop_Actions takes nothing returns nothing
    local integer groupCount = BlzGroupGetSize(udg_UnitGroup_MissileTargets)
    local integer groupIndex = groupCount - 1
    local integer missileCount = 0
    local integer missileIndex = 0
    local unit pickedUnit = null

    local integer missileBuff = 0
    local unit caster = null
    local MissileHitCallback callback = 0

    if (groupCount > 0) then
        loop
            exitwhen groupIndex < 0

            set pickedUnit = BlzGroupUnitAt(udg_UnitGroup_MissileTargets, groupIndex)
            set missileCount = LoadInteger(udg_HashTable_Missiles, GetHandleId(pickedUnit), StringHash("COUNT"))
            if (missileCount > 0) then
                set missileIndex = missileCount - 1
                loop
                    exitwhen missileIndex < 0

                    set missileBuff = LoadInteger(udg_HashTable_Missiles, GetHandleId(pickedUnit), StringHash("BUFF " + I2S(missileIndex)))
                    // Check if the target is still valid
                    if (IsInvalidMissileTarget(pickedUnit)) then
                        call ClearMissileTarget(pickedUnit, missileIndex)
                    elseif UnitHasBuffBJ(pickedUnit, missileBuff) then
                        set caster = LoadUnitHandle(udg_HashTable_Missiles, GetHandleId(pickedUnit), StringHash("CASTER " + I2S(missileIndex)))
                        set callback = LoadInteger(udg_HashTable_Missiles, GetHandleId(pickedUnit), StringHash("ONHIT " + I2S(missileIndex)))
                        call callback.evaluate(caster, pickedUnit)
                        call ClearMissileTarget(pickedUnit, missileIndex)
                    endif

                    set missileIndex = missileIndex - 1
                endloop
            else
                call GroupRemoveUnit(udg_UnitGroup_MissileTargets, pickedUnit)
            endif

            set groupIndex = groupIndex - 1
        endloop
    else
        call DisableTrigger(GetTriggeringTrigger())
    endif
endfunction

//===========================================================================
function InitTrig_Triggered_Missile_Loop takes nothing returns nothing
    set gg_trg_Triggered_Missile_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Triggered_Missile_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Triggered_Missile_Loop, TRIGGERED_MISSILE_INTERVAL)
    call TriggerAddAction( gg_trg_Triggered_Missile_Loop, function Trig_Triggered_Missile_Loop_Actions )
endfunction

globals
    constant real MISSILE_UPDATE_INTERVAL = 0.01
endglobals

function interface MissileUpdateCallback takes IMissile missile, real dt returns boolean
function interface MissileDestroyCallback takes IMissile missile returns nothing

function OnDestroyMissile takes IMissile missile returns nothing
    if (missile.destroyCallback != 0) then
        call missile.destroyCallback.evaluate(missile)
    endif
    call DestroyEffect(missile.model)
    call missile.visualPos.destroy()
    call missile.velocity.destroy()
    call missile.update.destroy()
    call RemoveLocation(missile.actualPos)
endfunction

function MissileTimerLoop takes IntTimer missileTimer returns nothing
    local IMissile missile = missileTimer.owner
    local real dt = TimerPlusGetElapsed(missileTimer)
    local boolean shouldDestroy = false
    if (missile.updateLoop != 0) then
        set shouldDestroy = missile.updateLoop.evaluate(missile, dt)
    endif
    
    if (missile.userUpdateCallback != 0) then
        set missile.userUpdateElapsed = missile.userUpdateElapsed + dt
        if (missile.userUpdateElapsed >= missile.userUpdateInterval) then
            set shouldDestroy = missile.userUpdateCallback.evaluate(missile, dt) or shouldDestroy
            set missile.userUpdateElapsed = missile.userUpdateElapsed - missile.userUpdateInterval
        endif
    endif

    if (shouldDestroy) then
        call missile.destroy()
    endif
endfunction

function BaseMissileUpdate takes IMissile missile, real dt returns boolean
    local vec3 delta = VecMultiply(missile.velocity, dt)
    local vec3 deltaNorm = vec3.create(delta.x, delta.y, 0.0).normalize()
    local real arcZOffset = GetMissileHeight(missile.arc, missile.range, missile.rangeRemaining)
    local vec3 nextVisualPos = 0

    call MoveLocation(missile.actualPos, GetLocationX(missile.actualPos) + delta.x, GetLocationY(missile.actualPos) + delta.y)
    set nextVisualPos = GetLocVec(missile.actualPos).addZ(missile.zOffset + arcZOffset + delta.z)

    call BlzSetSpecialEffectYaw(missile.model, VecYawRad(deltaNorm))
    call BlzSetSpecialEffectPitch(missile.model, PitchBetweenVecsRad(missile.visualPos, nextVisualPos))
    call BlzSetSpecialEffectPosition(missile.model, nextVisualPos.x, nextVisualPos.y, nextVisualPos.z)

    set missile.visualPos = missile.visualPos.copy(nextVisualPos)
    set missile.rangeRemaining = missile.rangeRemaining - delta.setZ(0.0).mag()

    call delta.destroy()
    call deltaNorm.destroy()
    call nextVisualPos.destroy()

    return missile.rangeRemaining <= 0.0
endfunction

interface IMissile
    effect model = null
    unit owner = null
    location actualPos = null
    real zOffset = 0.0
    vec3 visualPos = 0
    vec3 velocity = 0
    real range = BIG_REAL
    real rangeRemaining = 0.0
    real arc = 0.0
    real speed = 0.0
    real userUpdateInterval = 0.0
    real userUpdateElapsed = 0.0
    MissileUpdateCallback updateLoop = 0
    MissileUpdateCallback userUpdateCallback = 0
    MissileDestroyCallback destroyCallback = 0
    IntTimer update = 0
    integer data = 0
endinterface

function InitMissile takes IMissile missile, string modelName, unit owner, real originX, real originY, real zOffset, real yawInRadians, real pitchInRadians returns nothing
    set missile.model = AddSpecialEffect(modelName, originX, originY)
    set missile.owner = owner
    set missile.actualPos = Location(originX, originY)
    set missile.visualPos = GetLocVec(missile.actualPos).addZ(zOffset)
    set missile.zOffset = zOffset
    call BlzSetSpecialEffectYaw(missile.model, yawInRadians)
    call BlzSetSpecialEffectPitch(missile.model, pitchInRadians)
    call BlzSetSpecialEffectZ(missile.model, missile.visualPos.z)
endfunction

function FireMissile takes IMissile missile, real speed, real range, real yawInRadians, real pitchInRadians, MissileUpdateCallback updateLoop, MissileDestroyCallback onDestroyed returns nothing
    call BlzSetSpecialEffectYaw(missile.model, yawInRadians)
    call BlzSetSpecialEffectPitch(missile.model, pitchInRadians)
    set missile.velocity = VecDirection(yawInRadians, pitchInRadians).multiply(speed)
    set missile.range = range
    set missile.rangeRemaining = range
    set missile.speed = speed
    set missile.updateLoop = updateLoop
    set missile.destroyCallback = onDestroyed
    set missile.update = CreateIntTimer(missile, false)
    call StartIntTimerPeriodic(missile.update, 0.0, MISSILE_UPDATE_INTERVAL, MissileTimerLoop, 0)
endfunction

function interface WaveMissileFilter takes WaveMissile missile, unit filter returns boolean
    function interface WaveMissileOnHitCallback takes WaveMissile missle, unit hit returns nothing
    
    function WaveMissileUpdate takes WaveMissile missile, real dt returns boolean
        local real aoe = 0.0
        local group nearbyUnits = null
        local unit picked = null
        local boolean result = BaseMissileUpdate.evaluate(missile, dt)
    
        if (UpdateDumbTimer(missile.hitInterval, TimerPlusGetElapsed(missile.update))) then
            set aoe = (missile.aoeEnd - missile.aoeStart) * (1 - (missile.rangeRemaining / missile.range)) + missile.aoeStart
            set nearbyUnits = CreateGroup()
    
            call GroupEnumUnitsInRangeOfLoc(nearbyUnits, missile.actualPos, aoe, null)
    
            loop
                set picked = FirstOfGroup(nearbyUnits)
                exitwhen picked == null
                if (missile.filter != 0 and missile.onHit != 0) then
                    if (missile.multiHit or not IsUnitInGroup(picked, missile.allHit)) then
                        call GroupAddUnit(missile.allHit, picked)
                        if (missile.filter.evaluate(missile, picked)) then
                            call missile.onHit.execute(missile, picked)
                        endif    
                    endif
                endif
                call GroupRemoveUnit(nearbyUnits, picked)
            endloop
            
            call DestroyGroup(nearbyUnits)
        endif
    
        return result
    endfunction
    
    struct WaveMissile extends IMissile
        real aoeStart = 0.0
        real aoeEnd = 0.0
        boolean multiHit = false
        group allHit = null
        DumbTimer hitInterval = 0
        WaveMissileFilter filter = 0
        WaveMissileOnHitCallback onHit = 0
    
        method onDestroy takes nothing returns nothing
            call OnDestroyMissile(this)
            call hitInterval.destroy()
            call DestroyGroup(allHit)
        endmethod
    endstruct
    
    function CreateWaveMissileYawPitch takes string modelName, unit owner, real originX, real originY, real originZ, real hitInterval, real yawInRadians, real pitchInRadians returns WaveMissile
        local WaveMissile waveMissile = WaveMissile.create()
        call InitMissile(waveMissile, modelName, owner, originX, originY, originZ, yawInRadians, pitchInRadians)
        set waveMissile.hitInterval = CreateDumbTimer(hitInterval)
        return waveMissile
    endfunction
    
    function CreateWaveMissileInterval takes string modelName, unit owner, real originX, real originY, real originZ, real hitInterval returns WaveMissile
        return CreateWaveMissileYawPitch(modelName, owner, originX, originY, originZ, hitInterval, 0.0, 0.0)
    endfunction
    
    function CreateWaveMissile takes string modelName, unit owner, real originX, real originY, real originZ returns WaveMissile
        return CreateWaveMissileYawPitch(modelName, owner, originX, originY, originZ, 0.0, 0.0, 0.0)
    endfunction
    
    function FireWaveMissile takes WaveMissile missile, real speed, real range, real yawInRadians, real pitchInRadians, real aoeStart, real aoeEnd, WaveMissileFilter filter, WaveMissileOnHitCallback onHit returns nothing
        if (not missile.multiHit) then
            set missile.allHit = CreateGroup()
        endif
        set missile.aoeStart = aoeStart
        set missile.aoeEnd = aoeEnd
        set missile.filter = filter
        set missile.onHit = onHit
        call FireMissile(missile, speed, range, yawInRadians, pitchInRadians, WaveMissileUpdate, 0)
    endfunction

function interface PointMissileOnHitCallback takes PointMissile missile, real x, real y returns nothing

function PointMissileDestroyed takes PointMissile pm returns nothing
    if (pm.onHit != 0) then
        call pm.onHit.evaluate(pm, GetLocationX(pm.actualPos), GetLocationY(pm.actualPos))
    endif
endfunction

struct PointMissile extends IMissile
    PointMissileOnHitCallback onHit = 0
    
    method onDestroy takes nothing returns nothing
        call OnDestroyMissile(this)
    endmethod
endstruct

function CreatePointMissile takes string modelName, unit owner, real originX, real originY, real zOffset, real yawInRadians, real pitchInRadians returns PointMissile
    local PointMissile pointMissile = PointMissile.create()
    call InitMissile(pointMissile, modelName, owner, originX, originY, zOffset, yawInRadians, pitchInRadians)
    return pointMissile
endfunction

function FirePointMissile takes PointMissile missile, real speed, real targetX, real targetY, real targetZOffset, real arc, PointMissileOnHitCallback onHit returns nothing
    local location targetLoc = Location(targetX, targetY)
    local vec3 source = GetLocVec(missile.actualPos)
    local vec3 target = GetLocVec(targetLoc).addZ(targetZOffset)
    local real distance = DistanceBetweenPointsXY(source.x, source.y, target.x, target.y)
    set missile.arc = arc
    set missile.onHit = onHit
    call FireMissile(missile, speed, distance, YawBetweenVecsRad(source, target), -PitchBetweenVecsRad(source, target), BaseMissileUpdate, PointMissileDestroyed)
    call RemoveLocation(targetLoc)
    call source.destroy()
    call target.destroy()
endfunction

function interface TargetMissileOnHitCallback takes TargetMissile missile, real x, real y returns nothing

function TargetMissileDestroyed takes TargetMissile tm returns nothing
    if (tm.onHit != 0) then
        call tm.onHit.evaluate(tm, GetLocationX(tm.actualPos), GetLocationY(tm.actualPos))
    endif
endfunction

function TargetMissileWithHomingUpdate takes TargetMissile missile, real dt returns boolean
    local vec3 currentPos = GetLocVec(missile.actualPos)
    local vec3 targetPos = GetUnitVec(missile.target).addZ(missile.targetZOffset)
    local vec3 delta = VecSub(targetPos, currentPos)
    local vec3 deltaNorm = vec3.create(delta.x, delta.y, 0.0).normalize()
    local real rangeRemaining = DistanceBetweenPointsXY(currentPos.x, currentPos.y, targetPos.x, targetPos.y)
    local real arcZOffset = GetMissileHeight(missile.arc, missile.range, rangeRemaining)
    local real targetZOffset = missile.targetZOffset + GetUnitFlyHeight(missile.target)
    local real zOffset = (1.0 - RMinBJ(DBZ(rangeRemaining, missile.range, 1.0), 1.0)) * (targetZOffset - missile.zOffset) + missile.zOffset + arcZOffset
    local real speed = missile.speed * dt
    local vec3 nextVisualPos = 0
    local boolean hit = false

    if (rangeRemaining <= speed) then
        call MoveLocation(missile.actualPos, targetPos.x, targetPos.y)
        set nextVisualPos = targetPos.dupe().addZ(arcZOffset)
        set rangeRemaining = 0.0
        set hit = true
    else
        call MoveLocation(missile.actualPos, currentPos.x + deltaNorm.x * speed, currentPos.y + deltaNorm.y * speed)
        set nextVisualPos = GetLocVec(missile.actualPos).addZ(zOffset)
    endif

    call BlzSetSpecialEffectYaw(missile.model, VecYawRad(deltaNorm))
    call BlzSetSpecialEffectPitch(missile.model, PitchBetweenVecsRad(missile.visualPos, nextVisualPos))
    call BlzSetSpecialEffectPosition(missile.model, nextVisualPos.x, nextVisualPos.y, nextVisualPos.z)

    set missile.rangeRemaining = rangeRemaining
    set missile.visualPos = missile.visualPos.copy(nextVisualPos)

    call currentPos.destroy()
    call targetPos.destroy()
    call delta.destroy()
    call deltaNorm.destroy()
    call nextVisualPos.destroy()

    return hit
endfunction

struct TargetMissile extends IMissile
    unit target = null
    real targetZOffset = 0.0
    TargetMissileOnHitCallback onHit = 0

    method onDestroy takes nothing returns nothing
        call OnDestroyMissile(this)
    endmethod
endstruct

function CreateTargetMissileYawPitch takes string modelName, unit owner, real originX, real originY, real zOffset, real yawInRadians, real pitchInRadians returns TargetMissile
    local TargetMissile targetMissile = TargetMissile.create()
    call InitMissile(targetMissile, modelName, owner, originX, originY, GetUnitFlyHeight(owner) + zOffset, yawInRadians, pitchInRadians)
    return targetMissile
endfunction

function CreateTargetMissile takes string modelName, unit owner, real originX, real originY, real zOffset returns TargetMissile
    return CreateTargetMissileYawPitch(modelName, owner, originX, originY, zOffset, 0.0, 0.0)
endfunction

function FireTargetMissile takes TargetMissile missile, unit targetUnit, real speed, real arc, real zOffset, boolean enableHoming, TargetMissileOnHitCallback onHit returns nothing
    local vec3 source = GetLocVec(missile.actualPos).addZ(missile.zOffset)
    local vec3 target = GetUnitVec(targetUnit).addZ(zOffset)
    local real distance = DistanceBetweenPointsXY(source.x, source.y, target.x, target.y)
    local MissileUpdateCallback updateCallback = BaseMissileUpdate
    set missile.target = targetUnit
    set missile.arc = arc
    set missile.onHit = onHit
    set missile.targetZOffset = zOffset
    if (enableHoming) then
        set updateCallback = TargetMissileWithHomingUpdate
    endif

    call FireMissile(missile, speed, distance, YawBetweenVecsRad(source, target), -PitchBetweenVecsRad(source, target), updateCallback, TargetMissileDestroyed)
    
    call source.destroy()
    call target.destroy()
endfunction

function FireUnitAbilityTargetMissile takes unit whichUnit, unit target, integer abilityId, real projectileLaunchZOffset, real projectileHitZOffset, boolean enableHoming, TargetMissileOnHitCallback onHit returns TargetMissile
    local string missileArt = GetUnitAbilityStringLevelField(whichUnit, abilityId, ABILITY_SLF_MISSILE_ART)
    local real missileSpeed = GetUnitAbilityIntegerField(whichUnit, abilityId, ABILITY_IF_MISSILE_SPEED)
    local real missileArc = GetUnitAbilityRealField(whichUnit, abilityId, ABILITY_RF_ARF_MISSILE_ARC)
    local TargetMissile missile = CreateTargetMissile(missileArt, whichUnit, GetUnitX(whichUnit), GetUnitY(whichUnit), projectileLaunchZOffset)
    call FireTargetMissile(missile, target, missileSpeed, missileArc, projectileHitZOffset, enableHoming, onHit)
    return missile
endfunction

globals
    key KEY_ITEMUNITS
endglobals

function interface OnCollectCallback takes unit itemUnit, unit collector returns nothing
function interface CollectionFilter takes unit itemUnit, unit filterUnit returns boolean

struct ItemUnitParams
    group OrderedUnits = CreateGroup()
    real CollectionRadius = 100.0
    CollectionFilter CollectionFilter = 0
    OnCollectCallback OnCollect = 0

    method onDestroy takes nothing returns nothing
        call DestroyGroup(OrderedUnits)
    endmethod
endstruct

scope ItemUnit

    public function AddItemUnit takes unit whichUnit, CollectionFilter filter, OnCollectCallback callback returns nothing
        local ItemUnitParams params = ItemUnitParams.create()
        set params.CollectionFilter = filter
        set params.OnCollect = callback

        call SaveInteger(G_ITEMUNIT_LOOKUP, GetHandleId(whichUnit), KEY_ITEMUNITS, params)
        call GroupAddUnit(udg_UnitGroup_ItemUnits, whichUnit)
        call EnableTrigger(gg_trg_ItemUnit_Loop)
        call EnableTrigger(gg_trg_ItemUnit_Collect_Order)
        call EnableTrigger(gg_trg_ItemUnit_Other_Order)
    endfunction

endscope

function Trig_ItemUnit_Collect_Order_Conditions takes nothing returns boolean
    if (not IsOrder(GetIssuedOrderId(), "smart")) then
        return false
    elseif (GetOrderTargetUnit() == null) then
        return false
    elseif (not IsUnitInGroup(GetOrderTargetUnit(), udg_UnitGroup_ItemUnits)) then
        return false
    endif
    return true
endfunction

function Trig_ItemUnit_Collect_Order_Actions takes nothing returns nothing
    local unit itemUnit = GetOrderTargetUnit()
    local ItemUnitParams param = LoadInteger(G_ITEMUNIT_LOOKUP, GetHandleId(itemUnit), KEY_ITEMUNITS)
    
    if (param.CollectionFilter != 0 and param.CollectionFilter.evaluate(itemUnit, GetOrderedUnit())) then
        call SaveUnitHandle(udg_HashTable_UnitInfo, GetHandleId(GetOrderedUnit()), KEY_ITEMUNITS, itemUnit)
        call GroupAddUnit(param.OrderedUnits, GetOrderedUnit())
    endif
endfunction

//===========================================================================
function InitTrig_ItemUnit_Collect_Order takes nothing returns nothing
    set gg_trg_ItemUnit_Collect_Order = CreateTrigger(  )
    call DisableTrigger( gg_trg_ItemUnit_Collect_Order )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_ItemUnit_Collect_Order, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER )
    call TriggerAddCondition( gg_trg_ItemUnit_Collect_Order, Condition( function Trig_ItemUnit_Collect_Order_Conditions ) )
    call TriggerAddAction( gg_trg_ItemUnit_Collect_Order, function Trig_ItemUnit_Collect_Order_Actions )
endfunction

function Trig_ItemUnit_Other_Order_Conditions takes nothing returns boolean
    if (not IsOrder(GetIssuedOrderId(), "smart")) then
        return false
    elseif (GetOrderTargetUnit() != null and IsUnitInGroup(GetOrderTargetUnit(), udg_UnitGroup_ItemUnits)) then
        return false
    endif
    return true
endfunction

function Trig_ItemUnit_Other_Order_Actions takes nothing returns nothing
    local unit itemUnit = LoadUnitHandle(udg_HashTable_UnitInfo, GetHandleId(GetOrderedUnit()), KEY_ITEMUNITS)
    local ItemUnitParams param = LoadInteger(G_ITEMUNIT_LOOKUP, GetHandleId(itemUnit), KEY_ITEMUNITS)

    if (itemUnit != null) then
        call RemoveSavedHandle(udg_HashTable_UnitInfo, GetHandleId(GetOrderedUnit()), KEY_ITEMUNITS)
        call GroupRemoveUnit(param.OrderedUnits, GetOrderedUnit())
    endif
endfunction

//===========================================================================
function InitTrig_ItemUnit_Other_Order takes nothing returns nothing
    set gg_trg_ItemUnit_Other_Order = CreateTrigger(  )
    call DisableTrigger( gg_trg_ItemUnit_Other_Order )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_ItemUnit_Other_Order, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_ItemUnit_Other_Order, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_ItemUnit_Other_Order, EVENT_PLAYER_UNIT_ISSUED_ORDER )
    call TriggerAddCondition( gg_trg_ItemUnit_Other_Order, Condition( function Trig_ItemUnit_Other_Order_Conditions ) )
    call TriggerAddAction( gg_trg_ItemUnit_Other_Order, function Trig_ItemUnit_Other_Order_Actions )
endfunction

globals
    constant real ITEM_UNIT_LOOP_INTERVAL = 0.25
    constant hashtable G_ITEMUNIT_LOOKUP = InitHashtable()
endglobals

function Trig_ItemUnit_ClearOrderedUnit takes nothing returns nothing
    call RemoveSavedHandle(udg_HashTable_UnitInfo, GetHandleId(GetEnumUnit()), KEY_ITEMUNITS)
endfunction

function Trig_ItemUnit_Loop takes nothing returns nothing
    local unit itemUnit = GetEnumUnit()
    local ItemUnitParams params = LoadInteger(G_ITEMUNIT_LOOKUP, GetHandleId(itemUnit), KEY_ITEMUNITS)
    local integer size = BlzGroupGetSize(params.OrderedUnits)
    local integer index = 0
    local real dist = 0.0
    local real minDist = BIG_REAL
    local unit pickedUnit = null
    local unit closestUnit = null

    if (UnitAlive(itemUnit)) then
        if (not IsUnitHidden(itemUnit)) then
            loop
                exitwhen index >= size
                set pickedUnit = BlzGroupUnitAt(params.OrderedUnits, index)
                set dist = DistanceBetweenUnits(pickedUnit, itemUnit) - BlzGetUnitCollisionSize(pickedUnit) - BlzGetUnitCollisionSize(itemUnit)
                if (dist <= params.CollectionRadius and dist < minDist) then
                    set minDist = dist
                    set closestUnit = pickedUnit
                endif
                set index = index + 1
            endloop

            if (closestUnit != null and params.OnCollect != 0) then
                call params.OnCollect.execute(itemUnit, closestUnit)
            endif
        endif
    else
        call ForGroupBJ(params.OrderedUnits, function Trig_ItemUnit_ClearOrderedUnit)
        call params.destroy()
        call GroupRemoveUnit(udg_UnitGroup_ItemUnits, itemUnit)
        call RemoveSavedInteger(G_ITEMUNIT_LOOKUP, GetHandleId(itemUnit), KEY_ITEMUNITS)
    endif
endfunction

function Trig_ItemUnit_Loop_Actions takes nothing returns nothing
    local integer size = BlzGroupGetSize(udg_UnitGroup_ItemUnits)

    if (size > 0) then
        call ForGroupBJ(udg_UnitGroup_ItemUnits, function Trig_ItemUnit_Loop)
    else
        call DisableTrigger(GetTriggeringTrigger())
        call DisableTrigger(gg_trg_ItemUnit_Collect_Order)
        call DisableTrigger(gg_trg_ItemUnit_Other_Order)
    endif
endfunction

//===========================================================================
function InitTrig_ItemUnit_Loop takes nothing returns nothing
    set gg_trg_ItemUnit_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_ItemUnit_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_ItemUnit_Loop, ITEM_UNIT_LOOP_INTERVAL )
    call TriggerAddAction( gg_trg_ItemUnit_Loop, function Trig_ItemUnit_Loop_Actions )
endfunction

globals
    constant key KEY_BUFF_EFFECTS
endglobals

struct BuffEffect
    integer BuffType = 0
    string EffectModel = null
    effect Effect = null
    UnitFunc onBuffRemoved = 0

    method onDestroy takes nothing returns nothing
        call DestroyEffect(Effect)
    endmethod
endstruct

function AddBuffEffectWithCallback takes unit whichUnit, integer whichBuff, string attachmentPoint, string modelName, UnitFunc onBuffRemoved returns effect
    local LinkedList_Int buffEffects = LoadInteger(udg_HashTable_SpecialEffects, GetHandleId(whichUnit), KEY_BUFF_EFFECTS)
    local LinkedListNode_Int node = 0
    local BuffEffect buffEffect = 0

    if (buffEffects == 0) then
        set buffEffects = CreateLinkedList_Int()
        call SaveInteger(udg_HashTable_SpecialEffects, GetHandleId(whichUnit), KEY_BUFF_EFFECTS, buffEffects)
    endif

    set node = LinkedListGetFirst(buffEffects)
    loop
        exitwhen node == 0
        set buffEffect = node.value
        if (buffEffect.BuffType == whichBuff and buffEffect.EffectModel == modelName) then
            return buffEffect.Effect
        endif
        set node = node.next
    endloop

    set buffEffect = BuffEffect.create()
    set buffEffect.BuffType = whichBuff
    set buffEffect.EffectModel = modelName
    set buffEffect.Effect = AddSpecialEffectTargetUnitBJ(attachmentPoint, whichUnit, modelName)
    set buffEffect.onBuffRemoved = onBuffRemoved
    
    call LinkedListAddLastInt(buffEffects, buffEffect)
    call GroupAddUnit(udg_UnitGroup_BuffEffects, whichUnit)
    call EnableTrigger(gg_trg_Triggered_Buff_Effects)

    return buffEffect.Effect
endfunction

function AddBuffEffect takes unit whichUnit, integer whichBuff, string attachmentPoint, string modelName returns effect
    return AddBuffEffectWithCallback(whichUnit, whichBuff, attachmentPoint, modelName, 0)
endfunction

globals
    constant real TRIGGERED_BUFF_EFFECT_INTERVAL = 0.25
endglobals

function Trig_Triggered_Buff_Effects_Loop takes nothing returns nothing
    local LinkedList_Int buffEffects = LoadInteger(udg_HashTable_SpecialEffects, GetHandleId(GetEnumUnit()), KEY_BUFF_EFFECTS)
    local LinkedListNode_Int node = LinkedListGetFirst(buffEffects)
    local LinkedListNode_Int nextNode = 0
    local BuffEffect buffEffect = 0

    if (buffEffects.count > 0) then
        loop
            exitwhen node == 0
            set buffEffect = node.value
            if (not UnitHasBuffBJ(GetEnumUnit(), buffEffect.BuffType)) then
                if (buffEffect.onBuffRemoved != 0) then
                    call buffEffect.onBuffRemoved.evaluate(GetEnumUnit())
                endif
                call buffEffect.destroy()
                set nextNode = node.next
                call LinkedListRemove(buffEffects, node)
                call node.destroy()
                set node = nextNode
            else
                set node = node.next
            endif        
        endloop
    else
        call DestroyLinkedList(buffEffects)
        call RemoveSavedInteger(udg_HashTable_SpecialEffects, GetHandleId(GetEnumUnit()), KEY_BUFF_EFFECTS)
        call GroupRemoveUnit(udg_UnitGroup_BuffEffects, GetEnumUnit())
    endif
endfunction

function Trig_Triggered_Buff_Effects_Actions takes nothing returns nothing
    local integer count = BlzGroupGetSize(udg_UnitGroup_BuffEffects)
    if (count > 0) then
        call ForGroupBJ(udg_UnitGroup_BuffEffects, function Trig_Triggered_Buff_Effects_Loop)
    else
        call DisableTrigger(GetTriggeringTrigger())
    endif
endfunction

//===========================================================================
function InitTrig_Triggered_Buff_Effects takes nothing returns nothing
    set gg_trg_Triggered_Buff_Effects = CreateTrigger()
    call DisableTrigger(gg_trg_Triggered_Buff_Effects)
    call TriggerRegisterTimerEventPeriodic(gg_trg_Triggered_Buff_Effects, TRIGGERED_BUFF_EFFECT_INTERVAL)
    call TriggerAddAction(gg_trg_Triggered_Buff_Effects, function Trig_Triggered_Buff_Effects_Actions)
endfunction

scope Buffs

    globals
        private constant hashtable HT = InitHashtable()
        private constant real DEFAULT_UPDATE_INTERVAL = 0.25
    endglobals

    function interface BuffCallback takes IBuff b returns nothing

    struct IBuff
        unit host = null
        integer buffId = 0
        integer abilityId = 0
        BuffCallback onUpdate = 0
        BuffCallback onRemoved = 0
        IntTimer updateTimer = 0
    endstruct

    private struct SimpleBuff extends IBuff
    endstruct

    function CreateSimpleBuff takes unit host returns IBuff
        local SimpleBuff b = SimpleBuff.create()
        set b.host = host
        return b
    endfunction

    function DestroyBuff takes IBuff b returns nothing
        if (b != 0) then
            call UnitRemoveAbility(b.host, b.abilityId)
            call UnitRemoveAbility(b.host, b.buffId)
            call b.updateTimer.destroy()
            if (b.onRemoved != 0) then
                call b.onRemoved.evaluate(b)
            endif
            call RemoveSavedInteger(HT, GetHandleId(b.host), b.buffId)
            call b.destroy()
        endif
    endfunction

    private function OnBuffUpdate takes IntTimer it returns nothing
        local IBuff b = it.owner
        if (UnitHasAbility(b.host, b.buffId)) then
            if (b.onUpdate != 0) then
                call b.onUpdate.evaluate(b)
            endif
        else
            call DestroyBuff(b)
        endif
    endfunction

    function GetBuff takes unit host, integer buffId returns IBuff
        return LoadInteger(HT, GetHandleId(host), buffId)
    endfunction

    function HasBuff takes unit host, integer buffId returns boolean
        return UnitHasAbility(host, buffId)
    endfunction

    function TrackBuff takes IBuff b, integer buffId, real updateInterval, BuffCallback onRemoved, BuffCallback onUpdate returns nothing
        local IBuff existing = GetBuff(b.host, buffId)
        if (existing != 0) then
            call DestroyBuff(existing)
        endif
        if (updateInterval <= 0.0) then
            set updateInterval = DEFAULT_UPDATE_INTERVAL
        endif
        set b.buffId = buffId
        set b.onUpdate = onUpdate
        set b.onRemoved = onRemoved
        set b.updateTimer = CreateIntTimer(b, false)
        call StartTimerPlusPeriodic(b.updateTimer, 0.0, updateInterval, OnBuffUpdate, 0)
        call SaveInteger(HT, GetHandleId(b.host), buffId, b)
    endfunction

    function DummyCastBuff takes IBuff b, player p, integer buffId, integer abilityId, string order returns unit
        local unit dummy = null
        call TrackBuff(b, buffId, DEFAULT_UPDATE_INTERVAL, b.onRemoved, b.onUpdate)
        set dummy = DummyCastUnit(p, b.host, GetUnitX(b.host), GetUnitY(b.host), abilityId, order)
        return dummy
    endfunction

    function DummyCastBuffAll takes IBuff b, player p, integer buffId, real updateInterval, integer abilityId, string order returns unit
        local unit dummy = null
        call TrackBuff(b, buffId, updateInterval, b.onRemoved, b.onUpdate)
        set dummy = DummyCastUnit(p, b.host, GetUnitX(b.host), GetUnitY(b.host), abilityId, order)
        return dummy
    endfunction

endscope

globals
    key KEY_TRIGGERED_AURA
endglobals

function interface EmitterUpdate takes group unitsInsideAura returns nothing
function interface EmitterCondition takes unit emitter returns boolean

struct TriggeredAuraParams
    integer AuraKey = 0
    real UpdateInterval = 1.0
    real AreaOfEffect = 0.0
    group AuraEmitters = null
    ConditionFunc TargetFilter = 0
    UnitFunc ApplyAuraEffect = 0
    UnitFunc RemoveAuraEffect = 0
    EmitterUpdate OnEmitterUpdate = 0
    EmitterCondition IsEmitterValid = 0

    method ToString takes nothing returns string
        return "AuraKey: " + I2S(AuraKey) + ", UpdateInterval: " + R2S(UpdateInterval) + ", AreaOfEffect: " + R2S(AreaOfEffect) + ", AuraEmitters: " + I2S(GetHandleId(AuraEmitters))
    endmethod
endstruct

scope TriggeredAura
    globals
        private unit CurrentEmitter = null
        private TriggeredAuraParams CurrentParams = 0
        private hashtable lookup = InitHashtable()
    endglobals

    public function GetEmitter takes nothing returns unit
        return CurrentEmitter
    endfunction

    function IsEmitterValid takes unit emitter returns boolean
        if (CurrentParams.IsEmitterValid != 0) then
            return CurrentParams.IsEmitterValid.evaluate(emitter)
        else
            return UnitAlive(emitter)
        endif
    endfunction

    function TargetFilter takes nothing returns boolean
        if (CurrentParams.TargetFilter != 0) then
            return CurrentParams.TargetFilter.evaluate()
        endif
        return false
    endfunction

    function ApplyEffect takes nothing returns nothing
        if (CurrentParams.ApplyAuraEffect != 0) then
            call CurrentParams.ApplyAuraEffect.execute(GetEnumUnit())
        endif
    endfunction

    function RemoveEffect takes nothing returns nothing
        if (CurrentParams.RemoveAuraEffect != 0) then
            call CurrentParams.RemoveAuraEffect.execute(GetEnumUnit())
        endif
    endfunction

    public function Loop takes nothing returns nothing
        local TriggeredAuraParams params = LoadInteger(lookup, KEY_TRIGGERED_AURA, GetHandleId(GetTriggeringTrigger()))
        local group unitsOutsideAura = CreateGroup()
        local group unitsInsideAura = CreateGroup()
        local group auraEmitters = params.AuraEmitters
        local group lastAOE = null
        local group currentAOE = null
        local integer emitterCount = BlzGroupGetSize(auraEmitters)
        local integer emitterIndex = emitterCount - 1
        local integer unitCount = 0
        local integer unitIndex = 0
        local unit pickedUnit = null
        local location emitterPos = null
        local location unitPos = null

        set CurrentParams = params

        // Loop through all auraEmitters on the map
        loop
            exitwhen emitterIndex < 0
            set CurrentEmitter = BlzGroupUnitAt(auraEmitters, emitterIndex)
            set lastAOE = LoadGroupHandle(lookup, GetHandleId(CurrentEmitter), params.AuraKey)

            if (IsEmitterValid(CurrentEmitter)) then
                // Emitter is alive
                set emitterPos = GetUnitLoc(CurrentEmitter)
                set currentAOE = GetUnitsInRangeOfLocMatching(params.AreaOfEffect, emitterPos, Condition(function TargetFilter))
                call GroupAddGroup(currentAOE, lastAOE)
                set unitCount = BlzGroupGetSize(lastAOE)
                set unitIndex = unitCount - 1
                loop
                    exitwhen unitIndex < 0
                    set pickedUnit = BlzGroupUnitAt(lastAOE, unitIndex)
                    set unitPos = GetUnitLoc(pickedUnit)
                    if (not UnitAlive(pickedUnit) or DistanceBetweenPoints(emitterPos, unitPos) > params.AreaOfEffect) then
                        call GroupAddUnit(unitsOutsideAura, pickedUnit)
                        call GroupRemoveUnit(lastAOE, pickedUnit)
                    else
                        call GroupAddUnit(unitsInsideAura, pickedUnit)
                    endif
                    call RemoveLocation(unitPos)
                    set unitIndex = unitIndex - 1
                endloop

                call RemoveLocation(emitterPos)
                call DestroyGroup(currentAOE)

                if (params.OnEmitterUpdate != 0) then
                    call params.OnEmitterUpdate.execute(lastAOE)
                endif
            else
                // Emitter is not alive
                call ForGroupBJ(lastAOE, function RemoveEffect)
                call GroupRemoveUnit(auraEmitters, CurrentEmitter)
                call DestroyGroup(lastAOE)
            endif

            set emitterIndex = emitterIndex - 1
        endloop

        if (BlzGroupGetSize(auraEmitters) > 0) then
            call ForGroupBJ(unitsInsideAura, function ApplyEffect)
            call BlzGroupRemoveGroupFast(unitsInsideAura, unitsOutsideAura)
            call ForGroupBJ(unitsOutsideAura, function RemoveEffect)
        else
            call DisableTrigger(GetTriggeringTrigger())
        endif
        
        call DestroyGroup(unitsInsideAura)
        call DestroyGroup(unitsOutsideAura)
    endfunction

    public function Create takes TriggeredAuraParams params returns trigger
        local trigger auraTrigger = CreateTrigger()

        if (params.AuraEmitters == null) then
            set params.AuraEmitters = CreateGroup()
        endif

        call DisableTrigger(auraTrigger)
        call TriggerRegisterTimerEventPeriodic( auraTrigger, params.UpdateInterval)
        call TriggerAddAction(auraTrigger, function TriggeredAura_Loop)
        call SaveInteger(lookup, KEY_TRIGGERED_AURA, GetHandleId(auraTrigger), params)
        return auraTrigger
    endfunction
    
    public function AddEmitter takes unit whichUnit, trigger auraLoop returns nothing
        local location emitterPos = GetUnitLoc(whichUnit)
        set CurrentParams = LoadInteger(lookup, KEY_TRIGGERED_AURA, GetHandleId(auraLoop))
        set CurrentEmitter = whichUnit
        call SaveGroupHandle(lookup, GetHandleId(whichUnit), CurrentParams.AuraKey, GetUnitsInRangeOfLocMatching(CurrentParams.AreaOfEffect, emitterPos, Condition(function TargetFilter)))
        call GroupAddUnit(CurrentParams.AuraEmitters, whichUnit)
        call EnableTrigger(auraLoop)
        call RemoveLocation(emitterPos)
    endfunction

    public function RemoveEmitter takes unit whichUnit, trigger auraLoop returns nothing
        local group lastEmitterAOE = null
        set CurrentEmitter = whichUnit
        set CurrentParams = LoadInteger(lookup, KEY_TRIGGERED_AURA, GetHandleId(auraLoop))
        set lastEmitterAOE = LoadGroupHandle(lookup, GetHandleId(whichUnit), CurrentParams.AuraKey)

        call ForGroupBJ(lastEmitterAOE, function RemoveEffect)
        call GroupRemoveUnit(CurrentParams.AuraEmitters, whichUnit)
        call DestroyGroup(lastEmitterAOE)
        call RemoveSavedHandle(lookup, GetHandleId(whichUnit), CurrentParams.AuraKey)
    endfunction

endscope

globals
    constant key KEY_CONSTRUCTION_DUMMIES
    constant key KEY_CONSTRUCTION_DUMMIES_ALPHA_CHANGED
endglobals

function AddConstructionDummyNoTransparency takes unit target, integer dummyUnitTypeId, real timeScale returns unit
    local player p = GetOwningPlayer(target)
    local unit dummy = CreateUnit(p, dummyUnitTypeId, GetUnitX(target), GetUnitY(target), GetUnitFacing(target))
    local group constructionEffects = LoadGroupHandle(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES, GetHandleId(target))
    if (constructionEffects == null) then
        set constructionEffects = CreateGroup()
    endif

    call SetUnitAnimation(dummy, "birth")
    call SetUnitTimeScale(dummy, timeScale)
    call LifelinkUnits(target, dummy, LIFELINK_KILL)
    call GroupAddUnit(constructionEffects, dummy)
    call SaveGroupHandle(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES, GetHandleId(target), constructionEffects)

    return dummy
endfunction

function AddConstructionDummy takes unit target, integer dummyUnitTypeId, real timeScaleBuffer returns unit
    local unit dummy = AddConstructionDummyNoTransparency(target, dummyUnitTypeId, timeScaleBuffer)

    call ChangeUnitAlpha(target, 0)
    call SaveBoolean(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES_ALPHA_CHANGED, GetHandleId(target), true)

    return dummy
endfunction

function RemoveConstructionDummies takes unit target returns nothing
    local player p = GetOwningPlayer(target)
    local group constructionEffects = LoadGroupHandle(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES, GetHandleId(target))
    local unit pickedUnit = null
    if (constructionEffects != null) then
        loop
            set pickedUnit = FirstOfGroup(constructionEffects)
            exitwhen pickedUnit == null
            call GroupRemoveUnit(constructionEffects, pickedUnit)
            call RemoveUnit(pickedUnit)
        endloop
        call RemoveSavedHandle(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES, GetHandleId(target))
        call DestroyGroup(constructionEffects)
    endif

    if (HaveSavedBoolean(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES_ALPHA_CHANGED, GetHandleId(target))) then
        call RestoreUnitColor(target)
        call RemoveSavedBoolean(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES_ALPHA_CHANGED, GetHandleId(target))
    endif
endfunction

function Trig_Construction_Complete_Conditions takes nothing returns boolean
    return HaveSavedHandle(udg_HashTable_ConstructionEffects, KEY_CONSTRUCTION_DUMMIES, GetHandleId(GetConstructedStructure()))
endfunction

function Trig_Construction_Complete_Actions takes nothing returns nothing
    call RemoveConstructionDummies(GetConstructedStructure())
endfunction

//===========================================================================
function InitTrig_Construction_Complete takes nothing returns nothing
    set gg_trg_Construction_Complete = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Construction_Complete, EVENT_PLAYER_UNIT_CONSTRUCT_FINISH )
    call TriggerAddCondition( gg_trg_Construction_Complete, Condition( function Trig_Construction_Complete_Conditions ) )
    call TriggerAddAction( gg_trg_Construction_Complete, function Trig_Construction_Complete_Actions )
endfunction

globals
    constant key KEY_SWARM_UNIT
    constant key KEY_SWARM_TARGET
    constant integer SWARM_UNIT_STATE_NONE = 0
    constant integer SWARM_UNIT_STATE_ATTACK = 1
    constant integer SWARM_UNIT_STATE_RETURN = 2
endglobals

function interface SwarmTargetFilter takes Swarm swarm, unit filterUnit returns boolean

//===========================================================================
struct SwarmMember
    unit swarmUnit = null
    unit targetUnit = null
    location targetLoc = null
    integer state = SWARM_UNIT_STATE_NONE

    method SetStateAttack takes unit target returns nothing
        call ClearTargets()
        set targetUnit = target
        set state = SWARM_UNIT_STATE_ATTACK
    endmethod

    method SetStateReturn takes location target returns nothing
        call ClearTargets()
        set targetLoc = target
        set state = SWARM_UNIT_STATE_RETURN
    endmethod

    private method ClearTargets takes nothing returns nothing
        if (targetUnit != null) then
            call HashTableAddInteger(udg_HashTable_UnitInfo, GetHandleId(targetUnit), KEY_SWARM_TARGET, -1, true)
        endif
        set targetUnit = null
        call RemoveLocation(targetLoc)
    endmethod

    method onDestroy takes nothing returns nothing
        call ClearTargets()
        call RemoveSavedInteger(udg_HashTable_UnitInfo, GetHandleId(swarmUnit), KEY_SWARM_UNIT)
        call KillUnit(swarmUnit)
    endmethod
endstruct

//===========================================================================
struct Swarm
    unit host = null
    LinkedList_Int members = 0
    integer maxAttackersPerTarget = 0
    real aoe = 0.0
    SwarmTargetFilter targetFilter

    method AddMember takes unit newMember returns nothing
        call EnsureList()
        call CreateMember(newMember)
    endmethod

    method AddMembers takes group newMembers returns nothing
        local integer size = BlzGroupGetSize(newMembers)
        local integer i = 0
        local unit pickedUnit = null

        call EnsureList()

        loop
            exitwhen i >= size
            set pickedUnit = BlzGroupUnitAt(newMembers, i)
            call CreateMember(pickedUnit)
            set i = i + 1
        endloop

    endmethod

    method RemoveMember takes SwarmMember member returns nothing
        local integer i = 0
        local SwarmMember sm = 0
        local LinkedListNode_Int node = LinkedListGetFirst(members)

        call EnsureList()

        loop
            exitwhen node == 0
            set sm = node.value
            if (sm == member) then
                if (LinkedListRemove(members, node)) then
                    call node.destroy()
                endif
                exitwhen true
            endif
            set node = node.next
        endloop
    endmethod

    private method EnsureList takes nothing returns nothing
        if (members == 0) then
            set members = CreateLinkedList_Int()
        endif
    endmethod

    private method CreateMember takes unit whichUnit returns SwarmMember
        local SwarmMember member = SwarmMember.create()
        set member.swarmUnit = whichUnit
        call LinkedListAddLastInt(members, member)
        call SaveInteger(udg_HashTable_UnitInfo, GetHandleId(whichUnit), KEY_SWARM_UNIT, member)
        return member
    endmethod

    method onDestroy takes nothing returns nothing
        local integer i = 0
        local LinkedListNode_Int node = 0
        local SwarmMember member = 0
        
        // Remove this swarm from the global array
        loop
            exitwhen i >= SwarmsCount
            if (udg_IntArr_Swarms[i] == this) then
                loop
                    exitwhen i >= SwarmsCount - 1
                    set udg_IntArr_Swarms[i] = udg_IntArr_Swarms[i + 1]
		    set i = i + 1
                endloop
                set SwarmsCount = SwarmsCount - 1
                exitwhen true
            endif
            set i = i + 1
        endloop
        
        // Destroy all of the swarm's members
        loop
            exitwhen members.count == 0
            set node = LinkedListRemoveLast(members)
            set member = node.value
            call member.destroy()
            call node.destroy()
        endloop

        call DestroyLinkedList(members)
        call KillUnit(host)
    endmethod
endstruct

globals
    constant real SWARM_AOE_BUFFER = 150.0
    integer SwarmsCount = 0
    Swarm bj_currentSwarm = 0
    group bj_swarmTargets = null
endglobals

//===========================================================================
function SetSwarmingEnabled takes boolean enable returns nothing
    if (enable) then
        call EnableTrigger(gg_trg_Swarm_Loop)
        call EnableTrigger(gg_trg_Swarm_Orders)
    else
        call DisableTrigger(gg_trg_Swarm_Loop)
        call DisableTrigger(gg_trg_Swarm_Orders)
    endif
endfunction

//===========================================================================
function CreateSwarm takes unit host, real aoe, SwarmTargetFilter targetFilter returns Swarm
    local Swarm swarm = Swarm.create()

    set swarm.host = host
    set swarm.aoe = aoe
    set swarm.targetFilter = targetFilter

    set udg_IntArr_Swarms[SwarmsCount] = swarm
    set SwarmsCount = SwarmsCount + 1
    call SetSwarmingEnabled(true)

    return swarm
endfunction

//===========================================================================
function GetEnumSwarm takes nothing returns Swarm
    return bj_currentSwarm
endfunction

function FindSwarmTargetFilter takes nothing returns boolean
    local Swarm swarm = bj_currentSwarm
    local unit filter = GetFilterUnit()
    if (swarm.maxAttackersPerTarget > 0 and LoadInteger(udg_HashTable_UnitInfo, GetHandleId(filter), KEY_SWARM_TARGET) >= swarm.maxAttackersPerTarget) then
        return false
    elseif (swarm.targetFilter != 0) then
        return swarm.targetFilter.evaluate(swarm, filter)
    endif
    return true
endfunction

//===========================================================================
function FindSwarmTarget takes Swarm swarm returns unit
    if (bj_swarmTargets == null) then
        set bj_swarmTargets = CreateGroup()
        call GroupEnumUnitsInRange(bj_swarmTargets, GetUnitX(swarm.host), GetUnitY(swarm.host), swarm.aoe + SWARM_AOE_BUFFER, Condition(function FindSwarmTargetFilter))
    endif
    return GroupPickRandomUnit(bj_swarmTargets)
endfunction

//===========================================================================
function UpdateSwarmMember takes Swarm swarm, SwarmMember member returns nothing
    local unit target = null
    local location loc = null
    local integer lastState = member.state

    if (GetUnitCurrentOrder(member.swarmUnit) == 0) then
        set target = FindSwarmTarget(swarm)
        if (lastState != SWARM_UNIT_STATE_ATTACK and target != null) then
            call member.SetStateAttack(target)
            call IssueTargetOrder(member.swarmUnit, "attackonce", target)
            call HashTableAddInteger(udg_HashTable_UnitInfo, GetHandleId(target), KEY_SWARM_TARGET, 1, true)
        else
            set loc = RandomPointInCircle(GetUnitX(swarm.host), GetUnitY(swarm.host), swarm.aoe)
            call member.SetStateReturn(loc)
            call IssuePointOrderLoc(member.swarmUnit, "move", loc)
        endif
    endif
endfunction

//===========================================================================
function UpdateSwarm takes Swarm swarm returns nothing
    local SwarmMember swarmMember = 0
    local LinkedListNode_Int node = LinkedListGetFirst(swarm.members)
    local LinkedListNode_Int nodeTemp = 0

    set bj_currentSwarm = swarm

    loop
        exitwhen node == 0
        set swarmMember = node.value
        if (UnitAlive(swarmMember.swarmUnit)) then
            call UpdateSwarmMember(swarm, swarmMember)
            set node = node.next
        elseif (LinkedListRemove(swarm.members, node)) then
            call swarmMember.destroy()
            set nodeTemp = node
            set node = node.next
            call nodeTemp.destroy()
        endif
    endloop

    set bj_currentSwarm = 0

    if (swarm.members.count <= 0) then
        call swarm.destroy()
    endif

    call DestroyGroup(bj_swarmTargets)
    set bj_swarmTargets = null
endfunction

globals
    constant real SWARM_LOOP_INTERVAL = 0.1
endglobals

function Trig_Swarm_Loop_Actions takes nothing returns nothing
    local integer index = SwarmsCount - 1
    local integer shiftIndex = 0
    local Swarm swarm = 0

    loop
        exitwhen index < 0
        set swarm = udg_IntArr_Swarms[index]
        if (UnitAlive(swarm.host)) then
            call UpdateSwarm(swarm)
        else
            set shiftIndex = index
            loop
                exitwhen shiftIndex >= SwarmsCount - 1
                set udg_IntArr_Swarms[shiftIndex] = udg_IntArr_Swarms[shiftIndex + 1]
                set shiftIndex = shiftIndex + 1
            endloop
            set SwarmsCount = SwarmsCount - 1
            call swarm.destroy()
        endif
        set index = index - 1
    endloop

    if (SwarmsCount == 0) then
        call SetSwarmingEnabled(false)
    endif

endfunction

//===========================================================================
function InitTrig_Swarm_Loop takes nothing returns nothing
    set gg_trg_Swarm_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Swarm_Loop )
    call TriggerRegisterTimerEventPeriodic( gg_trg_Swarm_Loop, SWARM_LOOP_INTERVAL )
    call TriggerAddAction( gg_trg_Swarm_Loop, function Trig_Swarm_Loop_Actions )
endfunction

function Trig_Swarm_Orders_Conditions takes nothing returns boolean
    local SwarmMember member = LoadInteger(udg_HashTable_UnitInfo, GetHandleId(GetOrderedUnit()), KEY_SWARM_UNIT)
    return member != 0
endfunction

function Trig_Swarm_Orders_Actions takes nothing returns nothing
    local SwarmMember member = LoadInteger(udg_HashTable_UnitInfo, GetHandleId(GetOrderedUnit()), KEY_SWARM_UNIT)
    local integer order = GetIssuedOrderId()
    local unit targetUnit = null
    local location targetLoc = null

    if (member.state == SWARM_UNIT_STATE_ATTACK) then
        set targetUnit = GetOrderTargetUnit()
        if (order != String2OrderIdBJ("attackonce") or targetUnit != member.targetUnit) then
            call IssueTargetOrder(member.swarmUnit, "attackonce", member.targetUnit)
        endif
    else
        set targetLoc = GetOrderPointLoc()
        if (order != String2OrderIdBJ("move") or CompareLocationsBJ(targetLoc, member.targetLoc) == false) then
            call IssuePointOrderLoc(member.swarmUnit, "move", member.targetLoc)
        endif
    endif

endfunction

//===========================================================================
function InitTrig_Swarm_Orders takes nothing returns nothing
    set gg_trg_Swarm_Orders = CreateTrigger(  )
    call DisableTrigger( gg_trg_Swarm_Orders )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Swarm_Orders, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Swarm_Orders, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Swarm_Orders, EVENT_PLAYER_UNIT_ISSUED_ORDER )
    call TriggerAddCondition( gg_trg_Swarm_Orders, Condition( function Trig_Swarm_Orders_Conditions ) )
    call TriggerAddAction( gg_trg_Swarm_Orders, function Trig_Swarm_Orders_Actions )
endfunction

globals
    constant key KEY_EXILE
    constant key KEY_UNEXILE
endglobals

function ExileUnit takes unit whichUnit, boolean flag returns nothing
    if (flag) then
        call IssueImmediateOrder(whichUnit, "stop")
    endif
    call PauseUnit(whichUnit, flag)
    call ShowUnit(whichUnit, not flag)
    call SetUnitInvulnerable(whichUnit, flag)
endfunction

function ExileUnitTimerCallback takes UnitTimer ut returns nothing
    call ExileUnit(ut.owner, true)
    call RemoveSavedInteger(udg_HashTable_Timers, GetHandleId(ut.owner), KEY_EXILE)
endfunction

function UnexileUnitTimerCallback takes UnitTimer ut returns nothing
    call ExileUnit(ut.owner, false)
    call RemoveSavedInteger(udg_HashTable_Timers, GetHandleId(ut.owner), KEY_UNEXILE)
endfunction

function ExileUnitIn takes unit whichUnit, real delay returns nothing
    local UnitTimer ut = LoadInteger(udg_HashTable_Timers, GetHandleId(whichUnit), KEY_EXILE)
    if (ut == 0) then
        set ut = CreateUnitTimer(whichUnit, true)
        call SaveInteger(udg_HashTable_Timers, GetHandleId(whichUnit), KEY_EXILE, ut)
    endif
    call StartTimerPlus(ut, delay, ExileUnitTimerCallback)
endfunction

function ShowUnitIn takes unit whichUnit, real delay returns nothing
    local UnitTimer ut = LoadInteger(udg_HashTable_Timers, GetHandleId(whichUnit), KEY_UNEXILE)
    if (ut == 0) then
        set ut = CreateUnitTimer(whichUnit, true)
        call SaveInteger(udg_HashTable_Timers, GetHandleId(whichUnit), KEY_UNEXILE, ut)
    endif
    call StartTimerPlus(ut, delay, UnexileUnitTimerCallback)
endfunction

library CustomAuras requires LinkedList

    function interface CustomAuraCallback takes CustomAura aura, group unitsInAura returns nothing
    function interface CustomAuraEmitterCallback takes CustomAuraEmitter emitter, group unitsInRange returns nothing
    function interface UnitCallback takes unit whichUnit returns nothing
    function interface CustomAuraCondition takes CustomAuraEmitter emitter returns boolean

    globals
        constant hashtable HT_CUSTOM_AURAS = InitHashtable()
        constant key KEY_CUSTOM_AURA
        constant key KEY_ADDED_THIS_LOOP
        CustomAura CURRENT_AURA = 0
    endglobals

    struct CustomAura
        public real updateInterval = 0.0
        public group unitsInsideAura = null
        public timer updateTimer = null
        public UnitCallback unitEnterCallback = 0
        public UnitCallback unitLeaveCallback = 0
        public CustomAuraCondition targetFilter = 0
        public CustomAuraCondition emitterValidFilter = 0
        public CustomAuraCallback updateCallback = 0
        public LinkedList_Int emitters = 0

        static method create takes nothing returns CustomAura
            local CustomAura ca = CustomAura.allocate()
            set ca.unitsInsideAura = CreateGroup()
            set ca.updateTimer = CreateTimer()
            call SaveInteger(HT_CUSTOM_AURAS, GetHandleId(ca.updateTimer), KEY_CUSTOM_AURA, ca)
            return ca
        endmethod

        method onDestroy takes nothing returns nothing
            call DestroyGroup(unitsInsideAura)
            call emitters.destroy()
            call RemoveSavedInteger(HT_CUSTOM_AURAS, GetHandleId(updateTimer), KEY_CUSTOM_AURA)
            call DestroyTimer(updateTimer)
        endmethod
    endstruct

    public function CreateCustomAura takes real updateInterval, UnitCallback unitEnters, UnitCallback unitLeaves, CustomAuraCondition targetFilter, CustomAuraCondition emitterValidFilter, CustomAuraCallback updateCallback returns CustomAura
        local CustomAura aura = CustomAura.create()
        set aura.updateInterval = updateInterval
        set aura.unitEnterCallback = unitEnters
        set aura.unitLeaveCallback = unitLeaves
        set aura.targetFilter = targetFilter
        set aura.emitterValidFilter = emitterValidFilter
        set aura.updateCallback = updateCallback
        set aura.emitters = CreateLinkedList_Int()
        return aura
    endfunction

    struct CustomAuraEmitter extends ILinkedListNode
        public unit emitter = null
        public real areaOfEffect = 0.0
        public CustomAuraEmitterCallback updateCallback = 0
        public integer data = 0

        static method create takes nothing returns CustomAuraEmitter
            local CustomAuraEmitter emitter = CustomAuraEmitter.allocate()
            return emitter
        endmethod

        method onDestroy takes nothing returns nothing
        endmethod
    endstruct

    private function IsEmitterValid takes CustomAuraEmitter emitter, CustomAura aura returns boolean
        if (not UnitAlive(emitter.emitter)) then
            return false
        elseif (aura.emitterValidFilter != 0 and not aura.emitterValidFilter.evaluate(emitter)) then
            return false
        endif
        return true
    endfunction

    private function SqrDistanceBetweenUnits takes unit u1, unit u2 returns real
        local real dx = GetUnitX(u2) - GetUnitX(u1)
        local real dy = GetUnitY(u2) - GetUnitY(u1)
        return dx * dx + dy * dy
    endfunction

    private function AddUnit takes nothing returns nothing
        local unit whichUnit = GetEnumUnit()
        if (not HaveSavedBoolean(HT_CUSTOM_AURAS, GetHandleId(whichUnit), CURRENT_AURA)) then
            if (CURRENT_AURA.unitEnterCallback != 0) then
                call CURRENT_AURA.unitEnterCallback.evaluate(whichUnit)
            endif
            call SaveBoolean(HT_CUSTOM_AURAS, GetHandleId(whichUnit), CURRENT_AURA, true)
        endif
    endfunction

    private function RemoveUnit takes nothing returns nothing
        local unit whichUnit = GetEnumUnit()
        if (CURRENT_AURA.unitLeaveCallback != 0) then
            call CURRENT_AURA.unitLeaveCallback.evaluate(GetEnumUnit())
        endif
        call RemoveSavedBoolean(HT_CUSTOM_AURAS, GetHandleId(whichUnit), CURRENT_AURA)
    endfunction

    private function UpdateLoop takes nothing returns nothing
        local timer expired = GetExpiredTimer()
        local CustomAura aura = LoadInteger(HT_CUSTOM_AURAS, GetHandleId(expired), KEY_CUSTOM_AURA)
        local CustomAuraEmitter emitter = LinkedListGetFirst(aura.emitters)
        local CustomAuraEmitter temp = 0
        local real sqrRadius = emitter.areaOfEffect * emitter.areaOfEffect
        local group unitsOutsideAura = CreateGroup()
        local group unitsInsideAura = CreateGroup()
        local group currentAOE = null
        local unit picked = null

        set CURRENT_AURA = aura
        call GroupAddGroup(aura.unitsInsideAura, unitsOutsideAura)

        loop
            exitwhen emitter == 0
            if (IsEmitterValid(emitter, aura)) then
                // Emitter is valid
                set currentAOE = GetUnitsInAOEOfUnitInt(emitter.emitter, emitter.areaOfEffect, aura.targetFilter, emitter)

                if (emitter.updateCallback != 0) then
                    call emitter.updateCallback.evaluate(emitter, currentAOE)
                endif

                loop
                    set picked = FirstOfGroup(currentAOE)
                    exitwhen picked == null
                    call GroupRemoveUnit(unitsOutsideAura, picked)
                    call GroupRemoveUnit(currentAOE, picked)
                    call GroupAddUnit(unitsInsideAura, picked)
                endloop

                call DestroyGroup(currentAOE)
                set emitter = emitter.next
            else
                // Emitter is invalid
                set temp = emitter.next
                call LinkedListRemove(aura.emitters, emitter)
                call emitter.destroy()
                set emitter = temp
            endif
        endloop

        call ForGroupBJ(unitsInsideAura, function AddUnit)
        call ForGroupBJ(unitsOutsideAura, function RemoveUnit)

        if (aura.updateCallback != 0) then
            call aura.updateCallback.evaluate(aura, unitsInsideAura)
        endif

        call DestroyGroup(aura.unitsInsideAura)
        set aura.unitsInsideAura = unitsInsideAura

        if (aura.emitters.count == 0) then
            call PauseTimer(aura.updateTimer)
        endif

        call DestroyGroup(unitsOutsideAura)
    endfunction

    public function AddEmitter takes unit whichUnit, CustomAura aura, real aoe returns CustomAuraEmitter
        local CustomAuraEmitter emitter = CustomAuraEmitter.create()

        set emitter.emitter = whichUnit
        set emitter.areaOfEffect = aoe

        call LinkedListAddFirst(aura.emitters, emitter)

        if (aura.emitters.count == 1) then
            call TimerStart(aura.updateTimer, aura.updateInterval, true, function UpdateLoop)
        endif

        return emitter
    endfunction

endlibrary

library Races initializer Init requires MathUtil
    globals
        private integer array PLAYER_RACES
        private Race array RACES
        private integer NUM_RACES = 0
        private integer NUM_RACES_SELECTABLE = 3

        private constant real GOLD_MINE_RANGE = 1000.0
        private constant real WORKER_RADIUS = 72.0
    endglobals

    function interface PlaceStartingUnitsAction takes player p, location loc, real workerCenterX, real workerCenterY returns nothing

    struct Race
        string name = null
        string colorString = null
        string aiScript = null
        integer spellbringerUnitTypeId = 0
        PlaceStartingUnitsAction placeStartingUnitsAction = 0
    endstruct

    private function AddRace takes string name, string colorString, integer spellbringerUnitTypeId, PlaceStartingUnitsAction startingUnits, string aiScript returns Race
        local Race r = Race.create()
        set r.name = name
        set r.colorString = colorString
        set r.aiScript = aiScript
        set r.spellbringerUnitTypeId = spellbringerUnitTypeId
        set r.placeStartingUnitsAction = startingUnits
        set RACES[NUM_RACES] = r
        set NUM_RACES = NUM_RACES + 1
        return r
    endfunction

    function PlayerSetRace takes player p, integer raceId returns nothing
        set PLAYER_RACES[GetPlayerId(p)] = raceId
    endfunction

    function PlayerGetRaceId takes player p returns integer
        return PLAYER_RACES[GetPlayerId(p)]
    endfunction

    private function PlaceStartingUnits takes player p returns nothing
        local Race r = PlayerGetRaceId(p)
        local location startLoc = GetPlayerStartLocationLoc(p)
        local unit mine = MeleeFindNearestMine(startLoc, GOLD_MINE_RANGE)
        local real workerCenterX = GetLocationX(startLoc)
        local real workerCenterY = GetLocationY(startLoc) + WORKER_RADIUS * 1.5
        if (mine != null) then
            set workerCenterX = GetLocationX(startLoc) + (GetUnitX(mine) - GetLocationX(startLoc)) * 0.5
            set workerCenterY = GetLocationY(startLoc) + (GetUnitY(mine) - GetLocationY(startLoc)) * 0.5
        endif
        call r.placeStartingUnitsAction.evaluate(p, startLoc, workerCenterX, workerCenterY)
        call RemoveLocation(startLoc)
    endfunction

    private function PlaceStartingUnits_Order takes player p, location loc, real workerCenterX, real workerCenterY returns nothing
        local unit hall = CreateUnit(p, SB_CITADEL, GetLocationX(loc), GetLocationY(loc), bj_UNIT_FACING)
        local integer numWorkers = 5
        local real angle = 0.0
        local real angleStart = 90.0
        local real angleInterval = 360.0 / numWorkers
        local real x = 0.0
        local real y = 0.0
        
        loop
            set numWorkers = numWorkers - 1
            exitwhen numWorkers < 0
            set angle = angleStart + angleInterval * numWorkers
            set x = PolarProjectionX(workerCenterX, WORKER_RADIUS, angle)
            set y = PolarProjectionY(workerCenterY, WORKER_RADIUS, angle)
            call CreateUnit(p, SB_PEASANT, x, y, bj_UNIT_FACING)
        endloop
    endfunction

    private function PlaceStartingUnits_Nature takes player p, location loc, real workerCenterX, real workerCenterY returns nothing
        local unit hall = CreateUnit(p, SB_HOLD, GetLocationX(loc), GetLocationY(loc), bj_UNIT_FACING)
        local integer numWorkers = 3
        local real angle = 0.0
        local real angleStart = AngleBetweenPointsXY(GetLocationX(loc), GetLocationY(loc), workerCenterX, workerCenterY)
        local real angleInterval = 360.0 / numWorkers
        local real x = 0.0
        local real y = 0.0
        
        loop
            set numWorkers = numWorkers - 1
            exitwhen numWorkers < 0
            set angle = angleStart + angleInterval * numWorkers
            set x = PolarProjectionX(workerCenterX, WORKER_RADIUS, angle)
            set y = PolarProjectionY(workerCenterY, WORKER_RADIUS, angle)
            if (numWorkers == 0) then
                call CreateUnit(p, SB_DENDROID_TREEHERD, x, y, bj_UNIT_FACING)
            else
                call CreateUnit(p, SB_ELVEN_ARTISAN, x, y, bj_UNIT_FACING)
            endif
        endloop
    endfunction

    private function PlaceStartingUnits_Death takes player p, location loc, real workerCenterX, real workerCenterY returns nothing
        local unit hall = CreateUnit(p, SB_NECROPOLIS, GetLocationX(loc), GetLocationY(loc), bj_UNIT_FACING)
        local integer numWorkers = 3
        local real angle = 0.0
        local real angleStart = 90.0
        local real angleInterval = 360.0 / numWorkers
        local real x = 0.0
        local real y = 0.0

        loop
            set numWorkers = numWorkers - 1
            exitwhen numWorkers < 0
            set angle = angleStart + angleInterval * numWorkers
            set x = PolarProjectionX(workerCenterX, WORKER_RADIUS, angle)
            set y = PolarProjectionY(workerCenterY, WORKER_RADIUS, angle)
            call CreateUnit(p, SB_LOST_SOUL, x, y, bj_UNIT_FACING)
        endloop
    endfunction

    private function PlaceStartingUnits_Magic takes player p, location loc, real workerCenterX, real workerCenterY returns nothing
        local unit hall = CreateUnit(p, SB_SANCTUM, GetLocationX(loc), GetLocationY(loc), bj_UNIT_FACING)
        local integer numWorkers = 5
        local real angle = 0.0
        local real angleStart = 90.0
        local real angleInterval = 360.0 / numWorkers
        local real x = 0.0
        local real y = 0.0
        
        loop
            set numWorkers = numWorkers - 1
            exitwhen numWorkers < 0
            set angle = angleStart + angleInterval * numWorkers
            set x = PolarProjectionX(workerCenterX, WORKER_RADIUS, angle)
            set y = PolarProjectionY(workerCenterY, WORKER_RADIUS, angle)
            call CreateUnit(p, SB_SHAPER, x, y, bj_UNIT_FACING)
        endloop
    endfunction

    private function PlaceStartingUnits_Chaos takes player p, location loc, real workerCenterX, real workerCenterY returns nothing
        local unit hall = CreateUnit(p, SB_FORTRESS, GetLocationX(loc), GetLocationY(loc), bj_UNIT_FACING)
        local integer numWorkers = 5
        local real angle = 0.0
        local real angleStart = 90.0
        local real angleInterval = 360.0 / numWorkers
        local real x = 0.0
        local real y = 0.0
        
        loop
            set numWorkers = numWorkers - 1
            exitwhen numWorkers < 0
            set angle = angleStart + angleInterval * numWorkers
            set x = PolarProjectionX(workerCenterX, WORKER_RADIUS, angle)
            set y = PolarProjectionY(workerCenterY, WORKER_RADIUS, angle)
            call CreateUnit(p, SB_SLAVE, x, y, bj_UNIT_FACING)
        endloop

        call CreateUnit(p, 'n00G', workerCenterX, workerCenterY, bj_UNIT_FACING)
    endfunction

    private function Init takes nothing returns nothing
        call AddRace("None", "|cffa4a4a4", 0, 0, null)
        call AddRace("Order", "|cffffe428", 'H001', PlaceStartingUnits_Order, "war3mapImported/SBOrderAI.ai")
        call AddRace("Nature", "|cff00b105", 'H016', PlaceStartingUnits_Nature, null)
        call AddRace("Death", "|cff6d0065", 'H00A', PlaceStartingUnits_Death, null)
        call AddRace("Magic", "|cff92b5ff", 'H008', PlaceStartingUnits_Magic, null)
        call AddRace("Chaos", "|cffff4600", 0, PlaceStartingUnits_Chaos, null)
    endfunction
endlibrary

library SpellbringerAlerts initializer Init requires PlayerColors
    globals
        private real MINIMAP_PING_DURATION = 2.0
        private hashtable HT_SB_ALERTS = InitHashtable()
    endglobals

    private function PlaySBAlert takes player whichPlayer, Color pingColor, sound snd, real x, real y returns nothing
        if (whichPlayer == GetLocalPlayer()) then
            call PingMinimapEx(x, y, MINIMAP_PING_DURATION, pingColor.r, pingColor.g, pingColor.b, false)
            call SetCameraQuickPosition(x, y)
            call StartSound(snd)
        endif
    endfunction

    private function PlaySBAlertForObserver takes player whichPlayer, player owner, sound snd, real x, real y returns nothing
        local Color pc = PlayerColor(owner)
        call PlaySBAlert(whichPlayer, pc, snd, x, y)
    endfunction

    private function PlaySBAlertForAlly takes player whichPlayer, player owner, sound snd, real x, real y returns nothing
        local Color pc = PlayerColorToColor(PLAYER_COLOR_CYAN)
        call PlaySBAlert(whichPlayer, pc, snd, x, y)
    endfunction

    private function PlaySBAlertForEnemy takes player whichPlayer, player owner, sound snd, real x, real y returns nothing
        local Color pc = PlayerColorToColor(PLAYER_COLOR_RED)
        call PlaySBAlert(whichPlayer, pc, snd, x, y)
    endfunction

    function PlaySBAlertAtPos takes player owner, real x, real y, integer abilityId returns nothing
        local string audioCue = LoadStr(HT_SB_ALERTS, abilityId, 0)
        local sound snd = CreateSound(audioCue, false, false, true, 12700, 12700, "DefaultEAXON")
        local player p = null
        local integer i = 0
        loop
            exitwhen i >= bj_MAX_PLAYERS
            set p = Player(i)
            if (p == owner) then
                // Do nothing
            elseif (not IsVisibleToPlayer(x, y, p)) then
                // Do nothing
            elseif (IsPlayerObserver(p)) then
                call PlaySBAlertForObserver(p, owner, snd, x, y)
            elseif (IsPlayerAlly(p, owner)) then
                call PlaySBAlertForAlly(p, owner, snd, x, y)
            elseif (IsPlayerEnemy(p, owner)) then
                call PlaySBAlertForEnemy(p, owner, snd, x, y)
            endif
            set i = i + 1
        endloop
        call KillSoundWhenDone(snd)
    endfunction

    function PlaySBAlertOnUnit takes player owner, unit whichUnit, integer abilityId returns nothing
        call PlaySBAlertAtPos(owner, GetUnitX(whichUnit), GetUnitY(whichUnit), abilityId)
    endfunction

    private function Init takes nothing returns nothing
        call SaveStr(HT_SB_ALERTS, SB_DIVINE_INTERVENTION, 0, "Abilities\\Spells\\Human\\DivineShield\\DivineShield.flac")
        call SaveStr(HT_SB_ALERTS, SB_SUMMON_SPIRIT_DWARVES, 0, "Abilities\\Spells\\Human\\MassTeleport\\MassTeleportTarget.flac")
        call SaveStr(HT_SB_ALERTS, SB_GAVEL_OF_JUDGMENT, 0, "Abilities\\Spells\\Human\\FlameStrike\\FlameStrikeTargetWaveNonLoop1.flac")
        call SaveStr(HT_SB_ALERTS, SB_AVATAR_OF_COMMAND, 0, "Abilities\\Spells\\Human\\HolyBolt\\HolyBolt.flac")
        call SaveStr(HT_SB_ALERTS, SB_BATTLE_STANDARD, 0, "Abilities\\Spells\\Orc\\HealingWave\\HealingWave.flac")
        call SaveStr(HT_SB_ALERTS, SB_RESURRECTION, 0, "Abilities\\Spells\\Human\\ReviveHuman\\ReviveHuman.flac")
        call SaveStr(HT_SB_ALERTS, SB_ROOTGRASP, 0, "Abilities\\Spells\\NightElf\\EntanglingRoots\\EntanglingRootsTarget1.flac")
        call SaveStr(HT_SB_ALERTS, SB_ENTWINE, 0, "Abilities\\Spells\\NightElf\\Root\\Root.flac")
        call SaveStr(HT_SB_ALERTS, SB_MURDER_OF_CROWS, 0, "Units\\NightElf\\DruidOfTheTalon\\DruidOfTheTalonDeathAlternate1.flac")
        call SaveStr(HT_SB_ALERTS, SB_BEAST_WITHIN, 0, "Abilities\\Spells\\NightElf\\BattleRoar\\BattleRoar.flac")
        call SaveStr(HT_SB_ALERTS, SB_CLOUD_OF_MIST, 0, "Abilities\\Spells\\Other\\BreathOfFrost\\BreathOfFrost1.flac")
        call SaveStr(HT_SB_ALERTS, SB_CALL_GREAT_STAG, 0, "Abilities\\Spells\\NightElf\\Tranquility\\Tranquility.flac")
        call SaveStr(HT_SB_ALERTS, SB_BRINK_OF_DEATH, 0, "Abilities\\Spells\\Undead\\DeathCoil\\DeathCoilSpecialArt1.flac")
        call SaveStr(HT_SB_ALERTS, SB_ANIMATE_DEAD, 0, "Abilities\\Spells\\Undead\\RaiseSkeletonWarrior\\RaiseSkeleton.flac")
        call SaveStr(HT_SB_ALERTS, SB_UNHOLY_CROWN, 0, "Abilities\\Spells\\Demon\\SoulPreservation\\SoulPreservation.flac")
        call SaveStr(HT_SB_ALERTS, SB_ZOMBIE_PLAGUE, 0, "Abilities\\Weapons\\MeatwagonMissile\\MeatwagonMissileHit1.flac")
        call SaveStr(HT_SB_ALERTS, SB_DEATH_BEAM, 0, "Abilities\\Spells\\Other\\Parasite\\Parasite.flac")
    endfunction

endlibrary

function CreateSBDummyDependency takes player p returns unit
    local unit dummy = CreateUnit(p, SB_SPELLBRINGER_DUMMY_DEPENDENCY, GetRectMaxX(GetPlayableMapRect()), GetRectMaxY(GetPlayableMapRect()), 0.0)
    set udg_Unit_SpellbringerDependency[GetPlayerId(p)] = dummy
    return dummy
endfunction

function Trig_Spellbringer_Init_PlayerLoop takes nothing returns nothing
    local integer raceNumber = 1
    local integer SBCount = 0
    local integer SBLevel = 0
    local group spellbringers = null
    local unit spellbringer = null

    loop
        exitwhen raceNumber > udg_Int_RaceCount

        set SBLevel = GetSpellbringerLevelByTech(GetEnumPlayer(), raceNumber)
        set spellbringers = GetUnitsOfPlayerAndTypeId(GetEnumPlayer(), udg_UnitType_Spellbringer[raceNumber])
        loop
            set spellbringer = FirstOfGroup(spellbringers)
            exitwhen spellbringer == null
            set SBCount = SBCount + 1
            call SetHeroLevelBJ(spellbringer, SBLevel, false)
            call SuspendHeroXP(spellbringer, true)
            call GroupRemoveUnit(spellbringers, spellbringer)
        endloop
            
        if (SBCount > 0) then
            call CreateSBDummyDependency(GetEnumPlayer())
        endif

        call DestroyGroup(spellbringers)
        set raceNumber = raceNumber + 1
    endloop

endfunction

function Trig_Spellbringer_Init_Actions takes nothing returns nothing
    local force players = GetPlayingPlayers(false, true, true)
    call ForForce(players, function Trig_Spellbringer_Init_PlayerLoop)
    call DestroyForce(players)
endfunction

//===========================================================================
function InitTrig_Spellbringer_Init takes nothing returns nothing
    set gg_trg_Spellbringer_Init = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Spellbringer_Init, function Trig_Spellbringer_Init_Actions )
endfunction

function Trig_Spellbringer_Enter_Actions takes nothing returns nothing
    local integer SBLevel = 0
    local integer raceNumber = 1
    local player owner = GetOwningPlayer(GetEnteringUnit())
    loop
        exitwhen raceNumber > udg_Int_RaceCount
        if (GetUnitTypeId(GetEnteringUnit()) == udg_UnitType_Spellbringer[raceNumber]) then
            set SBLevel = GetSpellbringerLevelByTech(owner, raceNumber)
            call SetHeroLevelBJ(GetEnteringUnit(), SBLevel, false)
            call SuspendHeroXP(GetEnteringUnit(), true)
            exitwhen true
        endif
        set raceNumber = raceNumber + 1
    endloop
endfunction

//===========================================================================
function InitTrig_Spellbringer_Enter takes nothing returns nothing
    set gg_trg_Spellbringer_Enter = CreateTrigger(  )
    call TriggerRegisterEnterRectSimple( gg_trg_Spellbringer_Enter, GetPlayableMapRect() )
    call TriggerAddAction( gg_trg_Spellbringer_Enter, function Trig_Spellbringer_Enter_Actions )
endfunction

function Trig_Spellbringer_Construction_Complete_Conditions takes nothing returns boolean
    local integer raceNumber = 1
    local integer ownerIndex = GetPlayerId(GetOwningPlayer(GetConstructedStructure()))
    loop
        exitwhen raceNumber > udg_Int_RaceCount
        if (GetUnitTypeId(GetConstructedStructure()) == udg_UnitType_Spellbringer[raceNumber]) then
            return udg_Unit_SpellbringerDependency[ownerIndex] == null
        endif
        set raceNumber = raceNumber + 1
    endloop
    return false
endfunction

function Trig_Spellbringer_Construction_Complete_Actions takes nothing returns nothing
    call CreateSBDummyDependency(GetOwningPlayer(GetConstructedStructure()))
endfunction

//===========================================================================
function InitTrig_Spellbringer_Construction_Complete takes nothing returns nothing
    set gg_trg_Spellbringer_Construction_Complete = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spellbringer_Construction_Complete, EVENT_PLAYER_UNIT_CONSTRUCT_FINISH )
    call TriggerAddCondition(gg_trg_Spellbringer_Construction_Complete, Condition(function Trig_Spellbringer_Construction_Complete_Conditions))
    call TriggerAddAction( gg_trg_Spellbringer_Construction_Complete, function Trig_Spellbringer_Construction_Complete_Actions )
endfunction

function Trig_Spellbringer_Death_Actions takes nothing returns nothing
    local integer raceNumber = GetSpellbringerRace(GetDyingUnit())
    local unit sb = null
    if (raceNumber != -1) then
        set sb = GetDyingUnit()
        call KillUnit(CreateUnit(GetOwningPlayer(sb), udg_UnitType_SpellbringerDeath[raceNumber], GetUnitX(sb), GetUnitY(sb), bj_UNIT_FACING))
        call RemoveUnit(sb)
        if (CountSpellbringersForPlayer(GetOwningPlayer(sb)) <= 0) then
            call RemoveUnit(udg_Unit_SpellbringerDependency[GetPlayerId(GetOwningPlayer(sb))])
        endif
    endif
endfunction

//===========================================================================
function InitTrig_Spellbringer_Death takes nothing returns nothing
    set gg_trg_Spellbringer_Death = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spellbringer_Death, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddAction( gg_trg_Spellbringer_Death, function Trig_Spellbringer_Death_Actions )
endfunction

function Trig_Spellbringer_Research_Complete_Actions takes nothing returns nothing
    local integer raceNumber = 1
    local integer SBLevel = 0
    local group spellbringers = null
    local unit spellbringer = null

    loop
        exitwhen raceNumber > udg_Int_RaceCount
        if (GetResearched() == udg_TechType_Level3SBSpell[raceNumber]) then
            set SBLevel = 3
        elseif (GetResearched() == udg_TechType_Level2SBSpell[raceNumber]) then
            set SBLevel = 2
        endif

        if (SBLevel > 1) then
            set spellbringers = GetUnitsOfPlayerAndTypeId(GetOwningPlayer(GetResearchingUnit()), udg_UnitType_Spellbringer[raceNumber])
            loop
                set spellbringer = FirstOfGroup(spellbringers)
                exitwhen spellbringer == null
                call SuspendHeroXP(spellbringer, false)
                call SetHeroLevelBJ(spellbringer, SBLevel, true)
                call SuspendHeroXP(spellbringer, true)
                call GroupRemoveUnit(spellbringers, spellbringer)
            endloop
            exitwhen true
        endif

        set raceNumber = raceNumber + 1
    endloop
endfunction

//===========================================================================
function InitTrig_Spellbringer_Research_Complete takes nothing returns nothing
    set gg_trg_Spellbringer_Research_Complete = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spellbringer_Research_Complete, EVENT_PLAYER_UNIT_RESEARCH_FINISH )
    call TriggerAddAction( gg_trg_Spellbringer_Research_Complete, function Trig_Spellbringer_Research_Complete_Actions )
endfunction

scope GenericUnsummon initializer Init
    private function OnSpellEffect takes nothing returns nothing
        call KillUnit(GetSpellAbilityUnit())
    endfunction

    private function Init takes nothing returns nothing
        call CreateSpellEffectTrigger(SB_UNSUMMON_GENERIC, function OnSpellEffect)
    endfunction
endscope

scope CargoHoldDeath initializer Init

    private function OnUnitUnloadedFromTransport takes TransportEvent ev returns nothing
        if (not UnitAlive(ev.transport) and UnitHasAbility(ev.transport, SB_CARGO_HOLD_DEATH)) then
            call KillUnit(ev.cargo)
        endif
    endfunction

    private function Init takes nothing returns nothing
        call EventSystem_RegisterEventListener(TransportTracking_OnUnitUnloadedFromTransport, OnUnitUnloadedFromTransport)
    endfunction

endscope

function InitEject takes unit whichUnit returns nothing
    call OrderTracking_TrackUnit(whichUnit)
    call OrderTracking_FilterOutOrder(whichUnit, String2OrderIdBJ("berserk"))
    call BlzUnitDisableAbility(whichUnit, SB_EJECT, true, true)
endfunction

globals
    constant key KEY_EJECT
endglobals

function Trig_Eject_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == SB_EJECT
endfunction

function Trig_Eject_Unload_Unit takes unit transport returns boolean
    local group transportedUnits = GetLoadedUnits(transport)
    local unit dropped = FirstOfGroup(transportedUnits)
    local OrderTracking_Order lastOrder = 0
    if (dropped != null) then
        set lastOrder = OrderTracking_GetLastOrder(transport)
        call IssueTargetOrder(transport, "unload", dropped)
        if (lastOrder.orderId != SB_ORDER_STOP) then
            call OrderTracking_ExecuteOrder(transport, lastOrder)
        endif
    endif
    return CountUnitsInGroup(transportedUnits) > 1
endfunction

function Trig_Eject_Update takes UnitTimer ut returns nothing
    if (not Trig_Eject_Unload_Unit(ut.owner)) then
        call ut.destroy()
        call RemoveSavedInteger(udg_HashTable_UnitInfo, GetHandleId(ut.owner), KEY_EJECT)
    endif
endfunction

function Trig_Eject_Actions takes nothing returns nothing
    local unit transport = GetSpellAbilityUnit()
    local real dropoffInterval = GetUnitAbilityRealLevelField(transport, SB_EJECT, ABILITY_RLF_DURATION_HERO)
    local UnitTimer ejectTimer = LoadInteger(udg_HashTable_UnitInfo, GetHandleId(transport), KEY_EJECT)
    local boolean needTimer = Trig_Eject_Unload_Unit(transport)
    if (needTimer) then
        if (ejectTimer == 0) then
            set ejectTimer = CreateUnitTimer(transport, false)
            call SaveInteger(udg_HashTable_UnitInfo, GetHandleId(transport), KEY_EJECT, ejectTimer)
        endif
        call StartTimerPlusPeriodic(ejectTimer, 0.0, dropoffInterval, Trig_Eject_Update, 0)
    endif
endfunction

//===========================================================================
function InitTrig_Eject takes nothing returns nothing
    set gg_trg_Eject = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Eject, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Eject, Condition( function Trig_Eject_Conditions ) )
    call TriggerAddAction( gg_trg_Eject, function Trig_Eject_Actions )
endfunction

function Trig_Eject_Init_Actions takes nothing returns nothing
    local group ejectors = GetUnitsInRectWithAbility(GetEntireMapRect(), SB_EJECT)
    local unit picked = null
    loop
        set picked = FirstOfGroup(ejectors)
        exitwhen picked == null
        call InitEject(picked)
        call GroupRemoveUnit(ejectors, picked)
    endloop
    call DestroyGroup(ejectors)
endfunction

//===========================================================================
function InitTrig_Eject_Init takes nothing returns nothing
    set gg_trg_Eject_Init = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Eject_Init, function Trig_Eject_Init_Actions )
endfunction

function Trig_Eject_Enters_Conditions takes nothing returns boolean
    return UnitHasAbility(GetEnteringUnit(), SB_EJECT)
endfunction

function Trig_Eject_Enters_Actions takes nothing returns nothing
    call InitEject(GetEnteringUnit())
endfunction

//===========================================================================
function InitTrig_Eject_Enters takes nothing returns nothing
    set gg_trg_Eject_Enters = CreateTrigger(  )
    call TriggerRegisterEnterRectSimple( gg_trg_Eject_Enters, GetEntireMapRect() )
    call TriggerAddCondition( gg_trg_Eject_Enters, Condition( function Trig_Eject_Enters_Conditions ) )
    call TriggerAddAction( gg_trg_Eject_Enters, function Trig_Eject_Enters_Actions )
endfunction

function Trig_Eject_Loaded_Conditions takes nothing returns boolean
    return UnitHasAbility(GetTransportUnit(), SB_EJECT)
endfunction

function Trig_Eject_Unit_Unloaded takes TransportEvent ev returns nothing
    local unit transport = ev.transport
    local unit unloaded = ev.cargo
    local group transported = null
    if (UnitHasAbility(transport, SB_EJECT)) then
        set transported = GetLoadedUnits(transport)
        if (CountUnitsInGroup(transported) == 0) then
            call BlzUnitDisableAbility(transport, SB_EJECT, true, true)
        endif
    endif
endfunction

function Trig_Eject_Loaded_Actions takes nothing returns nothing
    local unit transport = GetTransportUnit()
    local group transported = GetLoadedUnits(transport)
    if (CountUnitsInGroup(transported) == 1) then
        call BlzUnitDisableAbility(transport, SB_EJECT, false, false)
    endif
endfunction

//===========================================================================
function InitTrig_Eject_Loaded takes nothing returns nothing
    set gg_trg_Eject_Loaded = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Eject_Loaded, EVENT_PLAYER_UNIT_LOADED )
    call TriggerAddCondition( gg_trg_Eject_Loaded, Condition( function Trig_Eject_Loaded_Conditions ) )
    call TriggerAddAction( gg_trg_Eject_Loaded, function Trig_Eject_Loaded_Actions )
    call EventSystem_RegisterEventListener(TransportTracking_OnUnitUnloadedFromTransport, Trig_Eject_Unit_Unloaded)
endfunction

function Trig_Damage_Resistance_Conditions takes nothing returns boolean
    return UnitHasAbility(BlzGetEventDamageTarget(), SB_DAMAGE_RESISTANCE)
endfunction

function Trig_Damage_Resistance_Actions takes nothing returns nothing
    local unit damaged = BlzGetEventDamageTarget()
    local real damageMultiplier = 1.0 - GetUnitAbilityRealLevelField(damaged, SB_DAMAGE_RESISTANCE, ABILITY_RLF_CASTING_TIME)
    call BlzSetEventDamage(GetEventDamage() * damageMultiplier)
endfunction

//===========================================================================
function InitTrig_Damage_Resistance takes nothing returns nothing
    set gg_trg_Damage_Resistance = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Damage_Resistance, EVENT_PLAYER_UNIT_DAMAGING )
    call TriggerAddCondition( gg_trg_Damage_Resistance, Condition( function Trig_Damage_Resistance_Conditions ) )
    call TriggerAddAction( gg_trg_Damage_Resistance, function Trig_Damage_Resistance_Actions )
    call GateAbilityTrigger(gg_trg_Damage_Resistance, SB_DAMAGE_RESISTANCE, 0)
endfunction

function Trig_Remove_Hero_Glow_Init_Actions takes nothing returns nothing
    local group heroGlowUnits = GetUnitsInRectWithAbility(GetEntireMapRect(), SB_NO_HERO_GLOW)
    local unit picked = null
    loop
        set picked = FirstOfGroup(heroGlowUnits)
        exitwhen picked == null
        call BlzShowUnitTeamGlow(picked, false)
        call GroupRemoveUnit(heroGlowUnits, picked)
    endloop
    call DestroyGroup(heroGlowUnits)
endfunction

//===========================================================================
function InitTrig_Remove_Hero_Glow_Init takes nothing returns nothing
    set gg_trg_Remove_Hero_Glow_Init = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Remove_Hero_Glow_Init, function Trig_Remove_Hero_Glow_Init_Actions )
endfunction

function Trig_Remove_Hero_Glow_Enters_Conditions takes nothing returns boolean
    return UnitHasAbility(GetEnteringUnit(), SB_NO_HERO_GLOW)
endfunction

function Trig_Remove_Hero_Glow_Enters_Actions takes nothing returns nothing
    call BlzShowUnitTeamGlow(GetEnteringUnit(), false)
endfunction

//===========================================================================
function InitTrig_Remove_Hero_Glow_Enters takes nothing returns nothing
    set gg_trg_Remove_Hero_Glow_Enters = CreateTrigger(  )
    call TriggerRegisterEnterRectSimple( gg_trg_Remove_Hero_Glow_Enters, GetEntireMapRect() )
    call TriggerAddCondition( gg_trg_Remove_Hero_Glow_Enters, Condition( function Trig_Remove_Hero_Glow_Enters_Conditions ) )
    call TriggerAddAction( gg_trg_Remove_Hero_Glow_Enters, function Trig_Remove_Hero_Glow_Enters_Actions )
endfunction