[Solved] MUI Structs

[NightSkyAurora]

Hi.

I want to make a timed effect struct that allows you to create a special effect at a target location and having it removed a few seconds later. This is what I have so far:

struct TimedEffect extends array
    effect sfx
    timer tmr
   
    static method RemoveEffect takes nothing returns nothing
        //call DestroyEffect(sfx)
    endmethod
   
    method AddEffect takes string path, real x, real y, real tm returns effect
        set sfx = AddSpecialEffect(path, x, y)
        call TimerStart(tmr, tm, false, function thistype.RemoveEffect)
        return sfx
    endmethod
endstruct

The problem is that timers can only call static methods that takes and returns nothing. How can I tell method RemoveEffect which instance to remove?

Thanks for your time.

 

[IcemanBo]

Use a hashtable. You can treat structs like integers, ans you can save "this" as an integer to your hashtable with using HandleId of the created timer.
Inside your callback you load data from hashtable again using HandleId of expired timer with "local thistype this = LoadInteger(....)".

 

[NightSkyAurora]

Thanks, but now I have encountered another problem. here is the code:

struct TimedEffect extends array
    effect sfx
    timer tmr
 
    static method RemoveEffect takes nothing returns nothing
        local thistype this = LoadInteger(htble, 0, GetHandleId(GetExpiredTimer()))
        call DestroyEffect(.sfx)
    endmethod
 
    method AddEffect takes string path, real x, real y, real tm returns effect
        set sfx = AddSpecialEffect(path, x, y)
        call SaveInteger(htble, 0, GetHandleId(tmr), this)
        call TimerStart(tmr, tm, false, function thistype.RemoveEffect)
        return sfx
    endmethod
endstruct

Example:
call AddEffect("units\\human\\Peasant\\Peasant",0,0,3)

I get the error saying that AddEffect() is undeclared. If I use "TimedEffect.AddEffect() then the compiler complains that AddEffect() is not a static method. Making AddEffect() static makes it unable to use the non-static timer. If my timer is static then saving the timer's handle in a hash is pointless. How can I create a new TimedEffect instance?

I also tried this:
local TimedEffect sfx
call sfx.AddEffect(...)

that compiles but prevents all my triggers from running

 

[Chaosy]

I suggest timer utilities.
You attach "this" to the timer and get the timer data in the static callback trigger.

 

[NightSkyAurora]

You attach "this" to the timer and get the timer data in the static callback trigger.

Isn't that what I did in the script above?

 

[IcemanBo]

It is a non-static method which means it it a reserved function for your struct instances. When ever you have a created "TimedEffect" you can call it with it.
For exampe:

local TimedEffect this = allocate()
call this.AddEffect("units\\human\\Peasant\\Peasant",0,0,3)

Other way it would not make sense and otherwise you could not use "this" inside your method. "this" refers to the instance which calls the method.

Also ensure everything is initialisized like the timer and hashtable.

 

[NightSkyAurora]

Like this?

    local TimedEffect this = allocate()
    call this.AddEffect("units\\human\\Peasant\\Peasant.mdl",-520,0,3)

I get an error saying undeclared function allocate().


note I added TimerUtils as Chaosy suggested. Here is the updated code:

code

struct TimedEffect extends array
    effect sfx
    timer tmr
  
    static method RemoveEffect takes nothing returns nothing
        local thistype this = GetTimerData(GetExpiredTimer())
        call DestroyEffect(.sfx)
        call ReleaseTimer(GetExpiredTimer())
    endmethod
  
    method AddEffect takes string path, real x, real y, real tm returns effect
        set sfx = AddSpecialEffect(path, x, y)
        set tmr = NewTimer()
        call SetTimerData(tmr, this)
        call TimerStart(tmr, tm, false, function thistype.RemoveEffect)
        return sfx
    endmethod
endstruct

 

[IcemanBo]

Do not use extends array unless you know what you are doing.

allocate() and deallocate() are not useable if you extends array

edit:

In the vjass part there are some recommended tutorials about structs: http://www.hiveworkshop.com/threads/elemental-coder-guide.274346/

 

[Flux]

Furthermore, it would make more sense to make addEffect as a static method then do the allocation inside addEffect.

And timer tmr doesn't have to be a member. You could achieve the same functionality if timer tmr is a local timer but be sure to remove/release it upon expire.

 

[NightSkyAurora]

Removing extends array didn't solve the problem. I'm checking the tutorials out now, thanks.

 

[Flux]

As I've said:
- Make it a static method
- Add local thistype this = thistype.allocate() in the first line of addEffect
- call it using TimedEffect.addEffect(path, x, y, time)

Be sure you do not have "extends array"

 

[NightSkyAurora]

@Flux I didn't talk to you in my previous post. I only saw your reply after I posted mine. Anyway thanks for your help, it works now

@IcemanBo I should have used create() and not allocate() to make a new instance. I saw that in one of the tutorials you linked ^^

Thanks for the help guys; +rep

 

[IcemanBo]

The static method create() is the constructor of a struct. If called, it returns a new struct instance.
So it must return something that is from type thistype / aka the struct.

So if you call create() you will get a new instance.

But you also have the chance to write your own create method and give it some parameters for example.
Inside the create method, to get a new instance for you struct, you can use the allocate() function which returns a integer that will be used for your thistype.

It may look like:

static method create takes nothing returns thistype
    local thistype this = allocate()
    return this
endmethod

You can add some parameters:

static method create takes string path, real x, real y returns thistype
    local thistype this = allocate()
    set this.sfx = set sfx = AddSpecialEffect(path, x, y)
    return this
endmethod

Now you want to get your instance inside the callback so you attach it also to a timer:

static method callback takes nothing returns nothing
    local thistype this = GetTimerData(GetExpiredTimer())
    call DestroyEffect(this.sfx)
    call ReleaseTimer(GetExpiredTimer())
    call this.destroy()
endmethod

static method create takes string path, real x, real y returns thistype
    local thistype this = allocate()
    set this.sfx = set sfx = AddSpecialEffect(path, x, y)
    call TimerStart(NewTimerEx(this), 5, false, function thistype.callback)
    return this
endmethod

^The destroy method is the opposite of create. When you don't need your instance anymore you call the destroy method with it.
Inside it will call the deallocate() functon to free your instance again.
Similar to the create method you also can write your own destroy method. This comes handy if you want to clear some stuff there, like this:

method destroy takes nothing returns nothing
    call this.deallocate()
    set this.sfx = null
endmethod

static method callback takes nothing returns nothing
    local thistype this = GetTimerData(GetExpiredTimer())
    call DestroyEffect(this.sfx)
    call ReleaseTimer(GetExpiredTimer())
    call this.destroy()
endmethod

static method create takes string path, real x, real y returns thistype
    local thistype this = allocate()
    set this.sfx = set sfx = AddSpecialEffect(path, x, y)
    call TimerStart(NewTimerEx(this), 5, false, function thistype.callback)
    return this
endmethod

Recgonize that method destroy() is a non-static method which means you only can call it with your struct instances.
And this makes perfect sense, since this method is only for destroying your struct instance and nothing else.

 

[Flux]

^typo in set this.sfx = set sfx = ..
Also, I think it's better to put DestroyEffect in method destroy
You forgot the duration input argument (you used a hardcoded value of 5)
function callback could be private

After fixing those, it will be perfect

 

[IcemanBo]

Something like perfect does not exist.

 

[NightSkyAurora]

Thanks for your effort IcemanBo. I would have ended up with a lot of leaks if you just left me there. I can't find the NewTimerEx() function. I guess it only assigns a value immediately to the timer upon creation. Anyway I edited my struct as well as applying the changes as Flux suggested. Here is the code

jass

struct TimedEffect
  
    effect sfx
  
    method destroy takes nothing returns nothing
        call DestroyEffect(.sfx)
        call ReleaseTimer(GetExpiredTimer())
        call this.deallocate()
        set this.sfx = null
    endmethod
  
    private static method callback takes nothing returns nothing
        local thistype this = GetTimerData(GetExpiredTimer())
        call this.destroy()
    endmethod
  
    static method create takes string path, real x, real y, real tm returns thistype
        local thistype this = thistype.allocate()
        local timer tmr = NewTimer()
        set sfx = AddSpecialEffect(path, x, y)
        call SetTimerData(tmr, this)
        call TimerStart(tmr, tm, false, function thistype.callback)
        return this
    endmethod
endstruct

 

[IcemanBo]

Recycle the timer in the callback function.

I can't find the NewTimerEx() function. I guess it only assigns a value immediately to the timer upon creation.

Yes.

 

[Dr Super Good]

One could drive it with a single static timer if one used an accompanying time based priority queue. You insert the effect instances into the priority queue at the times they are scheduled for. You get the timer to wait until the soonest event from the priority queue. On timer expiry the top of the queue is poped, destroyed and the timer waits until the new top. This has very good scaling as priority queues can be as fast as log2(n) for insertion/removal and is likely how JASS timers are implemented internally.

Needlessly complex I know but thought I should post the idea.

 

[Wietlol]

       local timer tmr = NewTimer()
       call SetTimerData(tmr, this)

=

       local timer tmr = NewTimerEx(this)

@Dr Super Good
I tried to make that, but it only works nice if you use triggers to execute instead of code.
EDIT:

Which would be this:

//! runtextmacro NewLinkedList("timerSetList")
struct TimerSet
  
    private timer t
  
    private static integer array l_data
    private static real array l_timestamp
    private static trigger array l_trigger
  
    private static method onExpire takes nothing returns nothing
        local thistype this = GetTimerData(GetExpiredTimer())
        local integer id = timerSetList.first[this]
      
        call TriggerEvaluate(.l_trigger[id])
        call timerSetList.removeIndex(id)
        set .l_data[id] = 0
        set .l_timestamp[id] = 0
        set .l_trigger[id] = null
      
        if timerSetList.first[this] > 0 then
            call TimerStart(.t, .l_timestamp[timerSetList.first[this]] - Time.getElapsedGameTime(), false, function thistype.onExpire)
        endif
    endmethod
    
    public method removeTimer takes integer id returns boolean
        local boolean isFirst = timerSetList.first[this] == id
       
        if timerSetList.removeIndexChecked(this, id) then
            set .l_data[id] = 0
            set .l_timestamp[id] = 0
            set .l_trigger[id] = null
           
            if isFirst then
                if timerSetList.first[this] > 0 then
                    call TimerStart(.t, .l_timestamp[timerSetList.first[this]] - Time.getElapsedGameTime(), false, function thistype.onExpire)
                else
                    call PauseTimer(.t)
                endif
            endif
            return true
        endif
        return false
    endmethod
    
    public method newTimer takes integer data, real duration, trigger trig returns integer
        local integer id
        local real timestamp = Time.getElapsedGameTime() + duration
        local integer lId = 0
        local integer nId = timerSetList.last[this]
        local boolean isFirst = false
      
        loop
            if nId == 0 then
                set id = timerSetList.insertIndex(this, lId)
                set isFirst = true
                exitwhen true
            endif
            set lId = nId
            set nId = timerSetList.previous[nId]
          
            if .l_timestamp[lId] <= timestamp then
                set id = timerSetList.insertIndexEx(this, lId)
                exitwhen true
            endif
        endloop
      
        set .l_data[id] = data
        set .l_timestamp[id] = timestamp
        set .l_trigger[id] = trig
      
        if isFirst then
            call TimerStart(.t, duration, false, function thistype.onExpire)
        endif
      
        return id
    endmethod
  
    public static method create takes nothing returns thistype
        local thistype this = .allocate()
        set .t = NewTimerEx(this)
        return this
    endmethod
  
endstruct