native UnitAlive takes unit u returns boolean
//! zinc
	library Wander requires TimerUtils, Table
	{	
	
		/*
		***************************************************************************************************************************
			Info:
				The system is supposed to be a coded version of the 'Wander' ability.
				Benefits being that you can modify it slightly, pause duration and
				the area the units walk in. Also the unit will NOT become neutral
				and will actually attack nearby enemies.

			 API:
				static method create(unit u, real x, real y) -> thistype
				static method getByUnit(unit target) -> thistype
				method destroy()

			Config:
				real wanderCooldown
					Duration between each time the unit is ordered to move.
					
				real cooldownModifier
					To make the cooldown a bit random, this is used to make the cooldown equal to
						cooldown +- modifier.
					
				real maxWanderArea = 550;
					Max range from start point.
					
				real minWanderArea = 100;
					Min range from start point.
					
				real loopSpeed = 0.03;
					How often the system updates, higher value equals better performence but
						reduces accuracy.
						
			Event Ids
				0 = nothing
				1 = Added to system
				2 = New order
				3 = Removed from system

			Import:
				-Copy this trigger + the TimerUtils one into your map.
				-Requires JNGP to use, can be downloaded from Hive's tool section or from wc3c.net (offical)
				-Unless you copied the demo triggers into your map, you need to create the following GUI variables:
					real wanderEvent
					real whereToX
					real wheretoY
					unit wanderer

			Credit
				Chaosy @ www.hiveworkshop.com

		***************************************************************************************************************************
		*/
		public struct WanderStruct
		{
			//Wander Events
				// 1. Added to system
				// 2. New order
			    // 3. removed from system
				
			//Configurable variables bellow
			//these are default values and can be changed to be unique for each unit if needed.
			real wanderCooldown   = 5;
			real cooldownModifier = 2;
			real maxWanderArea    = 550;
			real minWanderArea    = 100;
			real loopSpeed        = 0.03125;
			
			//end of config
			private boolean onCooldown = false;
			private real    counter = 0;
			private real    x, y, finalCooldown;
			private unit    u;
			private timer   t;
			private static Table table;
			
			private method onDestroy()
			{
				if(this.t != null)
				{
					ReleaseTimer(this.t);
				}
				if(this.u != null)
				{
					table.remove(GetHandleId(u));
					udg_wanderer    = this.u;
					udg_wanderEvent = 3;
					udg_wanderEvent = 0;
				}
				t = null;
				u = null;
			}
			
			private static method Update()
			{
				
				thistype this = GetTimerData(GetExpiredTimer());
				real angle, dist, dx, dy;
				if(!UnitAlive(u))
				{
					this.destroy();
				}
				if(GetUnitCurrentOrder(this.u) == null && !this.onCooldown)
				{
					angle = GetRandomReal(-bj_PI, bj_PI);
					dist  = GetRandomReal(minWanderArea, maxWanderArea);
					dx    = this.x + dist * Cos(angle);
					dy    = this.y + dist * Sin(angle);
					IssuePointOrder(u, "attack", dx, dy);
					this.finalCooldown = GetRandomReal(this.wanderCooldown - this.cooldownModifier,
						this.wanderCooldown + this.cooldownModifier);
					this.onCooldown = true;
					udg_wanderer    = this.u;
					udg_whereToX    = dx;
					udg_whereToY    = dy;
					udg_wanderEvent = 2;
					udg_wanderEvent = 0;
				}
				else if(this.onCooldown)
				{
					this.counter += this.loopSpeed;
					if(this.counter >= this.finalCooldown)
					{
						this.onCooldown = false;
						this.counter    = 0;
					}
				}
			}
			
			static method getByUnit(unit target) -> thistype
			{
				return table[GetHandleId(target)];
			}
			
			static method create(unit u, real x, real y) -> thistype
			{
				thistype this = thistype.allocate();
				integer h = GetHandleId(u);
				if(!table.has(h))
				{
					table[h] = this;
	
					this.t = NewTimerEx(this);
					TimerStart(this.t, this.loopSpeed, true, function thistype.Update);
					this.x = x;
					this.y = y;
					this.u = u;
					
					udg_wanderer    = this.u;
					udg_wanderEvent = 1;
					udg_wanderEvent = 0;
				}
				else
				{
					BJDebugMsg(GetUnitName(u) + " is already wandering!");
					this.destroy();
				}
				return this;
			}
			
			static method onInit()
			{
				table = TableArray[0x2000];
			}
		}
	}
//! endzinc