Triggers

//TESH.scrollpos=0
//TESH.alwaysfold=0
library Table // made by Bribe, special thanks to Nestharus, version 3.0.0.0
    
globals
    private hashtable ht = InitHashtable() //The last hashtable you need
    private integer more = 2 //Index generation for Tables (above 2)
    private integer less = 0 //Index generation for TableArrays (below 0)
endglobals
    
private struct dex extends array
    static method operator size takes nothing returns Table
        return 1
    endmethod
    static method operator list takes nothing returns Table
        return 2
    endmethod
endstruct
    
private struct handles extends array
    method has takes integer key returns boolean
        return HaveSavedHandle(ht, this, key)
    endmethod
    method remove takes integer key returns nothing
        call RemoveSavedHandle(ht, this, key)
    endmethod
endstruct
    
private struct agents extends array
    method operator []= takes integer key, agent value returns nothing
        call SaveAgentHandle(ht, this, key, value)
    endmethod
endstruct
    
//! textmacro NEW_ARRAY_BASIC takes SUPER, FUNC, TYPE
private struct $TYPE$s extends array
    method operator [] takes integer key returns $TYPE$
        return Load$FUNC$(ht, this, key)
    endmethod
    method operator []= takes integer key, $TYPE$ value returns nothing
        call Save$FUNC$(ht, this, key, value)
    endmethod
    method has takes integer key returns boolean
        return HaveSaved$SUPER$(ht, this, key)
    endmethod
    method remove takes integer key returns nothing
        call RemoveSaved$SUPER$(ht, this, key)
    endmethod
endstruct
private module $TYPE$m
    method operator $TYPE$ takes nothing returns $TYPE$s
        return this
    endmethod
endmodule
//! endtextmacro
    
//! textmacro NEW_ARRAY takes FUNC, TYPE
private struct $TYPE$s extends array
    method operator [] takes integer key returns $TYPE$
        return Load$FUNC$Handle(ht, this, key)
    endmethod
    method operator []= takes integer key, $TYPE$ value returns nothing
        call Save$FUNC$Handle(ht, this, key, value)
    endmethod
endstruct
private module $TYPE$m
    method operator $TYPE$ takes nothing returns $TYPE$s
        return this
    endmethod
endmodule
//! endtextmacro
    
//! runtextmacro NEW_ARRAY_BASIC("Real", "Real", "real")
//! runtextmacro NEW_ARRAY_BASIC("Boolean", "Boolean", "boolean")
//! runtextmacro NEW_ARRAY_BASIC("String", "Str", "string")
    
//! runtextmacro NEW_ARRAY("Player", "player")
//! runtextmacro NEW_ARRAY("Widget", "widget")
//! runtextmacro NEW_ARRAY("Destructable", "destructable")
//! runtextmacro NEW_ARRAY("Item", "item")
//! runtextmacro NEW_ARRAY("Unit", "unit")
//! runtextmacro NEW_ARRAY("Ability", "ability")
//! runtextmacro NEW_ARRAY("Timer", "timer")
//! runtextmacro NEW_ARRAY("Trigger", "trigger")
//! runtextmacro NEW_ARRAY("TriggerCondition", "triggercondition")
//! runtextmacro NEW_ARRAY("TriggerAction", "triggeraction")
//! runtextmacro NEW_ARRAY("TriggerEvent", "event")
//! runtextmacro NEW_ARRAY("Force", "force")
//! runtextmacro NEW_ARRAY("Group", "group")
//! runtextmacro NEW_ARRAY("Location", "location")
//! runtextmacro NEW_ARRAY("Rect", "rect")
//! runtextmacro NEW_ARRAY("BooleanExpr", "boolexpr")
//! runtextmacro NEW_ARRAY("Sound", "sound")
//! runtextmacro NEW_ARRAY("Effect", "effect")
//! runtextmacro NEW_ARRAY("UnitPool", "unitpool")
//! runtextmacro NEW_ARRAY("ItemPool", "itempool")
//! runtextmacro NEW_ARRAY("Quest", "quest")
//! runtextmacro NEW_ARRAY("QuestItem", "questitem")
//! runtextmacro NEW_ARRAY("DefeatCondition", "defeatcondition")
//! runtextmacro NEW_ARRAY("TimerDialog", "timerdialog")
//! runtextmacro NEW_ARRAY("Leaderboard", "leaderboard")
//! runtextmacro NEW_ARRAY("Multiboard", "multiboard")
//! runtextmacro NEW_ARRAY("MultiboardItem", "multiboarditem")
//! runtextmacro NEW_ARRAY("Trackable", "trackable")
//! runtextmacro NEW_ARRAY("Dialog", "dialog")
//! runtextmacro NEW_ARRAY("Button", "button")
//! runtextmacro NEW_ARRAY("TextTag", "texttag")
//! runtextmacro NEW_ARRAY("Lightning", "lightning")
//! runtextmacro NEW_ARRAY("Image", "image")
//! runtextmacro NEW_ARRAY("Ubersplat", "ubersplat")
//! runtextmacro NEW_ARRAY("Region", "region")
//! runtextmacro NEW_ARRAY("FogState", "fogstate")
//! runtextmacro NEW_ARRAY("FogModifier", "fogmodifier")
//! runtextmacro NEW_ARRAY("Hashtable", "hashtable")
    
struct Table extends array
    
    // Implement modules for intuitive type-syntax
    implement realm
    implement booleanm
    implement stringm
    implement playerm
    implement widgetm
    implement destructablem
    implement itemm
    implement unitm
    implement abilitym
    implement timerm
    implement triggerm
    implement triggerconditionm
    implement triggeractionm
    implement eventm
    implement forcem
    implement groupm
    implement locationm
    implement rectm
    implement boolexprm
    implement soundm
    implement effectm
    implement unitpoolm
    implement itempoolm
    implement questm
    implement questitemm
    implement defeatconditionm
    implement timerdialogm
    implement leaderboardm
    implement multiboardm
    implement multiboarditemm
    implement trackablem
    implement dialogm
    implement buttonm
    implement texttagm
    implement lightningm
    implement imagem
    implement ubersplatm
    implement regionm
    implement fogstatem
    implement fogmodifierm
    implement hashtablem
    
    method operator handle takes nothing returns handles
        return this
    endmethod
    
    method operator agent takes nothing returns agents
        return this
    endmethod
    
    // set this = a[GetSpellAbilityId()]
    method operator [] takes integer key returns Table
        return LoadInteger(ht, this, key)
    endmethod
    
    // set a[389034] = 8192
    method operator []= takes integer key, Table a returns nothing
        call SaveInteger(ht, this, key, a)
    endmethod
    
    // set b = a.has(2493223)
    method has takes integer key returns boolean
        return HaveSavedInteger(ht, this, key)
    endmethod
    
    // call a.remove(294080)
    method remove takes integer key returns nothing
        call RemoveSavedInteger(ht, this, key)
    endmethod
    
    // Remove all data from a Table instance
    method flush takes nothing returns nothing
        call FlushChildHashtable(ht, this)
    endmethod
    
    // local Table a = Table.create()
    static method create takes nothing returns Table
        local Table this = dex.list[0]
        
        if this == 0 then
            set more = more + 1
            set this = more
        else
            set dex.list[0] = dex.list[this]
            call dex.list.remove(this)
        endif
        
        debug set dex.list[this] = -1
        return this
    endmethod
    
    // Removes all data from a Table instance and recycles its index.
    //
    //     call a.destroy()
    //
    method destroy takes nothing returns nothing
        debug if dex.list[this] != -1 then
            debug call BJDebugMsg("Table Error: Tried to double-free instance: " + I2S(this))
            debug return
        debug endif
        
        call this.flush()
        
        set dex.list[this] = dex.list[0]
        set dex.list[0] = this
    endmethod
    
endstruct
    
struct TableArray extends array
    
    //Returns a new TableArray to do your bidding. Simply use:
    //
    //    local TableArray ta = TableArray[array_size]
    //
    static method operator [] takes integer array_size returns TableArray
        local Table a = dex.size[array_size] //Get the unique recycle list for this array size
        local TableArray this = a[0]         //The last-destroyed TableArray that had this array size
        
        debug if array_size <= 0 then
            debug call BJDebugMsg("TypeError: Invalid specified TableArray size: " + I2S(array_size))
            debug return 0
        debug endif
        
        if this == 0 then
            set less = less - array_size
            set this = less
        else
            set a[0] = a[this]  //Set the last destroyed to the last-last destroyed
            call a.remove(this) //Clear hash memory
        endif
        
        set dex.size[this] = array_size //This remembers the array size
        return this
    endmethod
    
    //Returns the size of the TableArray
    method operator size takes nothing returns integer
        return dex.size[this]
    endmethod
    
    //da[integer a].unit[integer b] = unit u
    //da[integer a][integer c] = integer d
    //
    //Inline-friendly when not running in debug mode
    //
    method operator [] takes integer key returns Table
        static if DEBUG_MODE then
            local integer i = this.size
            if i == 0 then
                call BJDebugMsg("IndexError: Tried to get key from invalid TableArray instance: " + I2S(this))
                return 0
            elseif key < 0 or key >= i then
                call BJDebugMsg("IndexError: Tried to get key [" + I2S(key) + "] from outside TableArray bounds: " + I2S(i))
                return 0
            endif
        endif
        return this + key
    endmethod
    
    //Destroys a TableArray without flushing it; assumed you'd call .flush()
    //if you want it flushed too. This is public so that if you are flushing
    //instances the whole time you don't waste efficiency when disposing the
    //TableArray.
    //
    method destroy takes nothing returns nothing
        local Table a = dex.size[this.size]
        
        debug if this.size <= 0 then
            debug call BJDebugMsg("TypeError: Tried to destroy an invalid TableArray: " + I2S(this))
            debug return
        debug endif
        
        if a == 0 then
            //Create an array to index recycled instances with their array size
            set a = Table.create()
            set dex.size[this.size] = a
        endif
        
        call dex.size.remove(this) //Clear the array size from hash memory
        
        set a[this] = a[0]
        set a[0] = this
    endmethod
    
    //All you need to know about this one is that it won't hit the op limit.
    private static method clean takes Table a, integer end returns nothing
        local integer i = a + 5000
        if i < end then
            call clean.evaluate(i, end)
            set end = i
        endif
        loop
            call a.flush()
            set a = a + 1
            exitwhen a == end
        endloop
    endmethod
    
    //Flushes the TableArray and also destroys it. Doesn't get any more
    //similar to the FlushParentHashtable native than this.
    //
    method flush takes nothing returns nothing
        local integer end = this.size + this
        debug if this == end then
            debug call BJDebugMsg("TypeError: Tried to flush an invalid TableArray instance: " + I2S(this))
            debug return
        debug endif
        call clean.evaluate(this, end)
        call this.destroy()
    endmethod
    
endstruct
    
endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
library RegisterPlayerUnitEvent // Special Thanks to Bribe and azlier
    globals
        private trigger array t
    endglobals
    
    function RegisterPlayerUnitEvent takes playerunitevent p, code c returns nothing
        local integer i = GetHandleId(p)
        local integer k = 15
        if t[i] == null then
            set t[i] = CreateTrigger()
            loop
                call TriggerRegisterPlayerUnitEvent(t[i], Player(k), p, null)
                exitwhen k == 0
                set k = k - 1
            endloop
        endif
        call TriggerAddCondition(t[i], Filter(c))
    endfunction
    
    function RegisterPlayerUnitEventForPlayer takes playerunitevent p, code c, player pl returns nothing
        local integer i = 260 + 16 * GetHandleId(p) + GetPlayerId(pl)
        if t[i] == null then
            set t[i] = CreateTrigger()
            call TriggerRegisterPlayerUnitEvent(t[i], pl, p, null)
        endif
        call TriggerAddCondition(t[i], Filter(c))
    endfunction
endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
library SpellEffectEvent requires RegisterPlayerUnitEvent, Table
 
//============================================================================
private module M
    
    static Table tb
    
    static method onCast takes nothing returns nothing
        call TriggerEvaluate(.tb.trigger[GetSpellAbilityId()])
    endmethod
 
    private static method onInit takes nothing returns nothing
        set .tb = Table.create()
        call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_SPELL_EFFECT, function thistype.onCast)
    endmethod
endmodule
 
//============================================================================
private struct S extends array
    implement M
endstruct
 
//============================================================================
function RegisterSpellEffectEvent takes integer abil, code onCast returns nothing
    if not S.tb.handle.has(abil) then
        set S.tb.trigger[abil] = CreateTrigger()
    endif
    call TriggerAddCondition(S.tb.trigger[abil], Filter(onCast))
endfunction
 
endlibrary

//TESH.scrollpos=6
//TESH.alwaysfold=0
scope RotatingBlades

    //requires SpellEffectEvent, from Bribe
    
    globals
        //edit the values to customize
        private integer ABILITY_CODE = 'A000'
        private integer DUMMY_UNIT_CODE = 'h000'
        private attacktype ATTACK_TYPE = ATTACK_TYPE_HERO
        private damagetype DAMAGE_TYPE = DAMAGE_TYPE_NORMAL
        private real LOOP_INTERVAL = 0.0315
        private real HOVER_DIST = 150
        private real HOVER_DIST_DUR_DAM = 50
        private real MOVE_SPEED = 20
        private real ROTATE_SPEED = 1.5 * bj_DEGTORAD
        private integer DAM_DUR = 16
        private integer HOVER_DUR = 33
        private string ATTACH_MODEL = "Abilities\\Spells\\Other\\Stampede\\StampedeMissileDeath.mdl" //effect when dealing damage
        private string ATTACH_POINT = "chest"
        
        //do not edit below
        private timer LoopTimer = CreateTimer()
    endglobals
    
    //edit the return value to change the no of times blade swoops per level
    private function NoOfSwoopsPerLevel takes integer lvl returns integer
        return 2+lvl
    endfunction
    
    //edit the return value to change the damage dealt by blade per loop
    private function DamagePerLevel takes integer lvl returns real
        return 3.0+lvl //this * DAM_DUR gives total damage per swoop
    endfunction
    
    private struct Blade
        unit blade
        unit caster
        unit target
        integer lvl
        integer dur
        integer swoops
        integer status
        real angle
        effect model
        
        static Blade array Data
        static integer top = 0
        
        static method BladeLoop takes nothing returns nothing
            local integer i = 1
            local Blade bld
            local real dist
            local real x
            local real y
            local real tx
            local real ty
            local boolean kill
            loop
                exitwhen i > top
                set kill = false
                set bld = Data[i]
                if bld.status == 2 then
                    set bld.angle = bld.angle + ROTATE_SPEED
                    set dist = HOVER_DIST
                    if bld.dur < 5 then
                        set dist = HOVER_DIST*(bld.dur)/5
                    elseif HOVER_DUR - bld.dur < 5 then
                        set dist = HOVER_DIST*(HOVER_DUR - bld.dur)/5
                    endif
                    set x = GetUnitX(bld.target)
                    set y = GetUnitY(bld.target)
                    set bld.dur = bld.dur - 1
                    if bld.dur == 0 then
                        set bld.status = 3
                        set bld.dur = DAM_DUR
                        set bld.model = AddSpecialEffectTarget(ATTACH_MODEL, bld.target, ATTACH_POINT)
                    endif
                elseif bld.status == 1 then
                    set tx = GetUnitX(bld.target)
                    set ty = GetUnitY(bld.target)
                    set x = GetUnitX(bld.blade)
                    set y = GetUnitY(bld.blade)
                    set bld.angle = Atan2(ty - y, tx - x)
                    set dist = MOVE_SPEED
                    if RAbsBJ(x - tx) < HOVER_DIST and RAbsBJ(y - ty) < HOVER_DIST then
                        set bld.status = 2
                        set bld.dur = HOVER_DUR
                        set bld.swoops = NoOfSwoopsPerLevel(bld.lvl)
                    endif
                else
                    set bld.dur = bld.dur - 1
                    set dist = HOVER_DIST_DUR_DAM
                    set x = GetUnitX(bld.target)
                    set y = GetUnitY(bld.target)
                    call UnitDamageTarget(bld.caster, bld.target, DamagePerLevel(bld.lvl), true, false, ATTACK_TYPE, DAMAGE_TYPE, null) 
                    if bld.dur == 0 then
                        set bld.swoops = bld.swoops - 1
                        set bld.status = 2
                        set bld.dur = HOVER_DUR
                        call DestroyEffect(bld.model)
                        set bld.model = null
                    endif
                endif
                
                call SetUnitPosition(bld.blade, x + dist*Cos(bld.angle), y + dist*Sin(bld.angle))
                //call SetUnitX(bld.blade, x + dist*Cos(bld.angle))
                //call SetUnitY(bld.blade, y + dist*Sin(bld.angle))
                
                if IsUnitType(bld.target, UNIT_TYPE_DEAD) or bld.swoops == 0 then
                    call RemoveUnit(bld.blade)
                    call bld.destroy()
                    set Data[i] = Data[top]
                    set top = top - 1
                    if top == 0 then
                        call PauseTimer(LoopTimer)
                        return
                    endif
                else
                    set i = i + 1
                endif
                
            endloop
        endmethod
        
        static method Create takes nothing returns boolean
            local Blade bld = .allocate()
            local unit trig = GetTriggerUnit()
            local unit tar = GetSpellTargetUnit()
            local real x = GetUnitX(trig)
            local real y = GetUnitY(trig)
            local real tx = GetUnitX(tar)
            local real ty = GetUnitY(tar)
            set bld = .allocate()
            set bld.caster = trig
            set bld.target = tar
            set bld.angle = Atan2(ty - y, tx - x)
            set bld.blade = CreateUnit(GetTriggerPlayer(), DUMMY_UNIT_CODE, x, y, bld.angle)
            set bld.lvl = GetUnitAbilityLevel(bld.caster, ABILITY_CODE)
            set bld.status = 1
            set bld.dur = 1
            set bld.swoops = 1
            set top = top + 1
            set Data[top] = bld
            if top == 1 then
                call TimerStart(LoopTimer, LOOP_INTERVAL, true, function Blade.BladeLoop)
            endif
            return false
        endmethod
        
        static method onInit takes nothing returns nothing
            call RegisterSpellEffectEvent(ABILITY_CODE, function Blade.Create)
        endmethod    
    endstruct
    
endscope