[JASS] JASS Issue

[Kwah]

real damage = (GetHeroInt(GetTriggerUnit(), true ) + GetUnitAbilityLevel(GetTriggerUnit(), 'A003'))

For some reason this is returning 0, even if intelligence is one (default for the current map that I'm making. Any ideas why?

Full Code

scope StormBolt initializer Init

globals
    private constant integer Rawcode = 'A003'
    private constant string Model = "Abilities\\Weapons\\FireBallMissile\\FireBallMissile.mdl"
    private real damage = (GetHeroInt(GetTriggerUnit(), true ) + GetUnitAbilityLevel(GetTriggerUnit(), 'A003'))
endglobals

private function Conditions takes nothing returns boolean
    return GetSpellAbilityId() == Rawcode
endfunction

function StormBoltHit takes nothing returns nothing
    local Projectile p = ProjectileInt
    if IsUnitEnemy( p.hit, GetOwningPlayer( p.origin ) ) then
        call KnockbackTarget( p.hit, Atan2( GetUnitY( p.hit ) - GetUnitY( p.missile ), GetUnitX( p.hit ) - GetUnitX( p.missile ) ), 500, 60, false, true )
        call BJDebugMsg(R2S(damage))
        call UnitDamageTarget( p.origin, p.hit, damage, false, false, ATTACK_TYPE_HERO, DAMAGE_TYPE_NORMAL, null )
        set p.end = true
    endif    
endfunction

private function Actions takes nothing returns nothing
    local unit caster = GetTriggerUnit()
    local real damage = (GetHeroInt( caster, true ) + GetUnitAbilityLevel( caster, Rawcode) * 10 )
    local location loc = GetSpellTargetLoc()
    local real x = GetUnitX( caster )
    local real y = GetUnitY( caster )
    local real tx = GetLocationX( loc )
    local real ty = GetLocationY( loc )
    local real a = Atan2( ty - y, tx -x )
    local unit projectile = AddProjectile( caster, x + 50 * Cos( a ), y + 50 * Sin( a ), x + 2000 * Cos( a ), y + 2000 * Sin( a ), 1000, 115, 0, Model, "StormBoltHit", false, 0 )
    call SetUnitFlyHeight( projectile, 55, 0 )
    call SetUnitScale( projectile, 1.3, 1.3, 1.3 )
    set caster = null
    call RemoveLocation( loc )
    set loc = null
    set projectile = null
endfunction

private function Init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddAction( t, function Actions )
    call TriggerAddCondition( t, Condition( function Conditions ) )
endfunction

endscope

I've just started JASS, so please excuse me if its a stupid mistake,

I'm using systems by Bobo_The_Kodo (a friend of mine)

 

[PurplePoot]

Globals' values are set at map init, meaning that those are the ability level and damage of a null unit at map init.

 

[Kwah]

Ah.

Thanks.

So I should set it as a local in the knockbacktarget function?

 

[PurplePoot]

In StormBoltHit, rather. Or just inline it.

 

[Kwah]

That's what I meant.

Thanks.

btw, "inline"?

 

[PurplePoot]

Put it where you access "damage" currently, and skip the variable altogether.

 

[Kwah]

Update:

Still, when I return that folmurla when the hero has 2 Magic (Int) and 1 level of the skill it = 0. (Debug Msg)

Here is my new code.

Code Update

scope StormBolt initializer Init

globals
    private constant integer Rawcode = 'A003'
    private constant string Model = "Abilities\\Weapons\\FireBallMissile\\FireBallMissile.mdl"
endglobals

private function Conditions takes nothing returns boolean
    return GetSpellAbilityId() == Rawcode
endfunction

function StormBoltHit takes nothing returns nothing
    local Projectile p = ProjectileInt
    if IsUnitEnemy( p.hit, GetOwningPlayer( p.origin ) ) then
        call KnockbackTarget( p.hit, Atan2( GetUnitY( p.hit ) - GetUnitY( p.missile ), GetUnitX( p.hit ) - GetUnitX( p.missile ) ), 500, 60, false, true )
        call UnitDamageTarget( p.origin, p.hit, I2R((GetHeroInt(GetTriggerUnit(), true ) + GetUnitAbilityLevel(GetTriggerUnit(), 'A003')) * 10), false, false, ATTACK_TYPE_HERO, DAMAGE_TYPE_NORMAL, null )
        call BJDebugMsg(R2S(I2R((GetHeroInt(GetTriggerUnit(), true ) + GetUnitAbilityLevel(GetTriggerUnit(), 'A003')) * 10)))
        set p.end = true
    endif    
endfunction

private function Actions takes nothing returns nothing
    local unit caster = GetTriggerUnit()
    local real damage = (GetHeroInt( caster, true ) + GetUnitAbilityLevel( caster, Rawcode) * 10 )
    local location loc = GetSpellTargetLoc()
    local real x = GetUnitX( caster )
    local real y = GetUnitY( caster )
    local real tx = GetLocationX( loc )
    local real ty = GetLocationY( loc )
    local real a = Atan2( ty - y, tx -x )
    local unit projectile = AddProjectile( caster, x + 50 * Cos( a ), y + 50 * Sin( a ), x + 2000 * Cos( a ), y + 2000 * Sin( a ), 1000, 115, 0, Model, "StormBoltHit", false, 0 )
    call SetUnitFlyHeight( projectile, 55, 0 )
    call SetUnitScale( projectile, 1.3, 1.3, 1.3 )
    set caster = null
    call RemoveLocation( loc )
    set loc = null
    set projectile = null
endfunction

private function Init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddAction( t, function Actions )
    call TriggerAddCondition( t, Condition( function Conditions ) )
endfunction

endscope

 

[PurplePoot]

There is no GetTriggerUnit() in that function, seeing as it's called by a timer callback, not directly related to the action function of the event, thus an event response makes no sense there.

 

[Kwah]

Ah, good point.

I'm still thinking in GUI terms with a single trigger.

So, what should I put in place instead? I would make a local to do the samething, but there is still no GetTriggerUnit()

 

[PurplePoot]

If there's no good way to pass an integer, real or unit through that AddProjectile function, you're pretty much screwed and would have to edit the system code (Don't go near LHV).

 

[Kwah]

O. . . so.

Ummmmm.

Damn Sasha's code.

 

[PurplePoot]

Sasha says that there is a p.caster included...

 

[Bobo_The_Kodo]

or it might be called p.origin

AddProjectile( caster, x + 50 * Cos( a ), y + 50 * Sin( a ), x + 2000 * Cos( a ), y + 2000 * Sin( a ), 1000, 115, 0, Model, "StormBoltHit", false, 0 )

Look at the first value passed?

function AddProjectile takes unit origin, real x, real y, real tx, real ty, real speed, real radius, real damage, string model, string onhit, boolean checkDead, integer Struct returns unit
...
        set p.origin = origin

 

[Kwah]

Ah.

Thanks, I'm still new at this.