• Listen to a special audio message from Bill Roper to the Hive Workshop community (Bill is a former Vice President of Blizzard Entertainment, Producer, Designer, Musician, Voice Actor) 🔗Click here to hear his message!
  • Read Evilhog's interview with Gregory Alper, the original composer of the music for WarCraft: Orcs & Humans 🔗Click here to read the full interview.

Triggers

Mesmerizing Skull v1.3f.w3x
Variables
Mesmerizing Skull
MS Setup
MS Cast
MS Loop
MS Damage
Stun AOE
INIT
INIT
Enter map-specific custom script code below. This text will be included in the map script after variables are declared and before any trigger code.
Name Type is_array initial_value
AbilityLevel integer No
AffectedUnit unit No
AffectedUnitLoc location No
AffectedUnitMove location No
Angle real No
AOE real No
BaseAOE real No
BaseDamage real No
BaseDuration integer No
BaseTimeMesmerizedSpeed real No
BaseTimeSkullSpeed real No
Caster unit No
CasterLoc location No
Damage real No
Dummy unit No
DummyUnitType unitcode No
Duration integer No
DurationPowerValue integer No
DyingLoc location No
HandleID integer No
HashtableMS hashtable No
MesmerizedSpeed real No
MesmerizingSkull abilcode No
PowerAOE real No
Skull unit No
SkullGroup group No
SkullLoc location No
SkullMoveLoc location No
SkullSpeed real No
SkullUnitType unitcode No
StunLevel integer No
TargetLoc location No
FAQ

1. Why would the BaseTimeSkullSpeed has a larger value than BaseTimeMesmerizedSpeed ?
- It is because I want to let the dragged unit still have chance to escape from the skull
- If the skull speed is greater than dragged speed, the skull will be likely to speed up ahead and leave the dragged units behind and if it's too far, well it's time for the dragged unit to make a move and escape !

2. Why don't you use the JASS function of SetUnitX , SetUnitY instead ? It's more efficient, y'know.
- If I use that function, the unit will still be able to perform action such as Casting Spell, etc
- I want this spell to completely disable's the affected unit's mindpower (the ability to think wisely or something like that :D)
- Because, you have been MESMERIZED (search for it in http://dictionary.cambridge.org/dictionary/british/mesmerize#mesmerize__3, and you know it)
- The meaning of Mesmerized: to have someone's attention completely so that they cannot think of anything else.
- Example: I was completely mesmerized by the performance.

3. Is it me, or is the spell REALLY lags if I cast 2 of it at the same time ?
- You can delete all the SFX if you want
- I just did it for "eye-candy" and not to look boring
- But I suggest, leave the "mark" damage for "MS Damage" trigger SFX alone
- Because it's a sign for damaging the dragged unit and the SFX itself is not so laggy

STANDARD SETTINGS (SPEED)

Skull Speed Level 1 = 50/s (rounded up) | True Speed = 49.5/s
Skull Speed Level 2 = 99/s (this is the true speed)
Skull Speed Level 3 = 150/s (rounded up) | True Speed = 148.5/s
Skull Speed Level 4 = 198/s (this is the true speed)

Dragged Speed Level 1 = 25/s (rounded up) | True Speed = 24.75/s
Dragged Speed Level 2 = 50/s (rounded up) | True Speed = 49.5/s
Dragged Speed Level 3 = 75/s (rounded up) | True Speed = 74.25/s
Dragged Speed Level 4 = 99/s (this is the true speed)
MS Setup
Events
Time - Elapsed game time is 0.00 seconds
Conditions
Actions
-------- Creating a hashtable --------
Hashtable - Create a hashtable
-------- Setting the last created hashtable in a variable (for easier referrence) --------
Set Variable Set HashtableMS = (Last created hashtable)
-------- This is the base duration for the skull's lifespan --------
Set Variable Set BaseDuration = "6"
-------- The "multiplication" power of the duration formula --------
Set Variable Set DurationPowerValue = "1"
-------- The "multiplication" power of AOE formula --------
Set Variable Set PowerAOE = "100.00"
-------- Base speed of the skull --------
Set Variable Set BaseTimeSkullSpeed = "1.50"
-------- Base speed of the dragged unit --------
Set Variable Set BaseTimeMesmerizedSpeed = "0.75"
-------- Base AOE of the effect --------
Set Variable Set BaseAOE = "200.00"
-------- Base damage done to the dragged unit per second --------
Set Variable Set BaseDamage = "5.00"
Set Variable Set MesmerizingSkull = "A000"
Set Variable Set SkullUnitType = "h000"
Set Variable Set DummyUnitType = "h001"
MS Cast
Events
Unit - A unit Starts the effect of an ability
Conditions
(Ability being cast) Equal to MesmerizingSkull
Actions
Set Variable Set Caster = (Triggering unit)
Set Variable Set AbilityLevel = (Level of Mesmerizing Skull for Caster)
-------- Setting up caster's location --------
Set Variable Set CasterLoc = (Position of Caster)
-------- Setting up target location --------
Set Variable Set TargetLoc = (Target point of ability being cast)
-------- By combining both variable of CasterLoc and TargetLoc, we got Angle which is used for moving the skull towards a correct angle --------
Set Variable Set Angle = (Angle from CasterLoc to TargetLoc)
-------- The duration of the skull's lifespan --------
Set Variable Set Duration = (BaseDuration + (AbilityLevel x DurationPowerValue))
-------- The skull speed during his lifespan --------
Set Variable Set SkullSpeed = (BaseTimeSkullSpeed x (Real(AbilityLevel)))
-------- Dragged unit's speed --------
Set Variable Set MesmerizedSpeed = (BaseTimeMesmerizedSpeed x (Real(AbilityLevel)))
-------- AOE of the effect around the skull --------
Set Variable Set AOE = (BaseAOE + ((Real(AbilityLevel)) x PowerAOE))
-------- Damage done to the dragged unit per second --------
Set Variable Set Damage = (BaseDamage x (Real(AbilityLevel)))
Set Variable Set StunLevel = AbilityLevel
-------- Now, create the skull --------
Unit - Create 1 . SkullUnitType for (Triggering player) at CasterLoc facing Angle degrees
Set Variable Set Skull = (Last created unit)
Custom script: set udg_HandleID = GetHandleId(udg_Skull)
-------- Add its lifespan --------
Unit - Add a (Real(Duration)) second Generic expiration timer to Skull
-------- Save all valueable data into a hashtable (for later usage) --------
Hashtable - Save Angle as (Key Angle.) of HandleID in HashtableMS .
Hashtable - Save SkullSpeed as (Key SkullSpeed.) of HandleID in HashtableMS .
Hashtable - Save MesmerizedSpeed as (Key MesmerizedSpeed.) of HandleID in HashtableMS .
Hashtable - Save AOE as (Key AOE.) of HandleID in HashtableMS .
Hashtable - Save Damage as (Key Damage.) of HandleID in HashtableMS .
Hashtable - Save StunLevel as (Key StunLevel.) of HandleID in HashtableMS .
-------- Add the last created unit (Skull) to a Unit Group for the spell effect --------
Unit Group - Add (Last created unit) to SkullGroup
-------- Turn both Loop Trigger (for 0.03 second per loop) and Damage Trigger (for 1.00 second per loop) --------
Trigger - Turn on MS_Loop <gen>
Trigger - Turn on MS_Damage <gen>
Trigger - Turn on Stun_AOE <gen>
-------- Cleaning leaks of CasterLoc and TargetLoc --------
Custom script: call RemoveLocation(udg_CasterLoc)
Custom script: call RemoveLocation(udg_TargetLoc)
MS Loop
Events
Time - Every 0.03 seconds of game time
Conditions
Actions
-------- This trigger is to move (the skull) and drag (the victim) --------
Unit Group - Pick every unit in SkullGroup and do (Actions)
Loop - Actions
Set Variable Set Skull = (Picked unit)
Custom script: set udg_HandleID = GetHandleId(udg_Skull)
-------- I put IF/THEN/ELSE Action here is because if the skull is alive, do the effect of the spell, else, remove the skull from the unit group and ends the spell effect for the skull --------
If (All Conditions are True) then do (Then Actions) else do (Else Actions)
If - Conditions
(Skull is alive) Equal to True
Then - Actions
-------- Load all the saved data from the hashtable (earlier we saved the data from the "Cast" Trigger) --------
Set Variable Set SkullSpeed = (Load (Key SkullSpeed.) of HandleID from HashtableMS.)
Set Variable Set MesmerizedSpeed = (Load (Key MesmerizedSpeed.) of HandleID from HashtableMS.)
Set Variable Set AOE = (Load (Key AOE.) of HandleID from HashtableMS.)
Set Variable Set Angle = (Load (Key Angle.) of HandleID from HashtableMS.)
-------- Setting up new variable for the picked unit --------
-------- Setting up location of the picked unit (for both referrence and clean leaks) --------
Set Variable Set SkullLoc = (Position of Skull)
-------- Determines where would the skull move for the next 0.03 second --------
Set Variable Set SkullMoveLoc = (SkullLoc offset by SkullSpeed towards Angle degrees.)
If (All Conditions are True) then do (Then Actions) else do (Else Actions)
If - Conditions
((Playable map area) contains SkullMoveLoc) Equal to True
Then - Actions
-------- After setting its path, move the skull to the designated location --------
Custom script: call SetUnitX(udg_Skull, GetLocationX(udg_SkullMoveLoc))
Custom script: call SetUnitY(udg_Skull, GetLocationY(udg_SkullMoveLoc))
Else - Actions
Unit - Kill Skull
-------- Once the skull moves, it picks up any enemy unit around the AOE and drag along with it --------
Custom script: set bj_wantDestroyGroup = true
Unit Group - Pick every unit in (Units within AOE of SkullMoveLoc matching ((((Matching unit) is alive) Equal to True) and (((Matching unit) belongs to an enemy of (Owner of Skull).) Equal to True)).) and do (Actions)
Loop - Actions
-------- Setting up new variable for the picked unit --------
Set Variable Set AffectedUnit = (Picked unit)
-------- Setting up location of the picked unit (for both referrence and clean leaks) --------
Set Variable Set AffectedUnitLoc = (Position of AffectedUnit)
-------- Determines where would the dragged unit move for the next 0.03 second --------
Set Variable Set AffectedUnitMove = (AffectedUnitLoc offset by MesmerizedSpeed towards (Angle from AffectedUnitLoc to SkullLoc) degrees.)
-------- Drags the unit to follow along with the skull --------
Unit - Move AffectedUnit instantly to AffectedUnitMove
-------- Clean leaks ! --------
Custom script: call RemoveLocation(udg_AffectedUnitLoc)
Custom script: call RemoveLocation(udg_AffectedUnitMove)
-------- Clean leaks ! --------
Custom script: call RemoveLocation(udg_SkullLoc)
Custom script: call RemoveLocation(udg_SkullMoveLoc)
Else - Actions
-------- Now, if the skull is dead, remove it from the Unit Group --------
Unit - Remove Skull from the game
-------- Clean the child hashtable of the skull --------
Hashtable - Clear all child hashtables of child HandleID in HashtableMS .
Unit Group - Remove Skull from SkullGroup .
-------- This is for trigger efficiency. If the game detects 0 unit in that Unit Group, turn off this trigger (meaning, no longer checks for 0.03 second per check and game could be less-laggy :D) --------
If (All Conditions are True) then do (Then Actions) else do (Else Actions)
If - Conditions
(SkullGroup is empty) Equal to True
Then - Actions
Trigger - Turn off (This trigger)
Trigger - Turn off Stun_AOE <gen>
Trigger - Turn off MS_Damage <gen>
Else - Actions
MS Damage
Events
Time - Every 1.00 seconds of game time
Conditions
Actions
-------- This trigger is to damage the dragged unit once per 1 second --------
Unit Group - Pick every unit in SkullGroup and do (Actions)
Loop - Actions
Set Variable Set Skull = (Picked unit)
Custom script: set udg_HandleID = GetHandleId(udg_Skull)
If (All Conditions are True) then do (Then Actions) else do (Else Actions)
If - Conditions
(Skull is alive) Equal to True
Then - Actions
-------- Load all the saved data from the hashtable (earlier we saved the data from the "Cast" Trigger) --------
Set Variable Set AOE = (Load (Key AOE.) of HandleID from HashtableMS.)
Set Variable Set Damage = (Load (Key Damage.) of HandleID from HashtableMS.)
-------- Setting up new variable for the picked unit --------
-------- Setting up location of the picked unit (for both referrence and clean leaks) --------
Set Variable Set SkullLoc = (Position of Skull)
-------- Damage the dragged unit once per second around XXX(variable setup) AOE --------
Custom script: set bj_wantDestroyGroup = true
Unit Group - Pick every unit in (Units within AOE of SkullLoc matching ((((Matching unit) is alive) Equal to True) and (((Matching unit) belongs to an enemy of (Owner of Skull).) Equal to True)).) and do (Actions)
Loop - Actions
-------- This SFX marks that the unit is damaged by the spell --------
Special Effect - Create a special effect attached to the overhead (Unexpected type: 'attachpoint') of (Picked unit) using Abilities\Spells\Undead\Possession\PossessionTarget.mdl
-------- Clean leaks ! --------
Special Effect - Destroy (Last created special effect)
Unit - Cause Skull to damage (Picked unit) , dealing Damage damage of attack type Spells and damage type Normal
-------- Clean leaks ! --------
Custom script: call RemoveLocation(udg_SkullLoc)
Custom script: call RemoveLocation(udg_SkullMoveLoc)
Else - Actions
-------- Now, if the skull is dead, remove it from the Unit Group --------
Unit - Remove Skull from the game
-------- Clean the child hashtable of the skull --------
Hashtable - Clear all child hashtables of child HandleID in HashtableMS .
Unit Group - Remove Skull from SkullGroup .
-------- This is for trigger efficiency. If the game detects 0 unit in that Unit Group, turn off this trigger (meaning, no longer checks for 0.03 second per check and game could be less-laggy :D) --------
Stun AOE
Events
Unit - A unit Dies
Conditions
(Unit-type of (Triggering unit)) Equal to Mesmering Skull Dummy
Actions
Set Variable Set Skull = (Triggering unit)
Custom script: set udg_HandleID = GetHandleId(udg_Skull)
-------- This trigger is for the dummy unit to stun victim in an AOE after the skull is dead --------
-------- As usual, load the data from the hashtable --------
Set Variable Set AOE = (Load (Key AOE.) of HandleID from HashtableMS.)
Set Variable Set StunLevel = (Load (Key StunLevel.) of HandleID from HashtableMS.)
-------- Setting up a location for the skull's location --------
Set Variable Set DyingLoc = (Position of (Triggering unit))
-------- Playing some eye-candy SFX on the location --------
Special Effect - Create a special effect at DyingLoc using Abilities\Spells\Undead\AnimateDead\AnimateDeadTarget.mdl
-------- Cleaning Leaks ! --------
Special Effect - Destroy (Last created special effect)
-------- Pick the units in the AOE and stun `em ! --------
Custom script: set bj_wantDestroyGroup = true
Unit Group - Pick every unit in (Units within AOE of DyingLoc matching ((((Matching unit) is alive) Equal to True) and (((Matching unit) belongs to an enemy of (Triggering player).) Equal to True)).) and do (Actions)
Loop - Actions
-------- Simple basic actions for Many Dummy Units *ToDoSomeAction* on Many Picked Units --------
Unit - Create 1 . DummyUnitType for (Triggering player) at DyingLoc facing Default building facing degrees
Set Variable Set Dummy = (Last created unit)
Unit - Add a 0.50 second Generic expiration timer to Dummy
-------- Each level varies the stun damage --------
Unit - Set level of Dummy Stun for Dummy to StunLevel
Unit - Order Dummy to Human Mountain King - Storm Bolt . (Picked unit)
-------- Cleaning leaks on both location and hashtable --------
Custom script: call RemoveLocation(udg_DyingLoc)
Hashtable - Clear all child hashtables of child HandleID in HashtableMS .
INIT
Events
Map initialization
Conditions
Actions
Visibility - Disable fog of war
Visibility - Disable black mask
Top