Storm Bolt doesn't works for computer players

[imported_Galled]

Hello everybody.

I'm make a spell called INEPTITUD; when the unit with the buff attacks, it recieves some damage and is stunned (well i'm create a unit and order storm bolt it), there is my code:

function Trig_Ineptitud_Attack_Conditions takes nothing returns boolean
    if ( not ( UnitHasBuffBJ(GetAttacker(), 'B00O') == true ) ) then
        return false
    endif
    return true
endfunction

function Trig_Ineptitud_Attack_Actions takes nothing returns nothing
local real x = GetUnitX(GetAttacker())
local real y = GetUnitY(GetAttacker())
    call CreateNUnitsAtLoc( 1, 'h00C', GetOwningPlayer(GetAttackedUnitBJ()), Location(x,y), bj_UNIT_FACING )
    call UnitAddAbilityBJ( 'A08A', GetLastCreatedUnit() )
    call IssueTargetOrderBJ( GetLastCreatedUnit(), "thunderbolt", GetAttacker() )
    call UnitApplyTimedLifeBJ( 1.00, 'BTLF', GetLastCreatedUnit() )
endfunction

//===========================================================================
function InitTrig_Ineptitud_Attack takes nothing returns nothing
    set gg_trg_Ineptitud_Attack = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Ineptitud_Attack, EVENT_PLAYER_UNIT_ATTACKED )
    call TriggerAddCondition( gg_trg_Ineptitud_Attack, Condition( function Trig_Ineptitud_Attack_Conditions ) )
    call TriggerAddAction( gg_trg_Ineptitud_Attack, function Trig_Ineptitud_Attack_Actions )
endfunction

When the unit with the buff attacks some unit controled by me, the spell works fine. But when the unit with the buff attacks some unit controled by the computed doesn't works... What happends???

Thanks in advance

 

[PurplePoot]

wait a second while i laugh...

bwahahahahahaha

ok, sorry , its just that i've never seen someone who knows Locals and Unit X/Y commands without knowing not to use BJs, Swappeds, Swaps, CreateNUnitsAtLoc, and If/Then conditions before

anyways, are u using Test Map? in this case, its not a computer player, but just a (nothing) player that auto defaults to attack people that come near. try setting the player Player 2 - Blue to a computer instead of None.

replace your code with this xD

function Trig_Ineptitud_Attack_Conditions takes nothing returns boolean 
return GetUnitAbilityLevel(GetAttacker(), 'B00O' ) > 0
endfunction 

function Trig_Ineptitud_Attack_Actions takes nothing returns nothing 
local real x = GetUnitX(GetAttacker()) 
local real y = GetUnitY(GetAttacker())
local unit u = CreateUnit( GetOwningPlayer( GetTriggerUnit() ), 'h00C', x, y, 0  )
call UnitAddAbility( u, 'A08A' ) 
call IssueTargetOrder( u, "thunderbolt", GetAttacker() ) 
call UnitApplyTimedLife( u, 'BTLF', 1 )
set u = null
endfunction 

//=========================================================================== 
function InitTrig_Ineptitud_Attack takes nothing returns nothing 
set gg_trg_Ineptitud_Attack = CreateTrigger( ) 
call TriggerRegisterAnyUnitEventBJ( gg_trg_Ineptitud_Attack, EVENT_PLAYER_UNIT_ATTACKED ) 
call TriggerAddCondition( gg_trg_Ineptitud_Attack, Condition( function Trig_Ineptitud_Attack_Conditions ) ) 
call TriggerAddAction( gg_trg_Ineptitud_Attack, function Trig_Ineptitud_Attack_Actions ) 
endfunction