Triggers

//TESH.scrollpos=39
//TESH.alwaysfold=0
function Trig_Sanguis_Pyxis_Learn_Conditions takes nothing returns boolean
    if ( not ( GetLearnedSkillBJ() == 'A01E' ) ) then
        return false
    endif
    return true
endfunction

function Trig_Sanguis_Pyxis_Learn_Actions takes nothing returns nothing
    
    local unit caster = GetTriggerUnit()
    local integer id = GetUnitUserData(caster)
    local integer id2 = 0
    local integer i = 0
    local real x = GetUnitX(caster)
    local real y = GetUnitY(caster)
    local boolean b = false
    
    if udg_SP_IsLearned[id] == false then
        set udg_SP_IsLearned[id] = true
    endif
    
    if udg_SP_Pyxis[id] == null then
        
        set x = x + Cos(0) * 60
        set y = y + Sin(0) * 60
        
        set udg_SP_Pyxis[id] = CreateUnit(GetOwningPlayer(caster), 'e001', x, y, 270)
        call UnitAddAbility(udg_SP_Pyxis[id], 'A016')
        call SetUnitFlyHeight(udg_SP_Pyxis[id], 60, 0)
        call PauseUnit(udg_SP_Pyxis[id], true)
        
        set id2 = GetUnitUserData(udg_SP_Pyxis[id])
        set udg_SP_Angle[id2] = 0
        set udg_SP_Distance[id2] = 60
        set udg_SP_Source[id2] = caster
        set udg_SP_FloatTextSize[id2] = 6 * 0.0023
        set udg_SP_TextColour[id2] = "|cffff0000"
        
        call GroupAddUnit(udg_SP_Group, udg_SP_Pyxis[id])
        
        set udg_SP_ChargeFloatText[id2] = CreateTextTag()
        call SetTextTagVisibility(udg_SP_ChargeFloatText[id2], true)
        call SetTextTagPos(udg_SP_ChargeFloatText[id2], x, y, 80)
        if udg_SP_ChargeString[id2] == null then
            call SetTextTagText(udg_SP_ChargeFloatText[id2], "***", udg_SP_FloatTextSize[id2])
        else
            call SetTextTagText(udg_SP_ChargeFloatText[id2], udg_SP_ChargeString[id2], udg_SP_FloatTextSize[id2])
        endif
        
        if IsTriggerEnabled(gg_trg_Sanguis_Pyxis_Orbit) == false then
            call EnableTrigger( gg_trg_Sanguis_Pyxis_Orbit )
        endif
        
    else
        set id2 = GetUnitUserData(udg_SP_Pyxis[id])
        set b = true
    endif

    set udg_SP_Level[id2] = GetUnitAbilityLevel(caster, GetLearnedSkill())
    set udg_SP_ChargeLimit[id2] = 2 + udg_SP_Level[id2]
    
    set udg_SP_ChargeString[id2] = "*"
    
    loop
        set i = i + 1
        exitwhen i == udg_SP_ChargeLimit[id2]
        set udg_SP_ChargeString[id2] = udg_SP_ChargeString[id2] + "*"
    endloop
    
    if b == true then
        if udg_SP_Charge[id2] > 0 then
            call SetTextTagText(udg_SP_ChargeFloatText[id2], udg_SP_TextColour[id2] + SubString(udg_SP_ChargeString[id2], 0, udg_SP_Charge[id2]) + "|r" + SubString(udg_SP_ChargeString[id2], udg_SP_Charge[id2], udg_SP_ChargeLimit[id2]), udg_SP_FloatTextSize[id2])
        else
            call SetTextTagText(udg_SP_ChargeFloatText[id2], udg_SP_ChargeString[id2], udg_SP_FloatTextSize[id2])
        endif
    endif
    
endfunction

//===========================================================================
function InitTrig_Sanguis_Pyxis_Learn takes nothing returns nothing
    set gg_trg_Sanguis_Pyxis_Learn = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Sanguis_Pyxis_Learn, EVENT_PLAYER_HERO_SKILL )
    call TriggerAddCondition( gg_trg_Sanguis_Pyxis_Learn, Condition( function Trig_Sanguis_Pyxis_Learn_Conditions ) )
    call TriggerAddAction( gg_trg_Sanguis_Pyxis_Learn, function Trig_Sanguis_Pyxis_Learn_Actions )
endfunction

//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_Sanguis_Pyxis_Revive_Actions takes nothing returns nothing

    local unit caster = GetTriggerUnit()
    local integer id = GetUnitUserData(caster)
    local integer id2 = 0
    local integer i = 0
    local real x = GetUnitX(caster)
    local real y = GetUnitY(caster)
    
    if udg_SP_IsLearned[id] == true then
        set x = x + Cos(0) * 60
        set y = y + Sin(0) * 60
        
        set udg_SP_Pyxis[id] = CreateUnit(GetOwningPlayer(caster), 'e001', x, y, 270)
        call UnitAddAbility(udg_SP_Pyxis[id], 'A016')
        call SetUnitFlyHeight(udg_SP_Pyxis[id], 60, 0)
        call PauseUnit(udg_SP_Pyxis[id], true)
        
        set id2 = GetUnitUserData(udg_SP_Pyxis[id])
        set udg_SP_Angle[id2] = 0
        set udg_SP_Distance[id2] = 60
        set udg_SP_Source[id2] = caster
        set udg_SP_FloatTextSize[id2] = 6 * 0.0023
        set udg_SP_TextColour[id2] = "|cffff0000"
        
        call GroupAddUnit(udg_SP_Group, udg_SP_Pyxis[id])
        
        if IsTriggerEnabled(gg_trg_Sanguis_Pyxis_Orbit) == false then
            call EnableTrigger( gg_trg_Sanguis_Pyxis_Orbit )
        endif
        
        set udg_SP_Level[id2] = GetUnitAbilityLevel(caster, 'A01E')
        set udg_SP_ChargeLimit[id2] = 2 + udg_SP_Level[id2]
        
        set udg_SP_ChargeString[id2] = "*"
        
        loop
            set i = i + 1
            exitwhen i == udg_SP_ChargeLimit[id2]
            set udg_SP_ChargeString[id2] = udg_SP_ChargeString[id2] + "*"
        endloop
        
        set udg_SP_ChargeFloatText[id2] = CreateTextTag()
        call SetTextTagVisibility(udg_SP_ChargeFloatText[id2], true)
        call SetTextTagPos(udg_SP_ChargeFloatText[id2], x, y, 80)
        call SetTextTagText(udg_SP_ChargeFloatText[id2], udg_SP_ChargeString[id2], udg_SP_FloatTextSize[id2])
        
    endif
    
endfunction

//===========================================================================
function InitTrig_Sanguis_Pyxis_Revive takes nothing returns nothing
    set gg_trg_Sanguis_Pyxis_Revive = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Sanguis_Pyxis_Revive, EVENT_PLAYER_HERO_REVIVE_FINISH )
    call TriggerAddAction( gg_trg_Sanguis_Pyxis_Revive, function Trig_Sanguis_Pyxis_Revive_Actions )
endfunction

//TESH.scrollpos=24
//TESH.alwaysfold=0
function Trig_Sanguis_Pyxis_Orbit_Actions takes nothing returns nothing
    
    local real x = 0.00
    local real y = 0.00
    local real x2 = 0.00
    local real y2 = 0.00
    local real dx = 0.00
    local real dy = 0.00
    local real angle = 0.00
    local real dist = 0.00
    local integer id = 0
    local integer id2 = 0
    local integer IntervalThreshold = 0
    local unit ThePyxis = null
    
    if FirstOfGroup(udg_SP_Group) != null then
        loop
            set ThePyxis = FirstOfGroup(udg_SP_Group)
            exitwhen ThePyxis == null
            
            call GroupAddUnit(udg_SP_GroupTemp, ThePyxis)
            call GroupRemoveUnit(udg_SP_Group, ThePyxis)
            
            set id = GetUnitUserData(ThePyxis)
            set id2 = GetUnitUserData(udg_SP_Source[id])
            
            set IntervalThreshold = (50 - 10 * udg_SP_Level[id]) * 33
            set udg_SP_Interval[id] = (udg_SP_Interval[id] + 1)
            
            if udg_SP_Interval[id] >= IntervalThreshold then
                set udg_SP_Interval[id] = 0
                if udg_SP_Charge[id] < udg_SP_ChargeLimit[id] then
                    set udg_SP_Charge[id] = udg_SP_Charge[id] + 1
                    if udg_SP_Charge[id] == udg_SP_ChargeLimit[id] then
                        call SetTextTagText(udg_SP_ChargeFloatText[id], udg_SP_TextColour[id] + udg_SP_ChargeString[id] + "|r", udg_SP_FloatTextSize[id])
                    else
                        call SetTextTagText(udg_SP_ChargeFloatText[id], udg_SP_TextColour[id] + SubString(udg_SP_ChargeString[id], 0, udg_SP_Charge[id]) + "|r" + SubString(udg_SP_ChargeString[id], udg_SP_Charge[id], udg_SP_ChargeLimit[id]), udg_SP_FloatTextSize[id])
                    endif
                endif
            endif
            
            if udg_SPEC_FleshSpinner[id2] == true then
                if GetUnitTypeId(ThePyxis) == 'e001' then
                    call PauseUnit(ThePyxis, false)
                    call ShowUnit(ThePyxis, false)
                    call ShowUnit(ThePyxis, true)
                    call UnitRemoveAbility(ThePyxis, 'Aloc')
                    call UnitAddAbility(ThePyxis, 'A01D')
                    call UnitRemoveAbility(ThePyxis, 'A01D')
                endif
                
                set x = GetUnitX(ThePyxis)
                set y = GetUnitY(ThePyxis)
                set x2 = GetUnitX(udg_SP_Source[id])
                set y2 = GetUnitY(udg_SP_Source[id])
                set dx = x2 - x
                set dy = y2 - y
                set dist = SquareRoot(dx*dx+dy*dy)
                if dist > 900 then
                    call SetUnitPosition(ThePyxis, x2, y2)
                endif
            else
                set udg_SP_Angle[id] = udg_SP_Angle[id] + 3
                set angle = udg_SP_Angle[id] * bj_DEGTORAD
                
                set x = (GetUnitX(udg_SP_Source[id]) + Cos(angle) * udg_SP_Distance[id]) - 16
                set y = GetUnitY(udg_SP_Source[id]) + Sin(angle) * udg_SP_Distance[id]
                
                call SetUnitPosition(ThePyxis, x, y)
            endif
            
            call SetTextTagVisibility(udg_SP_ChargeFloatText[id], true)
            call SetTextTagPos(udg_SP_ChargeFloatText[id], x, y, 80)
            
        endloop
    else
        call DisableTrigger(GetTriggeringTrigger())
    endif
    
    loop
        set ThePyxis = FirstOfGroup(udg_SP_GroupTemp)
        exitwhen ThePyxis == null
        call GroupRemoveUnit(udg_SP_GroupTemp, ThePyxis)
        
        set id = GetUnitUserData(ThePyxis)
        set id2 = GetUnitUserData(udg_SP_Source[id])
        
        if GetUnitState(udg_SP_Source[id], UNIT_STATE_LIFE) > 0 or udg_IsUnitReincarnating[id2] == true then
            call GroupAddUnit(udg_SP_Group, ThePyxis)
        else
            call PauseUnit(ThePyxis, false)
            call UnitRemoveAbility(ThePyxis, 'A019')
            call UnitApplyTimedLife(ThePyxis, 'BTLF', 2.00)
            call DestroyTextTag(udg_SP_ChargeFloatText[id])
            set udg_SP_Charge[id2] = 0
            set udg_SP_Interval[id2] = 0
            set udg_SP_Pyxis[id2] = null
        endif
    endloop
    
endfunction

//===========================================================================
function InitTrig_Sanguis_Pyxis_Orbit takes nothing returns nothing
    set gg_trg_Sanguis_Pyxis_Orbit = CreateTrigger(  )
    call DisableTrigger( gg_trg_Sanguis_Pyxis_Orbit )
    call TriggerRegisterTimerEvent( gg_trg_Sanguis_Pyxis_Orbit, ( 1 / 32.00 ), true )
    call TriggerAddAction( gg_trg_Sanguis_Pyxis_Orbit, function Trig_Sanguis_Pyxis_Orbit_Actions )
endfunction

//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_Sanguis_Pyxis_Nearby_Death_Conditions takes nothing returns boolean
    if IsUnitType(GetTriggerUnit(), UNIT_TYPE_MECHANICAL) or GetUnitTypeId(GetTriggerUnit()) == 'e001' or GetUnitTypeId(GetTriggerUnit()) == 'uloc' or GetUnitTypeId(GetTriggerUnit()) == 'u006' or GetUnitTypeId(GetTriggerUnit()) == 'n00J' or GetUnitTypeId(GetTriggerUnit()) == 'n00K' or GetUnitTypeId(GetTriggerUnit()) == 'n00L' then
        return false
    endif
    return true
endfunction

function Trig_Sanguis_Pyxis_Nearby_Death_Actions takes nothing returns nothing
    
    local unit u = GetTriggerUnit()
    local integer id = 0
    local integer id2 = 0
    local real x = GetUnitX(u)
    local real y = GetUnitY(u)
    
    call GroupEnumUnitsInRange(udg_SP_GroupTemp, x, y, 600, null)
    set u = null
    
    loop
        set u = FirstOfGroup(udg_SP_GroupTemp)
        exitwhen u == null
        call GroupRemoveUnit(udg_SP_GroupTemp, u)
        
        set id = GetUnitUserData(u)
        if udg_SP_Pyxis[id] != null then
            set id2 = GetUnitUserData(udg_SP_Pyxis[id])
            if udg_SP_IsLearned[id] == true and udg_SP_Charge[id2] < udg_SP_ChargeLimit[id2] then
                set udg_SP_Charge[id2] = udg_SP_Charge[id2] + 1
                if udg_SP_Charge[id2] == udg_SP_ChargeLimit[id2] then
                    call SetTextTagText(udg_SP_ChargeFloatText[id2], udg_SP_TextColour[id2] + udg_SP_ChargeString[id2] + "|r", udg_SP_FloatTextSize[id2])
                else
                    call SetTextTagText(udg_SP_ChargeFloatText[id2], udg_SP_TextColour[id2] + SubString(udg_SP_ChargeString[id2], 0, udg_SP_Charge[id2]) + "|r" + SubString(udg_SP_ChargeString[id2], udg_SP_Charge[id2], udg_SP_ChargeLimit[id2]), udg_SP_FloatTextSize[id2])
                endif
            endif
        endif
    endloop
    
endfunction

//===========================================================================
function InitTrig_Sanguis_Pyxis_Nearby_Death takes nothing returns nothing
    set gg_trg_Sanguis_Pyxis_Nearby_Death = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Sanguis_Pyxis_Nearby_Death, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddCondition( gg_trg_Sanguis_Pyxis_Nearby_Death, Condition( function Trig_Sanguis_Pyxis_Nearby_Death_Conditions ) )
    call TriggerAddAction( gg_trg_Sanguis_Pyxis_Nearby_Death, function Trig_Sanguis_Pyxis_Nearby_Death_Actions )
endfunction

//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_Knifestorm_Loop_Actions takes nothing returns nothing

    local real x = 0.00
    local real y = 0.00
    local real x2 = 0.00
    local real y2 = 0.00
    local real dx = 0.00
    local real dy = 0.00
    local real scale = 1.00
    local real angle = 0.00
    local real distance = 0.00
    local unit source = null
    local unit missile = null
    local integer id = 0
    local integer id2 = 0
    local boolean array b

    if FirstOfGroup(udg_Knifestorm_Group) == null and FirstOfGroup(udg_Knifestorm_GroupKnives) == null then
        call DisableTrigger(GetTriggeringTrigger())
    else
        
        loop
            set source = FirstOfGroup(udg_Knifestorm_Group)
            set id = GetUnitUserData(source)
            exitwhen source == null
            
            call GroupRemoveUnit(udg_Knifestorm_Group, source)
            if GetUnitState(source, UNIT_STATE_LIFE) > 0 then
                call GroupAddUnit(udg_Knifestorm_GroupTemp, source)
            endif
            
            set udg_Knifestorm_Interval[id] = udg_Knifestorm_Interval[id] + 1
            set udg_Knifestorm_TimerInterval[id] = udg_Knifestorm_TimerInterval[id] + 1
            
            if udg_Knifestorm_Interval[id] >= 3 then
                
                set udg_Knifestorm_Interval[id] = 0
            
                set x = GetUnitX(source)
                set y = GetUnitY(source)
                set angle = GetRandomReal(0,360)
            
                set missile = CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), 'e001', x, y, angle)
                call UnitAddAbility(missile, 'A01Q')
                call SetUnitFlyHeight(missile, GetRandomReal(30,70), 0)
                call SetUnitScale(missile, scale, scale, scale)
                call PauseUnit(missile, true)
                set id2 = GetUnitUserData(missile)
                
                set udg_Collision_MissileSource[id2] = source
                set udg_Collision_Radius[id2] = 50
                set udg_Collision_Angle[id2] = angle
                set udg_Collision_Speed[id2] = GetRandomReal(10,15)
                set udg_Collision_Distance[id2] = 0
                set udg_Collision_Damage[id2] = 40
                set udg_Collision_MaxDistance[id2] = GetRandomReal(570,610)
                set udg_Collision_TargetFilter[id2] = 1
                set udg_Collision_EndOnHit[id2] = true
                set udg_Collision_OriginX[id2] = x
                set udg_Collision_OriginY[id2] = y
                
                call GroupAddUnit(udg_Knifestorm_GroupKnives, missile)
                
                set missile = null
                
            endif
            
            if udg_Knifestorm_TimerInterval[id] >= 495 then
                set udg_Knifestorm_TimerInterval[id] = 0
                set b[id] = true
            endif
            
        endloop
        
        loop //add the Grim Jester back into Knifestorm_Group
            set source = FirstOfGroup(udg_Knifestorm_GroupTemp)
            set id = GetUnitUserData(source)
            exitwhen source == null
            call GroupRemoveUnit(udg_Knifestorm_GroupTemp, source)
            if b[id] == true then
                set b[id] = false
            else
                call GroupAddUnit(udg_Knifestorm_Group, source)
            endif
        endloop
        
        loop
            set missile = FirstOfGroup(udg_Knifestorm_GroupKnives)
            set id2 = GetUnitUserData(missile)
            exitwhen missile == null
            
            call GroupRemoveUnit(udg_Knifestorm_GroupKnives, missile)
            if GetUnitState(missile, UNIT_STATE_LIFE) > 0 then
                call GroupAddUnit(udg_Knifestorm_GroupTemp, missile)
            else
                set b[id2] = true
            endif
            
            //set x = GetUnitX(udg_Collision_MissileSource[id2])
            //set y = GetUnitY(udg_Collision_MissileSource[id2])
            set x2 = GetUnitX(missile)
            set y2 = GetUnitY(missile)
            set dx = x2 - udg_Collision_OriginX[id2]
            set dy = y2 - udg_Collision_OriginY[id2]
            set distance = SquareRoot(dx*dx + dy*dy)
            
            if distance > udg_Collision_MaxDistance[id2] then
                call PauseUnit(missile, false)
                call UnitApplyTimedLife(missile, 'BTLF', 0.01)
            else
                set x = udg_Collision_OriginX[id2] + Cos(udg_Collision_Angle[id2]*bj_DEGTORAD) * udg_Collision_Distance[id2]
                set y = udg_Collision_OriginY[id2] + Sin(udg_Collision_Angle[id2]*bj_DEGTORAD) * udg_Collision_Distance[id2]
                
                call SetUnitPosition(missile, x, y)
                call SetUnitFacing(missile, udg_Collision_Angle[id2] + 90)
                
                set udg_Collision_Missile = missile
                set udg_Collision_ScanTargetsEvent = 1.00
                set udg_Collision_ScanTargetsEvent = 0.00
                set udg_Collision_Missile = null
                
                set udg_Collision_Angle[id2] = udg_Collision_Angle[id2] + 6
                set udg_Collision_Distance[id2] = udg_Collision_Distance[id2] + udg_Collision_Speed[id2]
            endif
            
        endloop
        
        loop //add the knives back into Knifestorm_GroupKnives
            set missile = FirstOfGroup(udg_Knifestorm_GroupTemp)
            set id2 = GetUnitUserData(missile)
            exitwhen missile == null
            call GroupRemoveUnit(udg_Knifestorm_GroupTemp, missile)
            if b[id2] == true then
                set b[id2] = false
                set udg_Collision_UnitHit[id2] = null
            else
                call GroupAddUnit(udg_Knifestorm_GroupKnives, missile)
            endif
        endloop
        
    endif

endfunction

//===========================================================================
function InitTrig_Knifestorm_Loop takes nothing returns nothing
    set gg_trg_Knifestorm_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Knifestorm_Loop )
    call TriggerRegisterTimerEvent( gg_trg_Knifestorm_Loop, 0.03125, true )
    call TriggerAddAction( gg_trg_Knifestorm_Loop, function Trig_Knifestorm_Loop_Actions )
endfunction

//TESH.scrollpos=9
//TESH.alwaysfold=0
function Trig_Mocking_Laugh_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A01R' ) ) then
        return false
    endif
    return true
endfunction

function Trig_Mocking_Laugh_Actions takes nothing returns nothing

    local unit source = GetTriggerUnit()
    local unit dummy = null
    local unit u = null
    local real x = GetUnitX(source)
    local real y = GetUnitY(source)
    local integer id = GetUnitUserData(source)
    
    call SetUnitPathing(source, false)
    
    set dummy = CreateUnit(GetOwningPlayer(source), 'e001', x, y, 270)
    call UnitApplyTimedLife(dummy, 'BTLF', 2.00)
    call UnitAddAbility(dummy, 'A01U')
    call IssueTargetOrderById(dummy, 852069, source)
    set dummy = null
    
    set dummy = CreateUnit(GetOwningPlayer(source), 'e001', x, y, 270)
    call UnitApplyTimedLife(dummy, 'BTLF', 2.00)
    call UnitAddAbility(dummy, 'A01T')
    call SetUnitAbilityLevel(dummy, 'A01T', udg_MasterOfIllusions[id] + 1)
    call IssueTargetOrderById(dummy, 852274, source)
    set dummy = null
    
    call GroupEnumUnitsInRange(udg_TempGroup, x, y, 450, null)
    
    loop
        set u = FirstOfGroup(udg_TempGroup)
        exitwhen u == null
        call GroupRemoveUnit(udg_TempGroup, u)
        
        if IsUnitEnemy(u, GetOwningPlayer(source)) and GetUnitState(u, UNIT_STATE_LIFE) > 0 and GetUnitAbilityLevel(u, 'Bvul') <= 0 and GetUnitAbilityLevel(u, 'Avul') <= 0 then
            set dummy = CreateUnit(GetOwningPlayer(source), 'e001', x, y, 270)
            call UnitApplyTimedLife(dummy, 'BTLF', 2.00)
            call UnitAddAbility(dummy, 'A01V')
            call IssueTargetOrderById(dummy, 852149, u)
            set dummy = null
        endif
    endloop
    
    call SetUnitPathing(source, true)
    
endfunction

//===========================================================================
function InitTrig_Mocking_Laugh takes nothing returns nothing
    set gg_trg_Mocking_Laugh = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Mocking_Laugh, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Mocking_Laugh, Condition( function Trig_Mocking_Laugh_Conditions ) )
    call TriggerAddAction( gg_trg_Mocking_Laugh, function Trig_Mocking_Laugh_Actions )
endfunction

//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_Shadow_Servants_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A01W' ) ) then
        return false
    endif
    return true
endfunction

function Trig_Shadow_Servants_Actions takes nothing returns nothing

    local unit source = GetTriggerUnit()
    local unit dummy = null
    local unit u = null
    local real x = GetUnitX(source)
    local real y = GetUnitY(source)
    local integer i = 0
    local integer id = GetUnitUserData(source)
    local integer SpellLvl = GetUnitAbilityLevel(source, 'A01W')
    
    set udg_IllusionCollision[id] = true
    
    loop
    exitwhen i >= SpellLvl
    set i = i + 1
        set dummy = CreateUnit(GetOwningPlayer(source), 'e001', x, y, 270)
        call UnitApplyTimedLife(dummy, 'BTLF', 2.00)
        call UnitAddAbility(dummy, 'A01T')
        call SetUnitAbilityLevel(dummy, 'A01T', udg_MasterOfIllusions[id] + 1)
        call IssueTargetOrderById(dummy, 852274, source)
        set dummy = null
    endloop
    
    set udg_IllusionCollision[id] = false
    
endfunction

//===========================================================================
function InitTrig_Shadow_Servants takes nothing returns nothing
    set gg_trg_Shadow_Servants = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Shadow_Servants, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Shadow_Servants, Condition( function Trig_Shadow_Servants_Conditions ) )
    call TriggerAddAction( gg_trg_Shadow_Servants, function Trig_Shadow_Servants_Actions )
endfunction

//TESH.scrollpos=12
//TESH.alwaysfold=0
function Trig_Shuriken_Flurry_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A01X' ) ) then
        return false
    endif
    return true
endfunction

function Trig_Shuriken_Flurry_Actions takes nothing returns nothing

    local unit source = GetTriggerUnit()
    local unit missile = null
    local real x = GetUnitX(source)
    local real y = GetUnitY(source)
    local real x2 = GetLocationX(GetSpellTargetLoc())
    local real y2 = GetLocationY(GetSpellTargetLoc())
    local real angle = 0.00
    local real distance = 0.00
    local real scale = .5
    local integer i = 0
    local integer iEnd = 0
    local integer id2 = GetUnitUserData(source) //to remain consistent with my other triggers, id2 with be the custom value of the missile.
    
    if GetUnitAbilityLevel(source, 'A01X') == 1 then
        set iEnd = 4
    elseif GetUnitAbilityLevel(source, 'A01X') == 2 then
        set iEnd = 7
    elseif GetUnitAbilityLevel(source, 'A01X') == 3 then
        set iEnd = 11
    endif
    
    loop
    exitwhen i >= iEnd
    set i = i + 1
        
        set angle = Atan2(y2-y,x2-x) + GetRandomReal(-20,20)*bj_DEGTORAD
        set missile = CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), 'e001', x, y, angle)
        call SetUnitFlyHeight(missile, GetRandomReal(60,100), 0)
        call SetUnitScale(missile, scale, scale, scale)
        call UnitAddAbility(missile, 'A01Y')
        call PauseUnit(missile, true)
        
        set id2 = GetUnitUserData(missile)
        
        set udg_Collision_MissileSource[id2] = source
        set udg_Collision_Radius[id2] = 50
        set udg_Collision_Angle[id2] = angle
        set udg_Collision_Speed[id2] = GetRandomReal(20,25)
        set udg_Collision_Distance[id2] = udg_Collision_Speed[id2]
        set udg_Collision_Damage[id2] = 30
        set udg_Collision_MaxDistance[id2] = GetRandomReal(690,750)
        set udg_Collision_TargetFilter[id2] = 1
        set udg_Collision_EndOnHit[id2] = true
        set udg_Collision_OriginX[id2] = x
        set udg_Collision_OriginY[id2] = y
        
        call GroupAddUnit(udg_ShurikenFlurry_Group, missile)
        if not IsTriggerEnabled(gg_trg_Shuriken_Flurry_Loop) then
            call EnableTrigger(gg_trg_Shuriken_Flurry_Loop)
        endif
        
        set missile = null
    
    endloop

endfunction

//===========================================================================
function InitTrig_Shuriken_Flurry takes nothing returns nothing
    set gg_trg_Shuriken_Flurry = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Shuriken_Flurry, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Shuriken_Flurry, Condition( function Trig_Shuriken_Flurry_Conditions ) )
    call TriggerAddAction( gg_trg_Shuriken_Flurry, function Trig_Shuriken_Flurry_Actions )
endfunction

//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_Shuriken_Flurry_Loop_Actions takes nothing returns nothing

    local unit missile = null
    local real x = 0.00
    local real y = 0.00
    local real x2 = 0.00
    local real y2 = 0.00
    local real dx = 0.00
    local real dy = 0.00
    local real distance = 0.00
    local integer id2 = 0
    local boolean array b

    if FirstOfGroup(udg_ShurikenFlurry_Group) == null then
        call DisableTrigger(GetTriggeringTrigger())
    endif
    
    loop
    
        set missile = FirstOfGroup(udg_ShurikenFlurry_Group)
        set id2 = GetUnitUserData(missile)
        exitwhen missile == null
        
        call GroupRemoveUnit(udg_ShurikenFlurry_Group, missile)
        if GetUnitState(missile, UNIT_STATE_LIFE) > 0 then
            call GroupAddUnit(udg_ShurikenFlurry_GroupTemp, missile)
        else
            set b[id2] = true
        endif
        
        set x2 = GetUnitX(missile)
        set y2 = GetUnitY(missile)
        set dx = x2 - udg_Collision_OriginX[id2]
        set dy = y2 - udg_Collision_OriginY[id2]
        set distance = SquareRoot(dx*dx + dy*dy)
        
        if distance > udg_Collision_MaxDistance[id2] then
            call PauseUnit(missile, false)
            call UnitApplyTimedLife(missile, 'BTLF', 0.01)
        else
            set x = udg_Collision_OriginX[id2] + Cos(udg_Collision_Angle[id2]) * udg_Collision_Distance[id2]
            set y = udg_Collision_OriginY[id2] + Sin(udg_Collision_Angle[id2]) * udg_Collision_Distance[id2]
            
            call SetUnitPosition(missile, x, y)
            call SetUnitFacing(missile, udg_Collision_Angle[id2])
            
            set udg_Collision_Missile = missile
            set udg_Collision_ScanTargetsEvent = 1.00
            set udg_Collision_ScanTargetsEvent = 0.00
            set udg_Collision_Missile = null
            
            set udg_Collision_Distance[id2] = udg_Collision_Distance[id2] + udg_Collision_Speed[id2]
        endif
        
    endloop
    
    loop //add the knives back into Knifestorm_GroupKnives
        set missile = FirstOfGroup(udg_ShurikenFlurry_GroupTemp)
        set id2 = GetUnitUserData(missile)
        exitwhen missile == null
        call GroupRemoveUnit(udg_ShurikenFlurry_GroupTemp, missile)
        if b[id2] == true then
            set b[id2] = false
            set udg_Collision_UnitHit[id2] = null
        else
            call GroupAddUnit(udg_ShurikenFlurry_Group, missile)
        endif
    endloop

endfunction

//===========================================================================
function InitTrig_Shuriken_Flurry_Loop takes nothing returns nothing
    set gg_trg_Shuriken_Flurry_Loop = CreateTrigger(  )
    call DisableTrigger( gg_trg_Shuriken_Flurry_Loop )
    call TriggerRegisterTimerEvent( gg_trg_Shuriken_Flurry_Loop, 0.03125, true )
    call TriggerAddAction( gg_trg_Shuriken_Flurry_Loop, function Trig_Shuriken_Flurry_Loop_Actions )
endfunction

//TESH.scrollpos=0
//TESH.alwaysfold=0
function Trig_Godsever_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A01Z' ) ) then
        return false
    endif
    return true
endfunction

function Trig_Godsever_Actions takes nothing returns nothing

    local unit u = GetTriggerUnit()
    local integer id = GetUnitUserData(u)
    
    set udg_Godsever_Bonus[id] = 400.00
    set udg_Godsever_IsActive[id] = true
    call UnitAddAbility( u, 'A020' )
    
    call PolledWait( 30.00 )
    
    set udg_Godsever_IsActive[id] = false
    call UnitRemoveAbility( u, 'A020' )
endfunction

//===========================================================================
function InitTrig_Godsever takes nothing returns nothing
    set gg_trg_Godsever = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Godsever, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Godsever, Condition( function Trig_Godsever_Conditions ) )
    call TriggerAddAction( gg_trg_Godsever, function Trig_Godsever_Actions )
endfunction