Triggers

library RemoveEffect
//Destroying an effect always plays its death animation and any associated sounds.
//This library fixes it in a simple way: move the effect to a location where nobody can see or hear it.

//By Pyrogasm, additional help by Bribe
//v1.1

globals
    private real SAFE_X = -3900.
    private real SAFE_Y =  3900.
    private real SAFE_Z = -1000.

    private real TIMESCALE = 10. //doesn't really matter what this is but we set it to > 0 so the animations actually finish
endglobals

function RemoveEffect takes effect e returns nothing
    call BlzSetSpecialEffectAlpha(e, 255)
    call BlzSetSpecialEffectZ(e, SAFE_Z)
    call BlzSetSpecialEffectPosition(e, SAFE_X, SAFE_Y, SAFE_Z)
    call BlzSetSpecialEffectTimeScale(e, TIMESCALE)
    call DestroyEffect(e)
endfunction
endlibrary

library GetLocZ
    globals
        private location moveableLoc = Location(0, 0)
    endglobals

    function GetLocZ takes real x, real y returns real
        call MoveLocation(moveableLoc, x, y)
        return GetLocationZ(moveableLoc)
    endfunction
endlibrary

library AddSpecialEffectTerrainAligned requires GetLocZ
    function AddSpecialEffectTerrainAligned takes string effectPath, real x, real y, real yaw returns effect
        local effect newEffect = AddSpecialEffect(effectPath, x, y)
        local real dzdx = (GetLocZ(x + 1, y) - GetLocZ(x - 1, y))/2
        local real dzdy = (GetLocZ(x, y + 1) - GetLocZ(x, y - 1))/2
        local real nx = -dzdx
        local real ny = -dzdy
        local real totalAngle = Acos(1/SquareRoot(nx*nx + ny*ny + 1))
        local real phiNormal = Atan2(ny, nx)
        local real pitch = totalAngle*Cos(yaw - phiNormal)
        local real roll = totalAngle*Sin(yaw - phiNormal)

        call BlzSetSpecialEffectOrientation(newEffect, yaw, pitch, roll)

        return newEffect
    endfunction

    function TerrainAlignEffect takes effect whichEffect returns nothing
        local real x = BlzGetLocalSpecialEffectX(whichEffect)
        local real y = BlzGetLocalSpecialEffectY(whichEffect)
        local real dzdx = (GetLocZ(x + 1, y) - GetLocZ(x - 1, y))/2
        local real dzdy = (GetLocZ(x, y + 1) - GetLocZ(x, y - 1))/2
        local real nx = -dzdx
        local real ny = -dzdy
        local real totalAngle = Acos(1/SquareRoot(nx*nx + ny*ny + 1))
        local real phiNormal = Atan2(ny, nx)
        local real pitch = totalAngle*Cos(-phiNormal)
        local real roll = totalAngle*Sin(-phiNormal)

        call BlzSetSpecialEffectOrientation(whichEffect, 0, pitch, roll)
    endfunction


endlibrary

//Place these functions at map header (Jass) or in a library/module (vJass)
library TimedEffect
function CreateTimedEffectOnUnit takes string mdl, unit target, string attach, real duration returns nothing
	set udg_TSELL_EffectName = mdl
	set udg_TSELL_TargetUnit = target
	set udg_TSELL_AttachPoint = attach
	set udg_TSELL_Duration = duration
	call ConditionalTriggerExecute( udg_TSELL_TriggerRegister )
endfunction

function CreateTimedEffectOnLoc takes string mdl, real x, real y, real duration returns nothing
	set udg_TSELL_EffectName = mdl
	set udg_TSELL_Point = Location(x,y)
	set udg_TSELL_Duration = duration
	call ConditionalTriggerExecute( udg_TSELL_TriggerRegister )
endfunction
endlibrary