Triggers

//TESH.scrollpos=0
//TESH.alwaysfold=0
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
//~~ Timer32 ~~ By Jesus4Lyf ~~ Version 1.06 ~~
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
//
//  What is Timer32?
//         - Timer32 implements a fully optimised timer loop for a struct.
//         - Instances can be added to the loop, which will call .periodic every
//           PERIOD until .stopPeriodic() is called.
//
//    =Pros=
//         - Efficient.
//         - Simple.
//
//    =Cons=
//         - Only allows one period.
//         - The called method must be named ".periodic".
//
//    Methods:
//         - struct.startPeriodic()
//         - struct.stopPeriodic()
//
//         - private method periodic takes nothing returns nothing
//
//           This must be defined in structs that implement Periodic Module.
//           It will be executed by the module every PERIOD until .stopPeriodic() is called.
//           Put "implement T32x" BELOW this method.
//
//    Modules:
//         - T32x
//           Has no safety on .stopPeriodic or .startPeriodic (except debug messages
//           to warn).
//
//         - T32xs
//           Has safety on .stopPeriodic and .startPeriodic so if they are called
//           multiple times, or while otherwise are already stopped/started respectively,
//           no error will occur, the call will be ignored.
//
//         - T32
//           The original, old version of the T32 module. This remains for backwards
//           compatability, and is deprecated. The periodic method must return a boolean,
//           false to continue running or true to stop.
//
//  Details:
//         - Uses one timer.
//
//         - Do not, within a .periodic method, follow a .stopPeriodic call with a
//           .startPeriodic call.
//
//  How to import:
//         - Create a trigger named T32.
//         - Convert it to custom text and replace the whole trigger text with this.
//
//  Thanks:
//         - Infinitegde for finding a bug in the debug message that actually altered
//           system operation (when in debug mode).
//
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
library T32 initializer OnInit
    globals
        public constant real PERIOD=0.03125
        public constant integer FPS=R2I(1/PERIOD)
        public integer Tick=0 // very useful.
        
//==============================================================================
        private trigger Trig=CreateTrigger()
    endglobals
    
    //==============================================================================
    // The standard T32 module, T32x.
    //
    module T32x
        private thistype next
        private thistype prev
        
        private static method PeriodicLoop takes nothing returns boolean
            local thistype this=thistype(0).next
            loop
                exitwhen this==0
                call this.periodic()
                set this=this.next
            endloop
            return false
        endmethod

        method startPeriodic takes nothing returns nothing
            debug if this.prev!=0 or thistype(0).next==this then
            debug   call BJDebugMsg("T32 ERROR: Struct #"+I2S(this)+" had startPeriodic called while already running!")
            debug endif
            set thistype(0).next.prev=this
            set this.next=thistype(0).next
            set thistype(0).next=this
            set this.prev=thistype(0)
        endmethod
        
        method stopPeriodic takes nothing returns nothing
            debug if this.prev==0 and thistype(0).next!=this then
            debug   call BJDebugMsg("T32 ERROR: Struct #"+I2S(this)+" had stopPeriodic called while not running!")
            debug endif
            // This is some real magic.
            set this.prev.next=this.next
            set this.next.prev=this.prev
            // This will even work for the starting element.
            debug set this.prev=0
        endmethod
        
        private static method onInit takes nothing returns nothing
            call TriggerAddCondition(Trig,Condition(function thistype.PeriodicLoop))
        endmethod
    endmodule
    
    //==============================================================================
    // The standard T32 module with added safety checks on .startPeriodic() and
    // .stopPeriodic(), T32xs.
    //
    module T32xs
        private thistype next
        private thistype prev
        private boolean runningPeriodic
        
        private static method PeriodicLoop takes nothing returns boolean
            local thistype this=thistype(0).next
            loop
                exitwhen this==0
                call this.periodic()
                set this=this.next
            endloop
            return false
        endmethod

        method startPeriodic takes nothing returns nothing
            if not this.runningPeriodic then
                set thistype(0).next.prev=this
                set this.next=thistype(0).next
                set thistype(0).next=this
                set this.prev=thistype(0)
                
                set this.runningPeriodic=true
            endif
        endmethod
        
        method stopPeriodic takes nothing returns nothing
            if this.runningPeriodic then
                // This is some real magic.
                set this.prev.next=this.next
                set this.next.prev=this.prev
                // This will even work for the starting element.
                
                set this.runningPeriodic=false
            endif
        endmethod
        
        private static method onInit takes nothing returns nothing
            call TriggerAddCondition(Trig,Condition(function thistype.PeriodicLoop))
        endmethod
    endmodule
    
    //==============================================================================
    // The original T32 module, for backwards compatability only.
    //
    module T32 // deprecated.
        private thistype next
        private thistype prev
        
        private static method PeriodicLoop takes nothing returns boolean
            local thistype this=thistype(0).next
            loop
                exitwhen this==0
                if this.periodic() then
                    // This is some real magic.
                    set this.prev.next=this.next
                    set this.next.prev=this.prev
                    // This will even work for the starting element.
                    debug set this.prev=0
                endif
                set this=this.next
            endloop
            return false
        endmethod

        method startPeriodic takes nothing returns nothing
            debug if this.prev!=0 or thistype(0).next==this then
            debug   call BJDebugMsg("T32 ERROR: Struct #"+I2S(this)+" had startPeriodic called while already running!")
            debug endif
            set thistype(0).next.prev=this
            set this.next=thistype(0).next
            set thistype(0).next=this
            set this.prev=thistype(0)
        endmethod
        
        private static method onInit takes nothing returns nothing
            call TriggerAddCondition(Trig,Condition(function thistype.PeriodicLoop))
        endmethod
    endmodule
    
    //==============================================================================
    // System Core.
    //
    private function OnExpire takes nothing returns nothing
        set Tick=Tick+1
        call TriggerEvaluate(Trig)
    endfunction
    
    private function OnInit takes nothing returns nothing
        call TimerStart(CreateTimer(),PERIOD,true,function OnExpire)
    endfunction
endlibrary

//TESH.scrollpos=0
//TESH.alwaysfold=0
/**************************************************************
*
*   RegisterPlayerUnitEvent
*   v4.2.0.0
*   By Magtheridon96
*
*   I would like to give a special thanks to Bribe, azlier
*   and BBQ for improving this library. For modularity, it only 
*   supports player unit events.
*
*   Functions passed to RegisterPlayerUnitEvent must
*   return false. They can return nothing as well.
*
*   Disclaimer:
*   -----------
*
*       - Don't use TriggerSleepAction inside registered code.
*
*      API:
*      ----
*
*       function RegisterPlayerUnitEvent
*           takes
*               playerunitevent whichEvent  :   The event you would like to register
*               code whichFunction          :   The code you would like to register
*           returns
*               nothing
*
*           - Registers code that will execute when an event fires.
*
**************************************************************/
library RegisterPlayerUnitEvent // Special Thanks to Bribe and azlier
    globals
        private trigger array t
    endglobals
    
    function RegisterPlayerUnitEvent takes playerunitevent p, code c returns nothing
        local integer i = GetHandleId(p)
        local integer k = 15
        if t[i] == null then
            set t[i] = CreateTrigger()
            loop
                call TriggerRegisterPlayerUnitEvent(t[i], Player(k), p, null)
                exitwhen k == 0
                set k = k - 1
            endloop
        endif
        call TriggerAddCondition(t[i], Filter(c))
    endfunction
endlibrary

//TESH.scrollpos=87
//TESH.alwaysfold=0
/*
=====Ignition v1.4
=====Made by: Mckill2009

REQUIRES:
- Jass New Gen Pack (JNGP) by Vexorian
- T32 by Jesus4Lyf
- RegisterPlayerUnitEvent by Magtheridon96

HOW TO USE:
- Make a trigger and convert to custom text via EDIT >>> CONVERT CUSTOM TEXT
- Copy ALL that is written here and overwrite the existing texts in the custom text
- Copy the necessary libraries (T32 and RegisterPlayerUnitEvent)
- Replace the raw code as stated below if necessary...
- You can view the raw codes by pressing CTRL+B in the object editor
*/

library Ignition uses T32, RegisterPlayerUnitEvent

globals
    private constant integer            SPELL_ID = 'A000' //spell raw code
    //Configurables 
    private constant real                    AOE = 90 //highly recommended
    private constant real               GAP_DIST = 9 //the bigger this, the longer the line
    private constant real              SFX_SPEED = 0.1 //lower value will cause lag, this is recommended
    private constant attacktype              ATK = ATTACK_TYPE_PIERCE
    private constant damagetype              DMG = DAMAGE_TYPE_FIRE
    private constant string                  SFX = "Objects\\Spawnmodels\\Other\\NeutralBuildingExplosion\\NeutralBuildingExplosion.mdl"
    private constant string                  LIG = "DRAL"
    //Not configurable
    private location LOC = Location(0,0)
endglobals

//Configurables:
private constant function GetDamage takes integer i returns real
    return 10 + i * 15.
endfunction

private constant function GetDuration takes integer i returns real
    return 2 + i * 2.
endfunction
//End of Configurables:

//Never touch the code below unless you know what you're doing
private constant function UnitAlive takes unit u returns boolean
    return not IsUnitType(u, UNIT_TYPE_DEAD)
endfunction

private function GetUnitZ takes unit u returns real
    call MoveLocation(LOC, GetUnitX(u), GetUnitY(u)) 
    return GetLocationZ(LOC) + GetUnitFlyHeight(u)
endfunction

private struct IG
    unit caster
    real effectgap
    real duration
    real damage
    real maxdist
    lightning lig
    
    method periodic takes nothing returns nothing
        local unit u
        local real x 
        local real y
        local real angle 
        local real dist = 0
        if .duration > 0 and UnitAlive(.caster) then
            set angle = GetUnitFacing(.caster) * bj_DEGTORAD
            set .duration = .duration - T32_PERIOD
            loop
                set dist = dist + AOE
                set x = GetUnitX(.caster) + dist * Cos(angle)
                set y = GetUnitY(.caster) + dist * Sin(angle)
                call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, AOE, null)  
                loop
                    set u = FirstOfGroup(bj_lastCreatedGroup)
                    exitwhen u==null
                    if UnitAlive(u) and not IsUnitType(u, UNIT_TYPE_FLYING) and IsUnitEnemy(.caster, GetOwningPlayer(u)) then
                        call UnitDamageTarget(.caster, u, .damage, false, false, ATK, DMG, null)
                    endif
                    call GroupRemoveUnit(bj_lastCreatedGroup, u)
                endloop
                exitwhen dist >= .maxdist
            endloop
            call MoveLightningEx(.lig, true, GetUnitX(.caster), GetUnitY(.caster), GetUnitZ(.caster)+100, x, y, GetUnitZ(.caster)+100)
            //To avoid lag
            set .effectgap = .effectgap + T32_PERIOD
            if .effectgap >= SFX_SPEED then
                set .effectgap = 0
                call DestroyEffect(AddSpecialEffect(SFX, x, y))
            endif
        else
            call DestroyLightning(.lig)
            call .stopPeriodic()
            call .destroy()              
        endif
    endmethod
    
    implement T32x
    
    private static method create takes unit u returns thistype
        local thistype this = thistype.allocate()
        local integer level = GetUnitAbilityLevel(u, SPELL_ID)     
        set .caster = u
        set .duration = GetDuration(level)
        set .damage = GetDamage(level) * T32_PERIOD
        set .lig = AddLightning(LIG, true, 0, 0, 0, 0) 
        set .maxdist = AOE * GAP_DIST
        set .effectgap = 0
        call .startPeriodic()
        return this
    endmethod

    private static method cond takes nothing returns boolean
        if GetSpellAbilityId()==SPELL_ID then
            call IG.create(GetTriggerUnit())
        endif
        return false
    endmethod

    private static method onInit takes nothing returns nothing
        call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_SPELL_EFFECT, function thistype.cond)
    endmethod

endstruct

endlibrary