Triggers

constant function JassBoolFilter takes nothing returns boolean
    return TRUE
endfunction

constant function DD_Ptr takes handle h returns integer
    return h
    return 0
endfunction

constant function ToRegion takes integer pointer returns region
    return pointer
    return null
endfunction

constant function GetDummyFilter takes nothing returns filterfunc
    return udg_this_filter
    return null
endfunction

constant function DD_Mod takes integer a, integer b returns integer
    return (a - (a/b) * b)
endfunction

function DD_PlayPortal takes location where, string id returns nothing
    local sound s = null

    if (id == "birth") then
        set s = CreateSound( "Sound\\Ambient\\DoodadEffects\\ShimmeringPortalBirth.wav", false, true, true, 10, 10, "DefaultEAXON" )
        call SetSoundParamsFromLabel( s, "ShimmeringPortalBirth" )
    elseif (id == "death") then
        set s = CreateSound( "Sound\\Ambient\\DoodadEffects\\ShimmeringPortalDeath.wav", false, true, true, 10, 10, "DefaultEAXON" )
        call SetSoundDuration( s, 8529 )
        call SetSoundParamsFromLabel( s, "ShimmeringPortalDeath" )
    elseif (id == "enter") then
        set s = CreateSound( "Sound\\Ambient\\DoodadEffects\\ShimmeringPortalEntrance.wav", false, true, true, 10, 10, "DefaultEAXON" )
        call SetSoundParamsFromLabel( s, "EnterShimmeringPortal" )
        call SetSoundDuration( s, 1829 )
    endif

    if (where == null) then
        call SetSoundPosition(s, 0., 0., 0.)
        call SetSoundVolume(s, 1)
        call StartSound(s)
        call KillSoundWhenDone(s)
        set s = null
        return
    endif
    call SetSoundPosition(s, GetLocationX(where), GetLocationY(where), 0.)
    call StartSound(s)
    call KillSoundWhenDone(s)

    set bj_lastPlayedSound = s
    set s = null
endfunction

constant function this_id takes handle obj returns integer
    return DD_Mod( DD_Ptr( obj ), JASS_MAX_ARRAY_SIZE )
endfunction

constant function Min4 takes real a, real b, real c, real d returns real
    if (a < b and a < c and a < d) then
        return a
    elseif (b < c and b < d) then
        return b
    elseif (c < d) then
        return c
    endif
    return d
endfunction

constant function Max4 takes real a, real b, real c, real d returns real
    if (a > b and a > c and a > d) then
        return a
    elseif (b > c and b > d) then
        return b
    elseif (c > d) then
        return c
    endif
    return d
endfunction

constant function GetTriggeringRect takes nothing returns rect
    return udg_Temp_Trig_Rect[this_id(GetTriggeringRegion())]
endfunction

function TeleportUnitActions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real x
    local real y
    local rect r
    local real d
    local location l
    local integer id = this_id(GetTriggeringTrigger())
    local real rad

    // No flying units or is unit dead?
    if ((IsUnitType(u, UNIT_TYPE_FLYING) and not udg_Portal_AllowFlyingUnits) or IsUnitType(u, UNIT_TYPE_DEAD)) then
        set u = null
        return
    endif

    // Unit is teleported
    if (udg_SP_UnitTeleported[this_id(u)]) then
        set udg_SP_UnitTeleported[this_id(u)] = false
        set u = null
        return
    endif

    set udg_SP_UnitTeleported[this_id(u)] = true
    
    // First portal is entred
    set r = GetTriggeringRect()
    if (r == udg_SP_Rect1[id]) then
        set r = udg_SP_Rect2[id]
    else
    // Second portal is entred
        set r = udg_SP_Rect1[id]
    endif
    set rad = GetUnitFacing(u) * bj_DEGTORAD
    set x = GetRandomReal(GetRectMinX(r), GetRectMaxX(r))
    set y = GetRandomReal(GetRectMinY(r), GetRectMaxY(r))

    if (IsTerrainPathable(x, y, PATHING_TYPE_WALKABILITY)) then
        set u = null
        set r = null
        return
    endif
    
    set l = Location(GetUnitX(u), GetUnitY(u))
    call DD_PlayPortal(l, "enter")
    if (udg_Portal_EffectOnEnter != "") then
        call DestroyEffect(AddSpecialEffectLoc(udg_Portal_EffectOnEnter, l))
    endif
    call RemoveLocation(l)
    
    call SetUnitPosition(u, x, y)
    set d = GetRandomReal(150., 200.)
    call IssuePointOrder(u, "move", x+d*Cos(rad), y+d*Sin(rad))
    
    if (udg_Portal_PanCamera) then
        if (GetLocalPlayer() == GetOwningPlayer(u)) then
            call PanCameraToTimed(x, y, 0.05)
        endif
    endif
    
    if (udg_Portal_EffectOnExit != "") then
        call DestroyEffect(AddSpecialEffect(udg_Portal_EffectOnExit, x, y))
    endif
    
    set u = null
    set r = null
    set l = null
endfunction


function TriggerRegisterUnitEnterPortal takes trigger t, location where, real angle, integer var returns event
    local real x = GetLocationX(where)
    local real y = GetLocationY(where)
    local real w = udg_Portal_Weight
    local real h = udg_Portal_Height
    local real d = SquareRoot(0.25*((w*w)+(h*h)))
    local real rad = Atan(h/w)
    local real x1 = x + d * Cos(angle+rad)
    local real y1 = y + d * Sin(angle+rad)
    local real x2 = x - d * Cos(angle-rad)
    local real y2 = y - d * Sin(angle-rad)
    local real x3 = x - d * Cos(angle+rad)
    local real y3 = y - d * Sin(angle+rad)
    local real x4 = x + d * Cos(angle-rad)
    local real y4 = y + d * Sin(angle-rad)
    local real minx = Min4(x1, x2, x3, x4)
    local real miny = Min4(y1, y2, y3, y4)
    local real maxx = Max4(x1, x2, x3, x4)
    local real maxy = Max4(y1, y2, y3, y4)
    local integer id = this_id(t)
    if (var == 0) then
        set udg_SP_Region1[id] = DD_Ptr(CreateRegion())
        set udg_SP_Rect1[id] = Rect(minx, miny, maxx, maxy)
        set udg_Temp_Trig_Rect[DD_Mod(udg_SP_Region1[id], JASS_MAX_ARRAY_SIZE)] = udg_SP_Rect1[id]
        call RegionAddRect(ToRegion(udg_SP_Region1[id]), udg_SP_Rect1[id])
        return TriggerRegisterEnterRegion(t, ToRegion(udg_SP_Region1[id]), GetDummyFilter())
    else
        set udg_SP_Region2[id] = DD_Ptr(CreateRegion())
        set udg_SP_Rect2[id] = Rect(minx, miny, maxx, maxy)
        set udg_Temp_Trig_Rect[DD_Mod(udg_SP_Region2[id], JASS_MAX_ARRAY_SIZE)] = udg_SP_Rect2[id]
        call RegionAddRect(ToRegion(udg_SP_Region2[id]), udg_SP_Rect2[id])
        return TriggerRegisterEnterRegion(t, ToRegion(udg_SP_Region2[id]), GetDummyFilter())
    endif
    return (null)
endfunction

constant function DD_TOTA takes integer pointer returns triggeraction
    return pointer
    return null
endfunction

function DeallocateMemory takes trigger t returns nothing
    local integer id = this_id(t)
    call RemoveRegion(ToRegion(udg_SP_Region1[id]))
    call RemoveRegion(ToRegion(udg_SP_Region2[id]))
    call RemoveRect(udg_SP_Rect1[id])
    call RemoveRect(udg_SP_Rect2[id])
    call TriggerRemoveAction(t, DD_TOTA(udg_SP_TriggerAction[id]))
    call DestroyTrigger(t)
    set udg_SP_Rect1[id] = null
    set udg_SP_Rect2[id] = null
endfunction

function TriggerRegisterGenericPortalEvent takes trigger t, playerunitevent pe returns event
    local integer i = 0
    
    loop
    exitwhen (i >= bj_MAX_PLAYER_SLOTS)
        call TriggerRegisterPlayerUnitEvent(t, Player(i), pe, GetDummyFilter())
        set i = i + 1
    endloop
    return (null)
endfunction