Triggers

function AdjustPlayerStateCS takes integer delta, integer i, playerstate whichPlayerState returns nothing
    if (whichPlayerState == PLAYER_STATE_RESOURCE_GOLD) then
        call SetPlayerState(Player(i), PLAYER_STATE_GOLD_GATHERED, GetPlayerState(Player(i), PLAYER_STATE_GOLD_GATHERED) + delta)
    elseif (whichPlayerState == PLAYER_STATE_RESOURCE_LUMBER) then
        call SetPlayerState(Player(i), PLAYER_STATE_LUMBER_GATHERED, GetPlayerState(Player(i), PLAYER_STATE_LUMBER_GATHERED) + delta)
    endif
    call SetPlayerState(Player(i), whichPlayerState, GetPlayerState(Player(i), whichPlayerState) + delta)
    set udg_TotalAssets[i] = udg_TotalAssets[i] + delta
endfunction

function SetPlayerStateCS takes integer i, playerstate whichPlayerState, integer value returns nothing
    local integer oldValue = GetPlayerState(Player(i), whichPlayerState)
    call AdjustPlayerStateCS(value - oldValue, i, whichPlayerState)
endfunction

function ISignCS takes integer a returns string
    if a >= 0 then
        return "+" + I2S(a)
    endif
    return "-" + I2S(-a)
endfunction

function ISignCS2 takes integer a returns string
    local string s = I2S(a)
    local integer i = StringLength(s)
    local integer j = i / 3
    local integer k
    if ModuloInteger(i, 3) == 0 then
        set j = j - 1
    endif
    loop
        exitwhen j < 1
        set k = i - j * 3
        set s = SubString(s, 0, k) + "," + SubString(s, k, i)
        set i = i + 1
        set j = j - 1
    endloop
    return s
endfunction

function BoardWidth takes nothing returns real
    return 4 + 0.5 * Pow(2, 5-I2R(udg_Players))
endfunction

function DistanceBetweenUnits takes unit a, unit b returns real
    local real dx = GetUnitX(b) - GetUnitX(a)
    local real dy = GetUnitY(b) - GetUnitY(a)
    return SquareRoot(dx * dx + dy * dy)
endfunction

function SetPlayerAbilityAvailableCS takes integer i returns nothing
    call SetPlayerAbilityAvailable(Player(i), 'A008', false)
    call SetPlayerAbilityAvailable(Player(i), 'A009', true)
endfunction

function SetPlayerAbilityAvailableCS2 takes integer i returns nothing
    call SetPlayerAbilityAvailable(Player(i), 'A003', false)
    call SetPlayerAbilityAvailable(Player(i), 'A005', true)
    call SetPlayerAbilityAvailable(Player(i), 'A00F', false)
    call SetPlayerAbilityAvailable(Player(i), 'A007', true)
endfunction

function SetPlayerAbilityAvailableCS3 takes integer i returns nothing
    call DestroyEffect(udg_Attention)
    set udg_Attention = null
    call SetPlayerAbilityAvailable(Player(i), 'A009', false)
    call SetPlayerAbilityAvailable(Player(i), 'A008', true)
    call LeaderboardDisplay(udg_Leaderboard[i], false)
    call TimerDialogDisplayForPlayerBJ(false, udg_TimerWindow, Player(i))
    call PauseTimer(udg_Timer)
endfunction

function Destroy_Timer takes nothing returns nothing
    call DestroyTimerDialog(udg_TimerWindow)
    set udg_TimerWindow = null
    call PauseTimer(udg_Timer)
endfunction

function Take_Over takes integer i returns nothing
    local integer j = 0
    local location loc = GetUnitLoc(udg_Token[i])
    set udg_Status[i] = 0
    call LeaderboardDisplay(udg_Leaderboard[i], false)
    call KillUnit(udg_Token[i])
    set udg_Token[i] = CreateUnitAtLoc(Player(i), 'n009', loc, GetRandomReal(0, 360))
    call SetUnitUserData(udg_Token[i], i)
    call DestroyEffect(AddSpecialEffectLoc("Objects\\Spawnmodels\\Human\\HumanLargeDeathExplode\\HumanLargeDeathExplode.mdl", loc))
    loop
        exitwhen j > udg_FoodCap
        if udg_BuildingOwner[j] == i then
            set udg_BuildingOwner[j] = 8
            call SetUnitOwner(udg_Building[j], Player(8), true)
        endif
        set j = j + 1
    endloop
    call DisplayTimedTextToForce(GetPlayersAll(), 15, udg_PlayerName[i] + " has failed completely!")
    call StartSound(gg_snd_ArrangedTeamInvitation)
    call RemoveLocation(loc)
    set loc = null
endfunction

function Game_Over takes nothing returns nothing
    local integer i = udg_Turn[udg_Mover]
    local integer j = 0
    local location unitLoc = GetUnitLoc(udg_Token[i])
    call ClearTextMessagesBJ(GetPlayersAll())
    call DisplayTimedTextToForce(GetPlayersAll(), 15, udg_PlayerName[i] + " has won finally!")
    call StartSound(gg_snd_ArrangedTeamInvitation)
    call PolledWait(5)
    call CinematicModeExBJ(true, GetPlayersAll(), 0.5)
    call ClearSelection()
    loop
        exitwhen j > 4
        call SetCameraFieldForPlayer(Player(j), CAMERA_FIELD_FARZ, 10000, 0)
        call PanCameraToTimedLocForPlayer(Player(j), unitLoc, 5)
        call SetCameraFieldForPlayer(Player(j), CAMERA_FIELD_TARGET_DISTANCE, 500, 5)
        call SetCameraFieldForPlayer(Player(j), CAMERA_FIELD_ROTATION, GetUnitFacing(udg_Token[i])-150, 5)
        call SetCameraFieldForPlayer(Player(j), CAMERA_FIELD_ZOFFSET, 65, 5)
        set j = j + 1
    endloop
    call RemoveLocation(unitLoc)
    set unitLoc = null
    call PolledWait(2)
    call StartSound(gg_snd_ClanInvitation)
    call PolledWait(2)
    call TransmissionFromUnitWithNameBJ(GetPlayersAll(), udg_Token[i], udg_PlayerName[i], null, "I have won this war.|nI don't feel surprised at all!", 0, 5, true)
    call SetUnitAnimation(udg_Token[i], "attack")
    call TransmissionFromUnitWithNameBJ(GetPlayersAll(), udg_Token[i], udg_PlayerName[i], null, "In fact other pitiful creatures have failed from the beginning of war.|nBecause their rival is me.", 0, 5, true)
    call CinematicFadeBJ(1, 2, "ReplaceableTextures\\CameraMasks\\White_mask.blp", 0, 0, 0, 0)
    call DisplayTimedTextToForce(GetPlayersAll(), 15, "|cffffcc00Thanks you for playing!|r")
    call PolledWait(8)
    set j = 0
    loop
        exitwhen j > 4
        if j == i then
            call CustomVictoryBJ(Player(j), true, true)
        else
            call CustomDefeatBJ(Player(j), "Defeat!")
        endif
        set j = j + 1
    endloop
endfunction

function Standing takes unit whichUnit returns nothing
    local integer i = udg_Move[GetUnitUserData(whichUnit)]
    local location loc = GetUnitLoc(udg_Circle[i])
    call PauseUnit(whichUnit, true)
    call SetUnitPositionLoc(whichUnit, loc)
    call SetUnitFacing(whichUnit, udg_Signpost[i])
    call RemoveLocation(loc)
    set loc = null
    call PauseUnit(whichUnit, false)
endfunction

function Rolling takes integer i returns nothing
    set udg_TokenStatus[i] = 2
    set udg_TempPoint = GetUnitLoc(udg_Token[i])
    call SetUnitPositionLoc(udg_DiceUnit, udg_TempPoint)
    call SetUnitFlyHeight(udg_DiceUnit, 0, 0)
    call SetUnitFacing(udg_Token[i], udg_Signpost[udg_Move[i]])
    set udg_Length = 18
    call ShowUnit(udg_DiceUnit, true)
    call SetPlayerAbilityAvailableCS3(i)
    call EnableTrigger(gg_trg_Throwing)
endfunction

function Costing takes integer i, integer k, string s returns nothing
    call LeaderboardAddItemBJ(Player(4), udg_Leaderboard[i], s, k)
    call LeaderboardSetItemLabelColor(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(4)), 126, 191, 241, 255)
    call LeaderboardSetItemValueColor(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(4)), 126, 191, 241, 255)
endfunction

function Buying takes integer i, string order, integer abilid, integer abilid2 returns nothing
    call TimerDialogDisplayForPlayerBJ(true, udg_TimerWindow, Player(i))
    call ResumeTimer(udg_Timer)
    set udg_Attention = AddSpecialEffectTarget("Abilities\\Spells\\Other\\TalkToMe\\TalkToMe.mdl", udg_Token[i], "overhead")
    call SetPlayerAbilityAvailable(Player(i), abilid, false)
    call SetPlayerAbilityAvailable(Player(i), abilid2, true)
    call SetPlayerAbilityAvailable(Player(i), 'A002', true)
    if udg_Status[i] > 1 then
        call UnitResetCooldown(udg_Token[i])
        call PolledWait(0.05)
        call IssueImmediateOrder(udg_Token[i], order)
    endif
endfunction

function Selling takes unit whichUnit returns nothing
    local integer i = GetUnitUserData(whichUnit)
    local integer j = GetPlayerId(GetOwningPlayer(whichUnit))
    local integer k = udg_BuildingValue[i]
    call AdjustPlayerStateCS(-k, j, PLAYER_STATE_RESOURCE_LUMBER)
    call AdjustPlayerStateCS(k/2, j, PLAYER_STATE_RESOURCE_GOLD)
    set udg_BuildingOwner[i] = 8
    call SetUnitOwner(whichUnit, Player(8), true)
    call AddIndicator(whichUnit, 255, 255, 255, 255)
    call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\Thunderclap\\ThunderClapCaster.mdl", whichUnit, "origin"))
    call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[j] + " sells a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[i]] + "|r at discount.")
endfunction

function Camping takes integer i, integer j returns nothing
    local integer k
    local integer m
    local integer n
    set udg_TokenStatus[i] = 2
    call PolledWait(0.01)
    if j <= udg_FoodCap then
        call LeaderboardSetLabelBJ(udg_Leaderboard[i], udg_BuildingTypeName[udg_BuildingType[j]])
        call LeaderboardSetItemValue(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(0)), udg_BuildingValue[j])
        call LeaderboardSetItemValue(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(1)), udg_BuildingRent[j])
        call LeaderboardSetItemValue(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(2)), udg_BuildingLevel[j])
        call LeaderboardSetItemLabel(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(3)), "Owner      " + udg_PlayerName[udg_BuildingOwner[j]])
        call LeaderboardDisplay(udg_Leaderboard[i], true)
        if udg_BuildingOwner[j] == 8 then
            if udg_BuildingLevel[j] > 0 then
                set k = udg_BuildingValue[j]
            else
                set k = udg_BuildingValue[j] * 9 / 10
            endif
            call Costing(i, k, "Conquer")
            if GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD) > k then
                call Buying(i, "thunderclap", 'A005', 'A003')
                return
            endif
        elseif udg_BuildingOwner[j] == i then
            set k = udg_BuildingUpgrade[udg_BuildingType[j] * 2 + udg_BuildingLevel[j] - 1]
            if udg_BuildingLevel[j] > 0 and udg_BuildingLevel[j] < 3 and GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD) > k then
                call Costing(i, k, "Upgrade")
                call Buying(i, "stomp", 'A007', 'A00F')
                return
            else
                call Costing(i, 0, "Cost")
            endif
        elseif udg_BuildingLevel[j] > 0 then
            if udg_BuildingSleep[j] > 0 then
                set udg_BuildingSleep[j] = udg_BuildingSleep[j] - 1
                call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(udg_Building[j]), GetUnitY(udg_Building[j]), 5, 0, 0, 100, 0)
                call DisplayTextToForce( GetPlayersAll(), "A |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of the " + udg_PlayerName[udg_BuildingOwner[j]] + "'s is unable to charge the rent at present.")
            elseif udg_TokenFree[i] > 0 then
                call IssueTargetOrder(udg_DiceUnit, "bloodlust", udg_Token[i])
                call DisplayTextToForce( GetPlayersAll(), udg_PlayerName[i] + " is exempt from the rent.")
            else
                set k = udg_BuildingRent[j]
                set m = GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD)
                call Costing(i, k, "Cost")
                if m < k then
                    set k = m
                endif
                call AdjustPlayerStateCS(-k, i, PLAYER_STATE_RESOURCE_GOLD)
                call AdjustPlayerStateCS(k, udg_BuildingOwner[j], PLAYER_STATE_RESOURCE_GOLD)
                call DisplayTextToForce( GetPlayersAll(), udg_PlayerName[i] + " pays rent |cffffcc00" + ISignCS2(k) + "|r gold coins to " + udg_PlayerName[udg_BuildingOwner[j]] + ".")
                call IssueTargetOrder(udg_DiceUnit, "faeriefire", udg_Token[i])
                set m = GetRandomInt(1, 4)
                if m == 1 then
                    call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Orc\\Orcblood\\BattrollBlood.mdl", udg_Token[i], "origin"))
                elseif m == 2 then
                    call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Human\\HumanBlood\\BloodElfSpellThiefBlood.mdl", udg_Token[i], "origin"))
                elseif m == 3 then
                    call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Orc\\Orcblood\\OrcBloodHellScream.mdl", udg_Token[i], "origin"))
                else
                    call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Undead\\UndeadBlood\\UndeadBloodAbomination.mdl", udg_Token[i], "origin"))
                endif
                call SetUnitAnimation(udg_Token[i], "attack")
                call Destroy_Timer()
                call PolledWait(0.2)
                call SetUnitAnimation(udg_Token[i], "stand")
                call PolledWait(0.5)
                call LeaderboardDisplay(udg_Leaderboard[i], false)
                call LeaderboardRemovePlayerItemBJ(Player(4), udg_Leaderboard[i])
                call SetPlayerAbilityAvailableCS(i)
                if GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD) == 0 then
                    call Take_Over(i)
                endif
                call TriggerExecute(gg_trg_Carry_On)
                return
            endif
            call Costing(i, 0, "Cost")
        else
            call Costing(i, 0, "Cost")
        endif
        call PolledWait(0.5)
        call Destroy_Timer()
        call LeaderboardDisplay(udg_Leaderboard[i], false)
        call LeaderboardRemovePlayerItemBJ(Player(4), udg_Leaderboard[i])
    elseif j == udg_FoodCap + 1 then
        if udg_Status[i] == 4 and GetRandomInt(0, 4) == 1 then
            set k = 7
        else
            set k = GetRandomInt(0, 24)
        endif
        set n = -1
        set m = 0
        loop
            exitwhen m > 5
            if GetItemTypeId(UnitItemInSlot(udg_Token[i], m)) == udg_CardItemType[k] then
                set n = m
            endif
            set m = m + 1
        endloop
        if n != -1 then
            set m = GetItemUserData(UnitItemInSlot(udg_Token[i], n)) + 1
            call SetItemUserData(UnitItemInSlot(udg_Token[i], n), m)
            call SetItemCharges(UnitItemInSlot(udg_Token[i], n), m)
            call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Other\\ToonBoom\\ToonBoom.mdl", udg_Token[i], "origin"))
        elseif UnitInventoryCount(udg_Token[i]) < 6 then
            call UnitAddItemByIdSwapped(udg_CardItemType[k], udg_Token[i])
            call SetItemUserData(GetLastCreatedItem(), 1)
            call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Other\\ToonBoom\\ToonBoom.mdl", udg_Token[i], "origin"))
        endif
    elseif j == udg_FoodCap + 2 then
        set k = GetRandomInt(0, 17)
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[i] + udg_Event[k])
        if k < 16 then
            set m = GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD)
            if udg_Bonus[k] + m < 0 then
                call AdjustPlayerStateCS(-m, i, PLAYER_STATE_RESOURCE_GOLD)
                call Take_Over(i)
            else
                call AdjustPlayerStateCS(udg_Bonus[k], i, PLAYER_STATE_RESOURCE_GOLD)
            endif
        elseif udg_TokenSleep[i] == 0 then
            if k == 16 then
                set udg_TokenSleep[i] = 1
            else
                set udg_TokenSleep[i] = 2
            endif
        endif
    endif
    call SetPlayerAbilityAvailableCS(i)
    call TriggerExecute(gg_trg_Carry_On)
endfunction

function End_Turn takes integer i, boolean wink returns nothing
    local integer j
    set udg_TokenStatus[i] = 2
    call PauseTimer(udg_Timer)
    call DestroyEffect(udg_Attention)
    set udg_Attention = null
    if wink then
        set j = 1
        loop
            exitwhen j > 6
            if ModuloInteger(j, 2) != 0 then
                call LeaderboardSetItemLabelColor(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(4)), 255, 255, 255, 255)
                call LeaderboardSetItemValueColor(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(4)), 255, 255, 255, 255)
            else
                call LeaderboardSetItemLabelColor(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(4)), 126, 191, 241, 255)
                call LeaderboardSetItemValueColor(udg_Leaderboard[i], LeaderboardGetPlayerIndex(udg_Leaderboard[i], Player(4)), 126, 191, 241, 255)
            endif
            call PolledWait(0.12)
            set j = j + 1
        endloop
    else
        call PolledWait(0.5)
    endif
    call Destroy_Timer()
    call LeaderboardDisplay(udg_Leaderboard[i], false)
    call LeaderboardRemovePlayerItemBJ(Player(4), udg_Leaderboard[i])
    call SetPlayerAbilityAvailableCS(i)
endfunction

function Item_Charges takes integer i,unit whichUnit returns nothing
    local item whichItem = UnitItemInSlot(whichUnit, i)
    local integer j = GetItemUserData(whichItem) - 1
    if j == 0 then
        call UnitRemoveItemFromSlot(whichUnit, i)
    else
        call SetItemUserData(whichItem, j)
        call PolledWait(0.15)
        call SetItemCharges(whichItem, j)
    endif
endfunction

function Item_Charges2 takes item whichItem returns nothing
    call SetItemUserData(whichItem, GetItemUserData(whichItem)+1)
    call SetItemCharges(whichItem, GetItemCharges(whichItem)+1)
endfunction

function Item_Roaring takes integer j, unit whichUnit returns nothing
    local integer i = GetUnitUserData(whichUnit)
    local item whichItem = UnitItemInSlot(whichUnit, j)
    local integer itemTypeId = GetItemTypeId(whichItem)
    if itemTypeId == 'I003' then
        call AdjustPlayerStateCS(3000, i, PLAYER_STATE_RESOURCE_GOLD)
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[i] + " finds the gold mine. Earn |cffffcc003,000|r gold coins.")
    elseif itemTypeId == 'I002' then
        call AdjustPlayerStateCS(6000, i, PLAYER_STATE_RESOURCE_GOLD)
        call DisplayTextToForce(GetPlayersAll(), "The country where " + udg_PlayerName[i] + " ruled has obtained the great bumper harvest. Receive |cffffcc006,000|r gold coins of the repayment.")
    elseif itemTypeId == 'I000' then
        set udg_TokenFree[i] = 3
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Other\\Charm\\CharmTarget.mdl", whichUnit, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[i] + " promises not to pay the rent to any enemy.")
    else
        if udg_TokenStatus[i] == 0 then
            if itemTypeId == 'I001' then
                set udg_Dice = 1
            elseif itemTypeId == 'I006' then
                set udg_Dice = 2
            elseif itemTypeId == 'I007' then
                set udg_Dice = 3
            elseif itemTypeId == 'I004' then
                set udg_Dice = 4
            elseif itemTypeId == 'I005' then
                set udg_Dice = 5
            elseif itemTypeId == 'I008' then
                set udg_Dice = 0
            endif
            call SetPlayerAbilityAvailable(Player(i), 'A000', false)
            call SetPlayerAbilityAvailable(Player(i), 'A001', true)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Other\\HowlOfTerror\\HowlCaster.mdl", whichUnit, "origin"))
            call Rolling(i)
        else
            call Item_Charges2(whichItem)
        endif
    endif
    call Item_Charges(j, whichUnit)
endfunction

function Item_Robbery takes unit victim, unit villain returns boolean
    local integer i = 0
    local integer j = 0
    local integer k
    local integer n = 0
    local integer array count
    local integer itemTypeId
    loop
        exitwhen j > 5
        if UnitItemInSlot(victim, j) != null then
            set count[i] = j
            set i = i + 1
        endif
        set j = j + 1
    endloop
    if i > 0 then
        set k = GetRandomInt(0, i-1)
        set itemTypeId = GetItemTypeId(UnitItemInSlot(victim, count[k]))
        set i = 0
        set j = 0
        loop
            exitwhen j > 5
            if GetItemTypeId(UnitItemInSlot(villain, j)) == itemTypeId then
                set i = j + 1
                set j = 5
            endif
            set j = j + 1
        endloop
        set n = 1
        if i != 0 then
            call Item_Charges2(UnitItemInSlot(villain, i-1))
        else
            if UnitInventoryCount(villain) < 6 then
                call UnitAddItemByIdSwapped(itemTypeId, villain)
                call SetItemUserData(GetLastCreatedItem(), 1)
            else
                set n = 0
            endif
        endif
    endif
    if n == 1 then
        call Item_Charges(count[k], victim)
        return true
    endif
    return false
endfunction

function Item_Portal takes integer j returns nothing
    local integer i = 0
    local integer k
    local location loc
    loop
        exitwhen i > udg_WayPoints
        if udg_Portal[i] == j then
            set k = i
            set i = udg_WayPoints
        endif
        set i = i + 1
    endloop
    set loc = GetUnitLoc(udg_Circle[k])
    call RemoveUnit(udg_Circle[k])
    set udg_Circle[k] = null
    set udg_Circle[k] = CreateUnitAtLoc(Player(6), udg_BuildingUnitType[udg_BuildingLevel[j]+3], loc, 270)
    call SetUnitColor(udg_Circle[k], PLAYER_COLOR_GREEN)
    call RemoveLocation(loc)
    set loc = null
endfunction

function Item_RainOfFire takes integer i, unit victim returns nothing
    local location loc = GetUnitLoc(victim)
    call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 2, 100, 50, 0)
    call IssuePointOrderLoc(udg_DiceUnit, "rainoffire", loc)
    call DestroyEffect(AddSpecialEffectLoc("Abilities\\Spells\\Human\\MarkOfChaos\\MarkOfChaosTarget.mdl", loc))
    call KillUnit(victim)
    set udg_Field[i] = CreateDestructable('DTrx', GetUnitX(victim), GetUnitY(victim), 270, 1, 0)
    call ChangeElevatorHeight(udg_Field[i], 2)
    set udg_Building[i] = CreateUnitAtLoc(Player(8), 'n003', loc, 270)
    call SetUnitUserData(udg_Building[i], i)
    call RemoveLocation(loc)
    set loc = null
    if udg_BuildingLevel[i] > 1 then
        set udg_BuildingLevel[i] = 1
        call Item_Portal(i)
    endif
    set udg_BuildingValue[i] = (8 - udg_BuildingType[i] * 2) * 1000
    set udg_BuildingRent[i] = udg_BuildingValue[i] / 10
    set udg_BuildingLevel[i] = 0
    set udg_BuildingOwner[i] = 8
endfunction

function Item_AdjustStock takes integer stockId returns nothing
    local integer i = 0
    local integer j = udg_S_SharePrice[stockId] + udg_S_Swing[stockId]
    if j < 10 then
        set udg_S_Swing[stockId] = 10 - udg_S_SharePrice[stockId]
    elseif j > 200 then
        set udg_S_Swing[stockId] = 200 - udg_S_SharePrice[stockId]
    endif
    set udg_S_SharePrice[stockId] = udg_S_SharePrice[stockId] + udg_S_Swing[stockId]
    call MultiboardSetItemValueBJ(udg_Multiboard, 2, stockId+2, I2S(udg_S_SharePrice[stockId]))
    call MultiboardSetItemValueBJ(udg_Multiboard, 3, stockId+2, ISignCS(udg_S_Swing[stockId]))
    loop
        exitwhen i == udg_Players
        set j = udg_S_Amount[stockId * 5 + udg_Turn[i]] * udg_S_Swing[stockId]
        set udg_S_Amount[30+udg_Turn[i]] = udg_S_Amount[30+udg_Turn[i]] + j
        call MultiboardSetItemValueBJ(udg_Multiboard, udg_S_Column[udg_Turn[i]], 8, ISignCS2(udg_S_Amount[30+udg_Turn[i]]))
        set udg_TotalAssets[udg_Turn[i]] = udg_TotalAssets[udg_Turn[i]] + j
        set i = i + 1
    endloop
    if udg_S_Swing[stockId] > 0 then
        call MultiboardSetItemColorBJ(udg_Multiboard, 0, stockId+2, 100, 0, 0, 0)
    else
        call MultiboardSetItemColorBJ(udg_Multiboard, 0, stockId+2, 0, 100, 0, 0)
    endif
    call MultiboardSetItemColorBJ(udg_Multiboard, 1, stockId+2, 100, 80, 20, 0)
endfunction

function Item_Main takes integer i, unit victim, unit villain, integer m, integer n, integer itemTypeId returns nothing
    local integer j
    local integer k
    if itemTypeId == 'I00D' then
        set j = GetPlayerState(Player(m), PLAYER_STATE_RESOURCE_GOLD) / 5
        call AdjustPlayerStateCS(-j, m, PLAYER_STATE_RESOURCE_GOLD)
        call AdjustPlayerStateCS(j, n, PLAYER_STATE_RESOURCE_GOLD)
        call IssueTargetOrder(udg_DiceUnit, "faeriefire", victim)
        call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Human\\HumanLargeDeathExplode\\HumanLargeDeathExplode.mdl", victim, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1levy a tax|r card to " + udg_PlayerName[m] + ". The victim " + udg_PlayerName[m] + " is levied a tax by force.")
    elseif itemTypeId == 'I009' then
        set j = GetPlayerState(Player(n), PLAYER_STATE_RESOURCE_GOLD) + GetPlayerState(Player(m), PLAYER_STATE_RESOURCE_GOLD)
        set k = ModuloInteger(j, 2)
        set j = j / 2
        call SetPlayerStateCS(n, PLAYER_STATE_RESOURCE_GOLD, j+k)
        call SetPlayerStateCS(m, PLAYER_STATE_RESOURCE_GOLD, j)
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\Resurrect\\ResurrectCaster.mdl", victim, "origin"))
        call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Human\\HumanLargeDeathExplode\\HumanLargeDeathExplode.mdl", victim, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1even and rich|r card to " + udg_PlayerName[m] + ". The victim " + udg_PlayerName[m] + " is dismembered the property by force.")
    elseif itemTypeId == 'I00A' then
        set udg_TokenSleep[m] = 3
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Undead\\DeathCoil\\DeathCoilSpecialArt.mdl", victim, "origin"))
        call DisplayTextToForce( GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1plot against|r card to " + udg_PlayerName[m] + ". The victim " + udg_PlayerName[m] + " is plotted against. |cffa0ff003|r rounds stop.")
    elseif itemTypeId == 'I00C' then
        call Item_Charges(i, villain)
        if Item_Robbery(victim, villain) then
            call IssueTargetOrder(udg_DiceUnit, "shadowstrike", victim)
            call DestroyEffect(AddSpecialEffectTarget("Objects\\Spawnmodels\\Other\\ToonBoom\\ToonBoom.mdl", villain, "origin"))
            call DisplayTextToForce( GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1robbery|r card to " + udg_PlayerName[m] + ". The victim " + udg_PlayerName[m] + " is robbed.")
        else
            call DisplayTextToForce(bj_FORCE_PLAYER[n], "|cffa0ff00Have robbed and failed!|r")
        endif
        return
    elseif itemTypeId == 'I00E' then
        set udg_SnapToken[m] = 1
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\Feedback\\ArcaneTowerAttack.mdl", victim, "overhead"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1fix the body|r card to " + udg_PlayerName[m] + ". The victim " + udg_PlayerName[m] + " has the body fixed.")
    elseif itemTypeId == 'I00B' then
        set j = udg_Turn[udg_Mover]
        set k = GetPlayerState(Player(m), PLAYER_STATE_RESOURCE_GOLD)
        if k <= 2000 and m == j then
            if udg_TokenStatus[j] == 1 then
                call Item_Charges2(UnitItemInSlot(villain, i))
                set j = -1
            endif
        endif
        if j != -1 then
            if k > 2000 then
                set k = 2000
            endif
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\Polymorph\\PolyMorphFallingSheepArt.mdl", victim, "overhead"))
            call AdjustPlayerStateCS(-k, m, PLAYER_STATE_RESOURCE_GOLD)
            call DisplayTextToForce( GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1bad luck|r card to " + udg_PlayerName[m] + ". The victim " + udg_PlayerName[m] + "'s quilt bad luck.")
            if GetPlayerState(Player(m), PLAYER_STATE_RESOURCE_GOLD) == 0 then
                if m == j then
                    call PauseTimer(udg_Timer)
                    call Destroy_Timer()
                    call Take_Over(m)
                    call TriggerExecute(gg_trg_Carry_On)
                else
                    call Take_Over(m)
                endif
            endif
        endif
    elseif itemTypeId == 'I00K' then
        set j = GetUnitUserData(victim)
        set k = udg_BuildingValue[j]
        call AdjustPlayerStateCS(-k, m, PLAYER_STATE_RESOURCE_LUMBER)
        call AdjustPlayerStateCS(k, n, PLAYER_STATE_RESOURCE_LUMBER)
        set udg_BuildingOwner[j] = n
        call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 2, 100, 50, 0)
        call SetUnitOwner(victim, Player(n), true)
        call AddIndicator(victim, 255, 255, 255, 255)
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Orc\\WarStomp\\WarStompCaster.mdl", victim, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1conquer by force|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It is conquered by force.")
    elseif itemTypeId == 'I00G' then
        set j = GetUnitUserData(victim)
        set k = udg_BuildingValue[j]
        call AdjustPlayerStateCS(-k, m, PLAYER_STATE_RESOURCE_LUMBER)
        call AdjustPlayerStateCS(k/2, m, PLAYER_STATE_RESOURCE_GOLD)
        set udg_BuildingOwner[j] = 8
        call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 2, 100, 50, 0)
        call SetUnitOwner(victim, Player(8), true)
        call AddIndicator(victim, 255, 255, 255, 255)
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\Thunderclap\\ThunderClapCaster.mdl", victim, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1sell by force|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It is sold by force.")
    elseif itemTypeId == 'I00I' then
        set j = GetUnitUserData(victim)
        if udg_BuildingLevel[j] > 0 then
            call AdjustPlayerStateCS(-udg_BuildingValue[j], m, PLAYER_STATE_RESOURCE_LUMBER)
            call Item_RainOfFire(j, victim)
            call DisplayTextToForce( GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1destruction|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It is levelled to the ground.")
            call Item_Charges(i, villain)
            call PolledWait(5)
            call RemoveUnit(victim)
            set victim = null
            return
        else
            call DisplayTextToForce(bj_FORCE_PLAYER[n], "|cffa0ff00The|r |cff7ebff1destruction|r |cffa0ff00card has been used and failed!|r")
        endif
    elseif itemTypeId == 'I00H' then
        set udg_BuildingSleep[GetUnitUserData(victim)] = 3
        call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 0, 0, 100, 0)
        call IssueTargetOrder(udg_DiceUnit, "freezingbreath", victim)
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1ice-bound|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[GetUnitUserData(victim)]] + "|r of " + udg_PlayerName[m] + "'s. It has been sealed by the ice and snow.")
    elseif itemTypeId == 'I00M' then
        set j = GetUnitUserData(victim)
        if udg_BuildingLevel[j] > 0 and udg_BuildingLevel[j] < 3 then
            set k = udg_BuildingUpgrade[(udg_BuildingType[j] - 1) * 2 + udg_BuildingLevel[j]]
            call AdjustPlayerStateCS(k, m, PLAYER_STATE_RESOURCE_LUMBER)
            set udg_BuildingValue[j] = udg_BuildingValue[j] + k
            set udg_BuildingRent[j] = udg_BuildingRent[j] * 9 / 5
            set udg_BuildingLevel[j] = udg_BuildingLevel[j] + 1
            call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 0, 100, 50, 0)
            call AddIndicator(victim, 255, 255, 255, 255)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Other\\Awaken\\Awaken.mdl", victim, "origin"))
            call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1upgrade|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It is succeeded in extending.")
            call Item_Portal(j)
        else
            call DisplayTextToForce(bj_FORCE_PLAYER[n], "|cffa0ff00Have extended and failed.|r")
        endif
    elseif itemTypeId == 'I00L' then
        set j = GetUnitUserData(victim)
        set k = udg_BuildingValue[j] / 5
        call AdjustPlayerStateCS(k, m, PLAYER_STATE_RESOURCE_LUMBER)
        set udg_BuildingValue[j] = udg_BuildingValue[j] + k
        set udg_BuildingRent[j] = udg_BuildingRent[j] * 6 / 5
        call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 1, 100, 50, 0)
        call AddIndicator(victim, 255, 255, 255, 255)
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\ReviveHuman\\ReviveHuman.mdl", victim, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1prosperity|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It is more prosperous.")
    elseif itemTypeId == 'I00J' then
        set j = GetUnitUserData(victim)
        set k = udg_BuildingValue[j] / 5
        call AdjustPlayerStateCS(-k, m, PLAYER_STATE_RESOURCE_LUMBER)
        set udg_BuildingValue[j] = udg_BuildingValue[j] - k
        set udg_BuildingRent[j] = udg_BuildingRent[j] * 4 / 5
        call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 0, 0, 100, 0)
        call AddIndicator(victim, 255, 255, 255, 255)
        call DestroyEffect(AddSpecialEffectTarget("Units\\NightElf\\Wisp\\WispExplode.mdl", victim, "origin"))
        call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1decline|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It has declined further.")
    elseif itemTypeId == 'I00F' then
        set j = GetUnitUserData(victim)
        if udg_BuildingLevel[j] > 1 then
            set udg_BuildingLevel[j] = udg_BuildingLevel[j] - 1
            set k = udg_BuildingUpgrade[(udg_BuildingType[j] - 1) * 2 + udg_BuildingLevel[j]]
            call AdjustPlayerStateCS(-k, m, PLAYER_STATE_RESOURCE_LUMBER)
            set udg_BuildingValue[j] = udg_BuildingValue[j] - k
            set udg_BuildingRent[j] = udg_BuildingRent[j] / 5
            call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(victim), GetUnitY(victim), 5, 2, 100, 50, 0)
            call AddIndicator(victim, 255, 255, 255, 255)
            call DestroyEffect(AddSpecialEffectTarget("Units\\Demon\\Infernal\\InfernalBirth.mdl", victim, "origin"))
            call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1subversion|r card to a |cff7ebff1" + udg_BuildingTypeName[udg_BuildingType[j]] + "|r of " + udg_PlayerName[m] + "'s. It has been demoted.")
            call Item_Portal(j)
        else
            call DisplayTextToForce(bj_FORCE_PLAYER[n], "|cffa0ff00Have subverted and failed.|r")
        endif
    endif
    call Item_Charges(i, villain)
endfunction

function CheckStockId takes string source, integer start,integer end, integer start2, integer end2 returns integer
    local integer i = -1
    local integer j = 0
    loop
        exitwhen j > 5
        if SubString(source, start, end) == SubString(udg_S_Acronym[j], start2, end2) then
            set i = j
            set j = 5
        endif
        set j = j + 1
    endloop
    return i
endfunction

function CheckStockItemSlot takes unit whichUnit,integer itemtypeId returns integer
    local integer i = -1
    local integer j = 0
    loop
        exitwhen j > 5
        if GetItemTypeId(UnitItemInSlot(whichUnit, j)) == itemtypeId then
            set i = j
            set j = 5
        endif
        set j = j + 1
    endloop
    return i
endfunction

function Stock_Exchange takes string chatString, integer n returns nothing
    local integer i
    local integer j = 0
    local integer k
    local integer m
    if SubString(chatString, 0, 4) == "buy " then
        set i = CheckStockId(chatString, 4, 7, 0, 3)
        if i != -1 then
            set j = S2I(SubString(chatString, 7, StringLength(chatString)))
            set k = udg_S_SharePrice[i] * j
            if k < GetPlayerState(Player(n), PLAYER_STATE_RESOURCE_GOLD) then
                set m = i * 5 + n
                call AdjustPlayerStateCS(-k, n, PLAYER_STATE_RESOURCE_GOLD)
                set udg_TotalAssets[n] = udg_TotalAssets[n] + k
                set udg_S_Amount[m] = udg_S_Amount[m] + j
                set udg_S_Amount[30+n] = udg_S_Amount[30+n] + k
                call MultiboardSetItemValueBJ(udg_Multiboard, udg_S_Column[n], i+2, I2S(udg_S_Amount[m]))
                call MultiboardSetItemValueBJ(udg_Multiboard, udg_S_Column[n], 8, ISignCS2(udg_S_Amount[30+n]))
            else
                call DisplayTextToForce(bj_FORCE_PLAYER[n], "|cffa0ff00You don't have enough money.|r")
            endif
        endif
    elseif SubString(chatString, 0, 5) == "sell " then
        set i = CheckStockId(chatString, 5, 8, 0, 3)
        if i != -1 then
            set j = S2I(SubString(chatString, 8, StringLength(chatString)))
            set m = i * 5 + n
            if j <= udg_S_Amount[m] then
                set k = udg_S_SharePrice[i] * j
                call AdjustPlayerStateCS(k, n, PLAYER_STATE_RESOURCE_GOLD)
                set udg_TotalAssets[n] = udg_TotalAssets[n] - k
                set udg_S_Amount[m] = udg_S_Amount[m] - j
                set udg_S_Amount[30+n] = udg_S_Amount[30+n] - k
                call MultiboardSetItemValueBJ(udg_Multiboard, udg_S_Column[n], i+2, I2S(udg_S_Amount[m]))
                call MultiboardSetItemValueBJ(udg_Multiboard, udg_S_Column[n], 8, ISignCS2(udg_S_Amount[30+n]))
            else
                call DisplayTextToForce(bj_FORCE_PLAYER[n], "|cffa0ff00You don't have enough stock.|r")
            endif
        endif
    else
        if SubString(chatString, 0, 5) == "rise " then
            set j = CheckStockItemSlot(udg_Token[n], 'I00N')
            set k = 5
        elseif SubString(chatString, 0, 5) == "fall " then
            set j = CheckStockItemSlot(udg_Token[n], 'I00O')
            set k = -5
        endif
        if j != -1 then
            set i = CheckStockId(chatString, 5, StringLength(chatString), 0, 2)
            if i != -1 then
                if udg_S_SharePrice[i] > 1 or k > 0 then
                    set udg_S_Swing[i] = udg_S_SharePrice[i] / k
                    call Item_AdjustStock(i)
                endif
                call Item_Charges(j, udg_Token[n])
                if k > 0 then
                    call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1bull market|r card. |cff7ebff1" + udg_S_StockName[i] + "|r's stock price rises sharply!")
                else
                    call DisplayTextToForce(GetPlayersAll(), udg_PlayerName[n] + " use |cff7ebff1bear market|r card. |cff7ebff1" + udg_S_StockName[i] + "|r's stock price falls furiously!")
                endif
            endif
        endif
    endif
endfunction

function BotsGamble takes integer j returns nothing
    local integer i = udg_Turn[udg_Mover]
    local integer k = GetRandomInt(0, 5)
    local integer m
    local string chatString = SubString(udg_S_Acronym[k], 0, 2)
    local string chatString2
    if j == 23 then
        set chatString = "rise " + chatString
        if udg_Status[i] == 4 then
            set m = (GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD) - 1) / udg_S_SharePrice[k]
            set chatString2 = "buy " + udg_S_Acronym[k] + I2S(m)
            call Stock_Exchange(chatString2, i)
            call PolledWait(0.1)
            call Stock_Exchange(chatString, i)
            call PolledWait(0.1)
            set chatString2 = "sell " + udg_S_Acronym[k] + I2S(m)
            call Stock_Exchange(chatString2, i)
        endif
    else
        set chatString = "fall " + chatString
        call Stock_Exchange(chatString, i)
    endif
endfunction

function BotsUseItem takes unit whichUnit returns integer
    local integer i = 0
    local integer j
    local integer k = 0
    local integer m = 0
    local integer n
    local integer a = 0
    local integer array count
    local item whichItem
    loop
        exitwhen i > 5
        if UnitItemInSlot(whichUnit, i) != null then
            set count[a] = i
            set a = a + 1
        endif
        set i = i + 1
    endloop
    if a > 0 then
        set whichItem = UnitItemInSlot(whichUnit, count[GetRandomInt(0, a-1)])
        set i = 0
        loop
            exitwhen i > 24
            if GetItemTypeId(whichItem) == udg_CardItemType[i] then
                set j = i
                set i = 24
            endif
            set i = i + 1
        endloop
        if j < 6 then
            set udg_TokenStatus[udg_Turn[udg_Mover]] = 0
            call UnitUseItem(whichUnit, whichItem)
            return 1
        elseif j > 5 and j < 8 then
            call UnitUseItem(whichUnit, whichItem)
        elseif j == 8 then
            if udg_TokenFree[udg_Turn[udg_Mover]] < 1 then
                call UnitUseItem(whichUnit, whichItem)
            endif
        elseif j > 8 and j < 11 then
            set i = 0
            loop
                exitwhen i == udg_Players
                if i != udg_Mover then
                    set n = GetPlayerState(Player(udg_Turn[i]), PLAYER_STATE_RESOURCE_GOLD)
                    if n > m then
                        set m = n
                        set count[k] = i
                        set k = k + 1
                    endif
                endif
                set i = i + 1
            endloop
            if GetPlayerState(Player(udg_Turn[udg_Mover]), PLAYER_STATE_RESOURCE_GOLD) < m or j == 9 then
                call UnitUseItemTarget(whichUnit, whichItem, udg_Token[udg_Turn[count[GetRandomInt(0, k-1)]]])
            endif
        elseif j > 10 and j < 15 then
            set i = 0
            loop
                exitwhen i == udg_Players
                if i != udg_Mover then
                    set count[k] = i
                    set k = k + 1
                endif
                set i = i + 1
            endloop
            call UnitUseItemTarget(whichUnit, whichItem, udg_Token[udg_Turn[count[GetRandomInt(0, k-1)]]])
        elseif j > 14 and j < 17 then
            set n = GetPlayerState(Player(udg_Turn[udg_Mover]), PLAYER_STATE_RESOURCE_FOOD_USED)
            if n > 0 then
                set m = 0
                set i = 0
                loop
                    exitwhen i > udg_FoodCap
                    if udg_BuildingOwner[i] == udg_Turn[udg_Mover] then
                        set count[m] = i
                        set m = m + 1
                        if m == n then
                            set i = udg_FoodCap
                        endif
                    endif
                    set i = i + 1
                endloop
                set k = GetRandomInt(0, m-1)
                call UnitUseItemTarget(whichUnit, whichItem, udg_Building[count[k]])
            endif
        elseif j > 16 and j < 21 then
            set n = udg_FoodCap + 1 - GetPlayerState(Player(8), PLAYER_STATE_RESOURCE_FOOD_USED) - GetPlayerState(Player(udg_Turn[udg_Mover]), PLAYER_STATE_RESOURCE_FOOD_USED)
            if n > 0 then
                set m = 0
                set i = 0
                loop
                    exitwhen i > udg_FoodCap
                    if udg_BuildingOwner[i] != 8 and udg_BuildingOwner[i] != udg_Turn[udg_Mover] then
                        set count[m] = i
                        set m = m + 1
                        if m == n then
                            set i = udg_FoodCap
                        endif
                    endif
                    set i = i + 1
                endloop
                set k = GetRandomInt(0, m-1)
                call UnitUseItemTarget(whichUnit, whichItem, udg_Building[count[k]])
            endif
        elseif j > 20 and j < 23 then
            set n = udg_FoodCap + 1 - GetPlayerState(Player(udg_Turn[udg_Mover]), PLAYER_STATE_RESOURCE_FOOD_USED)
            if n > 0 then
                set m = 0
                set i = 0
                loop
                    exitwhen i > udg_FoodCap
                    if udg_BuildingOwner[i] != udg_Turn[udg_Mover] then
                        set count[m] = i
                        set m = m + 1
                        if m == n then
                            set i = udg_FoodCap
                        endif
                    endif
                    set i = i + 1
                endloop
                set k = GetRandomInt(0, m-1)
                call UnitUseItemTarget(whichUnit, whichItem, udg_Building[count[k]])
            endif
        else
            call BotsGamble(j)
        endif
    endif
    return 0
endfunction

function Auto takes integer i returns nothing
    set udg_Status[i] = 4
    call UnitResetCooldown(udg_Token[i])
    call PolledWait(0.05)
    call IssueImmediateOrder(udg_Token[i], "howlofterror")
    call IssueImmediateOrder(udg_Token[i], "thunderclap")
    call IssueImmediateOrder(udg_Token[i], "stomp")
endfunction

function Take_Turns takes nothing returns nothing
    local integer i = udg_Turn[udg_Mover]
    local integer j = 0
    if udg_TokenFree[i] > 0 then
        set udg_TokenFree[i] = udg_TokenFree[i] - 1
    endif
    loop
        exitwhen j == 1
        if udg_Mover == udg_Players - 1 then
            set udg_Mover = 0
            set udg_Round = udg_Round + 1
            if ModuloInteger(udg_Round, 6) == 0 then
                set i = 0
                loop
                    exitwhen i > udg_FoodCap
                    set udg_BuildingRent[i] = udg_BuildingRent[i] * 7 / 5
                    set i = i + 1
                endloop
            endif
        else
            set udg_Mover = udg_Mover + 1
        endif
        if udg_Status[udg_Turn[udg_Mover]] == 0 then
            set udg_Players = udg_Players - 1
            call MultiboardMinimize(udg_Multiboard, false)
            call DisableTrigger(gg_trg_Chat_String)
            set i = 0
            loop
                exitwhen i == udg_Mover
                call MultiboardSetItemWidthBJ(udg_Multiboard, i+4, 0, BoardWidth())
                set i = i + 1
            endloop
            loop
                exitwhen i == udg_Players
                set udg_Turn[i] = udg_Turn[i+1]
                set udg_S_Column[udg_Turn[i]] = i+4
                call MultiboardSetItemValueBJ(udg_Multiboard, i+4, 1, udg_PlayerName[udg_Turn[i]])
                set j = 0
                loop
                    exitwhen j > 5
                    call MultiboardSetItemValueBJ(udg_Multiboard, i+4, j+2, I2S(udg_S_Amount[j*5+udg_Turn[i]]))
                    set j = j + 1
                endloop
                call MultiboardSetItemValueBJ(udg_Multiboard, i+4, j+2, ISignCS2(udg_S_Amount[30+udg_Turn[i]]))
                call MultiboardSetItemWidthBJ(udg_Multiboard, i+4, 0, BoardWidth())
                set i = i + 1
            endloop
            set j = 0
            call MultiboardSetItemStyleBJ(udg_Multiboard, i+4, 0, false, false)
            call PolledWait(0.01)
            call MultiboardSetColumnCount(udg_Multiboard, i+3)
            call EnableTrigger(gg_trg_Chat_String)
            set udg_Mover = udg_Mover - 1
        else
            set i = udg_Turn[udg_Mover]
            if udg_TokenSleep[i] == 0 then
                set j = 1
            else
                set udg_TokenSleep[i] = udg_TokenSleep[i] - 1
                call IssueTargetOrder(udg_DiceUnit, "sleep", udg_Token[i])
            endif
        endif
    endloop
    set j = 0
    loop
        exitwhen j == udg_Players
        if udg_LockCamera[j] then
            call SetCameraTargetControllerNoZForPlayer(Player(j), udg_Token[i], 0, 0, false)
        endif
        set j = j + 1
    endloop
endfunction

function Stock_Swing takes integer j returns nothing
    local integer i = 0
    if udg_Round > j then
        call DisableTrigger(gg_trg_Chat_String)
        loop
            exitwhen i > 5
            if udg_S_Periods[i] == 0 then
                if udg_S_SharePrice[i] == 10 and GetRandomInt(1, 5) == 1 then
                    set udg_S_Swing[i] = 1
                else
                    set udg_S_Swing[i] = GetRandomInt(-udg_S_SharePrice[i]/10, udg_S_SharePrice[i]/10-1)
                endif
                if udg_S_Swing[i] < 1 then
                    set udg_S_Periods[i] = GetRandomInt(1, 3)
                else
                    set udg_S_Periods[i] = GetRandomInt(1, 2)
                endif
            endif
            call Item_AdjustStock(i)
            set udg_S_Periods[i] = udg_S_Periods[i] - 1
            set i = i + 1
        endloop
        call EnableTrigger(gg_trg_Chat_String)
    endif
endfunction

function Building_Company takes nothing returns nothing
    local integer i
    local integer j = 0
    local integer k
    loop
        exitwhen j == udg_Builds
        set i = udg_BuildingSite[j]
        set udg_BuildingSiteTime[i] = udg_BuildingSiteTime[i] - 1
        if udg_BuildingSiteTime[i] <= 0 then
            call ChangeElevatorHeight(udg_Field[i], 1)
            call PingMinimapForForceEx(GetPlayersAll(), GetUnitX(udg_Building[i]), GetUnitY(udg_Building[i]), 5, 1, 0, 100, 0)
            call RemoveUnit(udg_Building[i])
            set udg_Building[i] = null
            set udg_TempPoint = GetDestructableLoc(udg_Field[i])
            call DestroyEffect(AddSpecialEffectLoc("Abilities\\Spells\\Other\\Awaken\\Awaken.mdl", udg_TempPoint))
            call PolledWait(0.5)
            call RemoveDestructable(udg_Field[i])
            set udg_Field[i] = null
            call PolledWait(0.01)
            set udg_Building[i] = CreateUnitAtLoc(Player(udg_BuildingOwner[i]), udg_BuildingUnitType[udg_BuildingType[i]], udg_TempPoint, 270)
            call SetUnitUserData(udg_Building[i], i)
            call RemoveLocation(udg_TempPoint)
            set udg_TempPoint = null
            set udg_BuildingLevel[i] = 1
            set udg_BuildingSite[j] = udg_BuildingSite[udg_Builds-1]
            set j = j - 1
            set udg_Builds = udg_Builds - 1
        endif
        set j = j + 1
    endloop
endfunction

function Next_Player takes nothing returns nothing
    local integer i = udg_Turn[udg_Mover]
    local integer j = 0
    local integer k = 0
    call TimerStart(udg_Timer, 40, false, null)
    set udg_TimerWindow = CreateTimerDialogBJ(udg_Timer, "Timer")
    call TimerDialogDisplay(udg_TimerWindow, false)
    call TimerDialogDisplayForPlayerBJ(true, udg_TimerWindow, Player(i))
    set udg_Attention = AddSpecialEffectTarget("Abilities\\Spells\\Other\\TalkToMe\\TalkToMe.mdl", udg_Token[i], "overhead")
    call SetPlayerAbilityAvailable(Player(i), 'A001', false)
    call SetPlayerAbilityAvailable(Player(i), 'A000', true)
    if udg_SnapToken[i] == 1 then
        set udg_SnapToken[i] = 0
        call SetPlayerAbilityAvailableCS3(i)
        call SetPlayerAbilityAvailable(Player(i), 'A000', false)
        call SetPlayerAbilityAvailable(Player(i), 'A001', true)
        call IssueTargetOrder(udg_DiceUnit, "entanglingroots", udg_Token[i])
        call PolledWait(0.5)
        call Camping(i, udg_Portal[udg_Move[i]])
    elseif udg_Status[i] > 1 then
        if udg_Status[i] == 3 then
            set j = GetRandomInt(1, 5)
        elseif udg_Status[i] == 4 then
            set j = GetRandomInt(1, 3)
        endif
        if j == 1 then
            set k = BotsUseItem(udg_Token[i])
        endif
        if k == 0 then
            call UnitResetCooldown(udg_Token[i])
            call PolledWait(0.05)
            call IssueImmediateOrder(udg_Token[i], "howlofterror")
        endif
    else
        set udg_TokenStatus[i] = 0
    endif
endfunction