Triggers

function HasItemtype takes unit whichUnit, item this returns item
    local integer i = 0
    local item whichItem = null
    local integer itemType = GetItemTypeId(this)
    if whichUnit != null then
        loop
            exitwhen i > 6
            set whichItem = UnitItemInSlot(whichUnit, i)
            if GetItemTypeId(whichItem) == itemType and whichItem != this then
                return whichItem
            endif
            set i = i + 1
        endloop
    endif
    return null
endfunction
 
function StackItem takes unit whichHero, item whichItem returns nothing
    local item stack = HasItemtype(whichHero,whichItem)
    local integer itemCharges = GetItemCharges(stack)
    if stack != null and stack != whichItem and itemCharges > 0 then
        call SetItemCharges( stack, itemCharges+ GetItemCharges(whichItem))
        call RemoveItem( whichItem)
    endif
endfunction

function UnitGuardUnitAI takes unit summon, unit master returns nothing
    local location target
    local real angle
    local real dist
    loop
        exitwhen IsUnitDeadBJ(summon)
        if (DistanceBetweenPoints(GetUnitLoc(summon), GetUnitLoc(master)) > 1000.00 ) then
            set target = GetUnitLoc(master)
            call IssuePointOrderLocBJ(summon, "move", target)
            call RemoveLocation(target)
        else
            set target = GetUnitLoc(master)
            set angle =  GetRandomDirectionDeg()
            set dist = GetRandomReal(100.00, 500.00)
            call MoveLocation(target, GetLocationX(target) + dist * Cos(angle * bj_DEGTORAD), GetLocationY(target) + dist * Sin(angle * bj_DEGTORAD))
            call IssuePointOrderLocBJ(summon, "attack", target)
            call RemoveLocation(target)
        endif
        call TriggerSleepAction( 1.0+GetRandomReal(0.0,1.5))
    endloop
    set target = null
endfunction