GetTriggerWidget(), GetTriggerUnit()

[Catch_ya]

Well yes, I heard that Widet calling is faster than Unit calling. (Don't know if this is true though). But if it is then what is fastest

GetTriggerWidget()

or

GetTriggerUnit()

 

[Pharaoh_]

It depends, if for example you pick a GetWidgetLife, you will use the first one; for other actions, e.g. GetUnitLevel, you will use GetTriggerUnit. I don't think widget can be applied within a Unit function and vice versa.

 

[Justify]

Not completly.
Units are treated as units, widgets and handles. Widget or handle functions will work for units too, but not vice versa like Pharaoh said (at least if I remind correctly), so GetWidgetLife(GetTriggerUnit()) works but GetUnitState(GetTriggerWidget(), UNIT_STATE_LIFE) shouldn't work.

 

[Catch_ya]

Thanks both.

 

[Dr Super Good]

I am still trying to look into which is faster but I can not locate the compiled trigger script in the memory of WC3. Once I find that I can give proof as to which is faster and why.

 

[Catch_ya]

I am still trying to look into which is faster but I can not locate the compiled trigger script in the memory of WC3. Once I find that I can give proof as to which is faster and why.

Sounds great.

 

[PurgeandFire]

You could always typecast:

globals
    hashtable blah = InitHashtable()
endglobals
function W2U takes widget w returns unit
    call SaveWidgetHandle(blah,0,0,w)
    return LoadUnitHandle(blah,0,0)
endfunction

But that'd obviously be less efficient. =P

EDIT: Ok, I ran some benchmarks:

I've done it several times (more than shown below), and each time GetTriggerUnit() returned faster.

In the image, I show 8 trials, here is the speed comparison for GetTriggerUnit() to GetTriggerWidget():

• Trial 1: 1.4851% faster
• Trial 2: 5.2632% faster
• Trial 3: 0.5405% faster
• Trial 4: 23.519% faster
• Trial 5: 4.5714% faster
• Trial 6: 5.7618% faster
• Trial 7: 0.1841% faster
• Trial 8: 3.8847% faster

Test was done on a blank map using NewGen Editor along with the Stopwatch Natives.
Tested in version 1.24.4.6387 (latest version)

Benchmark Template - Jesus4Lyf

library Benchmark initializer OnInit
    native StopWatchCreate  takes nothing returns integer
    native StopWatchMark    takes integer stopwatch returns real
    native StopWatchDestroy takes integer stopwatch returns nothing
    globals
    private constant string TITLE_A="GetTriggerUnit()       "
    //! textmacro Benchmark__TestA
        call GetTriggerUnit()
    //! endtextmacro
    private constant string TITLE_B="GetTriggerWidget() "
    //! textmacro Benchmark__TestB
        call GetTriggerWidget()
    //! endtextmacro
    endglobals
    private function TestA1000 takes nothing returns nothing
        local integer i=100
        loop
            exitwhen i==0
            set i=i-1
            //! runtextmacro Benchmark__TestA() // 1
            //! runtextmacro Benchmark__TestA() // 2
            //! runtextmacro Benchmark__TestA() // 3
            //! runtextmacro Benchmark__TestA() // 4
            //! runtextmacro Benchmark__TestA() // 5
            //! runtextmacro Benchmark__TestA() // 6
            //! runtextmacro Benchmark__TestA() // 7
            //! runtextmacro Benchmark__TestA() // 8
            //! runtextmacro Benchmark__TestA() // 9
            //! runtextmacro Benchmark__TestA() // 10
        endloop
    endfunction
    private function TestB1000 takes nothing returns nothing
        local integer i=100
        loop
            exitwhen i==0
            set i=i-1
            //! runtextmacro Benchmark__TestB() // 1
            //! runtextmacro Benchmark__TestB() // 2
            //! runtextmacro Benchmark__TestB() // 3
            //! runtextmacro Benchmark__TestB() // 4
            //! runtextmacro Benchmark__TestB() // 5
            //! runtextmacro Benchmark__TestB() // 6
            //! runtextmacro Benchmark__TestB() // 7
            //! runtextmacro Benchmark__TestB() // 8
            //! runtextmacro Benchmark__TestB() // 9
            //! runtextmacro Benchmark__TestB() // 10
        endloop
    endfunction
    
    private function OnEsc takes nothing returns nothing
        local integer sw
        local integer i
        set i=0
        set sw=StopWatchCreate()
        loop
            set i=i+1
            call TestA1000.evaluate()
            exitwhen i==10
        endloop
        call BJDebugMsg("|cff66ddff"+TITLE_A+" : "+R2S(StopWatchMark(sw)*100)+"|r")
        call StopWatchDestroy(sw)
        set i=0
        set sw=StopWatchCreate()
        loop
            set i=i+1
            call TestB1000.evaluate()
            exitwhen i==10
        endloop
        call BJDebugMsg("|cffddff66"+TITLE_B+" : "+R2S(StopWatchMark(sw)*100)+"|r")
        call StopWatchDestroy(sw)
    endfunction
    private function OnInit takes nothing returns nothing
        local trigger t=CreateTrigger()
        call TriggerRegisterPlayerEvent(t,Player(0),EVENT_PLAYER_END_CINEMATIC)
        call TriggerAddAction(t,function OnEsc)
    endfunction
endlibrary

 

[Catch_ya]

Thanks, really useful library. Didn't knew it existed.