ItemHierarchy v1.00

Spellbound · Oct 18, 2017

Made upon request from Kam.
Feedback welcome.

A Void · Oct 19, 2017

damn, you sure know how to advertise. That picture caught my eyes. Not everyone puts so much effort into design.

Spellbound · Oct 19, 2017

Hah, thanks. I figured I might as well put all that photoshop knowledge to good use instead of letting it go to waste

axleion · Oct 25, 2017

I haven't tried the testmap, but based on your description on Maiev's shadow orb,
it seems the system is similar to usual recipe system with retrievable "level/grade" attached to the instance.

few questions:
1. I don't think user would want to set the automaticupgrade to false, even if the user want to,
how can the user retrieve the event of picking hierarchy item?

as written in the description:

the boolean argument should be true by default unless you wish to handle the upgrade manually and just need the hierarchy as a reference.

2. how about adding feature something like:

JASS:

call ItemHierarchy.addnextItem(baseline, 'sor2')

so it automatically add the item to the next level?

3. what will happen if I do something like this?

JASS:

call ItemHierarchy.addItem(baseline, 'sor2', 2)
call ItemHierarchy.addItem(baseline, 'sor3', 2)

will it just update the value of level 2 or what?

4. are user allowed to use same item rawcode on single instance of hierarchy or perhaps allowed on different instance or do user have to use unique item rawcode on both case?

for an example,

JASS:

call ItemHierarchy.addItem(baseline, 'sor3', 3)
call ItemHierarchy.addItem(baseline, 'sor3', 4)

is this ok or should be avoided?

5. so to use .setitemlevel on an item, that item must be in an unit's inventory? do user have to workaround with dummy if they want to .setitemlevel on an item on the ground?

6. any limitations or something the users have to be aware of? like level limit? or conflict with other resource? inability to use certain feature of other system maybe?

p.s. I'm sorry if what I ask above is out of the context because I misunderstand your resource.

Spellbound · Oct 25, 2017

Dark_Axl said:
1. I don't think user would want to set the automaticupgrade to false, even if the user want to,
how can the user retrieve the event of picking hierarchy item?

There's an example of automaticupgrade set to false in the test map. Then again, you could always just not have any baseline items in your map, but I put it there just in case.

Dark_Axl said:
2. how about adding feature something like:

JASS:

call ItemHierarchy.addnextItem(baseline, 'sor2')

so it automatically add the item to the next level?

The system was initially going to be like this but I figured I'd make the system require a number to enable the user to visualise the list he/she is making better (aka, you can tell from a glance what number what item id is bound to)

Dark_Axl said:
3. what will happen if I do something like this?

JASS:

call ItemHierarchy.addItem(baseline, 'sor2', 2) call ItemHierarchy.addItem(baseline, 'sor3', 2)

will it just update the value of level 2 or what?

The second line will be ignored. Your first entry is permanent.

Dark_Axl said:
4. are user allowed to use same item rawcode on single instance of hierarchy or perhaps allowed on different instance or do user have to use unique item rawcode on both case?

for an example,

JASS:

call ItemHierarchy.addItem(baseline, 'sor3', 3) call ItemHierarchy.addItem(baseline, 'sor3', 4)

is this ok or should be avoided?

Level 3 and 4 of the item hierarchy will return the same item in this instance.

Dark_Axl said:
5. so to use .setitemlevel on an item, that item must be in an unit's inventory? do user have to workaround with dummy if they want to .setitemlevel on an item on the ground?

Yep, .setItemLevel only work if it exists in a unit's inventory. I figured if users want to set the level of an item on the ground they can just remove and replace. That's given me something to thing about, however.

Dark_Axl said:
6. any limitations or something the users have to be aware of? like level limit? or conflict with other resource? inability to use certain feature of other system maybe?

None that I'm aware of.

MyPad · May 28, 2018

Nitpicks:

How would this be different from a recipe system?

Notes:

To be tested.

Status:

Awaiting Update

Spellbound · May 29, 2018

I guess it's a more straightforward library for upgrading an item into stronger variants of itself? It's also a reference list so if you have a Shadow Orb +3 and pick a +4, your Shadow Orb automatically becomes +7. I've never used a recipe system before (as a modder) so I guess this is just simpler to use?

MyPad · May 29, 2018

Hmm... Fair point. So, going by logical operation, this could potentially be an add-on to a recipe system, but implemented such that it stands on its' own, yet...

Going by recipe systems, this would be quite costly to implement, having a worst case of O(n^2). However, this has a behavior-specified set of operations that reduce the worst case to O(c), where c is a constant.

So far, I don't see any flops, though I have yet to test the map. The status shall be determined in near future.

Chaosy · May 29, 2018

I'd argue that a recipe system could work by running on acquiring item, which basically makes this an item recipe system.
Possibly easier to use for the specific purpose it was made for.

I think it is niche usage, but could be useful.

Spellbound · May 29, 2018

Yeah, niche usage does describe this accurately.

Aniki · May 30, 2018

It seems to me that this could be implemented in a "simpler" manner and have a simpler user level API.

I took the liberty of renaming ItemHierarchy to Item_Chain because hierarchies tend to have a "tree-like" structure and chains are really just lists.

JASS:

library libassert

function assert takes string s, boolean b returns nothing
    if not b then
        call BJDebugMsg("|cffFF0000assert failed: |r" + s)
        call I2S(1/0)
    endif
endfunction

function writeln takes string s returns nothing
    call BJDebugMsg(s)
endfunction

endlibrary


library libitemchain initializer init uses libassert

globals
    private hashtable ht = InitHashtable()
endglobals

struct Item_Chain extends array
    integer frag_item_id
    integer max_val
    boolean disabled
endstruct

// returns 0 if item_id is not part of an item chain
function item_get_chain takes integer item_id returns Item_Chain
    return Item_Chain(LoadInteger(ht, -1, item_id))
endfunction
private function item_set_chain takes integer item_id, Item_Chain chain returns nothing
    debug call assert("[item_set_chain] item(" + I2S(item_id) + ") is already part of Item_Chain(" + I2S(integer(item_get_chain(item_id))) + ")", /*
        */ 0 == item_get_chain(item_id))
    call SaveInteger(ht, -1, item_id, integer(chain))
endfunction

function item_get_chain_val takes integer item_id returns integer
    debug call assert("[item_set_chain] item(" + I2S(item_id) + ") is not part of any Item_Chain()", /*
        */ 0 != item_get_chain(item_id))
    return LoadInteger(ht, -2, item_id)
endfunction
private function item_set_chain_val takes integer item_id, integer val returns nothing
    call SaveInteger(ht, -2, item_id, val)
endfunction

function chain_val_get_item takes Item_Chain chain, integer chain_val returns integer
    debug call assert("[chain_val_get_item] invalid chain_val(" + I2S(chain_val) + " for Item_Chain(" + I2S(integer(chain)) + ")", /*
    */ 0 != LoadInteger(ht, integer(chain), chain_val))
    return LoadInteger(ht, integer(chain), chain_val)
endfunction
private function chain_val_set_item takes Item_Chain chain, integer chain_val, integer item_id returns nothing
    call SaveInteger(ht, integer(chain), chain_val, item_id)
endfunction

globals
    private integer next_chain_id = 0
    private Item_Chain curr_chain = 0
endglobals

// frag_item_id can be 0
function begin_item_chain takes integer frag_item_id returns nothing
    set next_chain_id = next_chain_id + 1
    set curr_chain = Item_Chain(next_chain_id)
    set curr_chain.max_val = 0
    set curr_chain.disabled = false

    set curr_chain.frag_item_id = frag_item_id
    call item_set_chain(frag_item_id, curr_chain)
endfunction

function chain_is_disabled takes nothing returns nothing
    set curr_chain.disabled = true
endfunction

function chain_add_item takes integer item_id returns nothing
    set curr_chain.max_val = curr_chain.max_val + 1
    call item_set_chain(item_id, curr_chain)
    call item_set_chain_val(item_id, curr_chain.max_val)
    call chain_val_set_item(curr_chain, curr_chain.max_val, item_id)
endfunction

// for symmetry with begin_item_chain
function end_item_chain takes nothing returns nothing
    // do nothing
endfunction

private function unit_get_item_slot takes unit u, item it returns integer
    local integer a = 0
    local integer aa = UnitInventorySize(u)
    loop
        exitwhen a == aa
        if it == UnitItemInSlot(u, a) then
            return a
        endif
        set a = a + 1
    endloop
    return -1
endfunction

// returns the item's slot
private function find_another_item_from_the_same_chain_not_maxed takes unit u, integer b_item_slot, Item_Chain chain returns integer
    local integer a = 0
    local integer aa = UnitInventorySize(u)
    local item it
    local integer item_id
    loop
        exitwhen a == aa
        if a != b_item_slot then
            set it = UnitItemInSlot(u, a)
            if it != null then
                set item_id = GetItemTypeId(it)
                if chain == item_get_chain(item_id) then
                    if chain.max_val !=  item_get_chain_val(item_id) then
                        return a
                    endif
                endif
            endif
        endif
        set a = a + 1
    endloop
    return -1
endfunction

private function first_free_slot takes unit u returns integer
    local integer a = 0
    local integer aa = UnitInventorySize(u)
    loop
        exitwhen a == aa
        if null == UnitItemInSlot(u, a) then
            return a
        endif
        set a = a + 1
    endloop
    call assert("[first_free_slot] unreachable", false)
    return -1
endfunction

private function on_item_pickup takes unit u, item picked_item returns nothing
    local Item_Chain chain
    local integer chain_first_item_id
    local integer b
    local integer b_item_id
    local integer b_item_slot
    local integer a
    local integer a_item_id
    local integer a_item_slot
    local integer res
    local integer res_item_id
    local integer diff
    local integer diff_item_id

    set b_item_id = GetItemTypeId(picked_item)
    set chain = item_get_chain(b_item_id)
    if chain == 0 or chain.disabled then
        return
    endif

    set b_item_slot = unit_get_item_slot(u, picked_item)
    if b_item_slot == -1 then
        // a tome-like item
        set b_item_slot = first_free_slot(u)
    endif

    if b_item_id == chain.frag_item_id then
        call RemoveItem(UnitItemInSlot(u, b_item_slot))
        set chain_first_item_id = chain_val_get_item(chain, 1)
        call UnitAddItemToSlotById(u, chain_first_item_id, b_item_slot) // invoke on_item_pickup recursively
        return
    endif

    set a_item_slot = find_another_item_from_the_same_chain_not_maxed(u, b_item_slot, chain)
    if a_item_slot == -1 then
        return
    endif
    set a_item_id = GetItemTypeId(UnitItemInSlot(u, a_item_slot))

    set a = item_get_chain_val(a_item_id)
    set b = item_get_chain_val(b_item_id)
    set res = a + b
    set diff = 0
    if res > chain.max_val then
        set diff = res - chain.max_val
        set res = chain.max_val
    endif

    call DisableTrigger(GetTriggeringTrigger())

    set res_item_id = chain_val_get_item(chain, res)
    call RemoveItem(UnitItemInSlot(u, a_item_slot))
    call RemoveItem(UnitItemInSlot(u, b_item_slot))
    call UnitAddItemToSlotById(u, res_item_id, a_item_slot)
    if diff != 0 then
        set diff_item_id = chain_val_get_item(chain, diff)
        call UnitAddItemToSlotById(u, diff_item_id, b_item_slot)
    endif

    call EnableTrigger(GetTriggeringTrigger())
endfunction

private function on_item_pickup_action takes nothing returns nothing
    call on_item_pickup(GetTriggerUnit(), GetManipulatedItem())
endfunction

private function init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_PICKUP_ITEM)
    call TriggerAddAction(t, function on_item_pickup_action)
endfunction

endlibrary // libitemchain

usage:

JASS:

function init_item_chains takes nothing returns nothing
    call begin_item_chain('sorf' /*can be 0*/)
        call chain_add_item('sor1')
        call chain_add_item('sor2')
        call chain_add_item('sor3')
        call chain_add_item('sor4')
        call chain_add_item('sor5')
        call chain_add_item('sor6')
        call chain_add_item('sor7')
        call chain_add_item('sor8')
        call chain_add_item('sor9')
        call chain_add_item('sora')
    call end_item_chain()

    call begin_item_chain('sg00')
        call chain_is_disabled()
        call chain_add_item('sg01')
        call chain_add_item('sg02')
        call chain_add_item('sg03')
        call chain_add_item('sg04')
        call chain_add_item('sg05')
    call end_item_chain()
endfunction

function on_unit_death takes nothing returns boolean
    local unit k = GetKillingUnit()
    local unit d = GetDyingUnit()
    local item it
    local integer item_id
    local Item_Chain chain
    local Item_Chain array searched_chains
    local integer searched_chains_len
    local integer aa
    local integer a
    local integer b
    local integer bb
    local integer res

    set searched_chains[0] = item_get_chain('sg00')
    set searched_chains[1] = item_get_chain('sorf')
    set searched_chains_len = 2

    if k == null or k == d then
        set k = null
        set d = null
        return
    endif

    set a = 0
    set aa = UnitInventorySize(k)
    loop
        set it = UnitItemInSlot(k, a)

        set chain = 0
        if it != null then
            set item_id = GetItemTypeId(it)
            set chain = item_get_chain(item_id)
        endif

        if chain != 0 then
            set bb = searched_chains_len
            set b = 0
            loop
                exitwhen b == bb

                if chain == searched_chains[b] then
                    set res = item_get_chain_val(item_id) + 1
                    if res <= chain.max_val then
                        call RemoveItem(UnitItemInSlot(k, a))
                        call UnitAddItemToSlotById(k, chain_val_get_item(chain, res), a)
                    endif
                endif

                set b = b + 1
            endloop
        endif

        set a = a + 1
    endloop

    set k = null
    set d = null
    set it = null

    return
endfunction

ItemHierarchy v1.00

ItemHierarchy (Map)

Spellbound

Spellbound

Resources

A Void

A Void

Resources

Spellbound

Spellbound

Resources

axleion

axleion

Resources

Spellbound

Spellbound

Resources

MyPad

MyPad

Resources

Nitpicks:

Notes:

Status:

Spellbound

Spellbound

Resources

MyPad

MyPad

Resources

Chaosy

Chaosy

Resources

Spellbound

Spellbound

Resources

Aniki

Aniki

Resources

Similar threads