• Listen to a special audio message from Bill Roper to the Hive Workshop community (Bill is a former Vice President of Blizzard Entertainment, Producer, Designer, Musician, Voice Actor) 🔗Click here to hear his message!
  • Read Evilhog's interview with Gregory Alper, the original composer of the music for WarCraft: Orcs & Humans 🔗Click here to read the full interview.

Triggers

Holyconversionby1)ark_NiTev1.20.w3x
Variables
Holy Conversion
Holy Conversion
What to Copy
Spell
Dies
Do Not Copy
X
Enter map-specific custom script code below. This text will be included in the map script after variables are declared and before any trigger code.
Name Type is_array initial_value
1)ark_NiTe's Zephyr Challenge #2 Entry: Holy Conversion (100% Multi-Instanceable & Leakless)

*To import this spell in your map, recreate all of the variables, copy the custom units, abilities, buffs FIRST, and then triggers.
Make sure you import the triggers last and do not miss anything or the spell may not work correctly!*

------------------------------------------------------------------

*****+Also, you will want to pay close attention to the constant functions because the rawcodes will likely change for you+*****

ex.) constant function Divine_ID takes nothing returns integer
return 'h001' // Divine Knight unit rawcode.
endfunction

The xxxx (e.g. h001) value will most likely change for you so pay close attention to make sure you use your maps rawcode for the spells.

All of the constant functions are the very first part of the script and can be found in the "Spell" trigger.

How to locate the raw code:

+Open up the Object Editor and find the Ability or Unit you need to replace the raw code for
+On the menu bar, click on View and then scroll down and click on Display Objects as Raw Data.
+Find the script or trigger that involves the raw code and the first four letters/numbers you see are the rawcode of the Ability or Unit.
+Replace the raw code (eg. 'h001') with the rawcode of the Ability or Unit.

+Remember to do this for all of the scripts/triggers that use a raw code

------------------------------------------------------------------


Multi-Instanceability:

This spell is completely Multi-Instanceable, so you do not need to worry about it not working if given to more than one hero.
-What to copy:

Custom Human Units:

+Dummy
+Divine Knight
+Holy Spirit
+Divya

Custom Abilities:

(Human)
+Holy Burst
+Blinding Light

(Night Elf)
+Holy Conversion

(Neutral Hostile)
+Holy Spirit (Holy Conversion)
+Devotion Aura (Divine Knight)

Custom Buffs:

(Human)
+Holy Spirit

(Special)
+Holy Conversion
+Blinded

Variables:

Point
NearbyEnemyUDUnits
NearbyUnits
This part of the spell creates the Special Effects, replaces the targeted unit with a Divine Knight, and adds the expiration timer to the Knight. 
//TESH.scrollpos=35
//TESH.alwaysfold=0
//==================================================================================================================================
// Start of constants. These will need to be changed by you. They provide the user with easier implementing//changing of the spell's rawcodes and effects.
//==================================================================================================================================

constant function Divine_ID takes nothing returns integer
    return 'h001' // Divine Knight unit rawcode.
endfunction

constant function Dummy_ID takes nothing returns integer
    return 'h002' // Dummy Unit rawcode.
endfunction

constant function Spirit_ID takes nothing returns integer
    return 'h003' // Spirit Knight unit rawcode.
endfunction

constant function Holy_ID takes nothing returns integer
    return 'A000' // Holy Spirit ability rawcode.
endfunction

constant function Burst_ID takes nothing returns integer
    return 'A001' // Holy Burst ability rawcode.
endfunction

constant function Conversion_ID takes nothing returns integer
    return 'A003' // Holy Conversion ability rawcode.
endfunction

constant function Blind_ID takes nothing returns integer
    return 'A005' // Blinding Light ability rawcode.
endfunction

//==================================================================================================================================
// End of constants. Do not touch anything below this unless you are familiar with JASS.
//==================================================================================================================================

function Trig_Spell_Copy_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == Conversion_ID()
endfunction

function Trig_Spell_Copy_Actions takes nothing returns nothing
    // Declares Local Variables
    local effect HandRight
    local effect HandLeft
    local effect Chest
    local effect Overhead
    local unit t = GetSpellTargetUnit()
    local unit dk
    local real x = GetUnitX(t)
    local real y = GetUnitY(t)
    // Pauses/Replaces the targeted unit
    call PauseUnit( t, true )
    call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Human\\Resurrect\\ResurrectTarget.mdl", x, y))
    call ShowUnit(t, false)
    // Creates Divine Knight
    set dk = CreateUnit(GetOwningPlayer(t), Divine_ID(), x, y, GetUnitFacing(t))
    call SetUnitOwner( dk, GetOwningPlayer(t), true )
    call UnitApplyTimedLife(dk, 'BTLF', 45.00)
    call RemoveUnit(t)
    set t = null
    // Adds Special Effects onto the Divine Knight
    set HandRight = AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\FaerieFire\\FaerieFireTarget.mdl",dk,"hand, right")
    set HandLeft = AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\FaerieFire\\FaerieFireTarget.mdl",dk,"hand, left")
    set Chest = AddSpecialEffectTarget("Abilities\\Spells\\Human\\DivineShield\\DivineShieldTarget.mdl",dk,"origin")
    set Overhead = AddSpecialEffectTarget("Abilities\\Spells\\Human\\InnerFire\\InnerFireTarget.mdl",dk,"overhead")
    set dk = null
    call TriggerSleepAction( 45.00 )
    // Destroys the Special Effects that were attached the Divine Knight
    call DestroyEffect( HandRight )
    set HandRight = null
    call DestroyEffect( HandLeft )
    set HandLeft = null
    call DestroyEffect( Chest )
    set Chest = null
    call DestroyEffect( Overhead )
    set Overhead = null
endfunction

//===========================================================================
function InitTrig_Spell takes nothing returns nothing
    set gg_trg_Spell = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spell, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Spell, Condition( function Trig_Spell_Copy_Conditions ) )
    call TriggerAddAction( gg_trg_Spell, function Trig_Spell_Copy_Actions )
endfunction
This part of the spell destroys the Special Effects that were attached to the Divine Knight, and also casts Holy Burst on up to
16 surrounding allied non-Undead units and Blinding Light on up to 16 enemy Undead units.
//TESH.scrollpos=36
//TESH.alwaysfold=0
function Trig_Dies_Conditions takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) == Divine_ID()
endfunction

function Holy_Filter_B takes nothing returns boolean
    return IsPlayerEnemy(GetOwningPlayer(GetTriggerUnit()), GetOwningPlayer(GetFilterUnit())) == true and GetUnitRace(GetFilterUnit()) == RACE_UNDEAD and IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) != true
endfunction

function Holy_Filter_A takes nothing returns boolean
    return IsPlayerEnemy(GetOwningPlayer(GetTriggerUnit()), GetOwningPlayer(GetFilterUnit())) != true and GetUnitRace(GetFilterUnit()) != RACE_UNDEAD and IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) != true
endfunction

function Trig_Dies_Actions takes nothing returns nothing
    // Declares Local/Global Variables
    local effect e
    local unit t = GetTriggerUnit()
    local unit u
    local unit d
    local unit q
    local unit r
    local unit s
    local unit v
    local real x = GetUnitX(t)
    local real y = GetUnitY(t)
    local group g = CreateGroup()
    local group h = CreateGroup()
    local player p = GetOwningPlayer(t)
    local integer i = 0
    // Creates Special Effect
    call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Human\\ReviveHuman\\ReviveHuman.mdl", x, y))
    // Creates a Holy Spirit that ascends to heaven
    set u = CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), Spirit_ID(), x, y, GetUnitFacing(t))
    call UnitApplyTimedLife( u, 'BTLF', 2.5 )
    call SetUnitAnimation( u, "Stand Victory" )
    call UnitAddAbility( u, 'Arav' )
    call UnitRemoveAbility( u, 'Arav' )
    call SetUnitFlyHeight( u, 3000.00, 850.00 )
    set d = CreateUnit(p, Dummy_ID(), x, y, 0.0)
    call UnitApplyTimedLife( d, 'BTLF', 1.50 )
    call UnitApplyTimedLife( t, 'BTLF', 3.00 )
    call UnitAddAbility( d, Holy_ID() )
    call IssueTargetOrder( d, "banish", u )
    // Creates the Unit Groups
    call GroupEnumUnitsInRange(g, x, y, 900.00, Condition(function Holy_Filter_A))
    call GroupEnumUnitsInRange(h, x, y, 900.00, Condition(function Holy_Filter_B))
    loop
        exitwhen i >= 16
        set i = ( i + 1 )
        set q = CreateUnit(p, Dummy_ID(), x, y, 0.0)
        call UnitAddAbility( q, Burst_ID() )
        call UnitApplyTimedLife( q, 'BTLF', 1.00 )
        set s = FirstOfGroup(g)
        call GroupRemoveUnit(g, s)
        call IssueTargetOrder( q, "holybolt", s )
        set r = CreateUnit(p, Dummy_ID(), x, y, 0.0)
        call UnitAddAbility( r, Blind_ID() )
        call UnitApplyTimedLife( r, 'BTLF', 1.00 )
        set v = FirstOfGroup(h)
        call GroupRemoveUnit(h, v)
        call IssueTargetOrder( r, "drunkenhaze", v )
    endloop
    call DestroyGroup(g)
    set g = null
    call DestroyGroup(h)
    set p = null
    set h = null
    set d = null
    set q = null
    set s = null
    set r = null
    set v = null
    set t = null
    set u = null
endfunction

//===========================================================================
function InitTrig_Dies takes nothing returns nothing
    set gg_trg_Dies = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Dies, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddCondition( gg_trg_Dies, Condition( function Trig_Dies_Conditions ) )
    call TriggerAddAction( gg_trg_Dies, function Trig_Dies_Actions )
endfunction
This is just to create the arrow effect over the Peasant so you know to cast the ability on him, since he's useless!
X
Events
Map initialization
Conditions
Actions
Special Effect - Create a special effect attached to the overhead (Unexpected type: 'attachpoint') of Cast On Me! 0005 <gen> using Abilities\Spells\Other\Aneu\AneuCaster.mdl
Top