Name | Type | is_array | initial_value |
TempUnit | unit | No |
library ItemHierarchy /*
ItemHierarchy v1.00
by Spellbound
*/ requires /*
*/ Table /*
DESCRIPTION
ItemHierarchy creates a list of items that automatically upgrade when another item in the
list, aka the hierarchy, is picked up. If you've played the Night Elf campaign in Frozen
Throne, Maieve can at one point collect Shadow Orb Fragments to increase the power of her
Shadow Orb. This is exactly what this system does.
API
ItemHierarchy.create( takes integer itemId, boolean automaticUpgrade )
This method will create the baseline of the hierarchy. The item HAS to be a power-up,
similar to how the Shadow Orb has Shadow Orb Fragments. The baseline is how to reference
the entire hierarchy later on by using it's item id in. See Soul Gem onKill for more info.
the boolean argument should be true by default unless you wish to handle the upgrade
manually and just need the hierarchy as a referrence.
ItemHierarchy.addItem( takes integer baselineId, integer itemId, integer i )
Once your hierarchy has been created, add every subsequent level to it with the above
method. baselineId will identify the hierarchy itself, itemId is the item you wish to
add, and the integer i argument says where in the hierarchy the item goes, aka what is
its level.
ItemHierarchy.setItemLevel( takes unit u, item itm, integer i ) returns item
In the event that you need to manually modify the level of an item, use the above
method. unit u is the carrier of the item, itm is the item itself, and i is the level
you wish the item to have. This method returns the item that was created to replace
the old one.
GetItemHierarchyLevel( takes integer itemId ) returns integer
If an item is inside of a hierarchy, this will return the level of the item inside
that hierarchy. It will NOT return the Object Editor item level.
GetHierarchyTable( takes integer itemId ) returns integer
This returns the instance of the Table in which the items of the hierarchy is stored.
See Soul Gem onKill for more information.
GetHierarchyInstance( takes integer itemId ) returns integer
This returns the instance of the hierarchy itself, allowing you to reference values like
this.maxItemLevels, etc. See Soul Gem onKill for more info.
*/
globals
private trigger itemChangeTrig = CreateTrigger()
private Table instanceStorage
endglobals
function GetItemHierarchyLevel takes integer itemId returns integer
local ItemHierarchy this = instanceStorage.integer[itemId]
return this.itemLevel
endfunction
function GetHierarchyTable takes integer itemId returns integer
local ItemHierarchy this = instanceStorage.integer[itemId]
return this.tableInstance
endfunction
function GetHierarchyInstance takes integer itemId returns integer
return instanceStorage.integer[itemId]
endfunction
struct IH
static Table LIST
endstruct
struct ItemHierarchy
boolean isBaselineItem
boolean isUpgradeAutomatic
integer instance
integer tableInstance
integer baselineInstance
integer itemLevel
integer maxItemLevels
static method setItemLevel takes unit u, item itm, integer i returns item
local integer itemId = GetItemTypeId(itm)
local thistype this = instanceStorage.integer[itemId]
local integer slot = 0
if itm != null then
call DisableTrigger(itemChangeTrig)
loop
exitwhen itm == UnitItemInSlot(u, slot) or slot >= bj_MAX_INVENTORY
set slot = slot + 1
endloop
call RemoveItem(itm)
set IH.LIST = this.tableInstance
call UnitAddItemToSlotById(u, IH.LIST.integer[i], slot)
call EnableTrigger(itemChangeTrig)
endif
return UnitItemInSlot(u, slot)
endmethod
private static method upgradeItemAutomatic takes nothing returns boolean
local item itm = GetManipulatedItem()
local unit u = GetTriggerUnit()
local integer itemId = GetItemTypeId(itm)
local thistype newItem = instanceStorage.integer[itemId]
local integer i
local integer slot
local item indexItem
local thistype baseline = newItem.baselineInstance
local integer levelCount = 0
local integer levelOverflow = 0
local real x
local real y
if baseline.isUpgradeAutomatic then
if newItem != 0 then
set IH.LIST = baseline.tableInstance
set i = 0
loop
set i = i + 1
exitwhen i >= baseline.maxItemLevels //set the loop to ignore max-levelled items
set slot = 0 //inventory slots start on zero in JASS
loop
set indexItem = UnitItemInSlot(u, slot)
if (indexItem != null) and (GetItemTypeId(indexItem) == IH.LIST.integer[i]) then
set levelCount = levelCount + i
call RemoveItem(indexItem)
endif
set slot = slot + 1
exitwhen slot >= bj_MAX_INVENTORY
endloop
endloop
set indexItem = null
call DisableTrigger(itemChangeTrig)
if newItem.isBaselineItem then
set levelCount = levelCount + 1
endif
set x = GetUnitX(u)
set y = GetUnitY(u)
if levelCount > baseline.maxItemLevels then
set levelOverflow = levelCount - baseline.maxItemLevels
call UnitAddItem(u, CreateItem(IH.LIST.integer[baseline.maxItemLevels], x, y))
loop
if levelOverflow > baseline.maxItemLevels then
call UnitAddItem(u, CreateItem(IH.LIST.integer[baseline.maxItemLevels], x, y))
set levelOverflow = levelOverflow - baseline.maxItemLevels
else
call UnitAddItem(u, CreateItem(IH.LIST.integer[levelOverflow], x, y))
set levelOverflow = 0
endif
exitwhen levelOverflow == 0
endloop
else
call UnitAddItem(u, CreateItem(IH.LIST.integer[levelCount], x, y))
endif
call EnableTrigger(itemChangeTrig)
endif
endif
return true
endmethod
static method addItem takes integer baselineId, integer itemId, integer i returns nothing
local thistype baseline = instanceStorage.integer[baselineId]
local thistype newItem = instanceStorage.integer[itemId]
if baseline != 0 and newItem == 0 then
set IH.LIST = baseline.tableInstance
set IH.LIST.integer[i] = itemId
set newItem = allocate()
set newItem.itemLevel = i
set newItem.tableInstance = IH.LIST
set newItem.isBaselineItem = false
set newItem.baselineInstance = baseline
set newItem.isUpgradeAutomatic = false
set instanceStorage.integer[itemId] = newItem
set baseline.maxItemLevels = baseline.maxItemLevels + 1
endif
endmethod
static method create takes integer itemId, boolean automaticUpgrade returns thistype
local thistype baseline
if instanceStorage.integer[itemId] == 0 then
set IH.LIST = Table.create()
set IH.LIST.integer[0] = itemId
set baseline = allocate()
set baseline.tableInstance = IH.LIST
set baseline.maxItemLevels = 0
set baseline.isBaselineItem = true
set baseline.itemLevel = 1
set baseline.baselineInstance = baseline
set baseline.isUpgradeAutomatic = automaticUpgrade
set instanceStorage.integer[itemId] = baseline
endif
return baseline
endmethod
private static method onInit takes nothing returns nothing
set instanceStorage = Table.create()
call TriggerRegisterAnyUnitEventBJ(itemChangeTrig, EVENT_PLAYER_UNIT_PICKUP_ITEM)
call TriggerAddCondition(itemChangeTrig, function thistype.upgradeItemAutomatic)
endmethod
endstruct
endlibrary
library Table /* made by Bribe, special thanks to Vexorian & Nestharus, version 4.1.0.1.
One map, one hashtable. Welcome to NewTable 4.1.0.1
This newest iteration of Table introduces the new HashTable struct.
You can now instantiate HashTables which enables the use of large
parent and large child keys, just like a standard hashtable. Previously,
the user would have to instantiate a Table to do this on their own which -
while doable - is something the user should not have to do if I can add it
to this resource myself (especially if they are inexperienced).
This library was originally called NewTable so it didn't conflict with
the API of Table by Vexorian. However, the damage is done and it's too
late to change the library name now. To help with damage control, I
have provided an extension library called TableBC, which bridges all
the functionality of Vexorian's Table except for 2-D string arrays &
the ".flush(integer)" method. I use ".flush()" to flush a child hash-
table, because I wanted the API in NewTable to reflect the API of real
hashtables (I thought this would be more intuitive).
API
------------
struct Table
| static method create takes nothing returns Table
| create a new Table
|
| method destroy takes nothing returns nothing
| destroy it
|
| method flush takes nothing returns nothing
| flush all stored values inside of it
|
| method remove takes integer key returns nothing
| remove the value at index "key"
|
| method operator []= takes integer key, $TYPE$ value returns nothing
| assign "value" to index "key"
|
| method operator [] takes integer key returns $TYPE$
| load the value at index "key"
|
| method has takes integer key returns boolean
| whether or not the key was assigned
|
----------------
struct TableArray
| static method operator [] takes integer array_size returns TableArray
| create a new array of Tables of size "array_size"
|
| method destroy takes nothing returns nothing
| destroy it
|
| method flush takes nothing returns nothing
| flush and destroy it
|
| method operator size takes nothing returns integer
| returns the size of the TableArray
|
| method operator [] takes integer key returns Table
| returns a Table accessible exclusively to index "key"
*/
globals
private integer less = 0 //Index generation for TableArrays (below 0).
private integer more = 8190 //Index generation for Tables.
//Configure it if you use more than 8190 "key" variables in your map (this will never happen though).
private hashtable ht = InitHashtable()
private key sizeK
private key listK
endglobals
private struct dex extends array
static method operator size takes nothing returns Table
return sizeK
endmethod
static method operator list takes nothing returns Table
return listK
endmethod
endstruct
private struct handles extends array
method has takes integer key returns boolean
return HaveSavedHandle(ht, this, key)
endmethod
method remove takes integer key returns nothing
call RemoveSavedHandle(ht, this, key)
endmethod
endstruct
private struct agents extends array
method operator []= takes integer key, agent value returns nothing
call SaveAgentHandle(ht, this, key, value)
endmethod
endstruct
//! textmacro NEW_ARRAY_BASIC takes SUPER, FUNC, TYPE
private struct $TYPE$s extends array
method operator [] takes integer key returns $TYPE$
return Load$FUNC$(ht, this, key)
endmethod
method operator []= takes integer key, $TYPE$ value returns nothing
call Save$FUNC$(ht, this, key, value)
endmethod
method has takes integer key returns boolean
return HaveSaved$SUPER$(ht, this, key)
endmethod
method remove takes integer key returns nothing
call RemoveSaved$SUPER$(ht, this, key)
endmethod
endstruct
private module $TYPE$m
method operator $TYPE$ takes nothing returns $TYPE$s
return this
endmethod
endmodule
//! endtextmacro
//! textmacro NEW_ARRAY takes FUNC, TYPE
private struct $TYPE$s extends array
method operator [] takes integer key returns $TYPE$
return Load$FUNC$Handle(ht, this, key)
endmethod
method operator []= takes integer key, $TYPE$ value returns nothing
call Save$FUNC$Handle(ht, this, key, value)
endmethod
method has takes integer key returns boolean
return HaveSavedHandle(ht, this, key)
endmethod
method remove takes integer key returns nothing
call RemoveSavedHandle(ht, this, key)
endmethod
endstruct
private module $TYPE$m
method operator $TYPE$ takes nothing returns $TYPE$s
return this
endmethod
endmodule
//! endtextmacro
//Run these textmacros to include the entire hashtable API as wrappers.
//Don't be intimidated by the number of macros - Vexorian's map optimizer is
//supposed to kill functions which inline (all of these functions inline).
//! runtextmacro NEW_ARRAY_BASIC("Real", "Real", "real")
//! runtextmacro NEW_ARRAY_BASIC("Boolean", "Boolean", "boolean")
//! runtextmacro NEW_ARRAY_BASIC("String", "Str", "string")
//New textmacro to allow table.integer[] syntax for compatibility with textmacros that might desire it.
//! runtextmacro NEW_ARRAY_BASIC("Integer", "Integer", "integer")
//! runtextmacro NEW_ARRAY("Player", "player")
//! runtextmacro NEW_ARRAY("Widget", "widget")
//! runtextmacro NEW_ARRAY("Destructable", "destructable")
//! runtextmacro NEW_ARRAY("Item", "item")
//! runtextmacro NEW_ARRAY("Unit", "unit")
//! runtextmacro NEW_ARRAY("Ability", "ability")
//! runtextmacro NEW_ARRAY("Timer", "timer")
//! runtextmacro NEW_ARRAY("Trigger", "trigger")
//! runtextmacro NEW_ARRAY("TriggerCondition", "triggercondition")
//! runtextmacro NEW_ARRAY("TriggerAction", "triggeraction")
//! runtextmacro NEW_ARRAY("TriggerEvent", "event")
//! runtextmacro NEW_ARRAY("Force", "force")
//! runtextmacro NEW_ARRAY("Group", "group")
//! runtextmacro NEW_ARRAY("Location", "location")
//! runtextmacro NEW_ARRAY("Rect", "rect")
//! runtextmacro NEW_ARRAY("BooleanExpr", "boolexpr")
//! runtextmacro NEW_ARRAY("Sound", "sound")
//! runtextmacro NEW_ARRAY("Effect", "effect")
//! runtextmacro NEW_ARRAY("UnitPool", "unitpool")
//! runtextmacro NEW_ARRAY("ItemPool", "itempool")
//! runtextmacro NEW_ARRAY("Quest", "quest")
//! runtextmacro NEW_ARRAY("QuestItem", "questitem")
//! runtextmacro NEW_ARRAY("DefeatCondition", "defeatcondition")
//! runtextmacro NEW_ARRAY("TimerDialog", "timerdialog")
//! runtextmacro NEW_ARRAY("Leaderboard", "leaderboard")
//! runtextmacro NEW_ARRAY("Multiboard", "multiboard")
//! runtextmacro NEW_ARRAY("MultiboardItem", "multiboarditem")
//! runtextmacro NEW_ARRAY("Trackable", "trackable")
//! runtextmacro NEW_ARRAY("Dialog", "dialog")
//! runtextmacro NEW_ARRAY("Button", "button")
//! runtextmacro NEW_ARRAY("TextTag", "texttag")
//! runtextmacro NEW_ARRAY("Lightning", "lightning")
//! runtextmacro NEW_ARRAY("Image", "image")
//! runtextmacro NEW_ARRAY("Ubersplat", "ubersplat")
//! runtextmacro NEW_ARRAY("Region", "region")
//! runtextmacro NEW_ARRAY("FogState", "fogstate")
//! runtextmacro NEW_ARRAY("FogModifier", "fogmodifier")
//! runtextmacro NEW_ARRAY("Hashtable", "hashtable")
struct Table extends array
// Implement modules for intuitive syntax (tb.handle; tb.unit; etc.)
implement realm
implement integerm
implement booleanm
implement stringm
implement playerm
implement widgetm
implement destructablem
implement itemm
implement unitm
implement abilitym
implement timerm
implement triggerm
implement triggerconditionm
implement triggeractionm
implement eventm
implement forcem
implement groupm
implement locationm
implement rectm
implement boolexprm
implement soundm
implement effectm
implement unitpoolm
implement itempoolm
implement questm
implement questitemm
implement defeatconditionm
implement timerdialogm
implement leaderboardm
implement multiboardm
implement multiboarditemm
implement trackablem
implement dialogm
implement buttonm
implement texttagm
implement lightningm
implement imagem
implement ubersplatm
implement regionm
implement fogstatem
implement fogmodifierm
implement hashtablem
method operator handle takes nothing returns handles
return this
endmethod
method operator agent takes nothing returns agents
return this
endmethod
//set this = tb[GetSpellAbilityId()]
method operator [] takes integer key returns Table
return LoadInteger(ht, this, key) //return this.integer[key]
endmethod
//set tb[389034] = 8192
method operator []= takes integer key, Table tb returns nothing
call SaveInteger(ht, this, key, tb) //set this.integer[key] = tb
endmethod
//set b = tb.has(2493223)
method has takes integer key returns boolean
return HaveSavedInteger(ht, this, key) //return this.integer.has(key)
endmethod
//call tb.remove(294080)
method remove takes integer key returns nothing
call RemoveSavedInteger(ht, this, key) //call this.integer.remove(key)
endmethod
//Remove all data from a Table instance
method flush takes nothing returns nothing
call FlushChildHashtable(ht, this)
endmethod
//local Table tb = Table.create()
static method create takes nothing returns Table
local Table this = dex.list[0]
if this == 0 then
set this = more + 1
set more = this
else
set dex.list[0] = dex.list[this]
call dex.list.remove(this) //Clear hashed memory
endif
debug set dex.list[this] = -1
return this
endmethod
// Removes all data from a Table instance and recycles its index.
//
// call tb.destroy()
//
method destroy takes nothing returns nothing
debug if dex.list[this] != -1 then
debug call BJDebugMsg("Table Error: Tried to double-free instance: " + I2S(this))
debug return
debug endif
call this.flush()
set dex.list[this] = dex.list[0]
set dex.list[0] = this
endmethod
//! runtextmacro optional TABLE_BC_METHODS()
endstruct
//! runtextmacro optional TABLE_BC_STRUCTS()
struct TableArray extends array
//Returns a new TableArray to do your bidding. Simply use:
//
// local TableArray ta = TableArray[array_size]
//
static method operator [] takes integer array_size returns TableArray
local Table tb = dex.size[array_size] //Get the unique recycle list for this array size
local TableArray this = tb[0] //The last-destroyed TableArray that had this array size
debug if array_size <= 0 then
debug call BJDebugMsg("TypeError: Invalid specified TableArray size: " + I2S(array_size))
debug return 0
debug endif
if this == 0 then
set this = less - array_size
set less = this
else
set tb[0] = tb[this] //Set the last destroyed to the last-last destroyed
call tb.remove(this) //Clear hashed memory
endif
set dex.size[this] = array_size //This remembers the array size
return this
endmethod
//Returns the size of the TableArray
method operator size takes nothing returns integer
return dex.size[this]
endmethod
//This magic method enables two-dimensional[array][syntax] for Tables,
//similar to the two-dimensional utility provided by hashtables them-
//selves.
//
//ta[integer a].unit[integer b] = unit u
//ta[integer a][integer c] = integer d
//
//Inline-friendly when not running in debug mode
//
method operator [] takes integer key returns Table
static if DEBUG_MODE then
local integer i = this.size
if i == 0 then
call BJDebugMsg("IndexError: Tried to get key from invalid TableArray instance: " + I2S(this))
return 0
elseif key < 0 or key >= i then
call BJDebugMsg("IndexError: Tried to get key [" + I2S(key) + "] from outside TableArray bounds: " + I2S(i))
return 0
endif
endif
return this + key
endmethod
//Destroys a TableArray without flushing it; I assume you call .flush()
//if you want it flushed too. This is a public method so that you don't
//have to loop through all TableArray indices to flush them if you don't
//need to (ie. if you were flushing all child-keys as you used them).
//
method destroy takes nothing returns nothing
local Table tb = dex.size[this.size]
debug if this.size == 0 then
debug call BJDebugMsg("TypeError: Tried to destroy an invalid TableArray: " + I2S(this))
debug return
debug endif
if tb == 0 then
//Create a Table to index recycled instances with their array size
set tb = Table.create()
set dex.size[this.size] = tb
endif
call dex.size.remove(this) //Clear the array size from hash memory
set tb[this] = tb[0]
set tb[0] = this
endmethod
private static Table tempTable
private static integer tempEnd
//Avoids hitting the op limit
private static method clean takes nothing returns nothing
local Table tb = .tempTable
local integer end = tb + 0x1000
if end < .tempEnd then
set .tempTable = end
call ForForce(bj_FORCE_PLAYER[0], function thistype.clean)
else
set end = .tempEnd
endif
loop
call tb.flush()
set tb = tb + 1
exitwhen tb == end
endloop
endmethod
//Flushes the TableArray and also destroys it. Doesn't get any more
//similar to the FlushParentHashtable native than this.
//
method flush takes nothing returns nothing
debug if this.size == 0 then
debug call BJDebugMsg("TypeError: Tried to flush an invalid TableArray instance: " + I2S(this))
debug return
debug endif
set .tempTable = this
set .tempEnd = this + this.size
call ForForce(bj_FORCE_PLAYER[0], function thistype.clean)
call this.destroy()
endmethod
endstruct
//NEW: Added in Table 4.0. A fairly simple struct but allows you to do more
//than that which was previously possible.
struct HashTable extends array
//Enables myHash[parentKey][childKey] syntax.
//Basically, it creates a Table in the place of the parent key if
//it didn't already get created earlier.
method operator [] takes integer index returns Table
local Table t = Table(this)[index]
if t == 0 then
set t = Table.create()
set Table(this)[index] = t //whoops! Forgot that line. I'm out of practice!
endif
return t
endmethod
//You need to call this on each parent key that you used if you
//intend to destroy the HashTable or simply no longer need that key.
method remove takes integer index returns nothing
local Table t = Table(this)[index]
if t != 0 then
call t.destroy()
call Table(this).remove(index)
endif
endmethod
//Added in version 4.1
method has takes integer index returns boolean
return Table(this).has(index)
endmethod
//HashTables are just fancy Table indices.
method destroy takes nothing returns nothing
call Table(this).destroy()
endmethod
//Like I said above...
static method create takes nothing returns thistype
return Table.create()
endmethod
endstruct
endlibrary
scope SetupItemLevels initializer init
private function Actions takes nothing returns boolean
local integer baseline
//Shadow Orb
set baseline = 'sorf'
call ItemHierarchy.create(baseline, true)
call ItemHierarchy.addItem(baseline, 'sor1', 1)
call ItemHierarchy.addItem(baseline, 'sor2', 2)
call ItemHierarchy.addItem(baseline, 'sor3', 3)
call ItemHierarchy.addItem(baseline, 'sor4', 4)
call ItemHierarchy.addItem(baseline, 'sor5', 5)
call ItemHierarchy.addItem(baseline, 'sor6', 6)
call ItemHierarchy.addItem(baseline, 'sor7', 7)
call ItemHierarchy.addItem(baseline, 'sor8', 8)
call ItemHierarchy.addItem(baseline, 'sor9', 9)
call ItemHierarchy.addItem(baseline, 'sora', 10)
//Soul Gem
set baseline = 'sg00'
call ItemHierarchy.create(baseline, false)
call ItemHierarchy.addItem(baseline, 'sg01', 1)
call ItemHierarchy.addItem(baseline, 'sg02', 2)
call ItemHierarchy.addItem(baseline, 'sg03', 3)
call ItemHierarchy.addItem(baseline, 'sg04', 4)
call ItemHierarchy.addItem(baseline, 'sg05', 5)
return false
endfunction
private function init takes nothing returns nothing
local trigger trig = CreateTrigger()
call TriggerRegisterTimerEvent(trig, 0., false)
call TriggerAddCondition(trig, function Actions)
set trig = null
endfunction
endscope
library SoulGemOnKill initializer init requires ItemHierarchy
globals
private trigger onKillTrig = CreateTrigger()
private trigger onReviveTrig = CreateTrigger()
endglobals
private function ActionsDeath takes nothing returns boolean
local unit u = GetKillingUnit()
local unit target = GetDyingUnit()
local boolean exitLoop = false
local integer array itemId
local integer iSetLimit
local integer iSet //Loops through item sets that level up on kill
local integer i //Loops through every level of a set
local integer slot //Loops through inventory slots
local item indexItem
local ItemHierarchy this
set itemId[1] = 'sg00'
set itemId[2] = 'sorf'
set iSetLimit = 2
if u != target then //this prevents levels from being gained if your hero somehow killed himself
set iSet = 0
loop
set iSet = iSet + 1
exitwhen iSet > iSetLimit
set this = GetHierarchyInstance(itemId[iSet])
set IH.LIST = GetHierarchyTable(itemId[iSet])
set i = this.maxItemLevels - 1
loop
set slot = 0 //inventory slots start on zero in JASS
loop
set indexItem = UnitItemInSlot(u, slot)
if (indexItem != null) and (GetItemTypeId(indexItem) == IH.LIST.integer[i]) then
set indexItem = ItemHierarchy.setItemLevel(u, indexItem, i + 1)
set exitLoop = true
endif
set slot = slot + 1
exitwhen slot >= bj_MAX_INVENTORY or exitLoop
endloop
exitwhen i == 0 or exitLoop
set i = i - 1
endloop
endloop
endif
set u = null
set target = null
set indexItem = null
return false
endfunction
//Downgrading the items must be done on revive because the moment the hero dies, its
//inventory becomes inaccessible
private function ActionsRevive takes nothing returns boolean
local unit u = GetRevivingUnit()
local boolean exitLoop = false
local integer array itemId
local item indexItem
local integer iSetLimit
local integer iSet //Loops through item sets that level up on kill
local integer i //Loops through every level of a set
local integer slot //Loops through inventory slots
local ItemHierarchy this
set itemId[1] = 'sg00'
set itemId[2] = 'sorf'
set iSetLimit = 2
set iSet = 0
loop
set iSet = iSet + 1
exitwhen iSet > iSetLimit
set this = GetHierarchyInstance(itemId[iSet])
set IH.LIST = GetHierarchyTable(itemId[iSet])
set i = this.maxItemLevels
loop
set slot = 0 //inventory slots start on zero in JASS
loop
set indexItem = UnitItemInSlot(u, slot)
if (indexItem != null) and (GetItemTypeId(indexItem) == IH.LIST.integer[i]) then
set indexItem = ItemHierarchy.setItemLevel(u, indexItem, i - 1)
set exitLoop = true
endif
set slot = slot + 1
exitwhen slot >= bj_MAX_INVENTORY or exitLoop
endloop
exitwhen i == 0 or exitLoop
set i = i - 1
endloop
endloop
set u = null
set indexItem = null
return false
endfunction
private function init takes nothing returns nothing
call TriggerRegisterAnyUnitEventBJ(onKillTrig, EVENT_PLAYER_UNIT_DEATH)
call TriggerAddCondition(onKillTrig, function ActionsDeath)
call TriggerRegisterAnyUnitEventBJ(onReviveTrig, EVENT_PLAYER_HERO_REVIVE_FINISH)
call TriggerAddCondition(onReviveTrig, function ActionsRevive)
endfunction
endlibrary
scope SoulGemOnKillStandlone initializer init
globals
private trigger onKillTrig = CreateTrigger()
private trigger onReviveTrig = CreateTrigger()
endglobals
private function ActionsDeath takes nothing returns boolean
local unit u = GetKillingUnit()
local unit target = GetDyingUnit()
local boolean exitLoop = false
local integer array itemId
local integer i
local integer slot
local item indexItem
set itemId[1] = 'sg01'
set itemId[2] = 'sg02'
set itemId[3] = 'sg03'
set itemId[4] = 'sg04'
set itemId[5] = 'sg05'
if u != target then //this prevents levels from being gained if your hero somehow killed himself
set i = 4
loop
set slot = 0 //inventory slots start on zero in JASS
loop
set indexItem = UnitItemInSlot(u, slot)
if (indexItem != null) and (GetItemTypeId(indexItem) == itemId[i]) then
call RemoveItem(indexItem)
call UnitAddItemToSlotById(u, itemId[i + 1], slot)
set exitLoop = true
endif
set slot = slot + 1
exitwhen slot >= bj_MAX_INVENTORY or exitLoop
endloop
exitwhen i == 0 or exitLoop
set i = i - 1
endloop
endif
set u = null
set target = null
set indexItem = null
return false
endfunction
//Downgrading the items must be done on revive because the moment the hero dies, its
//inventory becomes inaccessible
private function ActionsRevive takes nothing returns boolean
local unit u = GetRevivingUnit()
local boolean exitLoop = false
local integer array itemId
local item indexItem
local integer slot
local integer i
set itemId[1] = 'sg01'
set itemId[2] = 'sg02'
set itemId[3] = 'sg03'
set itemId[4] = 'sg04'
set itemId[5] = 'sg05'
set i = 5
loop
set slot = 0 //inventory slots start on zero in JASS
loop
set indexItem = UnitItemInSlot(u, slot)
if (indexItem != null) and (GetItemTypeId(indexItem) == itemId[i]) then
call RemoveItem(indexItem)
call UnitAddItemToSlotById(u, itemId[i - 1], slot)
set exitLoop = true
endif
set slot = slot + 1
exitwhen slot >= bj_MAX_INVENTORY or exitLoop
endloop
exitwhen i == 0 or exitLoop
set i = i - 1
endloop
set u = null
set indexItem = null
return false
endfunction
private function init takes nothing returns nothing
call TriggerRegisterAnyUnitEventBJ(onKillTrig, EVENT_PLAYER_UNIT_DEATH)
call TriggerAddCondition(onKillTrig, function ActionsDeath)
call TriggerRegisterAnyUnitEventBJ(onReviveTrig, EVENT_PLAYER_HERO_REVIVE_FINISH)
call TriggerAddCondition(onReviveTrig, function ActionsRevive)
endfunction
endscope
scope SoulGemNomNom initializer init
globals
constant integer useslot1 = 852008
constant integer useslot2 = 852009
constant integer useslot3 = 852010
constant integer useslot4 = 852011
constant integer useslot5 = 852012
constant integer useslot6 = 852013
private Table globalList
endglobals
struct SG
static Table STORAGE
endstruct
private function Actions takes nothing returns nothing
local integer issuedOrder = GetIssuedOrderId()
local unit u = GetOrderedUnit()
local unit target = GetOrderTargetUnit()
local integer i = 0
local integer slot
local boolean exitLoop = false
local item currentItem
local integer currentItemId
local integer currentItemTypeId
local item newItem
local integer baselineInstance
call BJDebugMsg("54ng73895")
if issuedOrder >= useslot1 and issuedOrder <= useslot6 then
loop
if issuedOrder == useslot1 + i then
set slot = i
set exitLoop = true
endif
exitwhen i >= bj_MAX_INVENTORY or exitLoop
set i = i + 1
endloop
set currentItem = UnitItemInSlot(u, slot)
set currentItemId = GetHandleId(currentItem)
set currentItemTypeId = GetItemTypeId(currentItem)
if currentItemTypeId == 'sg01' or currentItemTypeId == 'sg02' or currentItemTypeId == 'sg03' or currentItemTypeId == 'sg04' then
set SG.STORAGE = globalList.integer[currentItemId]
if SG.STORAGE == 0 then
set SG.STORAGE = Table.create()
endif
set i = GetItemHierarchyLevel(currentItemId)
set newItem = ItemHierarchy.setItemLevel(u, currentItem, i + 1)
set SG.STORAGE.unit[i + 1] = target
call ShowUnit(target, false)
call globalList.remove(currentItemId)
set globalList.integer[GetHandleId(newItem)] = SG.STORAGE
endif
set currentItem = null
set newItem = null
endif
set u = null
set target = null
endfunction
//===========================================================================
private function init takes nothing returns nothing
call RegisterOrderEvent(useslot1, function Actions)
call RegisterOrderEvent(useslot2, function Actions)
call RegisterOrderEvent(useslot3, function Actions)
call RegisterOrderEvent(useslot4, function Actions)
call RegisterOrderEvent(useslot5, function Actions)
call RegisterOrderEvent(useslot5, function Actions)
endfunction
endscope
//============================================================================
// OrderEvent by Bribe, special thanks to Nestharus and Azlier, version 3.0.1.1
//
// API
// ---
// RegisterOrderEvent(integer orderId, code eventFunc)
// RegisterAnyOrderEvent(code eventFunc) //Runs for point/target/instant for any order
//
// Requires
// --------
// RegisterPlayerUnitEvent: http://www.hiveworkshop.com/threads/snippet-registerevent-pack.250266/
// Table: http://www.hiveworkshop.com/forums/showthread.php?t=188084
//
library OrderEvent requires RegisterPlayerUnitEvent, Table
globals
private Table t = 0
endglobals
//============================================================================
function RegisterAnyOrderEvent takes code c returns nothing
static if RPUE_VERSION_NEW then
call RegisterAnyPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, c)
call RegisterAnyPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, c)
call RegisterAnyPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, c)
else
call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, c)
call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, c)
call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, c)
endif
endfunction
//============================================================================
private function OnOrder takes nothing returns nothing
call TriggerEvaluate(t.trigger[GetIssuedOrderId()])
endfunction
//============================================================================
function RegisterOrderEvent takes integer orderId, code c returns nothing
local trigger trig
if integer(t) == 0 then
set t = Table.create()
call RegisterAnyOrderEvent(function OnOrder)
endif
set trig = t.trigger[orderId]
if trig == null then
set trig = CreateTrigger()
set t.trigger[orderId] = trig
endif
call TriggerAddCondition(trig, Filter(c))
set trig = null
endfunction
endlibrary
/**************************************************************
*
* RegisterPlayerUnitEvent
* v5.1.0.1
* By Magtheridon96
*
* I would like to give a special thanks to Bribe, azlier
* and BBQ for improving this library. For modularity, it only
* supports player unit events.
*
* Functions passed to RegisterPlayerUnitEvent must either
* return a boolean (false) or nothing. (Which is a Pro)
*
* Warning:
* --------
*
* - Don't use TriggerSleepAction inside registered code.
* - Don't destroy a trigger unless you really know what you're doing.
*
* API:
* ----
*
* - function RegisterPlayerUnitEvent takes playerunitevent whichEvent, code whichFunction returns nothing
* - Registers code that will execute when an event fires.
* - function RegisterPlayerUnitEventForPlayer takes playerunitevent whichEvent, code whichFunction, player whichPlayer returns nothing
* - Registers code that will execute when an event fires for a certain player.
* - function GetPlayerUnitEventTrigger takes playerunitevent whichEvent returns trigger
* - Returns the trigger corresponding to ALL functions of a playerunitevent.
*
**************************************************************/
library RegisterPlayerUnitEvent // Special Thanks to Bribe and azlier
globals
private trigger array t
endglobals
function RegisterPlayerUnitEvent takes playerunitevent p, code c returns nothing
local integer i = GetHandleId(p)
local integer k = 15
if t[i] == null then
set t[i] = CreateTrigger()
loop
call TriggerRegisterPlayerUnitEvent(t[i], Player(k), p, null)
exitwhen k == 0
set k = k - 1
endloop
endif
call TriggerAddCondition(t[i], Filter(c))
endfunction
function RegisterPlayerUnitEventForPlayer takes playerunitevent p, code c, player pl returns nothing
local integer i = 16 * GetHandleId(p) + GetPlayerId(pl)
if t[i] == null then
set t[i] = CreateTrigger()
call TriggerRegisterPlayerUnitEvent(t[i], pl, p, null)
endif
call TriggerAddCondition(t[i], Filter(c))
endfunction
function GetPlayerUnitEventTrigger takes playerunitevent p returns trigger
return t[GetHandleId(p)]
endfunction
endlibrary