• Listen to a special audio message from Bill Roper to the Hive Workshop community (Bill is a former Vice President of Blizzard Entertainment, Producer, Designer, Musician, Voice Actor) 🔗Click here to hear his message!
  • Read Evilhog's interview with Gregory Alper, the original composer of the music for WarCraft: Orcs & Humans 🔗Click here to read the full interview.

Triggers

FrozenBlastby1)ark_NiTev.45.w3x
Variables
Frozen Blast
Change Log
Read Me
What to Copy
Frozen Blast
Do Not Copy
Level Up
Prompt
Enter map-specific custom script code below. This text will be included in the map script after variables are declared and before any trigger code.
Name Type is_array initial_value
v. 45

-Added multi-level support (3 levels).

v.40

-Created constant functions to make replacing rawcodes simple during spell implementation.
-Optimized to natively use radian measure instead of using bj_DEGTORAD function to convert to radians.
-Removed parentheses from simple math
-Updated/expanded documentation
-Replaced bj_UNITFACING with 270.0

v.35

-Changed "Begins Casting" to "Starts the Effect"

v.30

-Replaced GroupPickRandomUnit() with FirstOfGroup()
-exitwhen i == z changed to i >= z in case of it bugging

v.25

-Replaced GetUnitX/Y()'s with variables px and py.
-Replaced PolarProjectionBJ with variables qx and qy as coordinates.
-Added Change Log
*Thanks to Deuterium and Cheezeman for these suggestions.
1)ark_NiTe Presents: Frozen Blast (100% Multi-Instanceable & Leakless)

*To import this spell in your map copy the custom units, abilities, buffs FIRST, and then triggers.
Make sure you import the triggers last and do not miss anything or the spell may not work correctly!*

Damage for each Frozen Blast Wave is modified in the Frozen Blast (Actual Ability).
Cooldown/spell description is modified in the Frozen Blast (Dummy Ability).

------------------------------------------------------------------

*****+Also, you will want to pay close attention to the constant functions because the rawcodes will likely change for you+*****

ex.) constant function Frozen_Blast_ID takes nothing returns integer
return 'A000' // Frozen Blast actual ability rawcode.
endfunction

The xxxx (e.g. A000) value will most likely change for you so pay close attention to make sure you use your maps rawcode for the spells.

All of the constant functions are the very first part of the script.

How to locate the raw code:

+Open up the Object Editor and find the Ability or Unit you need to replace the raw code for
+On the menu bar, click on View and then scroll down and click on Display Objects as Raw Data.
+Find the script or trigger that involves the raw code and the first four letters/numbers you see are the rawcode of the Ability or Unit.
+Replace the raw code (eg. 'A001') with the rawcode of the Ability or Unit.

------------------------------------------------------------------


Multi-Instanceability:

This spell is completely Multi-Instanceable, so you do not need to worry about it not working if given to more than one hero.
-What to copy:

Custom Units:

(Human)
+Dummy

(Undead)
+Lich (unless you want to use a Hero in your map, in which case just add the ability to the Hero in YOUR map)

Custom Abilities:

(Human)
+Frozen Blast (Actual Ability)
+Frozen Blast (Dummy Ability)

Triggers:

+Frozen Blast
//////////////////////////////////////////////////////////////////////
//  Frozen Blast by 1)ark_NiTe                                      //
//  Originally made for Against the Darkness                        //
//                                                                  //
//  r = angle that wave will be fired towards                       //
//                                                                  //
//  Notes:                                                          //
//                                                                  //
//  1. Change the spells and dummy units rawcodes in the constants. //
//  2. Damage/duration data can be changed by accessing the spells  //
//     in the object editor                                         //
//     a.) Damage for each Frozen Blast Wave is modified in the     //
//         Frozen Blast (Actual Ability).                           //
//     b.) Cooldown/spell description is modified in the Frozen     //
//         Blast (Dummy Ability).                                   //
//////////////////////////////////////////////////////////////////////

//==================================================================================================================================
// Start of constants. These provide the user with easier implementing//changing of the spell's rawcodes. All of these can be changed.
//==================================================================================================================================

constant function Frozen_Blast_ID takes nothing returns integer
    return 'A000' // Frozen Blast actual ability rawcode. This is the spell that will be cast by a dummy unit.
endfunction

constant function Frozen_Blast_Dummy_ID takes nothing returns integer
    return 'A001' // Frozen Blast dummy ability rawcode. This is the spell that the Hero will use. 
endfunction
    
constant function Slow_ID takes nothing returns integer
    return 'A002' // Slow (Frozen Blast) rawcode.
endfunction
                 
constant function Dummy_ID takes nothing returns integer
    return 'h002' // Dummy unit rawcode
endfunction

//==================================================================================================================================
//End of constants. Do not touch anything below this if you are unfamiliar with JASS.
//==================================================================================================================================

//==================================================================================================================================
//Spell conditions.
//==================================================================================================================================

function Trig_Blast_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == Frozen_Blast_Dummy_ID()
endfunction

//==================================================================================================================================
//Filter function grouping enemies to be slowed.
//==================================================================================================================================

function Slow_Filter takes nothing returns boolean
    return IsPlayerEnemy(GetOwningPlayer(GetTriggerUnit()), GetOwningPlayer(GetFilterUnit())) == true
endfunction

//==================================================================================================================================
//Spell actions. Main block of coding
//==================================================================================================================================

function Trig_Blast_Actions takes nothing returns nothing    
    //Locals are declared
    local unit t = GetTriggerUnit()
    local real px = GetWidgetX(t)
    local real py = GetWidgetY(t)
    local real qx
    local real qy
    local unit array d
    local unit array u
    local unit e
    local group g = CreateGroup()
    local real r = 0.00
    local integer i = 0
    local integer z = 0
    local integer l = GetUnitAbilityLevel(t, Frozen_Blast_Dummy_ID())
    //Frozen Blasts are created. A blast occurs every 30 degrees out around the Hero 12 times (360 degrees).
    loop
        exitwhen i == 12
        set i = i + 1
        set r = r + .52359 
        set d[i] = CreateUnit(GetOwningPlayer(t), Dummy_ID(), px, py, 270.0)
        call UnitAddAbility(d[i], Frozen_Blast_ID())
        call SetUnitAbilityLevel(t, Frozen_Blast_ID(), l)
        call UnitApplyTimedLife(d[i], 'BTLF', 1.00)
        set qx = px + 300 * Cos(r)
        set qy = py + 300 * Sin(r)
        call IssuePointOrder (d[i], "carrionswarm", qx, qy)
        set d[i] = null
    endloop
    call GroupEnumUnitsInRange(g, px, py, 650.00, Condition(function Slow_Filter))
    set i = 0
    set z = CountUnitsInGroup(g)
    //Dummy units cast Slow (Frozen Blast) on the units in the area
    loop
        exitwhen i >= z
        set i = i + 1
        set u[i] = FirstOfGroup(g)
        call GroupRemoveUnit( g, u[i] )
        set e = CreateUnit(GetOwningPlayer(t), Dummy_ID(), px, py, 270.0)
        call UnitApplyTimedLife(e, 'BTLF', 1.00)
        call UnitAddAbility(e, Slow_ID())
        call IssueTargetOrder(e, "slow", u[i])
        set u[i] = null
    endloop
    set e = null
    set t = null
endfunction

function AntiLeaker takes nothing returns boolean
    return true
endfunction

//===========================================================================
function InitTrig_Frozen_Blast takes nothing returns nothing
    local trigger t = CreateTrigger( )
    local filterfunc f = Filter(function AntiLeaker)
    local integer i = 0
    loop
        call TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, f)
        set i = i + 1
        exitwhen i == 16
    endloop
    call TriggerAddCondition(t, Condition( function Trig_Blast_Conditions ) )
    call TriggerAddAction(t, function Trig_Blast_Actions )
    call DestroyFilter(f)
    set f = null
    set t = null
endfunction
Level Up
Events
Player - Player 1 (Red) types a chat message containing -level (Unexpected type: 'stringnoformat') as An exact match
Conditions
Actions
Hero - Set Lich 0000 <gen> Hero-level to ((Hero level of Lich 0000 <gen>) + 1) , Show level-up graphics
Prompt
Events
Time - Every 60.00 seconds of game time
Conditions
Actions
Game - Display to (All players) the text: Type "|cffffcc00-level|r" to increase the Lich's level.
Top