PreventSave

[TriggerHappy]

Introduction

This library is simple enough. It allows you to enable or disabled game saving. It works by showing a dialog instantly before a game is saved. This closes the save screen therefor the game is never actually saved. Nothing visually happens to the game except for maybe a quick open and close of the save dialog, though it's hardly noticeable.

This even works in single player surprisngly without pausing the game which usually happens when a dialog is opened offline. You can toggle allowing or disallowing saving by setting GameAllowSave to true, or false.

Code

//====================================
// PreventSave
//====================================
//
//   This library is simple enough. It allows you to enable or
//   disabled game saving. It works by showing a dialog instantly
//   before a game is saved. This closes the save screen therefor
//   the game is never actually saved.
//
//   Nothing visually happens to the game except for maybe a quick open
//   and close of the save dialog, though it's hardly noticeable.
//   This even works in single player surprisngly without pausing the game
//   which usually happens when a dialog is opened offline.
//
//   You can toggle allowing or disallowing saving by setting
//   GameAllowSave to true, or false.
//
//====================================
// Import Instructions
//====================================
//
//   1. Copy this entire script.
//   2. Create a new trigger in your trigger
//      editor and convert it to Jass.
//   3. Paste this in there and save the map.
//
//      This requires JassHelper which is included
//      in JassNewGenPack.
//
//====================================

library PreventSave initializer onInit
    
    globals
        boolean GameAllowSave = false
    endglobals
    
//====================================
// Do not edit below this line
//====================================
    
    globals
        private dialog D = DialogCreate()
        private timer T  = CreateTimer()
        private player p
    endglobals
    
    private function Exit takes nothing returns nothing
        call DialogDisplay(p, D, false)
    endfunction
    
    private function StopSave takes nothing returns nothing
        if not GameAllowSave then
            call DialogDisplay(p, D, true)
            call TimerStart(T, 0.00, false, function Exit)
        endif
    endfunction
    
    private function onInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterGameEvent(t, EVENT_GAME_SAVE)
        call TriggerAddAction(t, function StopSave)
        set p = GetLocalPlayer()
    endfunction

endlibrary

[azlier]

Efficient, and well tested. I myself can verify that it works on both single player and online.

Approved.

[Mooglefrooglian]

Every map should have an option to use this, to prevent laming.

Thank you!

Edit: Wait... why are you setting a global variable to GetLocalPlayer()? I'm pretty sure that desyncs.

library PreventSave initializer onInit

    globals
        boolean GameAllowSave = false
    endglobals

//====================================
// Do not edit below this line
//====================================

    globals
        private dialog D = DialogCreate()
        private timer T = CreateTimer()
    endglobals

    private function Exit takes nothing returns nothing
        call DialogDisplay(GetLocalPlayer(), D, false)
    endfunction

    private function StopSave takes nothing returns nothing
        if not GameAllowSave then
            call DialogDisplay(GetLocalPlayer(), D, true)
            call TimerStart(T, 0.00, false, function Exit)
        endif
    endfunction

    private function onInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterGameEvent(t, EVENT_GAME_SAVE)
        call TriggerAddAction(t, function StopSave)
    endfunction

endlibrary

Shouldnt it be like that?

[azlier]

No. Setting a global to the local player works just fine.

[Mooglefrooglian]

But dont globals sync, and having them different cause a desync?

Is it just when you try to use that data?

[azlier]

Globals are not synced.

[kennyman94]

I have no clue about what you guys are talking about but what version of jass is this for?

[TriggerHappy]

Do you mean vJass? Blizzard doesn't give Jass patch versions it's just Jass2. If you do mean vJass, just get the newest Jasshelper or download the GUI one in the spells section (check my profile).

[kennyman94]

I mean like i just got JNGP and i dont know if different editor versions use different forms of jass.

[cookies4you]

finally! i've been looking for something to prevent this! finally! a way to stop seekers from saving and exploiting moving props!