Burning Orbit v0.06

[Moderator]

19:27, 4th Oct 2009
TriggerHappy187:

You fixed all of the leaks I mentioned. I also said I would approve this once you had done so.

 

[Rmx]

Review

Review Rules

- Idea and creativity - # / 10

- Eye Candy and Ingame Play - # / 10

- Coding - # / 20

- Description of spell - # / 5

- If Spell is MUI you get +3

-if spell is Recycled efficiently you get +2

--------------------------------------------------------------------

-

The total amount is 50

If you get 10 = FAIL

If you get 20 = Lacking

If you get 30 = Acceptable

If you get 40 = Recommended

If you get 50 = Highly ! Recommended

---------------------------------------------------------------------

Review

Idea and Creativity - 9 / 10

Eye Candy & Ingame Play - 9 / 10

Coding - 16 / 20

Description of spell - 4 / 5


Total = 38

MUI [ yes ] then 38 + 3 = 41

Spell is Recycled Efficiently [ yes ] then 41 + 2 = 43

Status is [ Recommended ]

---------------------------------------------------------------------

How To Improve

WOW i must say, the spell remind me of ATOM in chemistry but outstanding effect , creativity is very nice

rmx hope this one is more creativ .

I laughed my ass off .. when i SAW the Debug messages lol anyway ...
I didn't see you null the (unit main) just the caster ...

 

[cedi]

Structs variables are only arrays with a special name. The struct is only an integer which stays for the index of the variable. Because of that you need to write in a constant array lenght for array variables in structs. Then this value representate the offset.

For example.

struct A
integer i
integer array i2[20]
endstruct

when you create a struct it has a number for example 0.
Yet there exist an integer array variable with the name A__i or something like that. When you set i == a value wc3 sets A__i[0] == the value.
On struct variable arrays they have reserved places. A__i2[0 - 20] is reserved for the struct.
The next struct has the places 21 - 41 and so on. Because of that you can have only 8191 / constant array size structs.

The result is, all struct members are globals. And globals can't leak.

So you see, caster is a local variable == Needs to be nulled. Main is a global variable == you don't have to null it. And where is there a debug msg?

Ahh btw, I done a second version of this spell, there the splits rotate around each axes. But the performance isn't so good like this one. But when you like to see it, I can send it.

cedi

 

[Rmx]

Well i understand, this is very good info for me .

About the Debug message .. it said ( Double free something... ) don't know where it is ...

BTW forgot to give you +REP .. also could i see the other version

 

[D1000]

Double-Free is a debug message which is created by JassHelper. It appears when you destroy a struct-member twice. (And you have to run the game in debug mode)

/€: 5/5 btw

 

[Rmx]

Damn this spell is of the HOOK !!!

I wish i could give you more rep, AWESOME and Amazing spell

5/5 for sure !

But one improvement .. the Starting Ball should be changed coz it looks bad .. but the ROTATING balls are AWESOME !! and i see how you made the rotation even more AMAZING !!

This link is going into my favourites !

 

[Kricz]

Awesome spell and nice and MUCH coding^^
+Rep for that

 

[N8-11_GER]

again an awesome spell.
what u can do else? only 5/5 and rep XD

 

[xxdingo93xx]

Wow the concept of this spell is great. The only problem I have with this - it is a little bit overpowered.
But whatever, since it is easy configurable it's not a big deal ^^
I will NEVER understand all these maths-formulas .... so I won't give it a try for now
Well, this spell is awesome, I can't say more than that. 5/5 +rep from me

 

[cedi]

Hehe, thought you will like it...

cedi

 

[Vulcano]

call PauseTimer( .t )
call ReleaseTimer( .t )

You dont need to pause timer (releaseTimer does it)

 

[Deuterium]

And globals can't leak.

Not true.

Global variable COULD (and by could I mean that there's only a possibility) get recycled. Yet, that doesn't mean it can't leak.

Actually, indexed variables happen to leak if not nulled.

Why? The index would reach a max. value sometimes of - take 50 for example - and from thereon only reach 5. 45 leaks till the end of the game.

So in the end, I must tell you, null your globals (specially the indexed ones).


About the spell, nice orbiting you've got there. Yet about the idea, meh... must say not impressive.

Also, just as a nice funky idea (yeah I used the word funky ) ummm... try giving each set of those missiles a vertex coloring

I tried green, seemed nice. Go for red, green & blue.


EDIT:
& oh, try not using lightning as it looks too, umm... flat use some missile which leaves a trail and move it quickly, or make something more creative

 

[Lambdadelta]

You ruin the spell by using Chain Lightnings. The orbiting effect is really good. But it gets ruined by some "WTF BLUE LIGHTNINGS?"....

 

[Deuterium]

Exactly

 

[cedi]

Changed it, hope its better now.

cedi

 

[YourNameHere]

ok, somehow it only damages the hero now, and only very rarely with mere damage.
Other than that the spell looks pretty neat. Looked over the code a bit and didn't find any issues, the coding is efficient and nicely done. 5/5 ofc <3

 

[Deuterium]

A bit too 4th of July hehe I was excited to see my coloring idea guess I wont...

 

[bigapple90]

to be honest it seems like random effects spam. lots going on and it doesn't really do anything impressive. however i do appreciate the work you put into it

 

[cedi]

It doesn't something impresive? Because it doesn't spam 100000000000000000 importet effects? When orbiting isn't impresive for you, I guess nothing is. That thingy required a lot of work, and I think it looks cool. May change the effects to something more like a missile, and then follow the way of one missile. Notic something? Yes every missile has an orbit.

@Deuterium you can change it by yourself, I made some new constants for the color of the missile also for the alpha value. So you can create ghost which flie around the middle and attacks with souls .

cedi

 

[bigapple90]

never mind.

 

[TriggerHappy]

Some minor improvements.

• GetWidgetLife is faster than GetUnitState(GetFilterUnit(), UNIT_STATE_LIFE ).
• In your Cast method if you stored GetOwningPlayer( .split ) somewhere, it would save many function calls depending on how much units are inside the group, and how many loops are ran.
• You don't need to null timers created by TimerUtils.
• I doubt you need to set caster = null in your create method.
• Your IsSpell function leaks twice, and GetSpellTargetX/Y were introduced in 1.24, using those would prevent those location leaks.

 

[cedi]

Ahh, yes, I didn't implent GetSpellTargetX/Y then because my jasshelper didn't like it, but yet, I can change it...

cedi

 

[cedi]

Fixed all mentioned things and made structs private.

cedi

 

[TriggerHappy]

This still leaks;

private function IsSpell takes nothing returns boolean
    if GetSpellAbilityId() == SPELL_ID then
        call SF_Main.create( GetTriggerUnit(), GetLocationX( GetSpellTargetLoc() ), GetLocationY( GetSpellTargetLoc() ), 0 )
    endif
    return false
endfunction

 

[Visionzs]

Wow very nice I will try it now!

 

[Mediumunwell]

Could someone please update this to save and work for Reforged!?

 

[Bribe]

Could someone please update this to save and work for Reforged!?

From looking at the code alone, I don't see anything obvious about it that would make it not work with Reforged. What is the issue you're encountering?

 

[Mediumunwell]

From looking at the code alone, I don't see anything obvious about it that would make it not work with Reforged. What is the issue you're encountering?

O, wow been so long since I last talked to you. Happy to see you're still here.

In the test map it does not load the game and when saving I get this as an error coming from the spell trigger:

Spoiler: testmap error

And in my map the first error comes up from the Vector trigger:

Spoiler: my map error

 

[Bribe]

O, wow been so long since I last talked to you. Happy to see you're still here.

In the test map it does not load the game and when saving I get this as an error coming from the spell trigger:

Spoiler: testmap error

And in my map the first error comes up from the Vector trigger:

Spoiler: my map error

I am not able to see your pictures. Not sure how you uploaded them. Can you either paste them in plain text or use a different image host?

 

[Mediumunwell]

I am not able to see your pictures. Not sure how you uploaded them. Can you either paste them in plain text or use a different image host?

Maybe because they were in a private album? I edited that last post a few times, before getting it right I thought, also.

Capture1 | HIVE

Capture2 | HIVE

I changed the privacy, so maybe they work now?

 

[Bribe]

In that case replace the Vector script with the below and it would fix those errors:

library VectorLib

    globals
        private location loc = Location(0.0,0.0)
    endglobals

    struct vector
        real x
        real y
        real z
      
        static method create takes real x, real y, real z returns vector
            local vector v = vector.allocate()
            set v.x=x
            set v.y=y
            set v.z=z
            return v
        endmethod
      
        method getLength takes nothing returns real
          return SquareRoot(.x*.x + .y*.y + .z*.z)
        endmethod
      
        static method sum takes vector augend, vector addend returns vector
            local vector v = vector.allocate()
            set v.x = augend.x+addend.x
            set v.y = augend.y+addend.y
            set v.z = augend.z+addend.z
            return v
        endmethod
        method add takes vector addend returns nothing
            set this.x=this.x+addend.x
            set this.y=this.y+addend.y
            set this.z=this.z+addend.z
        endmethod
      
        static method difference takes vector minuend, vector subtrahend returns vector
            local vector v = vector.allocate()
            set v.x = minuend.x-subtrahend.x
            set v.y = minuend.y-subtrahend.y
            set v.z = minuend.z-subtrahend.z
            return v
        endmethod
        method subtract takes vector subtrahend returns nothing
            set this.x=this.x-subtrahend.x
            set this.y=this.y-subtrahend.y
            set this.z=this.z-subtrahend.z
        endmethod
      
        method scale takes real factor returns nothing
            set this.x=this.x*factor
            set this.y=this.y*factor
            set this.z=this.z*factor
        endmethod
      
        method setLength takes real length returns nothing
            local real l = SquareRoot(.x*.x + .y*.y + .z*.z)
            if l == 0.0 then
                debug call BJDebugMsg("Attempted to set the length of a vector with no length!")
                return
            endif
            set l = length/l
            set this.x = this.x*l
            set this.y = this.y*l
            set this.z = this.z*l
        endmethod
      
        static method dotProduct takes vector a, vector b returns real
            return (a.x*b.x+a.y*b.y+a.z*b.z)
        endmethod
      
        static method crossProduct takes vector a, vector b returns vector
            local vector v = vector.allocate()
            set v.x = a.y*b.z - a.z*b.y
            set v.y = a.z*b.x - a.x*b.z
            set v.z = a.x*b.y - a.y*b.x
            return v
        endmethod
      
        static method projectionVector takes vector projected, vector direction returns vector
            local vector v = vector.allocate()
            local real l = direction.x*direction.x+direction.y*direction.y+direction.z*direction.z
            if l == 0.0 then
                call v.destroy()
                debug call BJDebugMsg("Attempted to project onto a vector with no length!")
                return 0
            endif
            set l = (projected.x*direction.x+projected.y*direction.y+projected.z*direction.z) / l
            set v.x = direction.x*l
            set v.y = direction.y*l
            set v.z = direction.z*l
            return v
        endmethod
        method projectVector takes vector direction returns nothing
            local real l = direction.x*direction.x+direction.y*direction.y+direction.z*direction.z
            if l == 0.0 then
                debug call BJDebugMsg("Attempted to project onto a vector with no length!")
                return
            endif
            set l = (this.x*direction.x+this.y*direction.y+this.z*direction.z) / l
            set this.x = direction.x*l
            set this.y = direction.y*l
            set this.z = direction.z*l
        endmethod

        static method projectionPlane takes vector projected, vector normal returns vector
            local vector v = vector.allocate()
            local real l = normal.x*normal.x+normal.y*normal.y+normal.z*normal.z
            if l == 0.0 then
                call v.destroy()
                debug call BJDebugMsg("Attempted to project onto an undefined plane!")
                return 0
            endif
            set l = (projected.x*normal.x+projected.y*normal.y+projected.z*normal.z) / l
            set v.x = projected.x - normal.x*l
            set v.y = projected.y - normal.y*l
            set v.z = projected.z - normal.z*l
            return v
        endmethod
        method projectPlane takes vector normal returns nothing
            local real l = normal.x*normal.x+normal.y*normal.y+normal.z*normal.z
            if l == 0.0 then
                debug call BJDebugMsg("Attempted to project onto an undefined plane!")
                return
            endif
            set l = (this.x*normal.x+this.y*normal.y+this.z*normal.z) / l
            set this.x = this.x - normal.x*l
            set this.y = this.y - normal.y*l
            set this.z = this.z - normal.z*l
        endmethod

        static method getAngle takes vector a, vector b returns real
            local real l = SquareRoot(a.x*a.x + a.y*a.y + a.z*a.z)*SquareRoot(b.x*b.x + b.y*b.y + b.z*b.z)
            if l == 0 then
                debug call BJDebugMsg("Attempted to get angle between vectors with no length!")
                return 0.0
            endif
            return Acos((a.x*b.x+a.y*b.y+a.z*b.z)/l) //angle is returned in radians
        endmethod
      
        method rotate takes vector axis, real angle returns nothing //angle is taken in radians
            local real xx
            local real xy
            local real xz
            local real yx
            local real yy
            local real yz
            local real zx
            local real zy
            local real zz
            local real al = axis.x*axis.x+axis.y*axis.y+axis.z*axis.z //axis length^2
            local real f
            local real c = Cos(angle)
            local real s = Sin(angle)
            if al == 0.0 then
                debug call BJDebugMsg("Attempted to project onto a vector with no length!")
                return
            endif
            set f = (this.x*axis.x+this.y*axis.y+this.z*axis.z) / al
            set zx = axis.x*f
            set zy = axis.y*f
            set zz = axis.z*f //axis component of rotated vector
            set xx = this.x-zx
            set xy = this.y-zy
            set xz = this.z-zz //component of vector perpendicular to axis
            set al = SquareRoot(al)
            set yx = (axis.y*xz - axis.z*xy)/al
            set yy = (axis.z*xx - axis.x*xz)/al //y same length as x by using cross product and dividing with axis length
            set yz = (axis.x*xy - axis.y*xx)/al //x,y - coordinate system in which we rotate
            set this.x=xx*c+yx*s+zx
            set this.y=xy*c+yy*s+zy
            set this.z=xz*c+yz*s+zz
        endmethod
      
        static method createTerrainPoint takes real x, real y returns vector
            local vector v = vector.allocate()
            call MoveLocation(loc,x,y)
            set v.x=x
            set v.y=y
            set v.z=GetLocationZ(loc)
            return v
        endmethod
        method getTerrainPoint takes real x, real y returns nothing
            call MoveLocation(loc,x,y)
            set this.x=x
            set this.y=y
            set this.z=GetLocationZ(loc)
        endmethod

        static method createTerrainNormal takes real x, real y, real sampleRadius returns vector
            local vector v = vector.allocate()
            local real z1
            local real z2
            local real z3
            local real z4
            call MoveLocation(loc, x-sampleRadius, y)
            set z1=GetLocationZ(loc)
            call MoveLocation(loc, x+sampleRadius, y)
            set z2=GetLocationZ(loc)
            call MoveLocation(loc, x, y-sampleRadius)
            set z3=GetLocationZ(loc)
            call MoveLocation(loc, x, y+sampleRadius)
            set z4=GetLocationZ(loc)
            set sampleRadius=2*sampleRadius
            set v.x = (z1-z2)*sampleRadius
            set v.y = (z3-z4)*sampleRadius
            set v.z = sampleRadius*sampleRadius
            return v
        endmethod
        method getTerrainNormal takes real x, real y, real sampleRadius returns nothing
            local real z1
            local real z2
            local real z3
            local real z4
            call MoveLocation(loc, x-sampleRadius, y)
            set z1=GetLocationZ(loc)
            call MoveLocation(loc, x+sampleRadius, y)
            set z2=GetLocationZ(loc)
            call MoveLocation(loc, x, y-sampleRadius)
            set z3=GetLocationZ(loc)
            call MoveLocation(loc, x, y+sampleRadius)
            set z4=GetLocationZ(loc)
            set sampleRadius=2*sampleRadius
            set this.x = (z1-z2)*sampleRadius
            set this.y = (z3-z4)*sampleRadius
            set this.z = sampleRadius*sampleRadius
        endmethod

        method isInCylinder takes vector cylinderOrigin, vector cylinderHeight, real cylinderRadius returns boolean
            local real l

            local real x = this.x-cylinderOrigin.x
            local real y = this.y-cylinderOrigin.y
            local real z = this.z-cylinderOrigin.z
            if x*cylinderHeight.x+y*cylinderHeight.y+z*cylinderHeight.z < 0.0 then //point below cylinder
                return false
            endif
          
            set x = x-cylinderHeight.x
            set y = y-cylinderHeight.y
            set z = z-cylinderHeight.z
            if x*cylinderHeight.x+y*cylinderHeight.y+z*cylinderHeight.z > 0.0 then //point above cylinder
                return false
            endif
          
            set l = cylinderHeight.x*cylinderHeight.x+cylinderHeight.y*cylinderHeight.y+cylinderHeight.z*cylinderHeight.z
            if l == 0.0 then
                debug call BJDebugMsg("Cylinder with no height!")
                return false
            endif
            set l = (x*cylinderHeight.x+y*cylinderHeight.y+z*cylinderHeight.z) / l
            set x = x - cylinderHeight.x*l
            set y = y - cylinderHeight.y*l
            set z = z - cylinderHeight.z*l
            if x*x+y*y+z*z > cylinderRadius*cylinderRadius then //point outside cylinder
                return false
            endif
          
            return true
        endmethod

        method isInCone takes vector coneOrigin, vector coneHeight, real coneRadius returns boolean
            local real l

            local real x = this.x-coneOrigin.x
            local real y = this.y-coneOrigin.y
            local real z = this.z-coneOrigin.z
            if x*coneHeight.x+y*coneHeight.y+z*coneHeight.z < 0.0 then //point below cone
                return false
            endif
          
            set l = coneHeight.x*coneHeight.x+coneHeight.y*coneHeight.y+coneHeight.z*coneHeight.z
            if l == 0.0 then
                debug call BJDebugMsg("cone with no height!")
                return false
            endif
            set l = (x*coneHeight.x+y*coneHeight.y+z*coneHeight.z) / l
            set x = x - coneHeight.x*l
            set y = y - coneHeight.y*l
            set z = z - coneHeight.z*l
            if SquareRoot(x*x+y*y+z*z) > coneRadius*(1.0-l) then //point outside cone
                return false
            endif
          
            return true
        endmethod

        method isInSphere takes vector sphereOrigin, real sphereRadius returns boolean
            if sphereRadius*sphereRadius < ((this.x-sphereOrigin.x)*(this.x-sphereOrigin.x)+(this.y-sphereOrigin.y)*(this.y-sphereOrigin.y)+(this.z-sphereOrigin.z)*(this.z-sphereOrigin.z)) then
                return false
            endif
            return true
        endmethod
    endstruct

endlibrary

 

[Mediumunwell]

Oh my god! It works! And it is so beautiful in reforged! Thank you so much! My Merlin has his ultimate again