[JASS] My codes crashing WC3

[Teelo]

I've narrowed it down to this somewhere:

function Trig_CTF_Flag_Dropped_Actions takes nothing returns nothing
    local item droppedItem = GetManipulatedItem()
    local integer playerID = 0
    loop
        exitwhen playerID == bj_MAX_PLAYERS
        if (droppedItem == playerFlags[playerID]) then
            call BJDebugMsg("DEBUG. droppedItem = " + GetItemName(droppedItem))
            call SetItemPosition(droppedItem, 1, 1)//GetUnitX(playerCops[playerID]), GetUnitY(playerCops[playerID]))
            //call UnitShareVision(GetTriggerUnit(), Player(playerID), false)
        endif
        set playerID = playerID + 1
    endloop
endfunction

Specificaly this line: call SetItemPosition(droppedItem, 1, 1)
I comment that line out, the trigger doesn't do what I want of course, but it doesnt crash. I uncomment it, and it crashes WC3... I've confirmed with the debug line that the variable does indeed have the right thing stored when it hits that line.

 

[Berb]

Do you want to send me your map attached to a private message? I'll figure it out.

 

[Bribe]

Definitely send it to Berbanong, and note that there is nothing wrong with your code, it's got to be something else.

 

[Berb]

The problem was you cannot use SetItemPosition on either item events, since both of them involve the item being "possessed" by a unit. If you do try to use SetItemPosition under these circumstances, it will crash WarCraft III without an error message even.

The fix was to use both CreateItem and RemoveItem instead.

This is the first reason I've had to recommend someone to using ItemUtils. It seems that more-than-basic vJass knowledge is required to use it though.

 

[Justify]

Na, this can be fixed quite easy, as far as Berbanog is right.
If this native realy retriggers the event, just turn the trigger of,
use it, and turn it on again.

 

[Teelo]

I think it has something to do with the item not having a position while the unit still carries it.
The unitdropitem function is like an issue order I believe, so it takes time for the order to respond, so the item will still be in the units inventory when my trigger hits the next line trying to move it?

 

[Berb]

Its a strange bug. It would seem that using SetItemPosition on the event response of EVENT_UNIT_DROP_ITEM crashes WarCraft III without an error. If you use SetItemPosition on the EVENT_UNIT_PICKUP_ITEM callback, the game responds fine (and moves the item from the unit's inventory to the terrain).

In other words:

scope Init initializer init

globals
    public trigger      flagDropTrig        = CreateTrigger()
endglobals

public function onDrop takes nothing returns nothing
    call SetItemPosition(GetManipulatedItem(), 0, 0)
endfunction
public function onDropFilter takes nothing returns boolean
    local integer id=GetItemTypeId(GetManipulatedItem())
    return (id=='flag') or (id=='nflg') or (id=='oflg') or (id=='uflg')
endfunction
public function init takes nothing returns nothing
    call TriggerRegisterAnyUnitEventBJ(flagDropTrig, EVENT_PLAYER_UNIT_PICKUP_ITEM)
    call TriggerAddCondition(flagDropTrig, Filter(function onDropFilter))
    call TriggerAddAction(flagDropTrig, function onDrop)
endfunction
    
endscope

This will not crash WarCraft III.

[jass=Crash]scope Init initializer init

globals
public trigger flagDropTrig = CreateTrigger()
endglobals

public function onDrop takes nothing returns nothing
call SetItemPosition(GetManipulatedItem(), 0, 0)
endfunction
public function onDropFilter takes nothing returns boolean
local integer id=GetItemTypeId(GetManipulatedItem())
return (id=='flag') or (id=='nflg') or (id=='oflg') or (id=='uflg')
endfunction
public function init takes nothing returns nothing
call TriggerRegisterAnyUnitEventBJ(flagDropTrig, EVENT_PLAYER_UNIT_DROP_ITEM)
call TriggerAddCondition(flagDropTrig, Filter(function onDropFilter))
call TriggerAddAction(flagDropTrig, function onDrop)
endfunction

endscope[/code]

This will.

 

[Element of Water]

You've got the principal right, but the theory wrong. SetItemPosition triggers a DropItem event, which creates an infinite loop and crashes the game if used in response to a DropItem event. For example, in this code, I use SetItemPosition in a DropItem event, but avoid the crash by limiting the number of times the trigger can fire in one actual drop. Change MAX_COUNT to whatever you want, and that's how many times the trigger will fire.

//! zinc
library Test
{
    constant integer MAX_COUNT = 2;
    integer count = 0;
    
    function Actions () -> boolean
    {
        boolean b;
        trigger tt;
        
        count += 1;
        b = count >= MAX_COUNT; if (b)
        {
            tt = GetTriggeringTrigger();
            DisableTrigger(tt);
        }
        
        BJDebugMsg("Drop event, count " + I2S(count));
        SetItemPosition(GetManipulatedItem(), 0., 0.);
        
        if (b)
        {
            BJDebugMsg(" ");
            count = 0;
            EnableTrigger(tt);
        }
        
        return false;
    }
    
    function onInit ()
    {
        trigger t = CreateTrigger();
        TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_DROP_ITEM);
        TriggerAddCondition(t, function Actions);
    }
}
//! endzinc

 

[Berb]

I can't believe I never put that together, seems my reasoning was off. Thanks for the tip.

That also means that you'll probably want to do something similar in your code, [b[Teelo[/b]. It would be quite easy to avoid the crash in this case and it would also avoid the hassle of creating/removing an item (which can act strangely when passing off items). Instead of using dynamic items, you should definitely use static ones. If you need help doing this just say so.